helm/http_getter/http_getter_misc.ml

   1 (*
   2  * Copyright (C) 2003:
   3  *    Stefano Zacchiroli <zack@cs.unibo.it>
   4  *    for the HELM Team http://helm.cs.unibo.it/
   5  *
   6  *  This file is part of HELM, an Hypertextual, Electronic
   7  *  Library of Mathematics, developed at the Computer Science
   8  *  Department, University of Bologna, Italy.
   9  *
  10  *  HELM is free software; you can redistribute it and/or
  11  *  modify it under the terms of the GNU General Public License
  12  *  as published by the Free Software Foundation; either version 2
  13  *  of the License, or (at your option) any later version.
  14  *
  15  *  HELM is distributed in the hope that it will be useful,
  16  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  *  GNU General Public License for more details.
  19  *
  20  *  You should have received a copy of the GNU General Public License
  21  *  along with HELM; if not, write to the Free Software
  22  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  23  *  MA  02111-1307, USA.
  24  *
  25  *  For details, see the HELM World-Wide-Web page,
  26  *  http://helm.cs.unibo.it/
  27  *)
  28
  29 open Http_getter_debugger;;
  30 open Printf;;
  31
  32 let trailing_dot_gz_RE = Pcre.regexp "\\.gz$"   (* for g{,un}zip *)
  33 let url_RE = Pcre.regexp "^([\\w.]+)(:(\\d+))?(/.*)?$"
  34 let http_scheme_RE = Pcre.regexp ~flags:[`CASELESS] "^http://"
  35 let file_scheme_RE = Pcre.regexp ~flags:[`CASELESS] "^file://"
  36 let dir_sep_RE = Pcre.regexp "/"
  37 let heading_slash_RE = Pcre.regexp "^/"
  38
  39 let bufsiz = 16384  (* for file system I/O *)
  40 let tcp_bufsiz = 4096 (* for TCP I/O *)
  41
  42 let fold_file f init fname =
  43   let inchan = open_in fname in
  44   let rec fold_lines' value =
  45     try
  46       let line = input_line inchan in
  47       fold_lines' (f value line)
  48     with End_of_file -> value
  49   in
  50   let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  51   close_in inchan;
  52   res
  53 let iter_file f = fold_file (fun _ line -> f line) ()
  54
  55 let hashtbl_sorted_fold f tbl init =
  56   let sorted_keys =
  57     List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  58   in
  59   List.fold_left (fun acc k -> f k (Hashtbl.find tbl k) acc) init sorted_keys
  60
  61 let cp src dst =
  62   let (ic, oc) = (open_in src, open_out dst) in
  63   let buf = String.create bufsiz in
  64   (try
  65     while true do
  66       let bytes = input ic buf 0 bufsiz in
  67       if bytes = 0 then raise End_of_file else output oc buf 0 bytes
  68     done
  69   with End_of_file -> ());
  70   close_in ic; close_out oc
  71
  72 let parse_url url =
  73   try
  74     let subs =
  75       Pcre.extract ~rex:url_RE (Pcre.replace ~rex:http_scheme_RE url)
  76     in
  77     (subs.(1),
  78     (if subs.(2) = "" then 80 else int_of_string subs.(3)),
  79     (if subs.(4) = "" then "/" else subs.(4)))
  80   with exc ->
  81     failwith
  82       (sprintf "Can't parse url: %s (exception: %s)"
  83         url (Printexc.to_string exc))
  84 let init_socket addr port =
  85   let inet_addr = (Unix.gethostbyname addr).Unix.h_addr_list.(0) in
  86   let sockaddr = Unix.ADDR_INET (inet_addr, port) in
  87   let suck = Unix.socket Unix.PF_INET Unix.SOCK_STREAM 0 in
  88   Unix.connect suck sockaddr;
  89   let outchan = Unix.out_channel_of_descr suck in
  90   let inchan = Unix.in_channel_of_descr suck in
  91   (inchan, outchan)
  92 let http_get_iter_buf ~callback url =
  93   let (address, port, path) = parse_url url in
  94   let buf = String.create tcp_bufsiz in
  95   let (inchan, outchan) = init_socket address port in
  96   output_string outchan (sprintf "GET %s\r\n" path);
  97   flush outchan;
  98   (try
  99     while true do
 100       match input inchan buf 0 tcp_bufsiz with
 101       | 0 -> raise End_of_file
 102       | bytes when bytes = tcp_bufsiz ->  (* buffer full, no need to slice it *)
 103           callback buf
 104       | bytes when bytes < tcp_bufsiz ->  (* buffer not full, slice it *)
 105           callback (String.sub buf 0 bytes)
 106       | _ -> (* ( bytes < 0 ) || ( bytes > tcp_bufsiz ) *)
 107           assert false
 108     done
 109   with End_of_file -> ());
 110   close_in inchan (* close also outchan, same fd *)
 111
 112 let wget ?output url =
 113   match url with
 114   | url when Pcre.pmatch ~rex:file_scheme_RE url -> (* file:// *)
 115       (let src_fname = Pcre.replace ~rex:file_scheme_RE url in
 116       match output with
 117       | Some dst_fname -> cp src_fname dst_fname
 118       | None ->
 119           let dst_fname = Filename.basename src_fname in
 120           if src_fname <> dst_fname then
 121             cp src_fname dst_fname
 122           else  (* src and dst are the same: do nothing *)
 123             ())
 124   | url when Pcre.pmatch ~rex:http_scheme_RE url -> (* http:// *)
 125       (let oc =
 126         open_out (match output with Some f -> f | None -> Filename.basename url)
 127       in
 128       http_get_iter_buf ~callback:(fun data -> output_string oc data) url;
 129       close_out oc)
 130   | scheme -> (* unsupported scheme *)
 131       failwith ("Http_getter_misc.wget: unsupported scheme: " ^ scheme)
 132
 133 let gzip ?(keep = false) fname =
 134   debug_print (sprintf "gzipping %s (keep: %b)" fname keep);
 135   let (ic, oc) = (open_in fname, Gzip.open_out (fname ^ ".gz")) in
 136   let buf = String.create bufsiz in
 137   (try
 138     while true do
 139       let bytes = input ic buf 0 bufsiz in
 140       if bytes = 0 then raise End_of_file else Gzip.output oc buf 0 bytes
 141     done
 142   with End_of_file -> ());
 143   close_in ic; Gzip.close_out oc;
 144   if not keep then Sys.remove fname
 145
 146 let gunzip ?(keep = false) fname =
 147   debug_print (sprintf "gunzipping %s (keep: %b)" fname keep);
 148   let basename = Pcre.replace ~rex:trailing_dot_gz_RE fname in
 149   assert (basename <> fname);
 150   let (ic, oc) = (Gzip.open_in fname, open_out basename) in
 151   let buf = String.create bufsiz in
 152   (try
 153     while true do
 154       let bytes = Gzip.input ic buf 0 bufsiz in
 155       if bytes = 0 then raise End_of_file else output oc buf 0 bytes
 156     done
 157   with End_of_file -> ());
 158   Gzip.close_in ic; close_out oc;
 159   if not keep then Sys.remove fname
 160
 161 let tempfile () = Filename.temp_file "http_getter_" ""
 162
 163 exception Mkdir_failure of string * string;;  (* dirname, failure reason *)
 164 let dir_perm = 0o755
 165
 166 let mkdir ?(parents = false) dirname =
 167   let mkdirhier () =
 168     let (pieces, hd) =
 169       let split = Pcre.split ~rex:dir_sep_RE dirname in
 170       if Pcre.pmatch ~rex:heading_slash_RE dirname then
 171         (List.tl split, "/")
 172       else
 173         (split, "")
 174     in
 175     ignore
 176       (List.fold_left
 177         (fun pre dir ->
 178           let next_dir =
 179             sprintf "%s%s%s" pre (match pre with "/" | "" -> "" | _ -> "/") dir
 180           in
 181           (try
 182             (match (Unix.stat next_dir).Unix.st_kind with
 183             | Unix.S_DIR -> ()  (* dir component already exists, go on! *)
 184             | _ ->  (* dir component already exists but isn't a dir, abort! *)
 185                 raise
 186                   (Mkdir_failure (dirname,
 187                     sprintf "'%s' already exists but is not a dir" next_dir)))
 188           with Unix.Unix_error (Unix.ENOENT, "stat", _) ->
 189             (* dir component doesn't exists, create it and go on! *)
 190             Unix.mkdir next_dir dir_perm);
 191           next_dir)
 192         hd pieces)
 193   in
 194   if parents then mkdirhier () else Unix.mkdir dirname dir_perm
 195
 196 let string_of_proc_status = function
 197   | Unix.WEXITED code -> sprintf "[Exited: %d]" code
 198   | Unix.WSIGNALED sg -> sprintf "[Killed: %d]" sg
 199   | Unix.WSTOPPED sg -> sprintf "[Stopped: %d]" sg
 200
 201 let http_get url =
 202   if Pcre.pmatch ~rex:file_scheme_RE url then begin
 203       (* file:// URL. Read data from file system *)
 204     let fname = Pcre.replace ~rex:file_scheme_RE url in
 205     try
 206       let size = (Unix.stat fname).Unix.st_size in
 207       let buf = String.create size in
 208       let ic = open_in fname in
 209       really_input ic buf 0 size;
 210       close_in ic;
 211       Some buf
 212     with Unix.Unix_error (Unix.ENOENT, "stat", _) -> None
 213   end else  (* other URL, pass it to netclient *)
 214     try
 215       Some (Http_client.Convenience.http_get url)
 216     with Http_client.Http_error (code, _) -> None
 217