helm/matita/library/nat/primes.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        Matita is distributed under the terms of the          *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/nat/primes".
  16
  17 include "nat/div_and_mod.ma".
  18 include "nat/minimization.ma".
  19 include "nat/sigma_and_pi.ma".
  20 include "nat/factorial.ma".
  21
  22 inductive divides (n,m:nat) : Prop \def
  23 witness : \forall p:nat.m = times n p \to divides n m.
  24
  25 theorem reflexive_divides : reflexive nat divides.
  26 simplify.
  27 intros.
  28 exact witness x x (S O) (times_n_SO x).
  29 qed.
  30
  31 theorem divides_to_div_mod_spec :
  32 \forall n,m. O < n \to divides n m \to div_mod_spec m n (div m n) O.
  33 intros.elim H1.rewrite > H2.
  34 constructor 1.assumption.
  35 apply lt_O_n_elim n H.intros.
  36 rewrite < plus_n_O.
  37 rewrite > div_times.apply sym_times.
  38 qed.
  39
  40 theorem div_mod_spec_to_div :
  41 \forall n,m,p. div_mod_spec m n p O \to divides n m.
  42 intros.elim H.
  43 apply witness n m p.
  44 rewrite < sym_times.
  45 rewrite > plus_n_O (p*n).assumption.
  46 qed.
  47
  48 theorem divides_to_mod_O:
  49 \forall n,m. O < n \to divides n m \to (mod m n) = O.
  50 intros.apply div_mod_spec_to_eq2 m n (div m n) (mod m n) (div m n) O.
  51 apply div_mod_spec_div_mod.assumption.
  52 apply divides_to_div_mod_spec.assumption.assumption.
  53 qed.
  54
  55 theorem mod_O_to_divides:
  56 \forall n,m. O< n \to (mod m n) = O \to  divides n m.
  57 intros.
  58 apply witness n m (div m n).
  59 rewrite > plus_n_O (n*div m n).
  60 rewrite < H1.
  61 rewrite < sym_times.
  62 (* Andrea: perche' hint non lo trova ?*)
  63 apply div_mod.
  64 assumption.
  65 qed.
  66
  67 theorem divides_n_O: \forall n:nat. divides n O.
  68 intro. apply witness n O O.apply times_n_O.
  69 qed.
  70
  71 theorem divides_SO_n: \forall n:nat. divides (S O) n.
  72 intro. apply witness (S O) n n. simplify.apply plus_n_O.
  73 qed.
  74
  75 theorem divides_plus: \forall n,p,q:nat.
  76 divides n p \to divides n q \to divides n (p+q).
  77 intros.
  78 elim H.elim H1. apply witness n (p+q) (n2+n1).
  79 rewrite > H2.rewrite > H3.apply sym_eq.apply distr_times_plus.
  80 qed.
  81
  82 theorem divides_minus: \forall n,p,q:nat.
  83 divides n p \to divides n q \to divides n (p-q).
  84 intros.
  85 elim H.elim H1. apply witness n (p-q) (n2-n1).
  86 rewrite > H2.rewrite > H3.apply sym_eq.apply distr_times_minus.
  87 qed.
  88
  89 theorem divides_times: \forall n,m,p,q:nat.
  90 divides n p \to divides m q \to divides (n*m) (p*q).
  91 intros.
  92 elim H.elim H1. apply witness (n*m) (p*q) (n2*n1).
  93 rewrite > H2.rewrite > H3.
  94 apply trans_eq nat ? (n*(m*(n2*n1))).
  95 apply trans_eq nat ? (n*(n2*(m*n1))).
  96 apply assoc_times.
  97 apply eq_f.
  98 apply trans_eq nat ? ((n2*m)*n1).
  99 apply sym_eq. apply assoc_times.
 100 rewrite > sym_times n2 m.apply assoc_times.
 101 apply sym_eq. apply assoc_times.
 102 qed.
 103
 104 theorem transitive_divides: \forall n,m,p.
 105 divides n m \to divides m p \to divides n p.
 106 intros.
 107 elim H.elim H1. apply witness n p (n2*n1).
 108 rewrite > H3.rewrite > H2.
 109 apply assoc_times.
 110 qed.
 111
 112 (* divides le *)
 113 theorem divides_to_le : \forall n,m. O < m \to divides n m \to n \le m.
 114 intros. elim H1.rewrite > H2.cut O < n2.
 115 apply lt_O_n_elim n2 Hcut.intro.rewrite < sym_times.
 116 simplify.rewrite < sym_plus.
 117 apply le_plus_n.
 118 elim le_to_or_lt_eq O n2.
 119 assumption.
 120 absurd O<m.assumption.
 121 rewrite > H2.rewrite < H3.rewrite < times_n_O.
 122 apply not_le_Sn_n O.
 123 apply le_O_n.
 124 qed.
 125
 126 theorem divides_to_lt_O : \forall n,m. O < m \to divides n m \to O < n.
 127 intros.elim H1.
 128 elim le_to_or_lt_eq O n (le_O_n n).
 129 assumption.
 130 rewrite < H3.absurd O < m.assumption.
 131 rewrite > H2.rewrite < H3.
 132 simplify.exact not_le_Sn_n O.
 133 qed.
 134
 135 (* boolean divides *)
 136 definition divides_b : nat \to nat \to bool \def
 137 \lambda n,m :nat. (eqb (mod m n) O).
 138
 139 theorem divides_b_to_Prop :
 140 \forall n,m:nat. O < n \to
 141 match divides_b n m with
 142 [ true \Rightarrow divides n m
 143 | false \Rightarrow \lnot (divides n m)].
 144 intros.
 145 change with
 146 match eqb (mod m n) O with
 147 [ true \Rightarrow divides n m
 148 | false \Rightarrow \lnot (divides n m)].
 149 apply eqb_elim.
 150 intro.simplify.apply mod_O_to_divides.assumption.assumption.
 151 intro.simplify.intro.apply H1.apply divides_to_mod_O.assumption.assumption.
 152 qed.
 153
 154 theorem divides_b_true_to_divides :
 155 \forall n,m:nat. O < n \to
 156 (divides_b n m = true ) \to divides n m.
 157 intros.
 158 change with
 159 match true with
 160 [ true \Rightarrow divides n m
 161 | false \Rightarrow \lnot (divides n m)].
 162 rewrite < H1.apply divides_b_to_Prop.
 163 assumption.
 164 qed.
 165
 166 theorem divides_b_false_to_not_divides :
 167 \forall n,m:nat. O < n \to
 168 (divides_b n m = false ) \to \lnot (divides n m).
 169 intros.
 170 change with
 171 match false with
 172 [ true \Rightarrow divides n m
 173 | false \Rightarrow \lnot (divides n m)].
 174 rewrite < H1.apply divides_b_to_Prop.
 175 assumption.
 176 qed.
 177
 178 theorem decidable_divides: \forall n,m:nat.O < n \to
 179 decidable (divides n m).
 180 intros.change with (divides n m) \lor \not (divides n m).
 181 cut
 182 match divides_b n m with
 183 [ true \Rightarrow divides n m
 184 | false \Rightarrow \not (divides n m)] \to (divides n m) \lor \not (divides n m).
 185 apply Hcut.apply divides_b_to_Prop.assumption.
 186 elim (divides_b n m).left.apply H1.right.apply H1.
 187 qed.
 188
 189 theorem divides_to_divides_b_true : \forall n,m:nat. O < n \to
 190 divides n m \to divides_b n m = true.
 191 intros.
 192 cut match (divides_b n m) with
 193 [ true \Rightarrow (divides n m)
 194 | false \Rightarrow \not (divides n m)] \to ((divides_b n m) = true).
 195 apply Hcut.apply divides_b_to_Prop.assumption.
 196 elim divides_b n m.reflexivity.
 197 absurd (divides n m).assumption.assumption.
 198 qed.
 199
 200 theorem not_divides_to_divides_b_false: \forall n,m:nat. O < n \to
 201 \not(divides n m) \to (divides_b n m) = false.
 202 intros.
 203 cut match (divides_b n m) with
 204 [ true \Rightarrow (divides n m)
 205 | false \Rightarrow \not (divides n m)] \to ((divides_b n m) = false).
 206 apply Hcut.apply divides_b_to_Prop.assumption.
 207 elim divides_b n m.
 208 absurd (divides n m).assumption.assumption.
 209 reflexivity.
 210 qed.
 211
 212 (* divides and pi *)
 213 theorem divides_f_pi_f : \forall f:nat \to nat.\forall n,i:nat.
 214 i < n \to divides (f i) (pi n f).
 215 intros 3.elim n.apply False_ind.apply not_le_Sn_O i H.
 216 simplify.
 217 apply le_n_Sm_elim (S i) n1 H1.
 218 intro.
 219 apply transitive_divides ? (pi n1 f).
 220 apply H.simplify.apply le_S_S_to_le. assumption.
 221 apply witness ? ? (f n1).apply sym_times.
 222 intro.cut i = n1.
 223 rewrite > Hcut.
 224 apply witness ? ? (pi n1 f).reflexivity.
 225 apply inj_S.assumption.
 226 qed.
 227
 228 theorem mod_S_pi: \forall f:nat \to nat.\forall n,i:nat.
 229 i < n \to (S O) < (f i) \to mod (S (pi n f)) (f i) = (S O).
 230 intros.cut mod (pi n f) (f i) = O.
 231 rewrite < Hcut.
 232 apply mod_S.apply trans_lt O (S O).apply le_n (S O).assumption.
 233 rewrite > Hcut.assumption.
 234 apply divides_to_mod_O.apply trans_lt O (S O).apply le_n (S O).assumption.
 235 apply divides_f_pi_f.assumption.
 236 qed.
 237
 238 (* divides and fact *)
 239 theorem divides_fact : \forall n,i:nat.
 240 O < i \to i \le n \to divides i (fact n).
 241 intros 3.elim n.absurd O<i.assumption.apply le_n_O_elim i H1.
 242 apply not_le_Sn_O O.
 243 change with divides i ((S n1)*(fact n1)).
 244 apply le_n_Sm_elim i n1 H2.
 245 intro.
 246 apply transitive_divides ? (fact n1).
 247 apply H1.apply le_S_S_to_le. assumption.
 248 apply witness ? ? (S n1).apply sym_times.
 249 intro.
 250 rewrite > H3.
 251 apply witness ? ? (fact n1).reflexivity.
 252 qed.
 253
 254 theorem mod_S_fact: \forall n,i:nat.
 255 (S O) < i \to i \le n \to mod (S (fact n)) i = (S O).
 256 intros.cut mod (fact n) i = O.
 257 rewrite < Hcut.
 258 apply mod_S.apply trans_lt O (S O).apply le_n (S O).assumption.
 259 rewrite > Hcut.assumption.
 260 apply divides_to_mod_O.apply trans_lt O (S O).apply le_n (S O).assumption.
 261 apply divides_fact.apply trans_lt O (S O).apply le_n (S O).assumption.
 262 assumption.
 263 qed.
 264
 265 theorem not_divides_S_fact: \forall n,i:nat.
 266 (S O) < i \to i \le n \to \not (divides i (S (fact n))).
 267 intros.
 268 apply divides_b_false_to_not_divides.
 269 apply trans_lt O (S O).apply le_n (S O).assumption.
 270 change with (eqb (mod (S (fact n)) i) O) = false.
 271 rewrite > mod_S_fact.simplify.reflexivity.
 272 assumption.assumption.
 273 qed.
 274
 275 (* prime *)
 276 definition prime : nat \to  Prop \def
 277 \lambda n:nat. (S O) < n \land
 278 (\forall m:nat. divides m n \to (S O) < m \to  m = n).
 279
 280 theorem not_prime_O: \lnot (prime O).
 281 simplify.intro.elim H.apply not_le_Sn_O (S O) H1.
 282 qed.
 283
 284 theorem not_prime_SO: \lnot (prime (S O)).
 285 simplify.intro.elim H.apply not_le_Sn_n (S O) H1.
 286 qed.
 287
 288 (* smallest factor *)
 289 definition smallest_factor : nat \to nat \def
 290 \lambda n:nat.
 291 match n with
 292 [ O \Rightarrow O
 293 | (S p) \Rightarrow
 294   match p with
 295   [ O \Rightarrow (S O)
 296   | (S q) \Rightarrow min_aux q (S(S q)) (\lambda m.(eqb (mod (S(S q)) m) O))]].
 297
 298 (* it works !
 299 theorem example1 : smallest_prime_factor (S(S(S O))) = (S(S(S O))).
 300 normalize.reflexivity.
 301 qed.
 302
 303 theorem example2: smallest_prime_factor (S(S(S(S O)))) = (S(S O)).
 304 normalize.reflexivity.
 305 qed.
 306
 307 theorem example3 : smallest_prime_factor (S(S(S(S(S(S(S O))))))) = (S(S(S(S(S(S(S O))))))).
 308 simplify.reflexivity.
 309 qed. *)
 310
 311 theorem lt_SO_smallest_factor:
 312 \forall n:nat. (S O) < n \to (S O) < (smallest_factor n).
 313 intro.
 314 apply nat_case n.intro.apply False_ind.apply not_le_Sn_O (S O) H.
 315 intro.apply nat_case m.intro. apply False_ind.apply not_le_Sn_n (S O) H.
 316 intros.
 317 change with
 318 S O < min_aux m1 (S(S m1)) (\lambda m.(eqb (mod (S(S m1)) m) O)).
 319 apply lt_to_le_to_lt ? (S (S O)).
 320 apply le_n (S(S O)).
 321 cut (S(S O)) = (S(S m1)) - m1.
 322 rewrite > Hcut.
 323 apply le_min_aux.
 324 apply sym_eq.apply plus_to_minus.apply le_S.apply le_n_Sn.
 325 rewrite < sym_plus.simplify.reflexivity.
 326 qed.
 327
 328 theorem lt_O_smallest_factor: \forall n:nat. O < n \to O < (smallest_factor n).
 329 intro.
 330 apply nat_case n.intro.apply False_ind.apply not_le_Sn_n O H.
 331 intro.apply nat_case m.intro.
 332 simplify.apply le_n.
 333 intros.apply trans_lt ? (S O).
 334 simplify. apply le_n.
 335 apply lt_SO_smallest_factor.simplify. apply le_S_S.
 336 apply le_S_S.apply le_O_n.
 337 qed.
 338
 339 theorem divides_smallest_factor_n :
 340 \forall n:nat. O < n \to divides (smallest_factor n) n.
 341 intro.
 342 apply nat_case n.intro.apply False_ind.apply not_le_Sn_O O H.
 343 intro.apply nat_case m.intro. simplify.
 344 apply witness ? ? (S O). simplify.reflexivity.
 345 intros.
 346 apply divides_b_true_to_divides.
 347 apply lt_O_smallest_factor ? H.
 348 change with
 349 eqb (mod (S(S m1)) (min_aux m1 (S(S m1))
 350   (\lambda m.(eqb (mod (S(S m1)) m) O)))) O = true.
 351 apply f_min_aux_true.
 352 apply ex_intro nat ? (S(S m1)).
 353 split.split.
 354 apply le_minus_m.apply le_n.
 355 rewrite > mod_n_n.reflexivity.
 356 apply trans_lt ? (S O).apply le_n (S O).simplify.
 357 apply le_S_S.apply le_S_S.apply le_O_n.
 358 qed.
 359
 360 theorem le_smallest_factor_n :
 361 \forall n:nat. smallest_factor n \le n.
 362 intro.apply nat_case n.simplify.reflexivity.
 363 intro.apply nat_case m.simplify.reflexivity.
 364 intro.apply divides_to_le.
 365 simplify.apply le_S_S.apply le_O_n.
 366 apply divides_smallest_factor_n.
 367 simplify.apply le_S_S.apply le_O_n.
 368 qed.
 369
 370 theorem lt_smallest_factor_to_not_divides: \forall n,i:nat.
 371 (S O) < n \to (S O) < i \to i < (smallest_factor n) \to \lnot (divides i n).
 372 intros 2.
 373 apply nat_case n.intro.apply False_ind.apply not_le_Sn_O (S O) H.
 374 intro.apply nat_case m.intro. apply False_ind.apply not_le_Sn_n (S O) H.
 375 intros.
 376 apply divides_b_false_to_not_divides.
 377 apply trans_lt O (S O).apply le_n (S O).assumption.
 378 change with (eqb (mod (S(S m1)) i) O) = false.
 379 apply lt_min_aux_to_false
 380 (\lambda i:nat.eqb (mod (S(S m1)) i) O) (S(S m1)) m1 i.
 381 cut (S(S O)) = (S(S m1)-m1).
 382 rewrite < Hcut.exact H1.
 383 apply sym_eq. apply plus_to_minus.
 384 apply le_S.apply le_n_Sn.
 385 rewrite < sym_plus.simplify.reflexivity.
 386 exact H2.
 387 qed.
 388
 389 theorem prime_smallest_factor_n :
 390 \forall n:nat. (S O) < n \to prime (smallest_factor n).
 391 intro. change with (S(S O)) \le n \to (S O) < (smallest_factor n) \land
 392 (\forall m:nat. divides m (smallest_factor n) \to (S O) < m \to  m = (smallest_factor n)).
 393 intro.split.
 394 apply lt_SO_smallest_factor.assumption.
 395 intros.
 396 cut le m (smallest_factor n).
 397 elim le_to_or_lt_eq m (smallest_factor n) Hcut.
 398 absurd divides m n.
 399 apply transitive_divides m (smallest_factor n).
 400 assumption.
 401 apply divides_smallest_factor_n.
 402 apply trans_lt ? (S O). simplify. apply le_n. exact H.
 403 apply lt_smallest_factor_to_not_divides.
 404 exact H.assumption.assumption.assumption.
 405 apply divides_to_le.
 406 apply trans_lt O (S O).
 407 apply le_n (S O).
 408 apply lt_SO_smallest_factor.
 409 exact H.
 410 assumption.
 411 qed.
 412
 413 theorem prime_to_smallest_factor: \forall n. prime n \to
 414 smallest_factor n = n.
 415 intro.apply nat_case n.intro.apply False_ind.apply not_prime_O H.
 416 intro.apply nat_case m.intro.apply False_ind.apply not_prime_SO H.
 417 intro.
 418 change with
 419 (S O) < (S(S m1)) \land
 420 (\forall m:nat. divides m (S(S m1)) \to (S O) < m \to  m = (S(S m1))) \to
 421 smallest_factor (S(S m1)) = (S(S m1)).
 422 intro.elim H.apply H2.
 423 apply divides_smallest_factor_n.
 424 apply trans_lt ? (S O).simplify. apply le_n.assumption.
 425 apply lt_SO_smallest_factor.
 426 assumption.
 427 qed.
 428
 429 (* a number n > O is prime iff its smallest factor is n *)
 430 definition primeb \def \lambda n:nat.
 431 match n with
 432 [ O \Rightarrow false
 433 | (S p) \Rightarrow
 434   match p with
 435   [ O \Rightarrow false
 436   | (S q) \Rightarrow eqb (smallest_factor (S(S q))) (S(S q))]].
 437
 438 (* it works!
 439 theorem example4 : primeb (S(S(S O))) = true.
 440 normalize.reflexivity.
 441 qed.
 442
 443 theorem example5 : primeb (S(S(S(S(S(S O)))))) = false.
 444 normalize.reflexivity.
 445 qed.
 446
 447 theorem example6 : primeb (S(S(S(S((S(S(S(S(S(S(S O)))))))))))) = true.
 448 normalize.reflexivity.
 449 qed.
 450
 451 theorem example7 : primeb (S(S(S(S(S(S((S(S(S(S((S(S(S(S(S(S(S O))))))))))))))))))) = true.
 452 normalize.reflexivity.
 453 qed. *)
 454
 455 theorem primeb_to_Prop: \forall n.
 456 match primeb n with
 457 [ true \Rightarrow prime n
 458 | false \Rightarrow \not (prime n)].
 459 intro.
 460 apply nat_case n.simplify.intro.elim H.apply not_le_Sn_O (S O) H1.
 461 intro.apply nat_case m.simplify.intro.elim H.apply not_le_Sn_n (S O) H1.
 462 intro.
 463 change with
 464 match eqb (smallest_factor (S(S m1))) (S(S m1)) with
 465 [ true \Rightarrow prime (S(S m1))
 466 | false \Rightarrow \not (prime (S(S m1)))].
 467 apply eqb_elim (smallest_factor (S(S m1))) (S(S m1)).
 468 intro.change with prime (S(S m1)).
 469 rewrite < H.
 470 apply prime_smallest_factor_n.
 471 simplify.apply le_S_S.apply le_S_S.apply le_O_n.
 472 intro.change with \not (prime (S(S m1))).
 473 change with prime (S(S m1)) \to False.
 474 intro.apply H.
 475 apply prime_to_smallest_factor.
 476 assumption.
 477 qed.
 478
 479 theorem primeb_true_to_prime : \forall n:nat.
 480 primeb n = true \to prime n.
 481 intros.change with
 482 match true with
 483 [ true \Rightarrow prime n
 484 | false \Rightarrow \not (prime n)].
 485 rewrite < H.
 486 apply primeb_to_Prop.
 487 qed.
 488
 489 theorem primeb_false_to_not_prime : \forall n:nat.
 490 primeb n = false \to \not (prime n).
 491 intros.change with
 492 match false with
 493 [ true \Rightarrow prime n
 494 | false \Rightarrow \not (prime n)].
 495 rewrite < H.
 496 apply primeb_to_Prop.
 497 qed.
 498
 499 theorem decidable_prime : \forall n:nat.decidable (prime n).
 500 intro.change with (prime n) \lor \not (prime n).
 501 cut
 502 match primeb n with
 503 [ true \Rightarrow prime n
 504 | false \Rightarrow \not (prime n)] \to (prime n) \lor \not (prime n).
 505 apply Hcut.apply primeb_to_Prop.
 506 elim (primeb n).left.apply H.right.apply H.
 507 qed.
 508
 509 theorem prime_to_primeb_true: \forall n:nat.
 510 prime n \to primeb n = true.
 511 intros.
 512 cut match (primeb n) with
 513 [ true \Rightarrow prime n
 514 | false \Rightarrow \not (prime n)] \to ((primeb n) = true).
 515 apply Hcut.apply primeb_to_Prop.
 516 elim primeb n.reflexivity.
 517 absurd (prime n).assumption.assumption.
 518 qed.
 519
 520 theorem not_prime_to_primeb_false: \forall n:nat.
 521 \not(prime n) \to primeb n = false.
 522 intros.
 523 cut match (primeb n) with
 524 [ true \Rightarrow prime n
 525 | false \Rightarrow \not (prime n)] \to ((primeb n) = false).
 526 apply Hcut.apply primeb_to_Prop.
 527 elim primeb n.
 528 absurd (prime n).assumption.assumption.
 529 reflexivity.
 530 qed.
 531