helm/matita/matitaGtkMisc.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30 let wrap_callback f = f
  31 (*
  32 let wrap_callback f () =
  33   try
  34     f ()
  35   with exn ->
  36     MatitaLog.error (sprintf "Uncaught exception: %s" (Printexc.to_string exn))
  37 *)
  38
  39 let connect_button (button: #GButton.button) callback =
  40   ignore (button#connect#clicked (wrap_callback callback))
  41
  42 let connect_toggle_button (button: #GButton.toggle_button) callback =
  43   ignore (button#connect#toggled (wrap_callback callback))
  44
  45 let connect_menu_item (menu_item: #GMenu.menu_item) callback =
  46   ignore (menu_item#connect#activate (wrap_callback callback))
  47
  48 let connect_key (ev:GObj.event_ops) ?(modifiers = []) ?(stop = false) key
  49   callback
  50 =
  51   ignore (ev#connect#key_press (fun key' ->
  52     let modifiers' = GdkEvent.Key.state key' in
  53     (match key' with
  54     | key' when GdkEvent.Key.keyval key' = key
  55           && List.for_all (fun m -> List.mem m modifiers') modifiers ->
  56         callback ();
  57         stop
  58     | _ -> false)))
  59
  60 let toggle_visibility ~(win: GWindow.window) ~(check: GMenu.check_menu_item) =
  61   ignore (check#connect#toggled (fun _ ->
  62     if check#active then win#show () else win#misc#hide ()));
  63   ignore (win#event#connect#delete (fun _ ->
  64     win#misc#hide ();
  65     check#set_active false;
  66     true))
  67
  68 let toggle_win ?(check: GMenu.check_menu_item option) (win: GWindow.window) () =
  69   if win#is_active then win#misc#hide () else win#show ();
  70   match check with
  71   | None -> ()
  72   | Some check -> check#set_active (not check#active)
  73
  74 let add_key_binding key callback (evbox: GBin.event_box) =
  75   ignore (evbox#event#connect#key_press (function
  76     | key' when GdkEvent.Key.keyval key' = key ->
  77         callback ();
  78         false
  79     | _ -> false))
  80
  81 class stringListModel (tree_view: GTree.view) =
  82   let column_list = new GTree.column_list in
  83   let text_column = column_list#add Gobject.Data.string in
  84   let list_store = GTree.list_store column_list in
  85   let renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
  86   let view_column = GTree.view_column ~renderer () in
  87   object (self)
  88     initializer
  89       tree_view#set_model (Some (list_store :> GTree.model));
  90       ignore (tree_view#append_column view_column)
  91
  92     method list_store = list_store
  93
  94     method easy_append s =
  95       let tree_iter = list_store#append () in
  96       list_store#set ~row:tree_iter ~column:text_column s
  97
  98     method easy_insert pos s =
  99       let tree_iter = list_store#insert pos in
 100       list_store#set ~row:tree_iter ~column:text_column s
 101
 102     method easy_selection () =
 103       List.map
 104         (fun tree_path ->
 105           let iter = list_store#get_iter tree_path in
 106           list_store#get ~row:iter ~column:text_column)
 107         tree_view#selection#get_selected_rows
 108   end
 109
 110 class taggedStringListModel ~(tags:(string * GdkPixbuf.pixbuf) list)
 111   (tree_view: GTree.view)
 112 =
 113   let column_list = new GTree.column_list in
 114   let tag_column = column_list#add Gobject.Data.gobject in
 115   let text_column = column_list#add Gobject.Data.string in
 116   let list_store = GTree.list_store column_list in
 117   let text_renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
 118   let tag_renderer = (GTree.cell_renderer_pixbuf [], ["pixbuf", tag_column]) in
 119   let text_vcolumn = GTree.view_column ~renderer:text_renderer () in
 120   let tag_vcolumn = GTree.view_column ~renderer:tag_renderer () in
 121   let lookup_pixbuf tag =
 122     try List.assoc tag tags with Not_found -> assert false
 123   in
 124   object (self)
 125     initializer
 126       tree_view#set_model (Some (list_store :> GTree.model));
 127       ignore (tree_view#append_column tag_vcolumn);
 128       ignore (tree_view#append_column text_vcolumn)
 129
 130     method list_store = list_store
 131
 132     method easy_append ~tag s =
 133       let tree_iter = list_store#append () in
 134       list_store#set ~row:tree_iter ~column:text_column s;
 135       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 136
 137     method easy_insert pos ~tag s =
 138       let tree_iter = list_store#insert pos in
 139       list_store#set ~row:tree_iter ~column:text_column s;
 140       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 141
 142     method easy_selection () =
 143       List.map
 144         (fun tree_path ->
 145           let iter = list_store#get_iter tree_path in
 146           list_store#get ~row:iter ~column:text_column)
 147         tree_view#selection#get_selected_rows
 148   end
 149
 150 class type gui =
 151   object
 152     method newUriDialog:          unit -> MatitaGeneratedGui.uriChoiceDialog
 153     method newInterpDialog:       unit -> MatitaGeneratedGui.interpChoiceDialog
 154     method newConfirmationDialog: unit -> MatitaGeneratedGui.confirmationDialog
 155     method newEmptyDialog:        unit -> MatitaGeneratedGui.emptyDialog
 156   end
 157
 158 let ask_confirmation ~(gui:#gui) ?(cancel = true) ?(title = "") ?(msg = "") () =
 159   let dialog = gui#newConfirmationDialog () in
 160   dialog#confirmationDialog#set_title title;
 161   dialog#confirmationDialogLabel#set_label msg;
 162   let result = ref None in
 163   let return r _ =
 164     result := Some r;
 165     dialog#confirmationDialog#destroy ();
 166     GMain.Main.quit ()
 167   in
 168   ignore (dialog#confirmationDialog#event#connect#delete (fun _ -> true));
 169   connect_button dialog#confirmationDialogOkButton (return true);
 170   connect_button dialog#confirmationDialogCancelButton (return false);
 171   if not cancel then dialog#confirmationDialogCancelButton#misc#hide ();
 172   dialog#confirmationDialog#show ();
 173   GtkThread.main ();
 174   (match !result with None -> assert false | Some r -> r)
 175
 176 let ask_text ~(gui:#gui) ?(title = "") ?(msg = "") ?(multiline = false) () =
 177   let dialog = gui#newEmptyDialog () in
 178   dialog#emptyDialog#set_title title;
 179   dialog#emptyDialogLabel#set_label msg;
 180   let result = ref None in
 181   let return r =
 182     result := r;
 183     dialog#emptyDialog#destroy ();
 184     GMain.Main.quit ()
 185   in
 186   ignore (dialog#emptyDialog#event#connect#delete (fun _ -> true));
 187   if multiline then begin (* multiline input required: use a TextView widget *)
 188     let win =
 189       GBin.scrolled_window ~width:400 ~height:150 ~hpolicy:`NEVER
 190         ~vpolicy:`ALWAYS ~packing:dialog#emptyDialogVBox#add ()
 191     in
 192     let view = GText.view ~wrap_mode:`CHAR ~packing:win#add () in
 193     view#misc#grab_focus ();
 194     connect_button dialog#emptyDialogOkButton (fun _ ->
 195       return (Some (view#buffer#get_text ())))
 196   end else begin (* monoline input required: use a TextEntry widget *)
 197     let entry = GEdit.entry ~packing:dialog#emptyDialogVBox#add () in
 198     entry#misc#grab_focus ();
 199     connect_button dialog#emptyDialogOkButton (fun _ ->
 200       return (Some entry#text))
 201   end;
 202   connect_button dialog#emptyDialogCancelButton (fun _ ->return None);
 203   dialog#emptyDialog#show ();
 204   GtkThread.main ();
 205   (match !result with None -> raise Cancel | Some r -> r)
 206