helm/http_getter/http_getter_misc.ml

   1 (*
   2  * Copyright (C) 2003:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 open Http_getter_debugger;;
  30 open Printf;;
  31
  32 let fold_file f init fname =
  33   let inchan = open_in fname in
  34   let rec fold_lines' value =
  35     try
  36       let line = input_line inchan in
  37       fold_lines' (f value line)
  38     with End_of_file -> value
  39   in
  40   let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  41   close_in inchan;
  42   res
  43 let iter_file f = fold_file (fun _ line -> f line) ()
  44
  45 let hashtbl_sorted_fold f tbl init =
  46   let sorted_keys =
  47     List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  48   in
  49   List.fold_left (fun acc k -> f k (Hashtbl.find tbl k) acc) init sorted_keys
  50
  51 let cp src dst =
  52   Shell.call
  53     ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
  54     [Shell.cmd "cp" [src; dst]]
  55
  56 let file_scheme_RE = Pcre.regexp "^file://"
  57 let wget ?output url =
  58   let use_wget () =
  59     let flags =
  60       (match output with Some file -> ["-O"; file] | None -> []) @ [url]
  61     in
  62     debug_print ("wget " ^ String.concat " " flags);
  63     Shell.call
  64       ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
  65       [Shell.cmd "wget" flags]
  66   in
  67   if Pcre.pmatch ~rex:file_scheme_RE url then begin (* file:// URL *)
  68     let src_fname = Pcre.replace ~rex:file_scheme_RE url in
  69     match output with
  70     | Some dst_fname -> cp src_fname dst_fname
  71     | None ->
  72         let dst_fname = Filename.basename src_fname in
  73         if src_fname <> dst_fname then
  74           cp src_fname dst_fname
  75         else  (* src and dst are the same: do nothing *)
  76           ()
  77   end else  (* other URL, pass it to wget *)
  78     use_wget ()
  79
  80 let bufsiz = 16384
  81 let gzip ?(keep = false) fname =
  82   let (ic, oc) = (open_in fname, Gzip.open_out (fname ^ ".gz")) in
  83   let buf = String.create bufsiz in
  84   (try
  85     while true do
  86       let bytes = input ic buf 0 bufsiz in
  87       if bytes = 0 then raise End_of_file else Gzip.output oc buf 0 bytes
  88     done
  89   with End_of_file -> ());
  90   close_in ic;
  91   Gzip.close_out oc;
  92   if not keep then Sys.remove fname
  93
  94 let trailing_dot_gz_RE = Pcre.regexp "\\.gz$"
  95 let gunzip ?(keep = false) fname =
  96   let basename = Pcre.replace ~rex:trailing_dot_gz_RE fname in
  97   assert (basename <> fname);
  98   let (ic, oc) = (Gzip.open_in fname, open_out basename) in
  99   let buf = String.create bufsiz in
 100   (try
 101     while true do
 102       let bytes = Gzip.input ic buf 0 bufsiz in
 103       if bytes = 0 then raise End_of_file else output oc buf 0 bytes
 104     done
 105   with End_of_file -> ());
 106   Gzip.close_in ic;
 107   close_out oc;
 108   if not keep then Sys.remove fname
 109
 110 let tempfile () =
 111   let buf = Buffer.create 28 in (* strlen("/tmp/fileSzb3Mw_http_getter") *)
 112   Shell.call
 113     ~stdout:(Shell.to_buffer buf)
 114     [Shell.cmd "tempfile" ["--suffix=_http_getter"]];
 115   Pcre.replace ~pat:"\n" (Buffer.contents buf)
 116
 117 let mkdir ?(parents = false) dirname =
 118   if not (Sys.file_exists dirname) then begin
 119     let flags = if parents then ["-p"; dirname] else [dirname] in
 120     debug_print ("mkdir " ^ String.concat " " flags);
 121     Shell.call [Shell.cmd "mkdir" flags]
 122   end
 123
 124 let string_of_proc_status = function
 125   | Unix.WEXITED code -> sprintf "[Exited: %d]" code
 126   | Unix.WSIGNALED sg -> sprintf "[Killed: %d]" sg
 127   | Unix.WSTOPPED sg -> sprintf "[Stopped: %d]" sg
 128
 129 let http_get url =
 130   if Pcre.pmatch ~rex:file_scheme_RE url then begin
 131       (* file:// URL. Read data from file system *)
 132     let fname = Pcre.replace ~rex:file_scheme_RE url in
 133     try
 134       let size = (Unix.stat fname).Unix.st_size in
 135       let buf = String.create size in
 136       let ic = open_in fname in
 137       really_input ic buf 0 size;
 138       close_in ic;
 139       Some buf
 140     with Unix.Unix_error (Unix.ENOENT, "stat", _) -> None
 141   end else  (* other URL, pass it to netclient *)
 142     try
 143       Some (Http_client.Convenience.http_get url)
 144     with Http_client.Http_error (code, _) -> None
 145