helm/matita/library/Z/plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/Z/plus".
  16
  17 include "Z/z.ma".
  18 include "nat/compare.ma".
  19 include "nat/minus.ma".
  20
  21 definition Zplus :Z \to Z \to Z \def
  22 \lambda x,y.
  23   match x with
  24     [ OZ \Rightarrow y
  25     | (pos m) \Rightarrow
  26         match y with
  27          [ OZ \Rightarrow x
  28          | (pos n) \Rightarrow (pos (pred ((S m)+(S n))))
  29          | (neg n) \Rightarrow
  30               match nat_compare m n with
  31                 [ LT \Rightarrow (neg (pred (n-m)))
  32                 | EQ \Rightarrow OZ
  33                 | GT \Rightarrow (pos (pred (m-n)))]]
  34     | (neg m) \Rightarrow
  35         match y with
  36          [ OZ \Rightarrow x
  37          | (pos n) \Rightarrow
  38               match nat_compare m n with
  39                 [ LT \Rightarrow (pos (pred (n-m)))
  40                 | EQ \Rightarrow OZ
  41                 | GT \Rightarrow (neg (pred (m-n)))]
  42          | (neg n) \Rightarrow (neg (pred ((S m)+(S n))))]].
  43
  44 (*CSC: the URI must disappear: there is a bug now *)
  45 interpretation "integer plus" 'plus x y = (cic:/matita/Z/plus/Zplus.con x y).
  46
  47 theorem Zplus_z_OZ:  \forall z:Z. z+OZ = z.
  48 intro.elim z.
  49 simplify.reflexivity.
  50 simplify.reflexivity.
  51 simplify.reflexivity.
  52 qed.
  53
  54 (* theorem symmetric_Zplus: symmetric Z Zplus. *)
  55
  56 theorem sym_Zplus : \forall x,y:Z. x+y = y+x.
  57 intros.elim x.rewrite > Zplus_z_OZ.reflexivity.
  58 elim y.simplify.reflexivity.
  59 simplify.
  60 rewrite < plus_n_Sm. rewrite < plus_n_Sm.rewrite < sym_plus.reflexivity.
  61 simplify.
  62 rewrite > nat_compare_n_m_m_n.
  63 simplify.elim nat_compare ? ?.simplify.reflexivity.
  64 simplify. reflexivity.
  65 simplify. reflexivity.
  66 elim y.simplify.reflexivity.
  67 simplify.rewrite > nat_compare_n_m_m_n.
  68 simplify.elim nat_compare ? ?.simplify.reflexivity.
  69 simplify. reflexivity.
  70 simplify. reflexivity.
  71 simplify.rewrite < plus_n_Sm. rewrite < plus_n_Sm.rewrite < sym_plus.reflexivity.
  72 qed.
  73
  74 theorem Zpred_Zplus_neg_O : \forall z:Z. Zpred z = (neg O)+z.
  75 intros.elim z.
  76 simplify.reflexivity.
  77 simplify.reflexivity.
  78 elim n.simplify.reflexivity.
  79 simplify.reflexivity.
  80 qed.
  81
  82 theorem Zsucc_Zplus_pos_O : \forall z:Z. Zsucc z = (pos O)+z.
  83 intros.elim z.
  84 simplify.reflexivity.
  85 elim n.simplify.reflexivity.
  86 simplify.reflexivity.
  87 simplify.reflexivity.
  88 qed.
  89
  90 theorem Zplus_pos_pos:
  91 \forall n,m. (pos n)+(pos m) = (Zsucc (pos n))+(Zpred (pos m)).
  92 intros.
  93 elim n.elim m.
  94 simplify.reflexivity.
  95 simplify.reflexivity.
  96 elim m.
  97 simplify.rewrite < plus_n_Sm.
  98 rewrite < plus_n_O.reflexivity.
  99 simplify.rewrite < plus_n_Sm.
 100 rewrite < plus_n_Sm.reflexivity.
 101 qed.
 102
 103 theorem Zplus_pos_neg:
 104 \forall n,m. (pos n)+(neg m) = (Zsucc (pos n))+(Zpred (neg m)).
 105 intros.reflexivity.
 106 qed.
 107
 108 theorem Zplus_neg_pos :
 109 \forall n,m. (neg n)+(pos m) = (Zsucc (neg n))+(Zpred (pos m)).
 110 intros.
 111 elim n.elim m.
 112 simplify.reflexivity.
 113 simplify.reflexivity.
 114 elim m.
 115 simplify.reflexivity.
 116 simplify.reflexivity.
 117 qed.
 118
 119 theorem Zplus_neg_neg:
 120 \forall n,m. (neg n)+(neg m) = (Zsucc (neg n))+(Zpred (neg m)).
 121 intros.
 122 elim n.elim m.
 123 simplify.reflexivity.
 124 simplify.reflexivity.
 125 elim m.
 126 simplify.rewrite > plus_n_Sm.reflexivity.
 127 simplify.rewrite > plus_n_Sm.reflexivity.
 128 qed.
 129
 130 theorem Zplus_Zsucc_Zpred:
 131 \forall x,y. x+y = (Zsucc x)+(Zpred y).
 132 intros.
 133 elim x. elim y.
 134 simplify.reflexivity.
 135 simplify.reflexivity.
 136 rewrite < Zsucc_Zplus_pos_O.
 137 rewrite > Zsucc_Zpred.reflexivity.
 138 elim y.rewrite < sym_Zplus.rewrite < sym_Zplus (Zpred OZ).
 139 rewrite < Zpred_Zplus_neg_O.
 140 rewrite > Zpred_Zsucc.
 141 simplify.reflexivity.
 142 rewrite < Zplus_neg_neg.reflexivity.
 143 apply Zplus_neg_pos.
 144 elim y.simplify.reflexivity.
 145 apply Zplus_pos_neg.
 146 apply Zplus_pos_pos.
 147 qed.
 148
 149 theorem Zplus_Zsucc_pos_pos :
 150 \forall n,m. (Zsucc (pos n))+(pos m) = Zsucc ((pos n)+(pos m)).
 151 intros.reflexivity.
 152 qed.
 153
 154 theorem Zplus_Zsucc_pos_neg:
 155 \forall n,m. (Zsucc (pos n))+(neg m) = (Zsucc ((pos n)+(neg m))).
 156 intros.
 157 apply nat_elim2
 158 (\lambda n,m. (Zsucc (pos n))+(neg m) = (Zsucc ((pos n)+(neg m)))).intro.
 159 intros.elim n1.
 160 simplify. reflexivity.
 161 elim n2.simplify. reflexivity.
 162 simplify. reflexivity.
 163 intros. elim n1.
 164 simplify. reflexivity.
 165 simplify.reflexivity.
 166 intros.
 167 rewrite < (Zplus_pos_neg ? m1).
 168 elim H.reflexivity.
 169 qed.
 170
 171 theorem Zplus_Zsucc_neg_neg :
 172 \forall n,m. (Zsucc (neg n))+(neg m) = Zsucc ((neg n)+(neg m)).
 173 intros.
 174 apply nat_elim2
 175 (\lambda n,m. ((Zsucc (neg n))+(neg m)) = Zsucc ((neg n)+(neg m))).intro.
 176 intros.elim n1.
 177 simplify. reflexivity.
 178 elim n2.simplify. reflexivity.
 179 simplify. reflexivity.
 180 intros. elim n1.
 181 simplify. reflexivity.
 182 simplify.reflexivity.
 183 intros.
 184 rewrite < (Zplus_neg_neg ? m1).
 185 reflexivity.
 186 qed.
 187
 188 theorem Zplus_Zsucc_neg_pos:
 189 \forall n,m. Zsucc (neg n)+(pos m) = Zsucc ((neg n)+(pos m)).
 190 intros.
 191 apply nat_elim2
 192 (\lambda n,m. (Zsucc (neg n))+(pos m) = Zsucc ((neg n)+(pos m))).
 193 intros.elim n1.
 194 simplify. reflexivity.
 195 elim n2.simplify. reflexivity.
 196 simplify. reflexivity.
 197 intros. elim n1.
 198 simplify. reflexivity.
 199 simplify.reflexivity.
 200 intros.
 201 rewrite < H.
 202 rewrite < (Zplus_neg_pos ? (S m1)).
 203 reflexivity.
 204 qed.
 205
 206 theorem Zplus_Zsucc : \forall x,y:Z. (Zsucc x)+y = Zsucc (x+y).
 207 intros.elim x.elim y.
 208 simplify. reflexivity.
 209 rewrite < Zsucc_Zplus_pos_O.reflexivity.
 210 simplify.reflexivity.
 211 elim y.rewrite < sym_Zplus.rewrite < sym_Zplus OZ.simplify.reflexivity.
 212 apply Zplus_Zsucc_neg_neg.
 213 apply Zplus_Zsucc_neg_pos.
 214 elim y.
 215 rewrite < sym_Zplus OZ.reflexivity.
 216 apply Zplus_Zsucc_pos_neg.
 217 apply Zplus_Zsucc_pos_pos.
 218 qed.
 219
 220 theorem Zplus_Zpred: \forall x,y:Z. (Zpred x)+y = Zpred (x+y).
 221 intros.
 222 cut Zpred (x+y) = Zpred ((Zsucc (Zpred x))+y).
 223 rewrite > Hcut.
 224 rewrite > Zplus_Zsucc.
 225 rewrite > Zpred_Zsucc.
 226 reflexivity.
 227 rewrite > Zsucc_Zpred.
 228 reflexivity.
 229 qed.
 230
 231
 232 theorem associative_Zplus: associative Z Zplus.
 233 change with \forall x,y,z:Z. (x + y) + z = x + (y + z).
 234 (* simplify. *)
 235 intros.elim x.simplify.reflexivity.
 236 elim n.rewrite < (Zpred_Zplus_neg_O (y+z)).
 237 rewrite < (Zpred_Zplus_neg_O y).
 238 rewrite < Zplus_Zpred.
 239 reflexivity.
 240 rewrite > Zplus_Zpred (neg n1).
 241 rewrite > Zplus_Zpred (neg n1).
 242 rewrite > Zplus_Zpred ((neg n1)+y).
 243 apply eq_f.assumption.
 244 elim n.rewrite < Zsucc_Zplus_pos_O.
 245 rewrite < Zsucc_Zplus_pos_O.
 246 rewrite > Zplus_Zsucc.
 247 reflexivity.
 248 rewrite > Zplus_Zsucc (pos n1).
 249 rewrite > Zplus_Zsucc (pos n1).
 250 rewrite > Zplus_Zsucc ((pos n1)+y).
 251 apply eq_f.assumption.
 252 qed.
 253
 254 variant assoc_Zplus : \forall x,y,z:Z.  (x+y)+z = x+(y+z)
 255 \def associative_Zplus.
 256
 257 (* Zopp *)
 258 definition Zopp : Z \to Z \def
 259 \lambda x:Z. match x with
 260 [ OZ \Rightarrow OZ
 261 | (pos n) \Rightarrow (neg n)
 262 | (neg n) \Rightarrow (pos n) ].
 263
 264 (*CSC: the URI must disappear: there is a bug now *)
 265 interpretation "integer unary minus" 'uminus x = (cic:/matita/Z/plus/Zopp.con x).
 266
 267 theorem Zopp_Zplus: \forall x,y:Z. -(x+y) = -x + -y.
 268 intros.
 269 elim x.elim y.
 270 simplify. reflexivity.
 271 simplify. reflexivity.
 272 simplify. reflexivity.
 273 elim y.
 274 simplify. reflexivity.
 275 simplify. reflexivity.
 276 simplify. apply nat_compare_elim.
 277 intro.simplify.reflexivity.
 278 intro.simplify.reflexivity.
 279 intro.simplify.reflexivity.
 280 elim y.
 281 simplify. reflexivity.
 282 simplify. apply nat_compare_elim.
 283 intro.simplify.reflexivity.
 284 intro.simplify.reflexivity.
 285 intro.simplify.reflexivity.
 286 simplify.reflexivity.
 287 qed.
 288
 289 theorem Zopp_Zopp: \forall x:Z. --x = x.
 290 intro. elim x.
 291 reflexivity.reflexivity.reflexivity.
 292 qed.
 293
 294 theorem Zplus_Zopp: \forall x:Z. x+ -x = OZ.
 295 intro.elim x.
 296 apply refl_eq.
 297 simplify.
 298 rewrite > nat_compare_n_n.
 299 simplify.apply refl_eq.
 300 simplify.
 301 rewrite > nat_compare_n_n.
 302 simplify.apply refl_eq.
 303 qed.
 304