helm/http_getter/http_getter_misc.ml

   1 (*
   2  *  Copyright (C) 2003, HELM Team.
   3  *
   4  *  This file is part of HELM, an Hypertextual, Electronic
   5  *  Library of Mathematics, developed at the Computer Science
   6  *  Department, University of Bologna, Italy.
   7  *
   8  *  HELM is free software; you can redistribute it and/or
   9  *  modify it under the terms of the GNU General Public License
  10  *  as published by the Free Software Foundation; either version 2
  11  *  of the License, or (at your option) any later version.
  12  *
  13  *  HELM is distributed in the hope that it will be useful,
  14  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  *  GNU General Public License for more details.
  17  *
  18  *  You should have received a copy of the GNU General Public License
  19  *  along with HELM; if not, write to the Free Software
  20  *  Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21  *  MA  02111-1307, USA.
  22  *
  23  *  For details, see the HELM World-Wide-Web page,
  24  *  http://cs.unibo.it/helm/.
  25  *)
  26
  27 open Http_getter_debugger;;
  28 open Printf;;
  29
  30 let fold_file f init fname =
  31   let inchan = open_in fname in
  32   let rec fold_lines' value =
  33     try
  34       let line = input_line inchan in
  35       fold_lines' (f value line)
  36     with End_of_file -> value
  37   in
  38   let res = (try fold_lines' init with e -> (close_in inchan; raise e)) in
  39   close_in inchan;
  40   res
  41 let iter_file f = fold_file (fun _ line -> f line) ()
  42
  43 let hashtbl_sorted_fold f tbl init =
  44   let sorted_keys =
  45     List.sort compare (Hashtbl.fold (fun key _ keys -> key::keys) tbl [])
  46   in
  47   List.fold_left (fun acc k -> f k (Hashtbl.find tbl k) acc) init sorted_keys
  48
  49 let cp src dst =
  50   Shell.call
  51     ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
  52     [Shell.cmd "cp" [src; dst]]
  53
  54 let file_scheme_RE = Pcre.regexp "^file://"
  55 let wget ?output url =
  56   let use_wget () =
  57     let flags =
  58       (match output with Some file -> ["-O"; file] | None -> []) @ [url]
  59     in
  60     debug_print ("wget " ^ String.concat " " flags);
  61     Shell.call
  62       ~stdout:Shell.to_dev_null ~stderr:Shell.to_dev_null
  63       [Shell.cmd "wget" flags]
  64   in
  65   if Pcre.pmatch ~rex:file_scheme_RE url then begin (* file:// URL *)
  66     let src_fname = Pcre.replace ~rex:file_scheme_RE url in
  67     match output with
  68     | Some dst_fname -> cp src_fname dst_fname
  69     | None ->
  70         let dst_fname = Filename.basename src_fname in
  71         if src_fname <> dst_fname then
  72           cp src_fname dst_fname
  73         else  (* src and dst are the same: do nothing *)
  74           ()
  75   end else  (* other URL, pass it to wget *)
  76     use_wget ()
  77
  78   (* stderr shown as usual *)
  79 let gzip ?(keep = false) fname =
  80   if keep then begin  (* keep original file *)
  81     debug_print ("gzip -f -c " ^ fname);
  82     Shell.call
  83       ~stdout:(Shell.to_file (fname ^ ".gz"))
  84       [Shell.cmd "gzip" ["-f"; "-c"; fname]]
  85   end else begin  (* don't keep original file *)
  86     debug_print ("gzip -f " ^ fname);
  87     Shell.call [Shell.cmd "gzip" ["-f"; fname]]
  88   end
  89
  90   (* stderr shown as usual *)
  91 let gunzip ?(keep = false) fname =
  92   if not (Pcre.pmatch ~pat:"\\.gz$" fname) then
  93     failwith "gunzip: source file doesn't end with '.gz'";
  94   let basename = Pcre.replace ~pat:"\\.gz$" fname in
  95   if keep then begin  (* keep original file *)
  96     debug_print ("gunzip -f -c " ^ fname);
  97     Shell.call
  98       ~stdout:(Shell.to_file basename)
  99       [Shell.cmd "gunzip" ["-f"; "-c"; fname]]
 100   end else begin  (* don't keep original file *)
 101     debug_print ("gunzip -f " ^ fname);
 102     Shell.call [Shell.cmd "gunzip" ["-f"; fname]]
 103   end
 104
 105 let tempfile () =
 106   let buf = Buffer.create 28 in (* strlen("/tmp/fileSzb3Mw_http_getter") *)
 107   Shell.call
 108     ~stdout:(Shell.to_buffer buf)
 109     [Shell.cmd "tempfile" ["--suffix=_http_getter"]];
 110   Pcre.replace ~pat:"\n" (Buffer.contents buf)
 111
 112 let mkdir ?(parents = false) dirname =
 113   if not (Sys.file_exists dirname) then begin
 114     let flags = if parents then ["-p"; dirname] else [dirname] in
 115     debug_print ("mkdir " ^ String.concat " " flags);
 116     Shell.call [Shell.cmd "mkdir" flags]
 117   end
 118
 119 let string_of_proc_status = function
 120   | Unix.WEXITED code -> sprintf "[Exited: %d]" code
 121   | Unix.WSIGNALED sg -> sprintf "[Killed: %d]" sg
 122   | Unix.WSTOPPED sg -> sprintf "[Stopped: %d]" sg
 123
 124 let http_get url =
 125   if Pcre.pmatch ~rex:file_scheme_RE url then begin
 126       (* file:// URL. Read data from file system *)
 127     let fname = Pcre.replace ~rex:file_scheme_RE url in
 128     try
 129       let size = (Unix.stat fname).Unix.st_size in
 130       let buf = String.create size in
 131       let ic = open_in fname in
 132       really_input ic buf 0 size;
 133       close_in ic;
 134       Some buf
 135     with Unix.Unix_error (Unix.ENOENT, "stat", _) -> None
 136   end else  (* other URL, pass it to netclient *)
 137     try
 138       Some (Http_client.Convenience.http_get url)
 139     with Http_client.Http_error (code, _) -> None
 140