helm/matita/matitaGtkMisc.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30 let wrap_callback f = f
  31 (*
  32 let wrap_callback f () =
  33   try
  34     f ()
  35   with exn ->
  36     MatitaLog.error (sprintf "Uncaught exception: %s" (Printexc.to_string exn))
  37 *)
  38
  39 let connect_button (button: #GButton.button) callback =
  40   ignore (button#connect#clicked (wrap_callback callback))
  41
  42 let connect_toggle_button (button: #GButton.toggle_button) callback =
  43   ignore (button#connect#toggled (wrap_callback callback))
  44
  45 let connect_menu_item (menu_item: #GMenu.menu_item) callback =
  46   ignore (menu_item#connect#activate (wrap_callback callback))
  47
  48 let connect_key (ev:GObj.event_ops) ?(modifiers = []) ?(stop = false) key
  49   callback
  50 =
  51   ignore (ev#connect#key_press (fun key' ->
  52     let modifiers' = GdkEvent.Key.state key' in
  53     (match key' with
  54     | key' when GdkEvent.Key.keyval key' = key
  55           && List.for_all (fun m -> List.mem m modifiers') modifiers ->
  56         callback ();
  57         stop
  58     | _ -> false)))
  59
  60 let toggle_widget_visibility ~(widget: GObj.widget)
  61                               ~(check: GMenu.check_menu_item)
  62 =
  63   ignore (check#connect#toggled (fun _ ->
  64     if check#active then widget#misc#show () else widget#misc#hide ()))
  65
  66 let toggle_window_visibility ~(window: GWindow.window)
  67                               ~(check: GMenu.check_menu_item)
  68 =
  69   ignore (check#connect#toggled (fun _ ->
  70     if check#active then window#show () else window#misc#hide ()));
  71   ignore (window#event#connect#delete (fun _ ->
  72     window#misc#hide ();
  73     check#set_active false;
  74     true))
  75
  76 let toggle_win ?(check: GMenu.check_menu_item option) (win: GWindow.window) () =
  77   if win#is_active then win#misc#hide () else win#show ();
  78   match check with
  79   | None -> ()
  80   | Some check -> check#set_active (not check#active)
  81
  82 let add_key_binding key callback (evbox: GBin.event_box) =
  83   ignore (evbox#event#connect#key_press (function
  84     | key' when GdkEvent.Key.keyval key' = key ->
  85         callback ();
  86         false
  87     | _ -> false))
  88
  89 class stringListModel (tree_view: GTree.view) =
  90   let column_list = new GTree.column_list in
  91   let text_column = column_list#add Gobject.Data.string in
  92   let list_store = GTree.list_store column_list in
  93   let renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
  94   let view_column = GTree.view_column ~renderer () in
  95   object (self)
  96     initializer
  97       tree_view#set_model (Some (list_store :> GTree.model));
  98       ignore (tree_view#append_column view_column)
  99
 100     method list_store = list_store
 101
 102     method easy_append s =
 103       let tree_iter = list_store#append () in
 104       list_store#set ~row:tree_iter ~column:text_column s
 105
 106     method easy_insert pos s =
 107       let tree_iter = list_store#insert pos in
 108       list_store#set ~row:tree_iter ~column:text_column s
 109
 110     method easy_selection () =
 111       List.map
 112         (fun tree_path ->
 113           let iter = list_store#get_iter tree_path in
 114           list_store#get ~row:iter ~column:text_column)
 115         tree_view#selection#get_selected_rows
 116   end
 117
 118 class taggedStringListModel ~(tags:(string * GdkPixbuf.pixbuf) list)
 119   (tree_view: GTree.view)
 120 =
 121   let column_list = new GTree.column_list in
 122   let tag_column = column_list#add Gobject.Data.gobject in
 123   let text_column = column_list#add Gobject.Data.string in
 124   let list_store = GTree.list_store column_list in
 125   let text_renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
 126   let tag_renderer = (GTree.cell_renderer_pixbuf [], ["pixbuf", tag_column]) in
 127   let text_vcolumn = GTree.view_column ~renderer:text_renderer () in
 128   let tag_vcolumn = GTree.view_column ~renderer:tag_renderer () in
 129   let lookup_pixbuf tag =
 130     try List.assoc tag tags with Not_found -> assert false
 131   in
 132   object (self)
 133     initializer
 134       tree_view#set_model (Some (list_store :> GTree.model));
 135       ignore (tree_view#append_column tag_vcolumn);
 136       ignore (tree_view#append_column text_vcolumn)
 137
 138     method list_store = list_store
 139
 140     method easy_append ~tag s =
 141       let tree_iter = list_store#append () in
 142       list_store#set ~row:tree_iter ~column:text_column s;
 143       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 144
 145     method easy_insert pos ~tag s =
 146       let tree_iter = list_store#insert pos in
 147       list_store#set ~row:tree_iter ~column:text_column s;
 148       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 149
 150     method easy_selection () =
 151       List.map
 152         (fun tree_path ->
 153           let iter = list_store#get_iter tree_path in
 154           list_store#get ~row:iter ~column:text_column)
 155         tree_view#selection#get_selected_rows
 156   end
 157
 158 class type gui =
 159   object
 160     method newUriDialog:          unit -> MatitaGeneratedGui.uriChoiceDialog
 161     method newInterpDialog:       unit -> MatitaGeneratedGui.interpChoiceDialog
 162     method newConfirmationDialog: unit -> MatitaGeneratedGui.confirmationDialog
 163     method newEmptyDialog:        unit -> MatitaGeneratedGui.emptyDialog
 164   end
 165
 166 let ask_confirmation ~(gui:#gui) ?(cancel = true) ?(title = "") ?(msg = "") () =
 167   let dialog = gui#newConfirmationDialog () in
 168   dialog#confirmationDialog#set_title title;
 169   dialog#confirmationDialogLabel#set_label msg;
 170   let result = ref None in
 171   let return r _ =
 172     result := Some r;
 173     dialog#confirmationDialog#destroy ();
 174     GMain.Main.quit ()
 175   in
 176   ignore (dialog#confirmationDialog#event#connect#delete (fun _ -> true));
 177   connect_button dialog#confirmationDialogOkButton (return true);
 178   connect_button dialog#confirmationDialogCancelButton (return false);
 179   if not cancel then dialog#confirmationDialogCancelButton#misc#hide ();
 180   dialog#confirmationDialog#show ();
 181   GtkThread.main ();
 182   (match !result with None -> assert false | Some r -> r)
 183
 184 let ask_text ~(gui:#gui) ?(title = "") ?(msg = "") ?(multiline = false) () =
 185   let dialog = gui#newEmptyDialog () in
 186   dialog#emptyDialog#set_title title;
 187   dialog#emptyDialogLabel#set_label msg;
 188   let result = ref None in
 189   let return r =
 190     result := r;
 191     dialog#emptyDialog#destroy ();
 192     GMain.Main.quit ()
 193   in
 194   ignore (dialog#emptyDialog#event#connect#delete (fun _ -> true));
 195   if multiline then begin (* multiline input required: use a TextView widget *)
 196     let win =
 197       GBin.scrolled_window ~width:400 ~height:150 ~hpolicy:`NEVER
 198         ~vpolicy:`ALWAYS ~packing:dialog#emptyDialogVBox#add ()
 199     in
 200     let view = GText.view ~wrap_mode:`CHAR ~packing:win#add () in
 201     view#misc#grab_focus ();
 202     connect_button dialog#emptyDialogOkButton (fun _ ->
 203       return (Some (view#buffer#get_text ())))
 204   end else begin (* monoline input required: use a TextEntry widget *)
 205     let entry = GEdit.entry ~packing:dialog#emptyDialogVBox#add () in
 206     entry#misc#grab_focus ();
 207     connect_button dialog#emptyDialogOkButton (fun _ ->
 208       return (Some entry#text))
 209   end;
 210   connect_button dialog#emptyDialogCancelButton (fun _ ->return None);
 211   dialog#emptyDialog#show ();
 212   GtkThread.main ();
 213   (match !result with None -> raise Cancel | Some r -> r)
 214