helm/matita/matitaEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30 exception Drop;;
  31 exception UnableToInclude of string
  32 exception IncludedFileNotCompiled of string
  33
  34 let debug = false ;;
  35 let debug_print = if debug then prerr_endline else ignore ;;
  36
  37 type options = {
  38   do_heavy_checks: bool ;
  39   include_paths: string list ;
  40   clean_baseuri: bool
  41 }
  42
  43 type statement =
  44   (CicNotationPt.term, CicNotationPt.term, GrafiteAst.reduction, GrafiteAst.obj,
  45    string)
  46   GrafiteAst.statement
  47
  48 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  49   * names as long as they are available, then it fallbacks to name generation
  50   * using FreshNamesGenerator module *)
  51 let namer_of names =
  52   let len = List.length names in
  53   let count = ref 0 in
  54   fun metasenv context name ~typ ->
  55     if !count < len then begin
  56       let name = Cic.Name (List.nth names !count) in
  57       incr count;
  58       name
  59     end else
  60       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  61
  62 let tactic_of_ast ast =
  63   let module PET = ProofEngineTypes in
  64   match ast with
  65   | GrafiteAst.Absurd (_, term) -> Tactics.absurd term
  66   | GrafiteAst.Apply (_, term) -> Tactics.apply term
  67   | GrafiteAst.Assumption _ -> Tactics.assumption
  68   | GrafiteAst.Auto (_,depth,width,paramodulation) ->
  69       AutoTactic.auto_tac ?depth ?width ?paramodulation
  70         ~dbd:(MatitaDb.instance ()) ()
  71   | GrafiteAst.Change (_, pattern, with_what) ->
  72      Tactics.change ~pattern with_what
  73   | GrafiteAst.Clear (_,id) -> Tactics.clear id
  74   | GrafiteAst.ClearBody (_,id) -> Tactics.clearbody id
  75   | GrafiteAst.Contradiction _ -> Tactics.contradiction
  76   | GrafiteAst.Compare (_, term) -> Tactics.compare term
  77   | GrafiteAst.Constructor (_, n) -> Tactics.constructor n
  78   | GrafiteAst.Cut (_, ident, term) ->
  79      let names = match ident with None -> [] | Some id -> [id] in
  80      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  81   | GrafiteAst.DecideEquality _ -> Tactics.decide_equality
  82   | GrafiteAst.Decompose (_, types, what, names) ->
  83       let to_type = function
  84          | GrafiteAst.Type (uri, typeno) -> uri, typeno
  85          | GrafiteAst.Ident _            -> assert false
  86       in
  87       let user_types = List.rev_map to_type types in
  88       let dbd = MatitaDb.instance () in
  89       let mk_fresh_name_callback = namer_of names in
  90       Tactics.decompose ~mk_fresh_name_callback ~dbd ~user_types what
  91   | GrafiteAst.Discriminate (_,term) -> Tactics.discriminate term
  92   | GrafiteAst.Elim (_, what, using, depth, names) ->
  93       Tactics.elim_intros ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  94         what
  95   | GrafiteAst.ElimType (_, what, using, depth, names) ->
  96       Tactics.elim_type ?using ?depth ~mk_fresh_name_callback:(namer_of names)
  97         what
  98   | GrafiteAst.Exact (_, term) -> Tactics.exact term
  99   | GrafiteAst.Exists _ -> Tactics.exists
 100   | GrafiteAst.Fail _ -> Tactics.fail
 101   | GrafiteAst.Fold (_, reduction_kind, term, pattern) ->
 102       let reduction =
 103         match reduction_kind with
 104         | `Normalize ->
 105             PET.const_lazy_reduction
 106               (CicReduction.normalize ~delta:false ~subst:[])
 107         | `Reduce -> PET.const_lazy_reduction ProofEngineReduction.reduce
 108         | `Simpl -> PET.const_lazy_reduction ProofEngineReduction.simpl
 109         | `Unfold None ->
 110             PET.const_lazy_reduction (ProofEngineReduction.unfold ?what:None)
 111         | `Unfold (Some lazy_term) ->
 112            (fun context metasenv ugraph ->
 113              let what, metasenv, ugraph = lazy_term context metasenv ugraph in
 114              ProofEngineReduction.unfold ~what, metasenv, ugraph)
 115         | `Whd ->
 116             PET.const_lazy_reduction (CicReduction.whd ~delta:false ~subst:[])
 117       in
 118       Tactics.fold ~reduction ~term ~pattern
 119   | GrafiteAst.Fourier _ -> Tactics.fourier
 120   | GrafiteAst.FwdSimpl (_, hyp, names) ->
 121      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names)
 122       ~dbd:(MatitaDb.instance ()) hyp
 123   | GrafiteAst.Generalize (_,pattern,ident) ->
 124      let names = match ident with None -> [] | Some id -> [id] in
 125      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
 126   | GrafiteAst.Goal (_, n) -> Tactics.set_goal n
 127   | GrafiteAst.IdTac _ -> Tactics.id
 128   | GrafiteAst.Injection (_,term) -> Tactics.injection term
 129   | GrafiteAst.Intros (_, None, names) ->
 130       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
 131   | GrafiteAst.Intros (_, Some num, names) ->
 132       PrimitiveTactics.intros_tac ~howmany:num
 133         ~mk_fresh_name_callback:(namer_of names) ()
 134   | GrafiteAst.LApply (_, how_many, to_what, what, ident) ->
 135       let names = match ident with None -> [] | Some id -> [id] in
 136       Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many
 137         ~to_what what
 138   | GrafiteAst.Left _ -> Tactics.left
 139   | GrafiteAst.LetIn (loc,term,name) ->
 140       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
 141   | GrafiteAst.Reduce (_, reduction_kind, pattern) ->
 142       (match reduction_kind with
 143       | `Normalize -> Tactics.normalize ~pattern
 144       | `Reduce -> Tactics.reduce ~pattern
 145       | `Simpl -> Tactics.simpl ~pattern
 146       | `Unfold what -> Tactics.unfold ~pattern what
 147       | `Whd -> Tactics.whd ~pattern)
 148   | GrafiteAst.Reflexivity _ -> Tactics.reflexivity
 149   | GrafiteAst.Replace (_, pattern, with_what) ->
 150      Tactics.replace ~pattern ~with_what
 151   | GrafiteAst.Rewrite (_, direction, t, pattern) ->
 152      EqualityTactics.rewrite_tac ~direction ~pattern t
 153   | GrafiteAst.Right _ -> Tactics.right
 154   | GrafiteAst.Ring _ -> Tactics.ring
 155   | GrafiteAst.Split _ -> Tactics.split
 156   | GrafiteAst.Symmetry _ -> Tactics.symmetry
 157   | GrafiteAst.Transitivity (_, term) -> Tactics.transitivity term
 158
 159 let singleton = function
 160   | [x], _ -> x
 161   | _ -> assert false
 162
 163 let disambiguate_term status_ref term =
 164   let status = !status_ref in
 165   let (aliases, metasenv, cic, _) =
 166     singleton
 167       (MatitaDisambiguator.disambiguate_term ~dbd:(MatitaDb.instance ())
 168         ~aliases:status.aliases ~universe:(Some status.multi_aliases)
 169         ~context:(MatitaMisc.get_proof_context status)
 170         ~metasenv:(MatitaMisc.get_proof_metasenv status) term)
 171   in
 172   let status = MatitaTypes.set_metasenv metasenv status in
 173   let status = MatitaSync.set_proof_aliases status aliases in
 174   status_ref := status;
 175   cic
 176
 177   (** disambiguate_lazy_term (circa): term -> (unit -> status) * lazy_term
 178    * rationale: lazy_term will be invoked in different context to obtain a term,
 179    * each invocation will disambiguate the term and can add aliases. Once all
 180    * disambiguations have been performed, the first returned function can be
 181    * used to obtain the resulting aliases *)
 182 let disambiguate_lazy_term status_ref term =
 183   (fun context metasenv ugraph ->
 184     let status = !status_ref in
 185     let (aliases, metasenv, cic, ugraph) =
 186       singleton
 187         (MatitaDisambiguator.disambiguate_term ~dbd:(MatitaDb.instance ())
 188           ~initial_ugraph:ugraph ~aliases:status.aliases
 189           ~universe:(Some status.multi_aliases) ~context ~metasenv term)
 190     in
 191     let status = MatitaTypes.set_metasenv metasenv status in
 192     let status = MatitaSync.set_proof_aliases status aliases in
 193     status_ref := status;
 194     cic, metasenv, ugraph)
 195
 196 let disambiguate_pattern status_ref (wanted, hyp_paths, goal_path) =
 197   let interp path = Disambiguate.interpretate_path [] path in
 198   let goal_path = interp goal_path in
 199   let hyp_paths = List.map (fun (name, path) -> name, interp path) hyp_paths in
 200   let wanted =
 201    match wanted with
 202       None -> None
 203     | Some wanted ->
 204        let wanted = disambiguate_lazy_term status_ref wanted in
 205        Some wanted
 206   in
 207   (wanted, hyp_paths ,goal_path)
 208
 209 let disambiguate_reduction_kind aliases_ref = function
 210   | `Unfold (Some t) ->
 211       let t = disambiguate_lazy_term aliases_ref t in
 212       `Unfold (Some t)
 213   | `Normalize
 214   | `Reduce
 215   | `Simpl
 216   | `Unfold None
 217   | `Whd as kind -> kind
 218
 219 let disambiguate_tactic status tactic =
 220   let status_ref = ref status in
 221   let tactic =
 222     match tactic with
 223     | GrafiteAst.Absurd (loc, term) ->
 224         let cic = disambiguate_term status_ref term in
 225         GrafiteAst.Absurd (loc, cic)
 226     | GrafiteAst.Apply (loc, term) ->
 227         let cic = disambiguate_term status_ref term in
 228         GrafiteAst.Apply (loc, cic)
 229     | GrafiteAst.Assumption loc -> GrafiteAst.Assumption loc
 230     | GrafiteAst.Auto (loc,depth,width,paramodulation) ->
 231         GrafiteAst.Auto (loc,depth,width,paramodulation)
 232     | GrafiteAst.Change (loc, pattern, with_what) ->
 233         let with_what = disambiguate_lazy_term status_ref with_what in
 234         let pattern = disambiguate_pattern status_ref pattern in
 235         GrafiteAst.Change (loc, pattern, with_what)
 236     | GrafiteAst.Clear (loc,id) -> GrafiteAst.Clear (loc,id)
 237     | GrafiteAst.ClearBody (loc,id) -> GrafiteAst.ClearBody (loc,id)
 238     | GrafiteAst.Compare (loc,term) ->
 239         let term = disambiguate_term status_ref term in
 240         GrafiteAst.Compare (loc,term)
 241     | GrafiteAst.Constructor (loc,n) -> GrafiteAst.Constructor (loc,n)
 242     | GrafiteAst.Contradiction loc -> GrafiteAst.Contradiction loc
 243     | GrafiteAst.Cut (loc, ident, term) ->
 244         let cic = disambiguate_term status_ref term in
 245         GrafiteAst.Cut (loc, ident, cic)
 246     | GrafiteAst.DecideEquality loc -> GrafiteAst.DecideEquality loc
 247     | GrafiteAst.Decompose (loc, types, what, names) ->
 248         let disambiguate types = function
 249            | GrafiteAst.Type _   -> assert false
 250            | GrafiteAst.Ident id ->
 251               (match disambiguate_term status_ref (CicNotationPt.Ident (id, None)) with
 252               | Cic.MutInd (uri, tyno, _) ->
 253                   (GrafiteAst.Type (uri, tyno) :: types)
 254               | _ -> raise Disambiguate.NoWellTypedInterpretation)
 255         in
 256         let types = List.fold_left disambiguate [] types in
 257         GrafiteAst.Decompose (loc, types, what, names)
 258     | GrafiteAst.Discriminate (loc,term) ->
 259         let term = disambiguate_term status_ref term in
 260         GrafiteAst.Discriminate(loc,term)
 261     | GrafiteAst.Exact (loc, term) ->
 262         let cic = disambiguate_term status_ref term in
 263         GrafiteAst.Exact (loc, cic)
 264     | GrafiteAst.Elim (loc, what, Some using, depth, idents) ->
 265         let what = disambiguate_term status_ref what in
 266         let using = disambiguate_term status_ref using in
 267         GrafiteAst.Elim (loc, what, Some using, depth, idents)
 268     | GrafiteAst.Elim (loc, what, None, depth, idents) ->
 269         let what = disambiguate_term status_ref what in
 270         GrafiteAst.Elim (loc, what, None, depth, idents)
 271     | GrafiteAst.ElimType (loc, what, Some using, depth, idents) ->
 272         let what = disambiguate_term status_ref what in
 273         let using = disambiguate_term status_ref using in
 274         GrafiteAst.ElimType (loc, what, Some using, depth, idents)
 275     | GrafiteAst.ElimType (loc, what, None, depth, idents) ->
 276         let what = disambiguate_term status_ref what in
 277         GrafiteAst.ElimType (loc, what, None, depth, idents)
 278     | GrafiteAst.Exists loc -> GrafiteAst.Exists loc
 279     | GrafiteAst.Fail loc -> GrafiteAst.Fail loc
 280     | GrafiteAst.Fold (loc,red_kind, term, pattern) ->
 281         let pattern = disambiguate_pattern status_ref pattern in
 282         let term = disambiguate_lazy_term status_ref term in
 283         let red_kind = disambiguate_reduction_kind status_ref red_kind in
 284         GrafiteAst.Fold (loc, red_kind, term, pattern)
 285     | GrafiteAst.FwdSimpl (loc, hyp, names) ->
 286        GrafiteAst.FwdSimpl (loc, hyp, names)
 287     | GrafiteAst.Fourier loc -> GrafiteAst.Fourier loc
 288     | GrafiteAst.Generalize (loc,pattern,ident) ->
 289         let pattern = disambiguate_pattern status_ref pattern in
 290         GrafiteAst.Generalize (loc,pattern,ident)
 291     | GrafiteAst.Goal (loc, g) -> GrafiteAst.Goal (loc, g)
 292     | GrafiteAst.IdTac loc -> GrafiteAst.IdTac loc
 293     | GrafiteAst.Injection (loc, term) ->
 294         let term = disambiguate_term status_ref term in
 295         GrafiteAst.Injection (loc,term)
 296     | GrafiteAst.Intros (loc, num, names) -> GrafiteAst.Intros (loc, num, names)
 297     | GrafiteAst.LApply (loc, depth, to_what, what, ident) ->
 298        let f term to_what =
 299           let term = disambiguate_term status_ref term in
 300           term :: to_what
 301        in
 302        let to_what = List.fold_right f to_what [] in
 303        let what = disambiguate_term status_ref what in
 304        GrafiteAst.LApply (loc, depth, to_what, what, ident)
 305     | GrafiteAst.Left loc -> GrafiteAst.Left loc
 306     | GrafiteAst.LetIn (loc, term, name) ->
 307         let term = disambiguate_term status_ref term in
 308         GrafiteAst.LetIn (loc,term,name)
 309     | GrafiteAst.Reduce (loc, red_kind, pattern) ->
 310         let pattern = disambiguate_pattern status_ref pattern in
 311         let red_kind = disambiguate_reduction_kind status_ref red_kind in
 312         GrafiteAst.Reduce(loc, red_kind, pattern)
 313     | GrafiteAst.Reflexivity loc -> GrafiteAst.Reflexivity loc
 314     | GrafiteAst.Replace (loc, pattern, with_what) ->
 315         let pattern = disambiguate_pattern status_ref pattern in
 316         let with_what = disambiguate_lazy_term status_ref with_what in
 317         GrafiteAst.Replace (loc, pattern, with_what)
 318     | GrafiteAst.Rewrite (loc, dir, t, pattern) ->
 319         let term = disambiguate_term status_ref t in
 320         let pattern = disambiguate_pattern status_ref pattern in
 321         GrafiteAst.Rewrite (loc, dir, term, pattern)
 322     | GrafiteAst.Right loc -> GrafiteAst.Right loc
 323     | GrafiteAst.Ring loc -> GrafiteAst.Ring loc
 324     | GrafiteAst.Split loc -> GrafiteAst.Split loc
 325     | GrafiteAst.Symmetry loc -> GrafiteAst.Symmetry loc
 326     | GrafiteAst.Transitivity (loc, term) ->
 327         let cic = disambiguate_term status_ref term in
 328         GrafiteAst.Transitivity (loc, cic)
 329   in
 330   status_ref, tactic
 331
 332 let apply_tactic tactic status =
 333  let status_ref, tactic = disambiguate_tactic status tactic in
 334  let proof_status = MatitaMisc.get_proof_status !status_ref in
 335  let tactic = tactic_of_ast tactic in
 336  (* apply tactic will change the status pointed by status_ref ... *)
 337  let (proof, goals) = ProofEngineTypes.apply_tactic tactic proof_status in
 338  let dummy = -1 in
 339  { !status_ref with
 340     proof_status = MatitaTypes.Incomplete_proof (proof,dummy) },
 341  goals
 342
 343 module MatitaStatus =
 344  struct
 345   type input_status = MatitaTypes.status
 346   type output_status = MatitaTypes.status * ProofEngineTypes.goal list
 347   type tactic = input_status -> output_status
 348
 349   let focus (status,_) goal =
 350    let proof,_ = MatitaMisc.get_proof_status status in
 351     {status with proof_status = MatitaTypes.Incomplete_proof (proof,goal)}
 352
 353   let goals (_,goals) = goals
 354
 355   let set_goals (status,_) goals = status,goals
 356
 357   let id_tac status =
 358     apply_tactic (GrafiteAst.IdTac DisambiguateTypes.dummy_floc) status
 359
 360   let mk_tactic tac = tac
 361
 362   let apply_tactic tac = tac
 363
 364  end
 365
 366 module MatitaTacticals = Tacticals.Make(MatitaStatus)
 367
 368 let eval_tactical status tac =
 369  let rec tactical_of_ast tac =
 370   match tac with
 371     | GrafiteAst.Tactic (loc, tactic) -> apply_tactic tactic
 372     | GrafiteAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 373        MatitaTacticals.seq ~tactics:(List.map tactical_of_ast tacticals)
 374     | GrafiteAst.Do (loc, num, tactical) ->
 375         MatitaTacticals.do_tactic ~n:num ~tactic:(tactical_of_ast tactical)
 376     | GrafiteAst.Repeat (loc, tactical) ->
 377         MatitaTacticals.repeat_tactic ~tactic:(tactical_of_ast tactical)
 378     | GrafiteAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 379         MatitaTacticals.thens ~start:(tactical_of_ast tactical)
 380           ~continuations:(List.map tactical_of_ast tacticals)
 381     | GrafiteAst.First (loc, tacticals) ->
 382         MatitaTacticals.first
 383           ~tactics:(List.map (fun t -> "", tactical_of_ast t) tacticals)
 384     | GrafiteAst.Try (loc, tactical) ->
 385         MatitaTacticals.try_tactic ~tactic:(tactical_of_ast tactical)
 386     | GrafiteAst.Solve (loc, tacticals) ->
 387         MatitaTacticals.solve_tactics
 388          ~tactics:(List.map (fun t -> "",tactical_of_ast t) tacticals)
 389  in
 390   let status,goals = tactical_of_ast tac status in
 391   let proof,_ = MatitaMisc.get_proof_status status in
 392   let new_status =
 393    match goals with
 394    | [] ->
 395        let (_,metasenv,_,_) = proof in
 396        (match metasenv with
 397        | [] -> Proof proof
 398        | (ng,_,_)::_ -> Incomplete_proof (proof,ng))
 399    | ng::_ -> Incomplete_proof (proof, ng)
 400   in
 401    { status with proof_status = new_status }
 402
 403 let eval_coercion status coercion =
 404   let coer_uri,coer_ty =
 405     match coercion with
 406     | Cic.Const (uri,_)
 407     | Cic.Var (uri,_) ->
 408         let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 409         (match o with
 410         | Cic.Constant (_,_,ty,_,_)
 411         | Cic.Variable (_,_,ty,_,_) ->
 412             uri,ty
 413         | _ -> assert false)
 414     | Cic.MutConstruct (uri,t,c,_) ->
 415         let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 416         (match o with
 417         | Cic.InductiveDefinition (l,_,_,_) ->
 418             let (_,_,_,cl) = List.nth l t in
 419             let (_,cty) = List.nth cl c in
 420               uri,cty
 421         | _ -> assert false)
 422     | _ -> assert false
 423   in
 424   (* we have to get the source and the tgt type uri
 425    * in Coq syntax we have already their names, but
 426    * since we don't support Funclass and similar I think
 427    * all the coercion should be of the form
 428    * (A:?)(B:?)T1->T2
 429    * So we should be able to extract them from the coercion type
 430    *)
 431   let extract_last_two_p ty =
 432     let rec aux = function
 433       | Cic.Prod( _, src, Cic.Prod (n,t1,t2)) -> aux (Cic.Prod(n,t1,t2))
 434       | Cic.Prod( _, src, tgt) -> src, tgt
 435       | _ -> assert false
 436     in
 437     aux ty
 438   in
 439   let ty_src,ty_tgt = extract_last_two_p coer_ty in
 440   let context = [] in
 441   let src_uri =
 442     let ty_src = CicReduction.whd context ty_src in
 443      CicUtil.uri_of_term ty_src
 444   in
 445   let tgt_uri =
 446     let ty_tgt = CicReduction.whd context ty_tgt in
 447      CicUtil.uri_of_term ty_tgt
 448   in
 449   let new_coercions =
 450     (* also adds them to the Db *)
 451     CoercGraph.close_coercion_graph src_uri tgt_uri coer_uri in
 452   let status =
 453    List.fold_left (fun s (uri,o,ugraph) -> MatitaSync.add_obj uri o status)
 454     status new_coercions in
 455   let statement_of name =
 456     GrafiteAst.Coercion (DisambiguateTypes.dummy_floc,
 457       (CicNotationPt.Ident (name, None)))
 458   in
 459   let moo_content =
 460     statement_of (UriManager.name_of_uri coer_uri) ::
 461     (List.map
 462       (fun (uri, _, _) ->
 463         statement_of (UriManager.name_of_uri uri))
 464     new_coercions)
 465   in
 466   let status = add_moo_content moo_content status in
 467   { status with proof_status = No_proof }
 468
 469 let generate_elimination_principles uri status =
 470  let elim sort status =
 471    try
 472     let uri,obj = CicElim.elim_of ~sort uri 0 in
 473      MatitaSync.add_obj uri obj status
 474    with CicElim.Can_t_eliminate -> status
 475  in
 476  List.fold_left (fun status sort -> elim sort status) status
 477   [ Cic.Prop; Cic.Set; (Cic.Type (CicUniv.fresh ())) ]
 478
 479 let generate_projections uri fields status =
 480  let projections = CicRecord.projections_of uri fields in
 481   List.fold_left
 482    (fun status (uri, name, bo) ->
 483      try
 484       let ty, ugraph =
 485         CicTypeChecker.type_of_aux' [] [] bo CicUniv.empty_ugraph in
 486       let attrs = [`Class `Projection; `Generated] in
 487       let obj = Cic.Constant (name,Some bo,ty,[],attrs) in
 488        MatitaSync.add_obj uri obj status
 489      with
 490         CicTypeChecker.TypeCheckerFailure s ->
 491          MatitaLog.message
 492           ("Unable to create projection " ^ name ^ " cause: " ^ s);
 493          status
 494       | CicEnvironment.Object_not_found uri ->
 495          let depend = UriManager.name_of_uri uri in
 496           MatitaLog.message
 497            ("Unable to create projection " ^ name ^ " because it requires " ^ depend);
 498          status
 499   ) status projections
 500
 501 (* to avoid a long list of recursive functions *)
 502 let eval_from_stream_ref = ref (fun _ _ _ -> assert false);;
 503
 504 let disambiguate_obj status obj =
 505   let uri =
 506    match obj with
 507       GrafiteAst.Inductive (_,(name,_,_,_)::_)
 508     | GrafiteAst.Record (_,name,_,_) ->
 509        Some (UriManager.uri_of_string (MatitaMisc.qualify status name ^ ".ind"))
 510     | GrafiteAst.Inductive _ -> assert false
 511     | GrafiteAst.Theorem _ -> None in
 512   let (aliases, metasenv, cic, _) =
 513     singleton
 514       (MatitaDisambiguator.disambiguate_obj ~dbd:(MatitaDb.instance ())
 515         ~aliases:status.aliases ~universe:(Some status.multi_aliases) ~uri obj)
 516   in
 517   let proof_status =
 518     match status.proof_status with
 519     | No_proof -> Intermediate metasenv
 520     | Incomplete_proof _
 521     | Proof _ -> command_error "imbricated proofs not allowed"
 522     | Intermediate _ -> assert false
 523   in
 524   let status = { status with proof_status = proof_status } in
 525   let status = MatitaSync.set_proof_aliases status aliases in
 526   status, cic
 527
 528 let disambiguate_command status = function
 529   | GrafiteAst.Alias _
 530   | GrafiteAst.Default _
 531   | GrafiteAst.Drop _
 532   | GrafiteAst.Dump _
 533   | GrafiteAst.Include _
 534   | GrafiteAst.Interpretation _
 535   | GrafiteAst.Notation _
 536   | GrafiteAst.Qed _
 537   | GrafiteAst.Render _
 538   | GrafiteAst.Set _ as cmd ->
 539       status,cmd
 540   | GrafiteAst.Coercion (loc, term) ->
 541       let status_ref = ref status in
 542       let term = disambiguate_term status_ref term in
 543       !status_ref, GrafiteAst.Coercion (loc,term)
 544   | GrafiteAst.Obj (loc,obj) ->
 545       let status,obj = disambiguate_obj status obj in
 546       status, GrafiteAst.Obj (loc,obj)
 547
 548 let make_absolute paths path =
 549   if path = "coq.ma" then path
 550   else
 551    let rec aux = function
 552    | [] -> ignore (Unix.stat path); path
 553    | p :: tl ->
 554       let path = p ^ "/" ^ path in
 555        try
 556          ignore (Unix.stat path); path
 557        with Unix.Unix_error _ -> aux tl
 558    in
 559    try
 560      aux paths
 561    with Unix.Unix_error _ as exc -> raise (UnableToInclude path)
 562 ;;
 563
 564 let eval_command opts status cmd =
 565   let status,cmd = disambiguate_command status cmd in
 566   let cmd,notation_ids' = CicNotation.process_notation cmd in
 567   let status =
 568     { status with notation_ids = notation_ids' @ status.notation_ids }
 569   in
 570   match cmd with
 571   | GrafiteAst.Default (loc, what, uris) as cmd ->
 572      LibraryObjects.set_default what uris;
 573      add_moo_content [cmd] status
 574   | GrafiteAst.Include (loc, path) ->
 575      let absolute_path = make_absolute opts.include_paths path in
 576      let moopath = MatitaMisc.obj_file_of_script absolute_path in
 577      let ic =
 578       try open_in moopath with Sys_error _ ->
 579         raise (IncludedFileNotCompiled moopath) in
 580      let stream = Stream.of_channel ic in
 581      let status = ref status in
 582       !eval_from_stream_ref status stream (fun _ _ -> ());
 583       close_in ic;
 584       !status
 585   | GrafiteAst.Set (loc, name, value) ->
 586       let value =
 587         if name = "baseuri" then
 588           let v = MatitaMisc.strip_trailing_slash value in
 589           try
 590             ignore (String.index v ' ');
 591             command_error "baseuri can't contain spaces"
 592           with Not_found -> v
 593         else
 594           value
 595       in
 596       if not (MatitaMisc.is_empty value) then
 597         begin
 598           MatitaLog.warn ("baseuri " ^ value ^ " is not empty");
 599           if opts.clean_baseuri then
 600             begin
 601               MatitaLog.message ("cleaning baseuri " ^ value);
 602               MatitacleanLib.clean_baseuris [value]
 603             end
 604         end;
 605       set_option status name value
 606   | GrafiteAst.Drop loc -> raise Drop
 607   | GrafiteAst.Qed loc ->
 608       let uri, metasenv, bo, ty =
 609         match status.proof_status with
 610         | Proof (Some uri, metasenv, body, ty) ->
 611             uri, metasenv, body, ty
 612         | Proof (None, metasenv, body, ty) ->
 613             command_error
 614               ("Someone allows to start a thm without giving the "^
 615                "name/uri. This should be fixed!")
 616         | _-> command_error "You can't qed an uncomplete theorem"
 617       in
 618       let suri = UriManager.string_of_uri uri in
 619       if metasenv <> [] then
 620         command_error "Proof not completed! metasenv is not empty!";
 621       let name = UriManager.name_of_uri uri in
 622       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 623       MatitaSync.add_obj uri obj status
 624   | GrafiteAst.Coercion (loc, coercion) ->
 625       eval_coercion status coercion
 626   | GrafiteAst.Alias (loc, spec) ->
 627      let aliases =
 628       (*CSC: Warning: this code should be factorized with the corresponding
 629              code in DisambiguatePp *)
 630       match spec with
 631       | GrafiteAst.Ident_alias (id,uri) ->
 632          DisambiguateTypes.Environment.add
 633           (DisambiguateTypes.Id id)
 634           (uri,(fun _ _ _-> CicUtil.term_of_uri (UriManager.uri_of_string uri)))
 635           status.aliases
 636       | GrafiteAst.Symbol_alias (symb, instance, desc) ->
 637          DisambiguateTypes.Environment.add
 638           (DisambiguateTypes.Symbol (symb,instance))
 639           (DisambiguateChoices.lookup_symbol_by_dsc symb desc)
 640           status.aliases
 641       | GrafiteAst.Number_alias (instance,desc) ->
 642          DisambiguateTypes.Environment.add
 643           (DisambiguateTypes.Num instance)
 644           (DisambiguateChoices.lookup_num_by_dsc desc) status.aliases
 645      in
 646       MatitaSync.set_proof_aliases status aliases
 647   | GrafiteAst.Render _ -> assert false (* ZACK: to be removed *)
 648   | GrafiteAst.Dump _ -> assert false   (* ZACK: to be removed *)
 649   | GrafiteAst.Interpretation (_, dsc, (symbol, _), _) as stm ->
 650       let status' = add_moo_content [stm] status in
 651       let aliases' =
 652         DisambiguateTypes.Environment.add
 653           (DisambiguateTypes.Symbol (symbol, 0))
 654           (DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 655           status.aliases
 656       in
 657       MatitaSync.set_proof_aliases status' aliases'
 658   | GrafiteAst.Notation _ as stm -> add_moo_content [stm] status
 659   | GrafiteAst.Obj (loc,obj) ->
 660      let ext,name =
 661       match obj with
 662          Cic.Constant (name,_,_,_,_)
 663        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 664        | Cic.InductiveDefinition (types,_,_,_) ->
 665           ".ind",
 666           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 667        | _ -> assert false in
 668      let uri =
 669        UriManager.uri_of_string (MatitaMisc.qualify status name ^ ext)
 670      in
 671      let metasenv = MatitaMisc.get_proof_metasenv status in
 672      match obj with
 673      | Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 674          let name = UriManager.name_of_uri uri in
 675          if not(CicPp.check name ty) then
 676            MatitaLog.error ("Bad name: " ^ name);
 677          if opts.do_heavy_checks then
 678            begin
 679              let dbd = MatitaDb.instance () in
 680              let similar = MetadataQuery.match_term ~dbd ty in
 681              let similar_len = List.length similar in
 682              if similar_len> 30 then
 683                (MatitaLog.message
 684                  ("Duplicate check will compare your theorem with " ^
 685                    string_of_int similar_len ^
 686                    " theorems, this may take a while."));
 687              let convertible =
 688                List.filter (
 689                  fun u ->
 690                    let t = CicUtil.term_of_uri u in
 691                    let ty',g =
 692                      CicTypeChecker.type_of_aux'
 693                        metasenv' [] t CicUniv.empty_ugraph
 694                    in
 695                    fst(CicReduction.are_convertible [] ty' ty g))
 696                similar
 697              in
 698              (match convertible with
 699              | [] -> ()
 700              | x::_ ->
 701                  MatitaLog.warn
 702                  ("Theorem already proved: " ^ UriManager.string_of_uri x ^
 703                   "\nPlease use a variant."));
 704            end;
 705          assert (metasenv = metasenv');
 706          let goalno =
 707            match metasenv' with (goalno,_,_)::_ -> goalno | _ -> assert false
 708          in
 709          let initial_proof = (Some uri, metasenv, bo, ty) in
 710          { status with proof_status = Incomplete_proof (initial_proof,goalno)}
 711      | _ ->
 712          if metasenv <> [] then
 713           command_error (
 714             "metasenv not empty while giving a definition with body: " ^
 715             CicMetaSubst.ppmetasenv [] metasenv);
 716          let status = MatitaSync.add_obj uri obj status in
 717           match obj with
 718              Cic.Constant _ -> status
 719            | Cic.InductiveDefinition (_,_,_,attrs) ->
 720               let status = generate_elimination_principles uri status in
 721               let rec get_record_attrs =
 722                function
 723                   [] -> None
 724                 | (`Class (`Record fields))::_ -> Some fields
 725                 | _::tl -> get_record_attrs tl
 726               in
 727                (match get_record_attrs attrs with
 728                    None -> status (* not a record *)
 729                  | Some fields -> generate_projections uri fields status)
 730            | Cic.CurrentProof _
 731            | Cic.Variable _ -> assert false
 732
 733 let eval_executable opts status ex =
 734   match ex with
 735   | GrafiteAst.Tactical (_, tac) -> eval_tactical status tac
 736   | GrafiteAst.Command (_, cmd) -> eval_command opts status cmd
 737   | GrafiteAst.Macro (_, mac) ->
 738       command_error (sprintf "The macro %s can't be in a script"
 739         (GrafiteAstPp.pp_macro_ast mac))
 740
 741 let eval_comment status c = status
 742
 743
 744 let eval_ast
 745   ?(do_heavy_checks=false) ?(include_paths=[]) ?(clean_baseuri=true) status st
 746 =
 747   let opts = {
 748     do_heavy_checks = do_heavy_checks ;
 749     include_paths = include_paths;
 750     clean_baseuri = clean_baseuri }
 751   in
 752   match st with
 753   | GrafiteAst.Executable (_,ex) -> eval_executable opts status ex
 754   | GrafiteAst.Comment (_,c) -> eval_comment status c
 755
 756 let eval_from_stream
 757   ?do_heavy_checks ?include_paths ?clean_baseuri status str cb
 758 =
 759   try
 760     while true do
 761       let ast = GrafiteParser.parse_statement str in
 762       cb !status ast;
 763       status := eval_ast ?do_heavy_checks ?include_paths ?clean_baseuri !status ast
 764     done
 765   with End_of_file -> ()
 766
 767 (* to avoid a long list of recursive functions *)
 768 let _ = eval_from_stream_ref := eval_from_stream
 769
 770 let eval_from_stream_greedy
 771   ?do_heavy_checks ?include_paths ?clean_baseuri status str cb
 772 =
 773   while true do
 774     print_string "matita> ";
 775     flush stdout;
 776     let ast = GrafiteParser.parse_statement str in
 777     cb !status ast;
 778     status := eval_ast ?do_heavy_checks ?include_paths ?clean_baseuri !status ast
 779   done
 780 ;;
 781
 782 let eval_string ?do_heavy_checks ?include_paths ?clean_baseuri status str =
 783   eval_from_stream
 784     ?do_heavy_checks ?include_paths ?clean_baseuri status (Stream.of_string str) (fun _ _ ->())
 785
 786 let default_options () =
 787 (*
 788   let options =
 789     StringMap.add "baseuri"
 790       (String
 791         (Helm_registry.get "matita.baseuri" ^ Helm_registry.get "matita.owner"))
 792       no_options
 793   in
 794 *)
 795   let options =
 796     StringMap.add "basedir"
 797       (String (Helm_registry.get "matita.basedir"))
 798       no_options
 799   in
 800   options
 801
 802 let initial_status =
 803   lazy {
 804     aliases = DisambiguateTypes.Environment.empty;
 805     multi_aliases = DisambiguateTypes.Environment.empty;
 806     moo_content_rev = [];
 807     proof_status = No_proof;
 808     options = default_options ();
 809     objects = [];
 810     notation_ids = [];
 811   }
 812