helm/matita/matitaGui.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaGeneratedGui
  29 open MatitaGtkMisc
  30 open MatitaMisc
  31
  32 let gui_instance = ref None ;;
  33
  34 class type browserWin =
  35   (* this class exists only because GEdit.combo_box_entry is not supported by
  36    * lablgladecc :-(((( *)
  37 object
  38   inherit MatitaGeneratedGui.browserWin
  39   method browserUri: GEdit.combo_box_entry
  40 end
  41
  42 class console ~(buffer: GText.buffer) () =
  43   object (self)
  44     val error_tag   = buffer#create_tag [ `FOREGROUND "red" ]
  45     val warning_tag = buffer#create_tag [ `FOREGROUND "orange" ]
  46     val message_tag = buffer#create_tag []
  47     val debug_tag   = buffer#create_tag [ `FOREGROUND "#888888" ]
  48     method message s = buffer#insert ~iter:buffer#end_iter ~tags:[message_tag] s
  49     method error s   = buffer#insert ~iter:buffer#end_iter ~tags:[error_tag] s
  50     method warning s = buffer#insert ~iter:buffer#end_iter ~tags:[warning_tag] s
  51     method debug s   = buffer#insert ~iter:buffer#end_iter ~tags:[debug_tag] s
  52     method clear () =
  53       buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter
  54     method log_callback (tag: MatitaLog.log_tag) s =
  55       match tag with
  56       | `Debug -> self#debug (s ^ "\n")
  57       | `Error -> self#error (s ^ "\n")
  58       | `Message -> self#message (s ^ "\n")
  59       | `Warning -> self#warning (s ^ "\n")
  60   end
  61
  62 let clean_current_baseuri status =
  63     try
  64       let baseuri = MatitaTypes.get_string_option status "baseuri" in
  65       MatitacleanLib.clean_baseuris [baseuri]
  66     with MatitaTypes.Option_error _ -> ()
  67
  68 let ask_and_save_moo_if_needed parent fname status =
  69   let save () =
  70     MatitacLib.dump_moo_to_file fname status.MatitaTypes.moo_content_rev in
  71   if (MatitaScript.instance ())#eos &&
  72      status.MatitaTypes.proof_status = MatitaTypes.No_proof
  73   then
  74     begin
  75       let mooname =
  76         MatitaMisc.obj_file_of_script fname
  77       in
  78       let rc =
  79         MatitaGtkMisc.ask_confirmation
  80         ~title:"A .moo can be generated"
  81         ~message:(Printf.sprintf
  82           "%s can be generated for %s.\n<i>Should I generate it?</i>"
  83           mooname fname)
  84         ~parent ()
  85       in
  86       let b =
  87         match rc with
  88         | `YES -> true
  89         | `NO -> false
  90         | `CANCEL -> raise MatitaTypes.Cancel
  91       in
  92       if b then
  93         save ()
  94       else
  95         clean_current_baseuri status
  96     end
  97   else
  98     clean_current_baseuri status
  99
 100 let ask_unsaved parent =
 101   MatitaGtkMisc.ask_confirmation
 102     ~parent ~title:"Unsaved work!"
 103     ~message:("Your work is <b>unsaved</b>!\n\n"^
 104          "<i>Do you want to save the script before exiting?</i>")
 105     ()
 106
 107 class gui () =
 108     (* creation order _is_ relevant for windows placement *)
 109   let main = new mainWin () in
 110   let about = new aboutWin () in
 111   let fileSel = new fileSelectionWin () in
 112   let findRepl = new findReplWin () in
 113   let develList = new develListWin () in
 114   let newDevel = new newDevelopmentWin () in
 115   let keyBindingBoxes = (* event boxes which should receive global key events *)
 116     [ main#mainWinEventBox ]
 117   in
 118   let console = new console ~buffer:main#logTextView#buffer () in
 119   let (source_view: GSourceView.source_view) =
 120     GSourceView.source_view
 121       ~auto_indent:true
 122       ~insert_spaces_instead_of_tabs:true ~tabs_width:2
 123       ~margin:80 ~show_margin:true
 124       ~smart_home_end:true
 125       ~packing:main#scriptScrolledWin#add
 126       ()
 127   in
 128   let default_font_size =
 129     Helm_registry.get_opt_default Helm_registry.int
 130       ~default:BuildTimeConf.default_font_size "matita.font_size"
 131   in
 132   let source_buffer = source_view#source_buffer in
 133   object (self)
 134     val mutable chosen_file = None
 135     val mutable _ok_not_exists = false
 136     val mutable _only_directory = false
 137     val mutable script_fname = None
 138     val mutable font_size = default_font_size
 139     val mutable next_devel_must_contain = None
 140
 141     initializer
 142         (* glade's check widgets *)
 143       List.iter (fun w -> w#check_widgets ())
 144         (let c w = (w :> <check_widgets: unit -> unit>) in
 145         [ c about; c fileSel; c main; c findRepl]);
 146         (* key bindings *)
 147       List.iter (* global key bindings *)
 148         (fun (key, callback) -> self#addKeyBinding key callback)
 149 (*
 150         [ GdkKeysyms._F3,
 151             toggle_win ~check:main#showProofMenuItem proof#proofWin;
 152           GdkKeysyms._F4,
 153             toggle_win ~check:main#showCheckMenuItem check#checkWin;
 154 *)
 155         [ ];
 156         (* about win *)
 157       ignore (about#aboutWin#event#connect#delete (fun _ -> true));
 158       ignore (main#aboutMenuItem#connect#activate (fun _ ->
 159         about#aboutWin#show ()));
 160       connect_button about#aboutDismissButton (fun _ ->
 161         about#aboutWin#misc#hide ());
 162       about#aboutLabel#set_label (Pcre.replace ~pat:"@VERSION@"
 163         ~templ:BuildTimeConf.version about#aboutLabel#label);
 164         (* findRepl win *)
 165       let show_find_Repl () =
 166         findRepl#toplevel#misc#show ();
 167         findRepl#toplevel#misc#grab_focus ()
 168       in
 169       let hide_find_Repl () = findRepl#toplevel#misc#hide () in
 170       let find_forward _ =
 171           let highlight start end_ =
 172             source_buffer#move_mark `INSERT ~where:start;
 173             source_buffer#move_mark `SEL_BOUND ~where:end_
 174           in
 175           let text = findRepl#findEntry#text in
 176           let iter = source_buffer#get_iter `SEL_BOUND in
 177           match iter#forward_search text with
 178           | None ->
 179               (match source_buffer#start_iter#forward_search text with
 180               | None -> ()
 181               | Some (start,end_) -> highlight start end_)
 182           | Some (start,end_) -> highlight start end_
 183       in
 184       let replace _ =
 185         let text = findRepl#replaceEntry#text in
 186         let ins = source_buffer#get_iter `INSERT in
 187         let sel = source_buffer#get_iter `SEL_BOUND in
 188         if ins#compare sel < 0 then
 189           begin
 190             ignore(source_buffer#delete_selection ());
 191             source_buffer#insert text
 192           end
 193       in
 194       connect_button findRepl#findButton find_forward;
 195       connect_button findRepl#findReplButton replace;
 196       connect_button findRepl#cancelButton (fun _ -> hide_find_Repl ());
 197       ignore(findRepl#toplevel#event#connect#delete
 198         ~callback:(fun _ -> hide_find_Repl ();true));
 199       ignore(self#main#findReplMenuItem#connect#activate
 200         ~callback:show_find_Repl);
 201       ignore (findRepl#findEntry#connect#activate ~callback:find_forward);
 202         (* developments win *)
 203       let model =
 204         new MatitaGtkMisc.multiStringListModel
 205           ~cols:2 develList#developmentsTreeview
 206       in
 207       let refresh_devels_win () =
 208         model#list_store#clear ();
 209         List.iter
 210           (fun (name, root) -> model#easy_mappend [name;root])
 211           (MatitamakeLib.list_known_developments ())
 212       in
 213       let get_devel_selected () =
 214         match model#easy_mselection () with
 215         | [[name;_]] -> MatitamakeLib.development_for_name name
 216         | _ -> assert false
 217       in
 218       connect_button develList#newButton
 219         (fun () ->
 220           next_devel_must_contain <- None;
 221           newDevel#toplevel#misc#show());
 222       connect_button develList#deleteButton
 223         (fun () ->
 224           (match get_devel_selected () with
 225           | None -> ()
 226           | Some d -> MatitamakeLib.destroy_development d);
 227           refresh_devels_win ());
 228       connect_button develList#buildButton
 229         (fun () ->
 230           match get_devel_selected () with
 231           | None -> ()
 232           | Some d -> ignore(MatitamakeLib.build_development d));
 233       connect_button develList#cleanButton
 234         (fun () ->
 235           match get_devel_selected () with
 236           | None -> ()
 237           | Some d -> ignore(MatitamakeLib.clean_development d));
 238       connect_button develList#closeButton
 239         (fun () -> develList#toplevel#misc#hide());
 240       ignore(develList#toplevel#event#connect#delete
 241         (fun _ -> develList#toplevel#misc#hide();true));
 242       let selected_devel = ref None in
 243       connect_menu_item self#main#developmentsMenuItem
 244         (fun () -> refresh_devels_win ();develList#toplevel#misc#show ());
 245
 246         (* add development win *)
 247       let check_if_root_contains root =
 248         match next_devel_must_contain with
 249         | None -> true
 250         | Some path ->
 251             let is_prefix_of d1 d2 =
 252               let len1 = String.length d1 in
 253               let len2 = String.length d2 in
 254               if len2 < len1 then
 255                 false
 256               else
 257                 let pref = String.sub d2 0 len1 in
 258                 pref = d1
 259             in
 260             is_prefix_of root path
 261       in
 262       connect_button newDevel#addButton
 263        (fun () ->
 264           let name = newDevel#nameEntry#text in
 265           let root = newDevel#rootEntry#text in
 266           if check_if_root_contains root then
 267             begin
 268               ignore (MatitamakeLib.initialize_development name root);
 269               refresh_devels_win ();
 270               newDevel#nameEntry#set_text "";
 271               newDevel#rootEntry#set_text "";
 272               newDevel#toplevel#misc#hide()
 273             end
 274           else
 275             MatitaLog.error ("The selected root does not contain " ^
 276               match next_devel_must_contain with
 277               | Some x -> x
 278               | _ -> assert false));
 279       connect_button newDevel#chooseRootButton
 280        (fun () ->
 281          let path = self#chooseDir () in
 282          match path with
 283          | Some path -> newDevel#rootEntry#set_text path
 284          | None -> ());
 285       connect_button newDevel#cancelButton
 286        (fun () -> newDevel#toplevel#misc#hide ());
 287       ignore(newDevel#toplevel#event#connect#delete
 288         (fun _ -> newDevel#toplevel#misc#hide();true));
 289
 290         (* file selection win *)
 291       ignore (fileSel#fileSelectionWin#event#connect#delete (fun _ -> true));
 292       ignore (fileSel#fileSelectionWin#connect#response (fun event ->
 293         let return r =
 294           chosen_file <- r;
 295           fileSel#fileSelectionWin#misc#hide ();
 296           GMain.Main.quit ()
 297         in
 298         match event with
 299         | `OK ->
 300             let fname = fileSel#fileSelectionWin#filename in
 301             if Sys.file_exists fname then
 302               begin
 303                 if is_regular fname && not(_only_directory) then
 304                   return (Some fname)
 305                 else if _only_directory && is_dir fname then
 306                   return (Some fname)
 307               end
 308             else
 309               begin
 310                 if _ok_not_exists then
 311                   return (Some fname)
 312               end
 313         | `CANCEL -> return None
 314         | `HELP -> ()
 315         | `DELETE_EVENT -> return None));
 316         (* menus *)
 317       List.iter (fun w -> w#misc#set_sensitive false) [ main#saveMenuItem ];
 318       main#helpMenu#set_right_justified true;
 319         (* console *)
 320       let adj = main#logScrolledWin#vadjustment in
 321         ignore (adj#connect#changed
 322                 (fun _ -> adj#set_value (adj#upper -. adj#page_size)));
 323       console#message (sprintf "\tMatita version %s\n" BuildTimeConf.version);
 324         (* toolbar *)
 325       let module A = TacticAst in
 326       let hole = CicAst.UserInput in
 327       let loc = CicAst.dummy_floc in
 328       let tac ast _ =
 329         if (MatitaScript.instance ())#onGoingProof () then
 330           (MatitaScript.instance ())#advance
 331             ~statement:("\n" ^ TacticAstPp.pp_tactical (A.Tactic (loc, ast))) ()
 332       in
 333       let tac_w_term ast _ =
 334         if (MatitaScript.instance ())#onGoingProof () then
 335           let buf = source_buffer in
 336           buf#insert ~iter:(buf#get_iter_at_mark (`NAME "locked"))
 337             ("\n" ^ TacticAstPp.pp_tactic ast)
 338       in
 339       let tbar = self#main in
 340       connect_button tbar#introsButton (tac (A.Intros (loc, None, [])));
 341       connect_button tbar#applyButton (tac_w_term (A.Apply (loc, hole)));
 342       connect_button tbar#exactButton (tac_w_term (A.Exact (loc, hole)));
 343       connect_button tbar#elimButton (tac_w_term (A.Elim (loc, hole, None, None, [])));
 344       connect_button tbar#elimTypeButton (tac_w_term (A.ElimType (loc, hole, None, None, [])));
 345       connect_button tbar#splitButton (tac (A.Split loc));
 346       connect_button tbar#leftButton (tac (A.Left loc));
 347       connect_button tbar#rightButton (tac (A.Right loc));
 348       connect_button tbar#existsButton (tac (A.Exists loc));
 349       connect_button tbar#reflexivityButton (tac (A.Reflexivity loc));
 350       connect_button tbar#symmetryButton (tac (A.Symmetry loc));
 351       connect_button tbar#transitivityButton
 352         (tac_w_term (A.Transitivity (loc, hole)));
 353       connect_button tbar#assumptionButton (tac (A.Assumption loc));
 354       connect_button tbar#cutButton (tac_w_term (A.Cut (loc, None, hole)));
 355       connect_button tbar#autoButton (tac (A.Auto (loc,None,None)));
 356       MatitaGtkMisc.toggle_widget_visibility
 357        ~widget:(self#main#tacticsButtonsHandlebox :> GObj.widget)
 358        ~check:self#main#tacticsBarMenuItem;
 359       let module Hr = Helm_registry in
 360       if
 361         not (Hr.get_opt_default Hr.bool ~default:false "matita.tactics_bar")
 362       then
 363         self#main#tacticsBarMenuItem#set_active false;
 364       MatitaGtkMisc.toggle_callback
 365         ~callback:(function
 366           | true -> self#main#toplevel#fullscreen ()
 367           | false -> self#main#toplevel#unfullscreen ())
 368         ~check:self#main#fullscreenMenuItem;
 369       self#main#fullscreenMenuItem#set_active false;
 370         (* log *)
 371       MatitaLog.set_log_callback self#console#log_callback;
 372       GtkSignal.user_handler :=
 373         (fun exn -> MatitaLog.error (MatitaExcPp.to_string exn));
 374         (* script *)
 375       let _ =
 376         match GSourceView.source_language_from_file BuildTimeConf.lang_file with
 377         | None ->
 378             MatitaLog.warn (sprintf "can't load language file %s"
 379               BuildTimeConf.lang_file)
 380         | Some matita_lang ->
 381             source_buffer#set_language matita_lang;
 382             source_buffer#set_highlight true
 383       in
 384       let s () = MatitaScript.instance () in
 385       let disableSave () =
 386         script_fname <- None;
 387         self#main#saveMenuItem#misc#set_sensitive false
 388       in
 389       let saveAsScript () =
 390         let script = s () in
 391         match self#chooseFile ~ok_not_exists:true () with
 392         | Some f ->
 393               script#assignFileName f;
 394               script#saveToFile ();
 395               console#message ("'"^f^"' saved.\n");
 396               self#_enableSaveTo f
 397         | None -> ()
 398       in
 399       let saveScript () =
 400         match script_fname with
 401         | None -> saveAsScript ()
 402         | Some f ->
 403               (s ())#assignFileName f;
 404               (s ())#saveToFile ();
 405               console#message ("'"^f^"' saved.\n");
 406       in
 407       let loadScript () =
 408         let script = s () in
 409         let status = script#status in
 410         try
 411           if source_view#buffer#modified then
 412             begin
 413               match ask_unsaved main#toplevel with
 414               | `YES -> saveScript ()
 415               | `NO -> ()
 416               | `CANCEL -> raise MatitaTypes.Cancel
 417             end;
 418           (match script_fname with
 419           | None -> ()
 420           | Some fname ->
 421               ask_and_save_moo_if_needed main#toplevel fname status);
 422           match self#chooseFile () with
 423           | Some f ->
 424                 script#reset ();
 425                 script#assignFileName f;
 426                 script#loadFromFile ();
 427                 console#message ("'"^f^"' loaded.\n");
 428                 self#_enableSaveTo f
 429           | None -> ()
 430         with MatitaTypes.Cancel -> ()
 431       in
 432       let newScript () =
 433         (s ())#reset ();
 434         (s ())#template ();
 435         disableSave ();
 436         script_fname <- None
 437       in
 438       let cursor () =
 439         source_buffer#place_cursor
 440           (source_buffer#get_iter_at_mark (`NAME "locked"))
 441       in
 442       let lock_world _ =
 443         main#buttonsToolbar#misc#set_sensitive false;
 444         source_view#set_editable false
 445       in
 446       let unlock_world _ =
 447         main#buttonsToolbar#misc#set_sensitive true;
 448         source_view#set_editable true
 449       in
 450       let advance _ = (MatitaScript.instance ())#advance (); cursor () in
 451       let retract _ = (MatitaScript.instance ())#retract (); cursor () in
 452       let top _ = (MatitaScript.instance ())#goto `Top (); cursor () in
 453       let bottom _ = (MatitaScript.instance ())#goto `Bottom (); cursor () in
 454       let jump _ = (MatitaScript.instance ())#goto `Cursor (); cursor () in
 455       let locker f =
 456         fun () ->
 457           lock_world ();
 458           try f ();unlock_world () with exc -> unlock_world (); raise exc
 459       in
 460       let advance = locker advance in
 461       let retract = locker retract in
 462       let top = locker top in
 463       let bottom = locker bottom in
 464       let jump = locker jump in
 465       let connect_key sym f =
 466         connect_key self#main#mainWinEventBox#event
 467           ~modifiers:[`CONTROL] ~stop:true sym f;
 468         connect_key self#sourceView#event
 469           ~modifiers:[`CONTROL] ~stop:true sym f
 470       in
 471         (* quit *)
 472       self#setQuitCallback (fun () ->
 473         let status = (MatitaScript.instance ())#status in
 474         if source_view#buffer#modified then
 475           begin
 476             let rc = ask_unsaved main#toplevel in
 477             try
 478               match rc with
 479               | `YES -> saveScript ();
 480                         if not source_view#buffer#modified then
 481                           begin
 482                             (match script_fname with
 483                             | None -> ()
 484                             | Some fname ->
 485                                ask_and_save_moo_if_needed
 486                                  main#toplevel fname status);
 487                           GMain.Main.quit ()
 488                           end
 489               | `NO -> GMain.Main.quit ()
 490               | `CANCEL -> raise MatitaTypes.Cancel
 491             with MatitaTypes.Cancel -> ()
 492           end
 493         else
 494           begin
 495             (match script_fname with
 496             | None -> clean_current_baseuri status; GMain.Main.quit ()
 497             | Some fname ->
 498                 try
 499                   ask_and_save_moo_if_needed main#toplevel fname status;
 500                   GMain.Main.quit ()
 501                 with MatitaTypes.Cancel -> ())
 502           end);
 503       connect_button self#main#scriptAdvanceButton advance;
 504       connect_button self#main#scriptRetractButton retract;
 505       connect_button self#main#scriptTopButton top;
 506       connect_button self#main#scriptBottomButton bottom;
 507       connect_key GdkKeysyms._Down advance;
 508       connect_key GdkKeysyms._Up retract;
 509       connect_key GdkKeysyms._Home top;
 510       connect_key GdkKeysyms._End bottom;
 511       connect_button self#main#scriptJumpButton jump;
 512       connect_menu_item self#main#openMenuItem   loadScript;
 513       connect_menu_item self#main#saveMenuItem   saveScript;
 514       connect_menu_item self#main#saveAsMenuItem saveAsScript;
 515       connect_menu_item self#main#newMenuItem    newScript;
 516       connect_key GdkKeysyms._period
 517         (fun () ->
 518           source_buffer#insert ~iter:(source_buffer#get_iter_at_mark `INSERT)
 519             ".\n";
 520           advance ());
 521       connect_key GdkKeysyms._Return
 522         (fun () ->
 523           source_buffer#insert ~iter:(source_buffer#get_iter_at_mark `INSERT)
 524             "\n";
 525           advance ());
 526          (* script monospace font stuff *)
 527       self#updateFontSize ();
 528         (* debug menu *)
 529       self#main#debugMenu#misc#hide ();
 530         (* status bar *)
 531       self#main#hintLowImage#set_file (image_path "matita-bulb-low.png");
 532       self#main#hintMediumImage#set_file (image_path "matita-bulb-medium.png");
 533       self#main#hintHighImage#set_file (image_path "matita-bulb-high.png");
 534         (* focus *)
 535       self#sourceView#misc#grab_focus ();
 536         (* main win dimension *)
 537       let width = Gdk.Screen.width () in
 538       let height = Gdk.Screen.height () in
 539       let main_w = width * 90 / 100 in
 540       let main_h = height * 80 / 100 in
 541       let script_w = main_w * 6 / 10 in
 542       self#main#toplevel#resize ~width:main_w ~height:main_h;
 543       self#main#hpaneScriptSequent#set_position script_w;
 544         (* source_view *)
 545       ignore(source_view#connect#after#paste_clipboard
 546         ~callback:(fun () -> (MatitaScript.instance ())#clean_dirty_lock))
 547
 548     method loadScript file =
 549       let script = MatitaScript.instance () in
 550       script#reset ();
 551       script#assignFileName file;
 552       if not (Sys.file_exists file) then
 553         begin
 554           let oc = open_out file in
 555           let template = MatitaMisc.input_file BuildTimeConf.script_template in
 556           output_string oc template;
 557           close_out oc
 558         end;
 559       script#loadFromFile ();
 560       console#message ("'"^file^"' loaded.");
 561       self#_enableSaveTo file
 562
 563     method setStar name b =
 564       let l = main#scriptLabel in
 565       if b then
 566         l#set_text (name ^  " *")
 567       else
 568         l#set_text (name)
 569
 570     method private _enableSaveTo file =
 571       script_fname <- Some file;
 572       self#main#saveMenuItem#misc#set_sensitive true
 573
 574
 575     method console = console
 576     method sourceView: GSourceView.source_view = (source_view: GSourceView.source_view)
 577     method about = about
 578     method fileSel = fileSel
 579     method findRepl = findRepl
 580     method main = main
 581     method develList = develList
 582     method newDevel = newDevel
 583
 584     method newBrowserWin () =
 585       object (self)
 586         inherit browserWin ()
 587         val combo = GEdit.combo_box_entry ()
 588         initializer
 589           self#check_widgets ();
 590           let combo_widget = combo#coerce in
 591           uriHBox#pack ~from:`END ~fill:true ~expand:true combo_widget;
 592           combo#entry#misc#grab_focus ()
 593         method browserUri = combo
 594       end
 595
 596     method newUriDialog () =
 597       let dialog = new uriChoiceDialog () in
 598       dialog#check_widgets ();
 599       dialog
 600
 601     method newInterpDialog () =
 602       let dialog = new interpChoiceDialog () in
 603       dialog#check_widgets ();
 604       dialog
 605
 606     method newConfirmationDialog () =
 607       let dialog = new confirmationDialog () in
 608       dialog#check_widgets ();
 609       dialog
 610
 611     method newEmptyDialog () =
 612       let dialog = new emptyDialog () in
 613       dialog#check_widgets ();
 614       dialog
 615
 616     method private addKeyBinding key callback =
 617       List.iter (fun evbox -> add_key_binding key callback evbox)
 618         keyBindingBoxes
 619
 620     method setQuitCallback callback =
 621       ignore (main#quitMenuItem#connect#activate callback);
 622       ignore (main#toplevel#event#connect#delete
 623         (fun _ -> callback ();true));
 624       self#addKeyBinding GdkKeysyms._q callback
 625
 626     method chooseFile ?(ok_not_exists = false) () =
 627       _ok_not_exists <- ok_not_exists;
 628       _only_directory <- false;
 629       fileSel#fileSelectionWin#show ();
 630       GtkThread.main ();
 631       chosen_file
 632
 633     method private chooseDir ?(ok_not_exists = false) () =
 634       _ok_not_exists <- ok_not_exists;
 635       _only_directory <- true;
 636       fileSel#fileSelectionWin#show ();
 637       GtkThread.main ();
 638       (* we should check that this is a directory *)
 639       chosen_file
 640
 641     method createDevelopment ~containing =
 642       next_devel_must_contain <- containing;
 643       newDevel#toplevel#misc#show()
 644
 645     method askText ?(title = "") ?(msg = "") () =
 646       let dialog = new textDialog () in
 647       dialog#textDialog#set_title title;
 648       dialog#textDialogLabel#set_label msg;
 649       let text = ref None in
 650       let return v =
 651         text := v;
 652         dialog#textDialog#destroy ();
 653         GMain.Main.quit ()
 654       in
 655       ignore (dialog#textDialog#event#connect#delete (fun _ -> true));
 656       connect_button dialog#textDialogCancelButton (fun _ -> return None);
 657       connect_button dialog#textDialogOkButton (fun _ ->
 658         let text = dialog#textDialogTextView#buffer#get_text () in
 659         return (Some text));
 660       dialog#textDialog#show ();
 661       GtkThread.main ();
 662       !text
 663
 664     method private updateFontSize () =
 665       self#sourceView#misc#modify_font_by_name
 666         (sprintf "%s %d" BuildTimeConf.script_font font_size)
 667
 668     method increaseFontSize () =
 669       font_size <- font_size + 1;
 670       self#updateFontSize ()
 671
 672     method decreaseFontSize () =
 673       font_size <- font_size - 1;
 674       self#updateFontSize ()
 675
 676     method resetFontSize () =
 677       font_size <- default_font_size;
 678       self#updateFontSize ()
 679
 680   end
 681
 682 let gui () =
 683   let g = new gui () in
 684   gui_instance := Some g;
 685   g
 686
 687 let instance = singleton gui
 688
 689 let non p x = not (p x)
 690
 691 (* this is a shit and should be changed :-{ *)
 692 let interactive_uri_choice
 693   ?(selection_mode:[`SINGLE|`MULTIPLE] = `MULTIPLE) ?(title = "")
 694   ?(msg = "") ?(nonvars_button = false) ?(hide_uri_entry=false)
 695   ?(hide_try=false) ?(ok_label="_Auto") ?(ok_action:[`SELECT|`AUTO] = `AUTO)
 696   ?copy_cb ()
 697   ~id uris
 698 =
 699   let gui = instance () in
 700   let nonvars_uris = lazy (List.filter (non UriManager.uri_is_var) uris) in
 701   if (selection_mode <> `SINGLE) &&
 702     (Helm_registry.get_bool "matita.auto_disambiguation")
 703   then
 704     Lazy.force nonvars_uris
 705   else begin
 706     let dialog = gui#newUriDialog () in
 707     if hide_uri_entry then
 708       dialog#uriEntryHBox#misc#hide ();
 709     if hide_try then
 710       begin
 711       dialog#uriChoiceSelectedButton#misc#hide ();
 712       dialog#uriChoiceConstantsButton#misc#hide ();
 713       end;
 714     dialog#okLabel#set_label ok_label;
 715     dialog#uriChoiceTreeView#selection#set_mode
 716       (selection_mode :> Gtk.Tags.selection_mode);
 717     let model = new stringListModel dialog#uriChoiceTreeView in
 718     let choices = ref None in
 719     let nonvars = ref false in
 720     (match copy_cb with
 721     | None -> ()
 722     | Some cb ->
 723         dialog#copyButton#misc#show ();
 724         connect_button dialog#copyButton
 725         (fun _ ->
 726           match model#easy_selection () with
 727           | [u] -> (cb u)
 728           | _ -> ()));
 729     dialog#uriChoiceDialog#set_title title;
 730     dialog#uriChoiceLabel#set_text msg;
 731     List.iter model#easy_append (List.map UriManager.string_of_uri uris);
 732     dialog#uriChoiceConstantsButton#misc#set_sensitive nonvars_button;
 733     let return v =
 734       choices := v;
 735       dialog#uriChoiceDialog#destroy ();
 736       GMain.Main.quit ()
 737     in
 738     ignore (dialog#uriChoiceDialog#event#connect#delete (fun _ -> true));
 739     connect_button dialog#uriChoiceConstantsButton (fun _ ->
 740       return (Some (Lazy.force nonvars_uris)));
 741     if ok_action = `AUTO then
 742       connect_button dialog#uriChoiceAutoButton (fun _ ->
 743         Helm_registry.set_bool "matita.auto_disambiguation" true;
 744         return (Some (Lazy.force nonvars_uris)))
 745     else
 746       connect_button dialog#uriChoiceAutoButton (fun _ ->
 747         match model#easy_selection () with
 748         | [] -> ()
 749         | uris -> return (Some (List.map UriManager.uri_of_string uris)));
 750     connect_button dialog#uriChoiceSelectedButton (fun _ ->
 751       match model#easy_selection () with
 752       | [] -> ()
 753       | uris -> return (Some (List.map UriManager.uri_of_string uris)));
 754     connect_button dialog#uriChoiceAbortButton (fun _ -> return None);
 755     dialog#uriChoiceDialog#show ();
 756     GtkThread.main ();
 757     (match !choices with
 758     | None -> raise MatitaTypes.Cancel
 759     | Some uris -> uris)
 760   end
 761
 762 class interpModel =
 763   let cols = new GTree.column_list in
 764   let id_col = cols#add Gobject.Data.string in
 765   let dsc_col = cols#add Gobject.Data.string in
 766   let interp_no_col = cols#add Gobject.Data.int in
 767   let tree_store = GTree.tree_store cols in
 768   let id_renderer = GTree.cell_renderer_text [], ["text", id_col] in
 769   let dsc_renderer = GTree.cell_renderer_text [], ["text", dsc_col] in
 770   let id_view_col = GTree.view_column ~renderer:id_renderer () in
 771   let dsc_view_col = GTree.view_column ~renderer:dsc_renderer () in
 772   fun tree_view choices ->
 773     object
 774       initializer
 775         tree_view#set_model (Some (tree_store :> GTree.model));
 776         ignore (tree_view#append_column id_view_col);
 777         ignore (tree_view#append_column dsc_view_col);
 778         let name_of_interp =
 779           (* try to find a reasonable name for an interpretation *)
 780           let idx = ref 0 in
 781           fun interp ->
 782             try
 783               List.assoc "0" interp
 784             with Not_found ->
 785               incr idx; string_of_int !idx
 786         in
 787         tree_store#clear ();
 788         let idx = ref ~-1 in
 789         List.iter
 790           (fun interp ->
 791             incr idx;
 792             let interp_row = tree_store#append () in
 793             tree_store#set ~row:interp_row ~column:id_col
 794               (name_of_interp interp);
 795             tree_store#set ~row:interp_row ~column:interp_no_col !idx;
 796             List.iter
 797               (fun (id, dsc) ->
 798                 let row = tree_store#append ~parent:interp_row () in
 799                 tree_store#set ~row ~column:id_col id;
 800                 tree_store#set ~row ~column:dsc_col dsc;
 801                 tree_store#set ~row ~column:interp_no_col !idx)
 802               interp)
 803           choices
 804
 805       method get_interp_no tree_path =
 806         let iter = tree_store#get_iter tree_path in
 807         tree_store#get ~row:iter ~column:interp_no_col
 808     end
 809
 810 let interactive_interp_choice () choices =
 811   let gui = instance () in
 812   assert (choices <> []);
 813   let dialog = gui#newInterpDialog () in
 814   let model = new interpModel dialog#interpChoiceTreeView choices in
 815   let interp_len = List.length (List.hd choices) in
 816   dialog#interpChoiceDialog#set_title "Interpretation choice";
 817   dialog#interpChoiceDialogLabel#set_label "Choose an interpretation:";
 818   let interp_no = ref None in
 819   let return _ =
 820     dialog#interpChoiceDialog#destroy ();
 821     GMain.Main.quit ()
 822   in
 823   let fail _ = interp_no := None; return () in
 824   ignore (dialog#interpChoiceDialog#event#connect#delete (fun _ -> true));
 825   connect_button dialog#interpChoiceOkButton (fun _ ->
 826     match !interp_no with None -> () | Some _ -> return ());
 827   connect_button dialog#interpChoiceCancelButton fail;
 828   ignore (dialog#interpChoiceTreeView#connect#row_activated (fun path _ ->
 829     interp_no := Some (model#get_interp_no path);
 830     return ()));
 831   let selection = dialog#interpChoiceTreeView#selection in
 832   ignore (selection#connect#changed (fun _ ->
 833     match selection#get_selected_rows with
 834     | [path] ->
 835         MatitaLog.debug (sprintf "selection: %d" (model#get_interp_no path));
 836         interp_no := Some (model#get_interp_no path)
 837     | _ -> assert false));
 838   dialog#interpChoiceDialog#show ();
 839   GtkThread.main ();
 840   (match !interp_no with Some row -> [row] | _ -> raise MatitaTypes.Cancel)
 841