helm/http_getter/http_getter_misc.ml

   1 (*
   2  *  Copyright (C) 2000, HELM Team.
   3  *
   4  *  This file is part of HELM, an Hypertextual, Electronic
   5  *  Library of Mathematics, developed at the Computer Science
   6  *  Department, University of Bologna, Italy.
   7  *
   8  *  HELM is free software; you can redistribute it and/or
   9  *  modify it under the terms of the GNU General Public License
  10  *  as published by the Free Software Foundation; either version 2
  11  *  of the License, or (at your option) any later version.
  12  *
  13  *  HELM is distributed in the hope that it will be useful,
  14  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  *  GNU General Public License for more details.
  17  *
  18  *  You should have received a copy of the GNU General Public License
  19  *  along with HELM; if not, write to the Free Software
  20  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21  *  MA  02111-1307, USA.
  22  *
  23  *  For details, see the HELM World-Wide-Web page,
  24  *  http://cs.unibo.it/helm/.
  25  *)
  26
  27 open Http_getter_debugger;;
  28 open Printf;;
  29
  30 let fold_file f init fname =
  31   let inchan = open_in fname in
  32   let rec fold_lines' value =
  33     try
  34       let line = input_line inchan in
  35       fold_lines' (f value line)
  36     with End_of_file -> value
  37   in
  38   let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  39   close_in inchan;
  40   res
  41 let iter_file f = fold_file (fun _ line -> f line) ()
  42
  43 let hashtbl_sorted_fold f tbl init =
  44   let sorted_keys =
  45     List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  46   in
  47   List.fold_left (fun acc k -> f k (Hashtbl.find tbl k) acc) init sorted_keys
  48
  49 let wget ?output url =
  50   let flags =
  51     (match output with Some file -> ["-O"; file] | None -> []) @ [url]
  52   in
  53   debug_print ("wget " ^ String.concat " " flags);
  54   Shell.call
  55     ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
  56     [Shell.cmd "wget" flags]
  57
  58   (* stderr shown as usual *)
  59 let gzip ?(keep = false) fname =
  60   if keep then begin  (* keep original file *)
  61     debug_print ("gzip -f -c " ^ fname);
  62     Shell.call
  63       ~stdout:(Shell.to_file (fname ^ ".gz"))
  64       [Shell.cmd "gzip" ["-f"; "-c"; fname]]
  65   end else begin  (* don't keep original file *)
  66     debug_print ("gzip -f " ^ fname);
  67     Shell.call [Shell.cmd "gzip" ["-f"; fname]]
  68   end
  69
  70   (* stderr shown as usual *)
  71 let gunzip ?(keep = false) fname =
  72   if not (Pcre.pmatch ~pat:"\\.gz$" fname) then
  73     failwith "gunzip: source file doesn't end with '.gz'";
  74   let basename = Pcre.replace ~pat:"\\.gz$" fname in
  75   if keep then begin  (* keep original file *)
  76     debug_print ("gunzip -f -c " ^ fname);
  77     Shell.call
  78       ~stdout:(Shell.to_file basename)
  79       [Shell.cmd "gunzip" ["-f"; "-c"; fname]]
  80   end else begin  (* don't keep original file *)
  81     debug_print ("gunzip -f " ^ fname);
  82     Shell.call [Shell.cmd "gunzip" ["-f"; fname]]
  83   end
  84
  85 let tempfile () =
  86   let buf = Buffer.create 28 in (* strlen("/tmp/fileSzb3Mw_http_getter") *)
  87   Shell.call
  88     ~stdout:(Shell.to_buffer buf)
  89     [Shell.cmd "tempfile" ["--suffix=_http_getter"]];
  90   Pcre.replace ~pat:"\n" (Buffer.contents buf)
  91
  92 let mkdir ?(parents = false) dirname =
  93   if not (Sys.file_exists dirname) then begin
  94     let flags = if parents then ["-p"; dirname] else [dirname] in
  95     debug_print ("mkdir " ^ String.concat " " flags);
  96     Shell.call [Shell.cmd "mkdir" flags]
  97   end
  98
  99 let string_of_proc_status = function
 100   | Unix.WEXITED code -> sprintf "[Exited: %d]" code
 101   | Unix.WSIGNALED sg -> sprintf "[Killed: %d]" sg
 102   | Unix.WSTOPPED sg -> sprintf "[Stopped: %d]" sg
 103
 104 let http_get url =
 105   try
 106     Some (Http_client.Convenience.http_get url)
 107   with Http_client.Http_error (code, _) -> None
 108