helm/DEVEL/ocaml-http/http_parser.ml

   1
   2 (*
   3   OCaml HTTP - do it yourself (fully OCaml) HTTP daemon
   4
   5   Copyright (C) <2002> Stefano Zacchiroli <zack@cs.unibo.it>
   6
   7   This program is free software; you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation; either version 2 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program; if not, write to the Free Software
  19   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20 *)
  21
  22 open Neturl;;
  23 open Printf;;
  24
  25 exception Malformed_query of string
  26 exception Malformed_query_binding of string * string
  27 exception Unsupported_method of string
  28 exception Unsupported_HTTP_version of string
  29 exception Malformed_request_URI of string
  30 exception Malformed_request of string
  31
  32 (*
  33 type url_syntax_option =
  34     Url_part_not_recognized
  35   | Url_part_allowed
  36   | Url_part_required
  37
  38 * (1) scheme://user:password@host:port/path;params?query#fragment
  39 *)
  40
  41 let request_uri_syntax = {
  42   url_enable_scheme    = Url_part_not_recognized;
  43   url_enable_user      = Url_part_not_recognized;
  44   url_enable_password  = Url_part_not_recognized;
  45   url_enable_host      = Url_part_not_recognized;
  46   url_enable_port      = Url_part_not_recognized;
  47   url_enable_path      = Url_part_required;
  48   url_enable_param     = Url_part_not_recognized;
  49   url_enable_query     = Url_part_allowed;
  50   url_enable_fragment  = Url_part_not_recognized;
  51   url_enable_other     = Url_part_not_recognized;
  52   url_accepts_8bits    = false;
  53   url_is_valid         = (fun _ -> true);
  54 }
  55
  56   (** given a list of length 2
  57   @return a pair formed by the elements of the list
  58   @raise Assert_failure if the list length isn't 2
  59   *)
  60 let pair_of_2_sized_list = function
  61   | [a;b] -> (a,b)
  62   | _ -> assert false
  63
  64   (** given an HTTP like query string (e.g. "name1=value1&name2=value2&...")
  65   @return a list of pairs [("name1", "value1"); ("name2", "value2")]
  66   @raise Malformed_query if the string isn't a valid query string
  67   @raise Malformed_query_binding if some piece of the query isn't valid
  68   *)
  69 let split_query_params =
  70   let (bindings_sep, binding_sep) = (Pcre.regexp "&", Pcre.regexp "=") in
  71   fun ~query ->
  72     let bindings = Pcre.split ~rex:bindings_sep query in
  73     if List.length bindings < 1 then
  74       raise (Malformed_query query);
  75     List.map
  76       (fun binding ->
  77         let pieces = Pcre.split ~rex:binding_sep binding in
  78         if List.length pieces <> 2 then
  79           raise (Malformed_query_binding (binding, query));
  80         pair_of_2_sized_list pieces)
  81       bindings
  82
  83   (** given an input channel and a separator
  84   @return a line read from it (like Pervasives.input_line)
  85   line is returned only after reading a separator string; separator string isn't
  86   included in the returned value
  87   FIXME what about efficiency?, input is performed char-by-char
  88   *)
  89 let generic_input_line ~sep ~ic =
  90   let sep_len = String.length sep in
  91   if sep_len < 1 then
  92     failwith ("Separator '" ^ sep ^ "' is too short!")
  93   else  (* valid separator *)
  94     let line = ref "" in
  95     let sep_pointer = ref 0 in
  96     try
  97       while true do
  98         if !sep_pointer >= String.length sep then (* line completed *)
  99           raise End_of_file
 100         else begin (* incomplete line: need to read more *)
 101           let ch = input_char ic in
 102           if ch = String.get sep !sep_pointer then  (* next piece of sep *)
 103             incr sep_pointer
 104           else begin  (* useful char *)
 105             for i = 0 to !sep_pointer - 1 do
 106               line := !line ^ (String.make 1 (String.get sep i))
 107             done;
 108             sep_pointer := 0;
 109             line := !line ^ (String.make 1 ch)
 110           end
 111         end
 112       done;
 113       assert false  (* unreacheable statement *)
 114     with End_of_file ->
 115       if !line = "" then
 116         raise End_of_file
 117       else
 118         !line
 119
 120   (** given an input channel, reads from it a GET HTTP request and
 121   @return a pair <path, query_params> where path is a string representing the
 122   requested path and query_params is a list of pairs <name, value> (the GET
 123   parameters)
 124   *)
 125 let parse_request =
 126   let patch_empty_path s = (if s = "" then "/" else s) in
 127   let pieces_sep = Pcre.regexp " " in
 128   fun ic ->
 129     let request_line = generic_input_line ~sep:Http_common.crlf ~ic in
 130     match Pcre.split ~rex:pieces_sep request_line with
 131     | [meth; request_uri_raw; http_version] ->
 132         if meth <> "GET" then
 133           raise (Unsupported_method meth);
 134         (match http_version with
 135         | "HTTP/1.0" | "HTTP/1.1" -> ()
 136         | _ -> raise (Unsupported_HTTP_version http_version));
 137         let request_uri =
 138           try
 139             url_of_string request_uri_syntax request_uri_raw
 140           with Malformed_URL ->
 141             raise (Malformed_request_URI request_uri_raw)
 142         in
 143         let path =
 144           patch_empty_path (String.concat "/" (url_path request_uri))
 145         in
 146         let query_params =
 147           try split_query_params (url_query request_uri) with Not_found -> []
 148         in
 149         Http_common.debug_print
 150           (sprintf
 151             "recevied request; path: %s; params: %s"
 152             path
 153             (String.concat
 154               ", "
 155               (List.map (fun (n, v) -> n ^ "=" ^ v) query_params)));
 156         (path, query_params)
 157     | _ -> raise (Malformed_request request_line)
 158