helm/matita/matitaGtkMisc.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 exception PopupClosed
  27 open Printf
  28
  29 open MatitaTypes
  30
  31 let wrap_callback f = f
  32
  33 let connect_button (button: #GButton.button) callback =
  34   ignore (button#connect#clicked (wrap_callback callback))
  35
  36 let connect_toggle_button (button: #GButton.toggle_button) callback =
  37   ignore (button#connect#toggled (wrap_callback callback))
  38
  39 let connect_menu_item (menu_item: #GMenu.menu_item) callback =
  40   ignore (menu_item#connect#activate (wrap_callback callback))
  41
  42 let connect_key (ev:GObj.event_ops) ?(modifiers = []) ?(stop = false) key
  43   callback
  44 =
  45   ignore (ev#connect#key_press (fun key' ->
  46     let modifiers' = GdkEvent.Key.state key' in
  47     (match key' with
  48     | key' when GdkEvent.Key.keyval key' = key
  49           && List.for_all (fun m -> List.mem m modifiers') modifiers ->
  50         callback ();
  51         stop
  52     | _ -> false)))
  53
  54 let toggle_widget_visibility ~(widget: GObj.widget)
  55                               ~(check: GMenu.check_menu_item)
  56 =
  57   ignore (check#connect#toggled (fun _ ->
  58     if check#active then widget#misc#show () else widget#misc#hide ()))
  59
  60 let toggle_window_visibility ~(window: GWindow.window)
  61                               ~(check: GMenu.check_menu_item)
  62 =
  63   ignore (check#connect#toggled (fun _ ->
  64     if check#active then window#show () else window#misc#hide ()));
  65   ignore (window#event#connect#delete (fun _ ->
  66     window#misc#hide ();
  67     check#set_active false;
  68     true))
  69
  70 let toggle_win ?(check: GMenu.check_menu_item option) (win: GWindow.window) () =
  71   if win#is_active then win#misc#hide () else win#show ();
  72   match check with
  73   | None -> ()
  74   | Some check -> check#set_active (not check#active)
  75
  76 let toggle_callback ~callback ~(check: GMenu.check_menu_item) =
  77   ignore (check#connect#toggled (fun _ -> callback check#active))
  78
  79 let add_key_binding key callback (evbox: GBin.event_box) =
  80   ignore (evbox#event#connect#key_press (function
  81     | key' when GdkEvent.Key.keyval key' = key ->
  82         callback ();
  83         false
  84     | _ -> false))
  85
  86 class multiStringListModel ~cols (tree_view: GTree.view) =
  87   let column_list = new GTree.column_list in
  88   let text_columns =
  89     let rec aux = function
  90       | 0 -> []
  91       | n -> column_list#add Gobject.Data.string :: aux (n - 1)
  92     in
  93     aux cols
  94   in
  95   let list_store = GTree.list_store column_list in
  96   let renderers =
  97     List.map
  98     (fun text_column ->
  99       (GTree.cell_renderer_text [], ["text", text_column]))
 100     text_columns
 101   in
 102   let view_columns =
 103     List.map
 104       (fun renderer -> GTree.view_column ~renderer ())
 105       renderers
 106   in
 107   object (self)
 108     val text_columns = text_columns
 109
 110     initializer
 111       tree_view#set_model (Some (list_store :> GTree.model));
 112       List.iter
 113         (fun view_column -> ignore (tree_view#append_column view_column))
 114         view_columns
 115
 116     method list_store = list_store
 117
 118     method easy_mappend slist =
 119       let tree_iter = list_store#append () in
 120       List.iter2
 121         (fun s text_column ->
 122         list_store#set ~row:tree_iter ~column:text_column s)
 123         slist text_columns
 124
 125     method easy_minsert pos s =
 126       let tree_iter = list_store#insert pos in
 127       List.iter2
 128         (fun s text_column ->
 129         list_store#set ~row:tree_iter ~column:text_column s)
 130         s text_columns
 131
 132     method easy_mselection () =
 133       List.map
 134         (fun tree_path ->
 135           let iter = list_store#get_iter tree_path in
 136           List.map
 137             (fun text_column ->
 138             list_store#get ~row:iter ~column:text_column)
 139           text_columns)
 140         tree_view#selection#get_selected_rows
 141   end
 142
 143 class stringListModel (tree_view: GTree.view) =
 144   object (self)
 145     inherit multiStringListModel ~cols:1 tree_view as multi
 146
 147     method list_store = multi#list_store
 148
 149     method easy_append s =
 150       multi#easy_mappend [s]
 151
 152     method easy_insert pos s =
 153       multi#easy_minsert pos [s]
 154
 155     method easy_selection () =
 156       let m = List.map
 157         (fun tree_path ->
 158           let iter = self#list_store#get_iter tree_path in
 159           List.map
 160             (fun text_column ->
 161             self#list_store#get ~row:iter ~column:text_column)
 162           text_columns)
 163         tree_view#selection#get_selected_rows
 164       in
 165       List.map (function [x] -> x | _ -> assert false) m
 166   end
 167
 168
 169 class taggedStringListModel ~(tags:(string * GdkPixbuf.pixbuf) list)
 170   (tree_view: GTree.view)
 171 =
 172   let column_list = new GTree.column_list in
 173   let tag_column = column_list#add Gobject.Data.gobject in
 174   let text_column = column_list#add Gobject.Data.string in
 175   let list_store = GTree.list_store column_list in
 176   let text_renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
 177   let tag_renderer = (GTree.cell_renderer_pixbuf [], ["pixbuf", tag_column]) in
 178   let text_vcolumn = GTree.view_column ~renderer:text_renderer () in
 179   let tag_vcolumn = GTree.view_column ~renderer:tag_renderer () in
 180   let lookup_pixbuf tag =
 181     try List.assoc tag tags with Not_found -> assert false
 182   in
 183   object (self)
 184     initializer
 185       tree_view#set_model (Some (list_store :> GTree.model));
 186       ignore (tree_view#append_column tag_vcolumn);
 187       ignore (tree_view#append_column text_vcolumn)
 188
 189     method list_store = list_store
 190
 191     method easy_append ~tag s =
 192       let tree_iter = list_store#append () in
 193       list_store#set ~row:tree_iter ~column:text_column s;
 194       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 195
 196     method easy_insert pos ~tag s =
 197       let tree_iter = list_store#insert pos in
 198       list_store#set ~row:tree_iter ~column:text_column s;
 199       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 200
 201     method easy_selection () =
 202       List.map
 203         (fun tree_path ->
 204           let iter = list_store#get_iter tree_path in
 205           list_store#get ~row:iter ~column:text_column)
 206         tree_view#selection#get_selected_rows
 207   end
 208
 209 class type gui =
 210   object
 211     method newUriDialog:          unit -> MatitaGeneratedGui.uriChoiceDialog
 212     method newInterpDialog:       unit -> MatitaGeneratedGui.interpChoiceDialog
 213     method newConfirmationDialog: unit -> MatitaGeneratedGui.confirmationDialog
 214     method newEmptyDialog:        unit -> MatitaGeneratedGui.emptyDialog
 215   end
 216
 217 let popup_message
 218   ~title ~message ~buttons ~callback
 219   ?(message_type=`QUESTION) ?parent ?(use_markup=true)
 220   ?(destroy_with_parent=true) ?(allow_grow=false) ?(allow_shrink=false)
 221   ?icon ?(modal=true) ?(resizable=false) ?screen ?type_hint
 222   ?(position=`CENTER_ON_PARENT) ?wm_name ?wm_class ?border_width ?width
 223   ?height ?(show=true) ()
 224 =
 225   let m =
 226     GWindow.message_dialog
 227       ~message ~use_markup ~message_type ~buttons ?parent ~destroy_with_parent
 228       ~title ~allow_grow ~allow_shrink ?icon ~modal ~resizable ?screen
 229       ?type_hint ~position ?wm_name ?wm_class ?border_width ?width ?height
 230       ~show ()
 231   in
 232   ignore(m#connect#response
 233     ~callback:(fun a ->  GMain.Main.quit ();callback a));
 234   ignore(m#connect#close
 235     ~callback:(fun _ -> GMain.Main.quit ();raise PopupClosed));
 236   GtkThread.main ();
 237   m#destroy ()
 238
 239 let popup_message_lowlevel
 240   ~title ~message ?(no_separator=true) ~callback ~message_type ~buttons
 241   ?parent  ?(destroy_with_parent=true) ?(allow_grow=false) ?(allow_shrink=false)
 242   ?icon ?(modal=true) ?(resizable=false) ?screen ?type_hint
 243   ?(position=`CENTER_ON_PARENT) ?wm_name ?wm_class ?border_width ?width
 244   ?height ?(show=true) ()
 245 =
 246   let m =
 247     GWindow.dialog
 248       ~no_separator
 249       ?parent ~destroy_with_parent
 250       ~title ~allow_grow ~allow_shrink ?icon ~modal ~resizable ?screen
 251       ?type_hint ~position ?wm_name ?wm_class ?border_width ?width ?height
 252       ~show:false ()
 253   in
 254   let stock =
 255     match message_type with
 256     | `WARNING -> `DIALOG_WARNING
 257     | `INFO -> `DIALOG_INFO
 258     | `ERROR ->`DIALOG_ERROR
 259     | `QUESTION -> `DIALOG_QUESTION
 260   in
 261   let image = GMisc.image ~stock ~icon_size:`DIALOG () in
 262   let label = GMisc.label ~markup:message () in
 263   label#set_line_wrap true;
 264   let hbox = GPack.hbox ~spacing:10 () in
 265   hbox#pack ~from:`START ~expand:true ~fill:true (image:>GObj.widget);
 266   hbox#pack ~from:`START ~expand:true ~fill:true (label:>GObj.widget);
 267   m#vbox#pack ~from:`START
 268     ~padding:20 ~expand:true ~fill:true (hbox:>GObj.widget);
 269   List.iter (fun (x, y) ->
 270     m#add_button_stock x y;
 271     if y = `CANCEL then
 272       m#set_default_response y
 273   ) buttons;
 274   ignore(m#connect#response
 275     ~callback:(fun a ->  GMain.Main.quit ();callback a));
 276   ignore(m#connect#close
 277     ~callback:(fun _ -> GMain.Main.quit ();callback `POPUPCLOSED));
 278   if show = true then
 279       m#show ();
 280   GtkThread.main ();
 281   m#destroy ()
 282
 283
 284 let ask_confirmation ~title ~message ?parent () =
 285   let rc = ref `YES in
 286   let callback =
 287     function
 288     | `YES -> rc := `YES
 289     | `NO -> rc := `NO
 290     | `CANCEL -> rc := `CANCEL
 291     | `DELETE_EVENT -> rc := `CANCEL
 292     | `POPUPCLOSED -> rc := `CANCEL
 293   in
 294   let buttons = [`YES,`YES ; `NO,`NO ; `CANCEL,`CANCEL] in
 295     popup_message_lowlevel
 296       ~title ~message ~message_type:`WARNING ~callback ~buttons ?parent ();
 297     !rc
 298
 299 let report_error ~title ~message ?parent () =
 300   let rc = ref false in
 301   let callback _ = () in
 302   let buttons = GWindow.Buttons.ok in
 303   try
 304     popup_message
 305       ~title ~message ~message_type:`ERROR ~callback ~buttons ?parent ()
 306   with
 307   | PopupClosed -> ()
 308
 309
 310 let ask_text ~(gui:#gui) ?(title = "") ?(msg = "") ?(multiline = false) () =
 311   let dialog = gui#newEmptyDialog () in
 312   dialog#emptyDialog#set_title title;
 313   dialog#emptyDialogLabel#set_label msg;
 314   let result = ref None in
 315   let return r =
 316     result := r;
 317     dialog#emptyDialog#destroy ();
 318     GMain.Main.quit ()
 319   in
 320   ignore (dialog#emptyDialog#event#connect#delete (fun _ -> true));
 321   if multiline then begin (* multiline input required: use a TextView widget *)
 322     let win =
 323       GBin.scrolled_window ~width:400 ~height:150 ~hpolicy:`NEVER
 324         ~vpolicy:`ALWAYS ~packing:dialog#emptyDialogVBox#add ()
 325     in
 326     let view = GText.view ~wrap_mode:`CHAR ~packing:win#add () in
 327     view#misc#grab_focus ();
 328     connect_button dialog#emptyDialogOkButton (fun _ ->
 329       return (Some (view#buffer#get_text ())))
 330   end else begin (* monoline input required: use a TextEntry widget *)
 331     let entry = GEdit.entry ~packing:dialog#emptyDialogVBox#add () in
 332     entry#misc#grab_focus ();
 333     connect_button dialog#emptyDialogOkButton (fun _ ->
 334       return (Some entry#text))
 335   end;
 336   connect_button dialog#emptyDialogCancelButton (fun _ ->return None);
 337   dialog#emptyDialog#show ();
 338   GtkThread.main ();
 339   (match !result with None -> raise Cancel | Some r -> r)
 340