helm/mathql/grammar.txt

   1 GRAMMATICA PER QUERY SU DOCUMENTI MATEMATICI
   2 MATHEMATICAL QUERY LANGUAGE (MathQL)
   3
   4 <query> := <list>                              (* clausola iniziale *)
   5
   6 <list> := ( <list> )                           (* parentesizazione *)
   7        |  <list> UNION <list>                  (* unione *)
   8        |  <list> INTERSECT <list>              (* intersezione *)
   9        |  <list> DIFF <list>                   (* differenza *)
  10        |  SELECT <rvar> IN <list> WHERE <bool> (* selezione *)
  11        |  EXISTS <rvar> IN <list> WHERE <bool> (* esistenziale *)
  12        |  USE <list> POSITION <svar>           (* unione lista backward *)
  13        |  USEDBY <list> POSITION <svar>        (* unione lista forward *)
  14        |  CONTRUCTORS <list>                   (* unione costruttori della
  15                                                   lista oggetti*)
  16        |  PATTERN <pattern>                    (* espansione del pattern *)
  17        |  INTHEORY <list> ITEMTYPE <svar>      (* unione oggetti lista teorie *)
  18        |  THEORYREFTO <list>                   (* unione teorie che fanno
  19                                                  riferimento a lista oggetti *)
  20        |  <list> OFTYPE <svar>                 (* unione oggetti in base a
  21                                                   classi *)
  22        |  <list> OFSUPERTYPE <svar>            (* unione oggetti in base a
  23                                                   classi e loro superclassi *)
  24        |  <list> OFSUBTYPE <svar>              (* unione oggetti in base a
  25                                                   classi e loro sottoclassi *)
  26
  27 <bool> := ( <bool> )                           (* parentesizzazione *)
  28        |  <bool> AND <bool>                    (* congiunzione *)
  29        |  <bool> OR <bool>                     (* disgiunzione *)
  30        |  NOT <bool>                           (* negazione *)
  31        |  TRUE                                 (* vero *)
  32        |  FALSE                                (* falso *)
  33        |  <string> IS <string>                 (* case sensitive matching *)
  34        |  <list> EQUAL <list>                  (* uguaglianza tra liste *)
  35
  36 <pattern> := <"-quoted-constant-string>        (* pattern costante *)
  37
  38 <string> := <'-quoted-constant-string>         (* costante letterale *)
  39          |  CONCLUSION | HYPOTHESIS | BODY     (* costanti simboliche *)
  40          |  MAINCONCLUSION | MAINHYPOTHESIS
  41          |  <rvar>                             (* variabile *)
  42          |  <svar>                             (* variabile *)
  43          |  <function> <rvar>                  (* applicazione di funzione *)
  44
  45 <function> := NAME                             (* URIREF -> nome_oggetto *)
  46            |  <property>
  47
  48 <property> := THEORY                           (* URIREF -> valore_Proprieta' *)
  49            |  TITLE                            (* URIREF -> valore_Prop_DC *)
  50            |  CONTRIBUTOR
  51            |  CREATOR
  52            |  PUBLISHER
  53            |  SUBJECT
  54            |  DESCRIPTION
  55            |  DATE
  56            |  TYPE
  57            |  FORMAT
  58            |  IDENTIFIER
  59            |  LANGUAGE
  60            |  RELATION
  61            |  SOURCE
  62            |  COVERAGE
  63            |  RIGHTS
  64            |  INSTITUTION
  65            |  CONTACT
  66            |  FIRSTVERSION
  67            |  MODIFIED
  68            |  <refineprop> <property>
  69
  70 <refineprop> := SUB                            (* proprieta' e sotto-proprieta'
  71                                                   di *)
  72              |  SUPER                          (* proprieta' e super-proprieta'
  73                                                   di *)
  74
  75 <rvar> := <not-reserved-identifier>            (* variabile per risorse *)
  76 <svar> := $ <not-reserved-identifier>          (* variabile per stringhe *)
  77
  78 - () = lista vuota (?)
  79 - le stringhe sono "case sensitive"
  80 - la funzione non definita sull'argomento restituisce la stringa nulla
  81 - le <rvar> si presuppongono essere istanziate come URI references costituite
  82   da un URI e da un fragment identifier opzionalecomplete; esse identificano
  83   risorse
  84 - ogni binding lega una variabile libera (nuova)
  85 - Precedenza operatori:
  86   NOT (+)  DIFF
  87   AND      INTERSECT
  88   OR  (-)  UNION
  89 - Possibili tipi di RELATION e DEPENDENCE sono rappresentati dalle loro
  90   subproperties
  91 - FUTURO: thesauri di parole e sinonimi per ricerche testuali, ordinamenti sui
  92   risultati, caratteri jolly. Una volta reperito l'oggetto si possono
  93   visualizzare le info associate.
  94 - FUTURO: in output numeri ad esempio a fini statistici, aggiungendo anche
  95   operatori aritmetici e di confronto (< = >). Es. Quante proofs di un certo
  96   teorema ci sono?
  97 - L'ordinamento di default e' quello alfabetico crescente in base al nome
  98   delle rvar
  99 - Note su <pattern>
 100   Contiene un'espressione regolare per selezionare delle "reference"
 101   (cioe` delle uri eventualmente seguite da un fragment identifier)
 102   L'espressione regolare contiene i seguenti costrutti:
 103
 104   costrutto        semanticamente fa match con
 105   ?                un singolo carattere diverso da / # :
 106   *                la piu' lunga sottostringa che non contiene / # :
 107   **               la piu' lunga sottostringa che non contiene # :
 108   altro carattere  solo se' stesso
 109
 110   costrutto        puo' appareire in
 111   ?                "body"
 112   *                dovunque
 113   **               "body" e "fragment"
 114   altro carattere  dovunque
 115
 116   "body"     parte compresa fra le occorrenze di ":/" e "#1" escluse
 117   "fragment" parte successiva all'occorrenza "#1"
 118 - FUTURO: operatore di ordinamento sul risultato finale della query.
 119   <query> SORTEDBY <order> <function>   (* unione lista ordinata secondo
 120                                            ordine e valore funzione *)
 121   <order>    := DESC                           (* ordinamento decrescente *)
 122              |  ASC                            (* ordinamento crescente *)
 123   DTD:
 124   <!ENTITY % order '(ascendant|descendant)'>
 125   <!ELEMENT Query %queryexpr;>
 126   <!ELEMENT SortBy (Query, SortField)>
 127   <!ELEMENT SortField %functexpr;>
 128   <!ATTLIST SortField
 129             order %order; #IMPLIED>
 130 - RILASSAMENTO degli operatori UNION e INTERSECT. Operatori fuzzy con
 131   introduzione di pesi associati ai risultati.