helm/matita/matitaEngine.ml

   1
   2 open Printf
   3 open MatitaTypes
   4
   5 exception Drop;;
   6
   7 let debug = false ;;
   8 let debug_print = if debug then prerr_endline else ignore ;;
   9
  10 (** create a ProofEngineTypes.mk_fresh_name_type function which uses given
  11   * names as long as they are available, then it fallbacks to name generation
  12   * using FreshNamesGenerator module *)
  13 let namer_of names =
  14   let len = List.length names in
  15   let count = ref 0 in
  16   fun metasenv context name ~typ ->
  17     if !count < len then begin
  18       let name = Cic.Name (List.nth names !count) in
  19       incr count;
  20       name
  21     end else
  22       FreshNamesGenerator.mk_fresh_name ~subst:[] metasenv context name ~typ
  23
  24 let tactic_of_ast = function
  25   | TacticAst.Absurd (_, term) -> Tactics.absurd term
  26   | TacticAst.Apply (_, term) -> Tactics.apply term
  27   | TacticAst.Assumption _ -> Tactics.assumption
  28   | TacticAst.Auto (_,depth,width) ->
  29       AutoTactic.auto_tac ?depth ?width ~dbd:(MatitaDb.instance ()) ()
  30   | TacticAst.Change (_, pattern, with_what) ->
  31      Tactics.change ~pattern with_what
  32   | TacticAst.Clear (_,id) -> Tactics.clear id
  33   | TacticAst.ClearBody (_,id) -> Tactics.clearbody id
  34   | TacticAst.Contradiction _ -> Tactics.contradiction
  35   | TacticAst.Compare (_, term) -> Tactics.compare term
  36   | TacticAst.Constructor (_, n) -> Tactics.constructor n
  37   | TacticAst.Cut (_, ident, term) ->
  38      let names = match ident with None -> [] | Some id -> [id] in
  39      Tactics.cut ~mk_fresh_name_callback:(namer_of names) term
  40   | TacticAst.DecideEquality _ -> Tactics.decide_equality
  41   | TacticAst.Decompose (_,term) -> Tactics.decompose term
  42   | TacticAst.Discriminate (_,term) -> Tactics.discriminate term
  43   | TacticAst.Elim (_, term, _) ->
  44       Tactics.elim_intros term
  45   | TacticAst.ElimType (_, term) -> Tactics.elim_type term
  46   | TacticAst.Exact (_, term) -> Tactics.exact term
  47   | TacticAst.Exists _ -> Tactics.exists
  48   | TacticAst.Fail _ -> Tactics.fail
  49   | TacticAst.Fold (_, reduction_kind, term, pattern) ->
  50      let reduction =
  51       match reduction_kind with
  52        | `Normalize -> CicReduction.normalize ~delta:false ~subst:[]
  53        | `Reduce -> ProofEngineReduction.reduce
  54        | `Simpl -> ProofEngineReduction.simpl
  55        | `Whd -> CicReduction.whd ~delta:false ~subst:[]
  56      in
  57       Tactics.fold ~reduction ~term ~pattern
  58   | TacticAst.Fourier _ -> Tactics.fourier
  59   | TacticAst.FwdSimpl (_, hyp, names) ->
  60      Tactics.fwd_simpl ~mk_fresh_name_callback:(namer_of names) ~dbd:(MatitaDb.instance ()) hyp
  61   | TacticAst.Generalize (_,pattern,ident) ->
  62      let names = match ident with None -> [] | Some id -> [id] in
  63      Tactics.generalize ~mk_fresh_name_callback:(namer_of names) pattern
  64   | TacticAst.Goal (_, n) -> Tactics.set_goal n
  65   | TacticAst.IdTac _ -> Tactics.id
  66   | TacticAst.Injection (_,term) -> Tactics.injection term
  67   | TacticAst.Intros (_, None, names) ->
  68       PrimitiveTactics.intros_tac ~mk_fresh_name_callback:(namer_of names) ()
  69   | TacticAst.Intros (_, Some num, names) ->
  70       PrimitiveTactics.intros_tac ~howmany:num
  71         ~mk_fresh_name_callback:(namer_of names) ()
  72   | TacticAst.LApply (_, how_many, to_what, what, ident) ->
  73      let names = match ident with None -> [] | Some id -> [id] in
  74      Tactics.lapply ~mk_fresh_name_callback:(namer_of names) ?how_many ~to_what what
  75   | TacticAst.Left _ -> Tactics.left
  76   | TacticAst.LetIn (loc,term,name) ->
  77       Tactics.letin term ~mk_fresh_name_callback:(namer_of [name])
  78   | TacticAst.Reduce (_, reduction_kind, pattern) ->
  79       (match reduction_kind with
  80       | `Normalize -> Tactics.normalize ~pattern
  81       | `Reduce -> Tactics.reduce ~pattern
  82       | `Simpl -> Tactics.simpl ~pattern
  83       | `Whd -> Tactics.whd ~pattern)
  84   | TacticAst.Reflexivity _ -> Tactics.reflexivity
  85   | TacticAst.Replace (_, pattern, with_what) ->
  86      Tactics.replace ~pattern ~with_what
  87   | TacticAst.Rewrite (_, direction, t, pattern) ->
  88      EqualityTactics.rewrite_tac ~direction ~pattern t
  89   | TacticAst.Right _ -> Tactics.right
  90   | TacticAst.Ring _ -> Tactics.ring
  91   | TacticAst.Split _ -> Tactics.split
  92   | TacticAst.Symmetry _ -> Tactics.symmetry
  93   | TacticAst.Transitivity (_, term) -> Tactics.transitivity term
  94
  95 let eval_tactical status tac =
  96   let apply_tactic tactic =
  97     let (proof, goals) =
  98       ProofEngineTypes.apply_tactic tactic (MatitaMisc.get_proof_status status)
  99     in
 100     let new_status =
 101       match goals with
 102       | [] ->
 103           let (_,metasenv,_,_) = proof in
 104           (match metasenv with
 105           | [] -> Proof proof
 106           | (ng,_,_)::_ -> Incomplete_proof (proof,ng))
 107       | ng::_ -> Incomplete_proof (proof, ng)
 108     in
 109     { status with proof_status = new_status }
 110   in
 111   let rec tactical_of_ast = function
 112     | TacticAst.Tactic (loc, tactic) -> tactic_of_ast tactic
 113     | TacticAst.Do (loc, num, tactical) ->
 114         Tacticals.do_tactic num (tactical_of_ast tactical)
 115     | TacticAst.Repeat (loc, tactical) ->
 116         Tacticals.repeat_tactic (tactical_of_ast tactical)
 117     | TacticAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 118         Tacticals.seq (List.map tactical_of_ast tacticals)
 119     | TacticAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 120         Tacticals.thens (tactical_of_ast tactical)
 121           (List.map tactical_of_ast tacticals)
 122     | TacticAst.Tries (loc, tacticals) ->
 123         Tacticals.try_tactics
 124           (List.map (fun t -> "", tactical_of_ast t) tacticals)
 125     | TacticAst.Try (loc, tactical) ->
 126         Tacticals.try_tactic (tactical_of_ast tactical)
 127   in
 128   apply_tactic (tactical_of_ast tac)
 129
 130 let eval_coercion status coercion =
 131   let coer_uri,coer_ty =
 132     match coercion with
 133     | Cic.Const (uri,_)
 134     | Cic.Var (uri,_) ->
 135         let o,_ =
 136           CicEnvironment.get_obj CicUniv.empty_ugraph uri
 137         in
 138         (match o with
 139         | Cic.Constant (_,_,ty,_,_)
 140         | Cic.Variable (_,_,ty,_,_) ->
 141             uri,ty
 142         | _ -> assert false)
 143     | Cic.MutConstruct (uri,t,c,_) ->
 144         let o,_ =
 145           CicEnvironment.get_obj CicUniv.empty_ugraph uri
 146         in
 147         (match o with
 148         | Cic.InductiveDefinition (l,_,_,_) ->
 149             let (_,_,_,cl) = List.nth l t in
 150             let (_,cty) = List.nth cl c in
 151               uri,cty
 152         | _ -> assert false)
 153     | _ -> assert false
 154   in
 155   (* we have to get the source and the tgt type uri
 156    * in Coq syntax we have already their names, but
 157    * since we don't support Funclass and similar I think
 158    * all the coercion should be of the form
 159    * (A:?)(B:?)T1->T2
 160    * So we should be able to extract them from the coercion type
 161    *)
 162   let extract_last_two_p ty =
 163     let rec aux = function
 164       | Cic.Prod( _, src, Cic.Prod (n,t1,t2)) -> aux (Cic.Prod(n,t1,t2))
 165       | Cic.Prod( _, src, tgt) -> src, tgt
 166       | _ -> assert false
 167     in
 168     aux ty
 169   in
 170   let ty_src,ty_tgt = extract_last_two_p coer_ty in
 171   let context = [] in
 172   let src_uri =
 173     let ty_src = CicReduction.whd context ty_src in
 174      CicUtil.uri_of_term ty_src
 175   in
 176   let tgt_uri =
 177     let ty_tgt = CicReduction.whd context ty_tgt in
 178      CicUtil.uri_of_term ty_tgt
 179   in
 180   let new_coercions =
 181     (* also adds them to the Db *)
 182     CoercGraph.close_coercion_graph src_uri tgt_uri coer_uri in
 183   let status =
 184    List.fold_left (fun s (uri,o,ugraph) -> MatitaSync.add_obj uri o status)
 185     status new_coercions in
 186   {status with proof_status = No_proof}
 187
 188 let generate_elimination_principles uri status =
 189  let elim sort status =
 190    try
 191     let uri,obj = CicElim.elim_of ~sort uri 0 in
 192      MatitaSync.add_obj uri obj status
 193    with CicElim.Can_t_eliminate -> status
 194  in
 195  List.fold_left (fun status sort -> elim sort status) status
 196   [ Cic.Prop; Cic.Set; (Cic.Type (CicUniv.fresh ())) ]
 197
 198 let generate_projections uri fields status =
 199  let projections = CicRecord.projections_of uri fields in
 200   List.fold_left
 201    (fun status (uri, name, bo) ->
 202      try
 203       let ty, ugraph =
 204         CicTypeChecker.type_of_aux' [] [] bo CicUniv.empty_ugraph in
 205       let bo = Unshare.unshare bo in
 206       let ty = Unshare.unshare ty in
 207       let attrs = [`Class `Projection; `Generated] in
 208       let obj = Cic.Constant (name,Some bo,ty,[],attrs) in
 209        MatitaSync.add_obj uri obj status
 210      with
 211         CicTypeChecker.TypeCheckerFailure s ->
 212          MatitaLog.message
 213           ("Unable to create projection " ^ name ^ " cause: " ^ s);
 214          status
 215       | CicEnvironment.Object_not_found uri ->
 216          let depend = UriManager.name_of_uri uri in
 217           MatitaLog.message
 218            ("Unable to create projection " ^ name ^ " because it requires " ^ depend);
 219          status
 220   ) status projections
 221
 222 (* to avoid a long list of recursive functions *)
 223 let eval_from_stream_ref = ref (fun _ _ _ -> assert false);;
 224
 225 let eval_command status cmd =
 226   match cmd with
 227   | TacticAst.Include (loc, path) ->
 228      let path = MatitaMisc.obj_file_of_script path in
 229      let stream = Stream.of_channel (open_in path) in
 230      let status = ref status in
 231       !eval_from_stream_ref status stream (fun _ _ -> ());
 232       !status
 233   | TacticAst.Set (loc, name, value) ->
 234       let value =
 235         if name = "baseuri" then
 236           MatitaMisc.strip_trailing_slash value
 237         else
 238           value
 239       in
 240       set_option status name value
 241   | TacticAst.Drop loc -> raise Drop
 242   | TacticAst.Qed loc ->
 243       let uri, metasenv, bo, ty =
 244         match status.proof_status with
 245         | Proof (Some uri, metasenv, body, ty) ->
 246             uri, metasenv, body, ty
 247         | Proof (None, metasenv, body, ty) ->
 248             command_error
 249               ("Someone allows to start a thm without giving the "^
 250                "name/uri. This should be fixed!")
 251         | _-> command_error "You can't qed an uncomplete theorem"
 252       in
 253       let suri = UriManager.string_of_uri uri in
 254       if metasenv <> [] then
 255         command_error "Proof not completed! metasenv is not empty!";
 256       let name = UriManager.name_of_uri uri in
 257       let obj = Cic.Constant (name,Some bo,ty,[],[]) in
 258       MatitaSync.add_obj uri obj status
 259   | TacticAst.Coercion (loc, coercion) ->
 260       eval_coercion status coercion
 261   | TacticAst.Alias (loc, spec) ->
 262      let aliases =
 263       match spec with
 264       | TacticAst.Ident_alias (id,uri) ->
 265          DisambiguateTypes.Environment.add
 266           (DisambiguateTypes.Id id)
 267           (uri,(fun _ _ _-> CicUtil.term_of_uri (UriManager.uri_of_string uri)))
 268           status.aliases
 269       | TacticAst.Symbol_alias (symb, instance, desc) ->
 270          DisambiguateTypes.Environment.add
 271           (DisambiguateTypes.Symbol (symb,instance))
 272           (DisambiguateChoices.lookup_symbol_by_dsc symb desc)
 273           status.aliases
 274       | TacticAst.Number_alias (instance,desc) ->
 275          DisambiguateTypes.Environment.add
 276           (DisambiguateTypes.Num instance)
 277           (DisambiguateChoices.lookup_num_by_dsc desc) status.aliases
 278      in
 279       MatitaSync.set_proof_aliases status aliases
 280   | TacticAst.Obj (loc,obj) ->
 281      let ext,name =
 282       match obj with
 283          Cic.Constant (name,_,_,_,_)
 284        | Cic.CurrentProof (name,_,_,_,_,_) -> ".con",name
 285        | Cic.InductiveDefinition (types,_,_,_) ->
 286           ".ind",
 287           (match types with (name,_,_,_)::_ -> name | _ -> assert false)
 288        | _ -> assert false in
 289      let uri =
 290        UriManager.uri_of_string (MatitaMisc.qualify status name ^ ext)
 291      in
 292      let metasenv = MatitaMisc.get_proof_metasenv status in
 293      match obj with
 294         Cic.CurrentProof (_,metasenv',bo,ty,_,_) ->
 295          assert (metasenv = metasenv');
 296          let goalno =
 297           match metasenv' with (goalno,_,_)::_ -> goalno | _ -> assert false in
 298          let initial_proof = (Some uri, metasenv, bo, ty) in
 299           { status with proof_status = Incomplete_proof (initial_proof,goalno)}
 300       | _ ->
 301         if metasenv <> [] then
 302          command_error (
 303            "metasenv not empty while giving a definition with body: " ^
 304            CicMetaSubst.ppmetasenv metasenv []);
 305         let status = MatitaSync.add_obj uri obj status in
 306          match obj with
 307             Cic.Constant _ -> status
 308           | Cic.InductiveDefinition (_,_,_,attrs) ->
 309              let status = generate_elimination_principles uri status in
 310              let rec get_record_attrs =
 311               function
 312                  [] -> None
 313                | (`Class (`Record fields))::_ -> Some fields
 314                | _::tl -> get_record_attrs tl
 315              in
 316               (match get_record_attrs attrs with
 317                   None -> status (* not a record *)
 318                 | Some fields -> generate_projections uri fields status)
 319           | Cic.CurrentProof _
 320           | Cic.Variable _ -> assert false
 321
 322 let eval_executable status ex =
 323   match ex with
 324   | TacticAst.Tactical (_, tac) -> eval_tactical status tac
 325   | TacticAst.Command (_, cmd) -> eval_command status cmd
 326   | TacticAst.Macro (_, mac) ->
 327       command_error (sprintf "The macro %s can't be in a script"
 328         (TacticAstPp.pp_macro_cic mac))
 329
 330 let eval_comment status c = status
 331
 332 let eval status st =
 333   match st with
 334   | TacticAst.Executable (_,ex) -> eval_executable status ex
 335   | TacticAst.Comment (_,c) -> eval_comment status c
 336
 337 let disambiguate_term status term =
 338   let (aliases, metasenv, cic, _) =
 339     match
 340       MatitaDisambiguator.disambiguate_term ~dbd:(MatitaDb.instance ())
 341         ~aliases:(status.aliases) ~context:(MatitaMisc.get_proof_context status)
 342         ~metasenv:(MatitaMisc.get_proof_metasenv status) term
 343     with
 344     | [x] -> x
 345     | _ -> assert false
 346   in
 347   let proof_status =
 348     match status.proof_status with
 349     | No_proof -> Intermediate metasenv
 350     | Incomplete_proof ((uri, _, proof, ty), goal) ->
 351         Incomplete_proof ((uri, metasenv, proof, ty), goal)
 352     | Intermediate _ -> Intermediate metasenv
 353     | Proof _ -> assert false
 354   in
 355   let status = { status with proof_status = proof_status } in
 356   let status = MatitaSync.set_proof_aliases status aliases in
 357   status, cic
 358
 359 let disambiguate_obj status obj =
 360   let uri =
 361    match obj with
 362       TacticAst.Inductive (_,(name,_,_,_)::_)
 363     | TacticAst.Record (_,name,_,_) ->
 364        Some (UriManager.uri_of_string (MatitaMisc.qualify status name ^ ".ind"))
 365     | TacticAst.Inductive _ -> assert false
 366     | _ -> None in
 367   let (aliases, metasenv, cic, _) =
 368     match
 369       MatitaDisambiguator.disambiguate_obj ~dbd:(MatitaDb.instance ())
 370         ~aliases:(status.aliases) ~uri obj
 371     with
 372     | [x] -> x
 373     | _ -> assert false
 374   in
 375   let proof_status =
 376     match status.proof_status with
 377     | No_proof -> Intermediate metasenv
 378     | Incomplete_proof _
 379     | Intermediate _
 380     | Proof _ -> assert false
 381   in
 382   let status = { status with proof_status = proof_status } in
 383   let status = MatitaSync.set_proof_aliases status aliases in
 384   status, cic
 385
 386 let disambiguate_pattern status (wanted, hyp_paths, goal_path) =
 387   let interp path = Disambiguate.interpretate_path [] status.aliases path in
 388   let goal_path = interp goal_path in
 389   let hyp_paths = List.map (fun (name, path) -> name, interp path) hyp_paths in
 390   let status,wanted =
 391    match wanted with
 392       None -> status,None
 393     | Some wanted ->
 394        let status,wanted = disambiguate_term status wanted in
 395         status, Some wanted
 396   in
 397    status, (wanted, hyp_paths ,goal_path)
 398
 399 let disambiguate_tactic status = function
 400   | TacticAst.Apply (loc, term) ->
 401       let status, cic = disambiguate_term status term in
 402       status, TacticAst.Apply (loc, cic)
 403   | TacticAst.Absurd (loc, term) ->
 404       let status, cic = disambiguate_term status term in
 405       status, TacticAst.Absurd (loc, cic)
 406   | TacticAst.Assumption loc -> status, TacticAst.Assumption loc
 407   | TacticAst.Auto (loc,depth,width) -> status, TacticAst.Auto (loc,depth,width)
 408   | TacticAst.Change (loc, pattern, with_what) ->
 409       let status, with_what = disambiguate_term status with_what in
 410       let status, pattern = disambiguate_pattern status pattern in
 411       status, TacticAst.Change (loc, pattern, with_what)
 412   | TacticAst.Clear (loc,id) -> status,TacticAst.Clear (loc,id)
 413   | TacticAst.ClearBody (loc,id) -> status,TacticAst.ClearBody (loc,id)
 414   | TacticAst.Compare (loc,term) ->
 415       let status, term = disambiguate_term status term in
 416       status, TacticAst.Compare (loc,term)
 417   | TacticAst.Constructor (loc,n) ->
 418       status, TacticAst.Constructor (loc,n)
 419   | TacticAst.Contradiction loc ->
 420       status, TacticAst.Contradiction loc
 421   | TacticAst.Cut (loc, ident, term) ->
 422       let status, cic = disambiguate_term status term in
 423       status, TacticAst.Cut (loc, ident, cic)
 424   | TacticAst.DecideEquality loc ->
 425       status, TacticAst.DecideEquality loc
 426   | TacticAst.Decompose (loc,term) ->
 427       let status,term = disambiguate_term status term in
 428       status, TacticAst.Decompose(loc,term)
 429   | TacticAst.Discriminate (loc,term) ->
 430       let status,term = disambiguate_term status term in
 431       status, TacticAst.Discriminate(loc,term)
 432   | TacticAst.Exact (loc, term) ->
 433       let status, cic = disambiguate_term status term in
 434       status, TacticAst.Exact (loc, cic)
 435   | TacticAst.Elim (loc, term, Some term') ->
 436       let status, cic1 = disambiguate_term status term in
 437       let status, cic2 = disambiguate_term status term' in
 438       status, TacticAst.Elim (loc, cic1, Some cic2)
 439   | TacticAst.Elim (loc, term, None) ->
 440       let status, cic = disambiguate_term status term in
 441       status, TacticAst.Elim (loc, cic, None)
 442   | TacticAst.ElimType (loc, term) ->
 443       let status, cic = disambiguate_term status term in
 444       status, TacticAst.ElimType (loc, cic)
 445   | TacticAst.Exists loc -> status, TacticAst.Exists loc
 446   | TacticAst.Fail loc -> status,TacticAst.Fail loc
 447   | TacticAst.Fold (loc,reduction_kind, term, pattern) ->
 448      let status, pattern = disambiguate_pattern status pattern in
 449      let status, term = disambiguate_term status term in
 450      status, TacticAst.Fold (loc,reduction_kind, term, pattern)
 451   | TacticAst.FwdSimpl (loc, hyp, names) ->
 452      status, TacticAst.FwdSimpl (loc, hyp, names)
 453   | TacticAst.Fourier loc -> status, TacticAst.Fourier loc
 454   | TacticAst.Generalize (loc,pattern,ident) ->
 455       let status, pattern = disambiguate_pattern status pattern in
 456       status, TacticAst.Generalize(loc,pattern,ident)
 457   | TacticAst.Goal (loc, g) -> status, TacticAst.Goal (loc, g)
 458   | TacticAst.IdTac loc -> status,TacticAst.IdTac loc
 459   | TacticAst.Injection (loc,term) ->
 460       let status, term = disambiguate_term status term in
 461       status, TacticAst.Injection (loc,term)
 462   | TacticAst.Intros (loc, num, names) ->
 463       status, TacticAst.Intros (loc, num, names)
 464   | TacticAst.LApply (loc, depth, to_what, what, ident) ->
 465      let f term (status, to_what) =
 466         let status, term = disambiguate_term status term in
 467         status, term :: to_what
 468      in
 469      let status, to_what = List.fold_right f to_what (status, []) in
 470      let status, what = disambiguate_term status what in
 471      status, TacticAst.LApply (loc, depth, to_what, what, ident)
 472   | TacticAst.Left loc -> status, TacticAst.Left loc
 473   | TacticAst.LetIn (loc, term, name) ->
 474       let status, term = disambiguate_term status term in
 475       status, TacticAst.LetIn (loc,term,name)
 476   | TacticAst.Reduce (loc, reduction_kind, pattern) ->
 477       let status, pattern = disambiguate_pattern status pattern in
 478       status, TacticAst.Reduce(loc, reduction_kind, pattern)
 479   | TacticAst.Reflexivity loc -> status, TacticAst.Reflexivity loc
 480   | TacticAst.Replace (loc, pattern, with_what) ->
 481       let status, pattern = disambiguate_pattern status pattern in
 482       let status, with_what = disambiguate_term status with_what in
 483       status, TacticAst.Replace (loc, pattern, with_what)
 484   | TacticAst.Rewrite (loc, dir, t, pattern) ->
 485       let status, term = disambiguate_term status t in
 486       let status, pattern = disambiguate_pattern status pattern in
 487       status, TacticAst.Rewrite (loc, dir, term, pattern)
 488   | TacticAst.Right loc -> status, TacticAst.Right loc
 489   | TacticAst.Ring loc -> status, TacticAst.Ring loc
 490   | TacticAst.Split loc -> status, TacticAst.Split loc
 491   | TacticAst.Symmetry loc -> status, TacticAst.Symmetry loc
 492   | TacticAst.Transitivity (loc, term) ->
 493       let status, cic = disambiguate_term status term in
 494       status, TacticAst.Transitivity (loc, cic)
 495
 496 let rec disambiguate_tactical status = function
 497   | TacticAst.Tactic (loc, tactic) ->
 498       let status, tac = disambiguate_tactic status tactic in
 499       status, TacticAst.Tactic (loc, tac)
 500   | TacticAst.Do (loc, num, tactical) ->
 501       let status, tac = disambiguate_tactical status tactical in
 502       status, TacticAst.Do (loc, num, tac)
 503   | TacticAst.Repeat (loc, tactical) ->
 504       let status, tac = disambiguate_tactical status tactical in
 505       status, TacticAst.Repeat (loc, tac)
 506   | TacticAst.Seq (loc, tacticals) ->  (* tac1; tac2; ... *)
 507       let status, tacticals = disambiguate_tacticals status tacticals in
 508       let tacticals = List.rev tacticals in
 509       status, TacticAst.Seq (loc, tacticals)
 510   | TacticAst.Then (loc, tactical, tacticals) ->  (* tac; [ tac1 | ... ] *)
 511       let status, tactical = disambiguate_tactical status tactical in
 512       let status, tacticals = disambiguate_tacticals status tacticals in
 513       status, TacticAst.Then (loc, tactical, tacticals)
 514   | TacticAst.Tries (loc, tacticals) ->
 515       let status, tacticals = disambiguate_tacticals status tacticals in
 516       status, TacticAst.Tries (loc, tacticals)
 517   | TacticAst.Try (loc, tactical) ->
 518       let status, tactical = disambiguate_tactical status tactical in
 519       status, TacticAst.Try (loc, tactical)
 520
 521 and disambiguate_tacticals status tacticals =
 522   let status, tacticals =
 523     List.fold_left
 524       (fun (status, tacticals) tactical ->
 525         let status, tac = disambiguate_tactical status tactical in
 526         status, tac :: tacticals)
 527       (status, [])
 528       tacticals
 529   in
 530   let tacticals = List.rev tacticals in
 531   status, tacticals
 532
 533 let disambiguate_command status = function
 534   | TacticAst.Include (loc,path) as cmd  -> status,cmd
 535   | TacticAst.Coercion (loc, term) ->
 536       let status, term = disambiguate_term status term in
 537       status, TacticAst.Coercion (loc,term)
 538   | (TacticAst.Set _ | TacticAst.Qed _ | TacticAst.Drop _ ) as cmd ->
 539       status, cmd
 540   | TacticAst.Alias _ as x -> status, x
 541   | TacticAst.Obj (loc,obj) ->
 542       let status,obj = disambiguate_obj status obj in
 543        status, TacticAst.Obj (loc,obj)
 544
 545 let disambiguate_executable status ex =
 546   match ex with
 547   | TacticAst.Tactical (loc, tac) ->
 548       let status, tac = disambiguate_tactical status tac in
 549       status, (TacticAst.Tactical (loc, tac))
 550   | TacticAst.Command (loc, cmd) ->
 551       let status, cmd = disambiguate_command status cmd in
 552       status, (TacticAst.Command (loc, cmd))
 553   | TacticAst.Macro (_, mac) ->
 554       command_error (sprintf "The macro %s can't be in a script"
 555         (TacticAstPp.pp_macro_ast mac))
 556
 557 let disambiguate_comment status c =
 558   match c with
 559   | TacticAst.Note (loc,n) -> status, TacticAst.Note (loc,n)
 560   | TacticAst.Code (loc,ex) ->
 561         let status, ex = disambiguate_executable status ex in
 562         status, TacticAst.Code (loc,ex)
 563
 564 let disambiguate_statement status statement =
 565   match statement with
 566   | TacticAst.Comment (loc,c) ->
 567         let status, c = disambiguate_comment status c in
 568         status, TacticAst.Comment (loc,c)
 569   | TacticAst.Executable (loc,ex) ->
 570         let status, ex = disambiguate_executable status ex in
 571         status, TacticAst.Executable (loc,ex)
 572
 573 let eval_ast status ast =
 574   let status,st = disambiguate_statement status ast in
 575   (* this disambiguation step should be deferred to support tacticals *)
 576   eval status st
 577
 578 let eval_from_stream status str cb =
 579   let stl = CicTextualParser2.parse_statements str in
 580   List.iter
 581    (fun ast -> cb !status ast;status := eval_ast !status ast) stl
 582 ;;
 583
 584 (* to avoid a long list of recursive functions *)
 585 eval_from_stream_ref := eval_from_stream;;
 586
 587 let eval_from_stream_greedy status str cb =
 588   while true do
 589     print_string "matita> ";
 590     flush stdout;
 591     let ast = CicTextualParser2.parse_statement str in
 592     cb !status ast;
 593     status := eval_ast !status ast
 594   done
 595 ;;
 596
 597 let eval_string status str =
 598   eval_from_stream status (Stream.of_string str) (fun _ _ -> ())
 599
 600 let default_options () =
 601 (*
 602   let options =
 603     StringMap.add "baseuri"
 604       (String
 605         (Helm_registry.get "matita.baseuri" ^ Helm_registry.get "matita.owner"))
 606       no_options
 607   in
 608 *)
 609   let options =
 610     StringMap.add "basedir"
 611       (String (Helm_registry.get "matita.basedir" ))
 612       no_options
 613   in
 614   options
 615
 616 let initial_status =
 617   lazy {
 618     aliases = DisambiguateTypes.empty_environment;
 619     moo_content_rev = [];
 620     proof_status = No_proof;
 621     options = default_options ();
 622     objects = [];
 623   }
 624
 625