helm/mathql/grammar.txt

   1 GRAMMATICA PER QUERY SU DOCUMENTI MATEMATICI
   2 MATHEMATICAL QUERY LANGUAGE (MathQL)
   3
   4 <query> := <list>                              (* clausola iniziale *)
   5
   6 <list> := ( <list> )                           (* parentesizazione *)
   7        |  <list> UNION <list>                  (* unione *)
   8        |  <list> INTERSECT <list>              (* intersezione *)
   9        |  <list> DIFF <list>                   (* differenza *)
  10        |  SELECT <rvar> IN <list> WHERE <bool> (* selezione *)
  11        |  EXISTS <rvar> IN <list> WHERE <bool> (* esistenziale *)
  12        |  USE <list> POSITION <svar>           (* unione lista backward *)
  13        |  USEDBY <list> POSITION <svar>        (* unione lista forward *)
  14        |  CONTRUCTORS <list>                   (* unione costruttori della
  15                                                   lista oggetti*)
  16        |  PATTERN <pattern>                    (* espansione del pattern *)
  17        |  INTHEORY <list> ITEMTYPE <svar>      (* unione oggetti lista teorie *)
  18        |  THEORYREFTO <list>                   (* unione teorie che fanno
  19                                                  riferimento a lista oggetti *)
  20        |  <list> OFTYPE <svar>                 (* unione oggetti in base a
  21                                                   classi *)
  22        |  <list> OFSUPERTYPE <svar>            (* unione oggetti in base a
  23                                                   classi e loro superclassi *)
  24        |  <list> OFSUBTYPE <svar>              (* unione oggetti in base a
  25                                                   classi e loro sottoclassi *)
  26
  27 <bool> := ( <bool> )                           (* parentesizzazione *)
  28        |  <bool> AND <bool>                    (* congiunzione *)
  29        |  <bool> OR <bool>                     (* disgiunzione *)
  30        |  NOT <bool>                           (* negazione *)
  31        |  TRUE                                 (* vero *)
  32        |  FALSE                                (* falso *)
  33        |  <string> IS <string>                 (* case sensitive matching *)
  34
  35 <pattern> := <"-quoted-constant-string>        (* pattern costante *)
  36
  37 <string> := <'-quoted-constant-string>         (* costante letterale *)
  38          |  CONCLUSION | HYPOTHESIS | BODY     (* costanti simboliche *)
  39          |  MAINCONCLUSION | MAINHYPOTHESIS
  40          |  <rvar>                             (* variabile *)
  41          |  <svar>                             (* variabile *)
  42          |  <function> <rvar>                  (* applicazione di funzione *)
  43
  44 <function> := NAME                             (* URIREF -> nome_oggetto *)
  45            |  <property>
  46
  47 <property> := THEORY                           (* URIREF -> valore_Proprieta' *)
  48            |  TITLE                            (* URIREF -> valore_Prop_DC *)
  49            |  CONTRIBUTOR
  50            |  CREATOR
  51            |  PUBLISHER
  52            |  SUBJECT
  53            |  DESCRIPTION
  54            |  DATE
  55            |  TYPE
  56            |  FORMAT
  57            |  IDENTIFIER
  58            |  LANGUAGE
  59            |  RELATION
  60            |  SOURCE
  61            |  COVERAGE
  62            |  RIGHTS
  63            |  INSTITUTION
  64            |  CONTACT
  65            |  FIRSTVERSION
  66            |  MODIFIED
  67            |  <refineprop> <property>
  68
  69 <refineprop> := SUB                            (* proprieta' e sotto-proprieta'
  70                                                   di *)
  71              |  SUPER                          (* proprieta' e super-proprieta'
  72                                                   di *)
  73
  74 <rvar> := <not-reserved-identifier>            (* variabile per risorse *)
  75 <svar> := $ <not-reserved-identifier>          (* variabile per stringhe *)
  76
  77 - le stringhe sono "case sensitive"
  78 - la funzione non definita sull'argomento restituisce la stringa nulla
  79 - le <rvar> si presuppongono essere istanziate come URI references costituite
  80   da un URI e da un fragment identifier opzionalecomplete; esse identificano
  81   risorse
  82 - ogni binding lega una variabile libera (nuova)
  83 - Precedenza operatori:
  84   NOT (+)  DIFF
  85   AND      INTERSECT
  86   OR  (-)  UNION
  87 - Possibili tipi di RELATION e DEPENDENCE sono rappresentati dalle loro
  88   subproperties
  89 - FUTURO: thesauri di parole e sinonimi per ricerche testuali, ordinamenti sui
  90   risultati, caratteri jolly. Una volta reperito l'oggetto si possono
  91   visualizzare le info associate.
  92 - FUTURO: in output numeri ad esempio a fini statistici, aggiungendo anche
  93   operatori aritmetici e di confronto (< = >). Es. Quante proofs di un certo
  94   teorema ci sono?
  95 - L'ordinamento di default e' quello alfabetico crescente in base al nome
  96   delle rvar
  97 - Note su <pattern>
  98   Contiene un'espressione regolare per selezionare delle "reference"
  99   (cioe` delle uri eventualmente seguite da un fragment identifier)
 100   L'espressione regolare contiene i seguenti costrutti:
 101
 102   costrutto        semanticamente fa match con
 103   ?                un singolo carattere diverso da / # :
 104   *                la piu' lunga sottostringa che non contiene / # :
 105   **               la piu' lunga sottostringa che non contiene # :
 106   altro carattere  solo se' stesso
 107
 108   costrutto        puo' appareire in
 109   ?                "body"
 110   *                dovunque
 111   **               "body" e "fragment"
 112   altro carattere  dovunque
 113
 114   "body"     parte compresa fra le occorrenze di ":/" e "#1" escluse
 115   "fragment" parte successiva all'occorrenza "#1"
 116 - FUTURO: operatore di ordinamento sul risultato finale della query.
 117   <query> SORTEDBY <order> <function>   (* unione lista ordinata secondo
 118                                            ordine e valore funzione *)
 119   <order>    := DESC                           (* ordinamento decrescente *)
 120              |  ASC                            (* ordinamento crescente *)
 121   DTD:
 122   <!ENTITY % order '(ascendant|descendant)'>
 123   <!ELEMENT Query %queryexpr;>
 124   <!ELEMENT SortBy (Query, SortField)>
 125   <!ELEMENT SortField %functexpr;>
 126   <!ATTLIST SortField
 127             order %order; #IMPLIED>
 128 - RILASSAMENTO degli operatori UNION e INTERSECT. Operatori fuzzy con
 129   introduzione di pesi associati ai risultati.