helm/matita/matitaMathView.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30 let list_map_fail f =
  31   let rec aux = function
  32     | [] -> []
  33     | he::tl ->
  34         try
  35           let he' = f he in
  36           he'::(aux tl)
  37         with Exit ->
  38           (aux tl)
  39   in
  40   aux
  41
  42 let add_trailing_slash =
  43   let rex = Pcre.regexp "/$" in
  44   fun s ->
  45     if Pcre.pmatch ~rex s then s
  46     else s ^ "/"
  47
  48 let strip_blanks =
  49   let rex = Pcre.regexp "^\\s*([^\\s]*)\\s*$" in
  50   fun s ->
  51     (Pcre.extract ~rex s).(1)
  52
  53 (** inherit from this class if you want to access current script *)
  54 class scriptAccessor =
  55 object (self)
  56   method private script = MatitaScript.instance ()
  57 end
  58
  59 let cicBrowsers = ref []
  60
  61 let default_font_size () =
  62   Helm_registry.get_opt_default Helm_registry.int
  63     ~default:BuildTimeConf.default_font_size "matita.font_size"
  64 let current_font_size = ref ~-1
  65 let increase_font_size () = incr current_font_size
  66 let decrease_font_size () = decr current_font_size
  67 let reset_font_size () = current_font_size := default_font_size ()
  68
  69   (* is there any lablgtk2 constant corresponding to the left mouse button??? *)
  70 let left_button = 1
  71
  72 let near (x1, y1) (x2, y2) =
  73   let distance = sqrt (((x2 -. x1) ** 2.) +. ((y2 -. y1) ** 2.)) in
  74   (distance < 4.)
  75
  76 class clickableMathView obj =
  77   let href = Gdome.domString "href" in
  78   let xref = Gdome.domString "xref" in
  79   object (self)
  80     inherit GMathViewAux.multi_selection_math_view obj
  81
  82     val mutable href_callback: (string -> unit) option = None
  83     method set_href_callback f = href_callback <- f
  84
  85     initializer
  86       self#set_font_size !current_font_size;
  87       ignore (self#connect#selection_changed self#choose_selection);
  88       ignore (self#event#connect#button_press self#button_press);
  89       ignore (self#event#connect#button_release self#button_release);
  90 (*       ignore (self#connect#click (fun (gdome_elt, _, _, _) ->
  91         match gdome_elt with
  92         | Some elt  |+ element is an hyperlink, use href_callback on it +|
  93           when elt#hasAttributeNS ~namespaceURI:DomMisc.xlink_ns ~localName:href ->
  94             (match href_callback with
  95             | None -> ()
  96             | Some f ->
  97                 let uri =
  98                   elt#getAttributeNS ~namespaceURI:DomMisc.xlink_ns ~localName:href
  99                 in
 100                 f (uri#to_string))
 101         | Some elt -> ignore (self#action_toggle elt)
 102         | None -> ())) *)
 103
 104     val mutable button_press_x = -1.
 105     val mutable button_press_y = -1.
 106
 107     method private button_press gdk_button =
 108       button_press_x <- GdkEvent.Button.x gdk_button;
 109       button_press_y <- GdkEvent.Button.y gdk_button;
 110       false
 111
 112     method private button_release gdk_button =
 113       let button_release_x = GdkEvent.Button.x gdk_button in
 114       let button_release_y = GdkEvent.Button.y gdk_button in
 115       (if near (button_press_x, button_press_y)
 116         (button_release_x, button_release_y)
 117       then
 118         let x = int_of_float button_press_x in
 119         let y = int_of_float button_press_y in
 120         (match self#get_element_at x y with
 121         | None -> ()
 122         | Some elt ->
 123             let namespaceURI = DomMisc.xlink_ns in
 124             let localName = href in
 125             if elt#hasAttributeNS ~namespaceURI ~localName then
 126               self#invoke_href_callback
 127                 (elt#getAttributeNS ~namespaceURI ~localName)#to_string
 128                 gdk_button
 129             else
 130               ignore (self#action_toggle elt)));
 131       false
 132
 133     method private invoke_href_callback href_value gdk_button =
 134       let button = GdkEvent.Button.button gdk_button in
 135       if button = left_button then
 136         let time = GdkEvent.Button.time gdk_button in
 137         match href_callback with
 138         | None -> ()
 139         | Some f ->
 140             (match MatitaMisc.split href_value with
 141             | [ uri ] ->  f uri
 142             | uris ->
 143                 let menu = GMenu.menu () in
 144                 List.iter
 145                   (fun uri ->
 146                     let menu_item =
 147                       GMenu.menu_item ~label:uri ~packing:menu#append ()
 148                     in
 149                     ignore (menu_item#connect#activate (fun () -> f uri)))
 150                   uris;
 151                 menu#popup ~button ~time)
 152
 153     method private choose_selection gdome_elt =
 154       let rec aux elt =
 155         if elt#hasAttributeNS ~namespaceURI:DomMisc.helm_ns ~localName:xref then
 156           self#set_selection (Some elt)
 157         else
 158           try
 159             (match elt#get_parentNode with
 160             | None -> assert false
 161             | Some p -> aux (new Gdome.element_of_node p))
 162           with GdomeInit.DOMCastException _ -> ()
 163 (*             debug_print "trying to select above the document root" *)
 164       in
 165       match gdome_elt with
 166       | Some elt -> aux elt
 167       | None   -> self#set_selection None
 168
 169     method update_font_size =
 170       self#set_font_size !current_font_size
 171
 172   end
 173
 174 let clickableMathView ?hadjustment ?vadjustment ?font_size ?log_verbosity =
 175   GtkBase.Widget.size_params
 176     ~cont:(OgtkMathViewProps.pack_return (fun p ->
 177       OgtkMathViewProps.set_params
 178         (new clickableMathView (GtkMathViewProps.MathView_GMetaDOM.create p))
 179         ~font_size:None ~log_verbosity:None))
 180     []
 181
 182 class sequentViewer obj =
 183   object(self)
 184
 185     inherit clickableMathView obj
 186
 187     val mutable current_infos = None
 188
 189     method get_selected_terms =
 190       let selections = self#get_selections in
 191       list_map_fail
 192         (fun node ->
 193           let xpath =
 194             ((node : Gdome.element)#getAttributeNS
 195               ~namespaceURI:DomMisc.helm_ns
 196               ~localName:(Gdome.domString "xref"))#to_string
 197           in
 198           if xpath = "" then assert false (* "ERROR: No xref found!!!" *)
 199           else
 200             match current_infos with
 201             | Some (ids_to_terms,_,_) ->
 202                 (try Hashtbl.find ids_to_terms xpath with _ -> raise Exit)
 203             | None -> assert false) (* "ERROR: No current term!!!" *)
 204         selections
 205
 206     method get_selected_hypotheses =
 207       let selections = self#get_selections in
 208       list_map_fail
 209         (fun node ->
 210           let xpath =
 211             ((node : Gdome.element)#getAttributeNS
 212               ~namespaceURI:DomMisc.helm_ns
 213               ~localName:(Gdome.domString "xref"))#to_string
 214           in
 215           if xpath = "" then assert false (* "ERROR: No xref found!!!" *)
 216           else
 217             match current_infos with
 218             | Some (_,_,ids_to_hypotheses) ->
 219                 (try Hashtbl.find ids_to_hypotheses xpath with _ -> raise Exit)
 220             | None -> assert false) (* "ERROR: No current term!!!" *)
 221         selections
 222
 223   method load_sequent metasenv metano =
 224     let sequent = CicUtil.lookup_meta metano metasenv in
 225     let (mathml,(_,(ids_to_terms, ids_to_father_ids, ids_to_hypotheses,_))) =
 226       ApplyTransformation.mml_of_cic_sequent metasenv sequent
 227     in
 228     current_infos <- Some (ids_to_terms, ids_to_father_ids, ids_to_hypotheses);
 229     let name = "sequent_viewer.xml" in
 230     prerr_endline ("load_sequent: dumping MathML to ./" ^ name);
 231     ignore (DomMisc.domImpl#saveDocumentToFile ~name ~doc:mathml ());
 232     self#load_root ~root:mathml#get_documentElement
 233  end
 234
 235 class sequentsViewer ~(notebook:GPack.notebook)
 236   ~(sequentViewer:sequentViewer) ()
 237 =
 238   object (self)
 239     inherit scriptAccessor
 240
 241     val mutable pages = 0
 242     val mutable switch_page_callback = None
 243     val mutable page2goal = []  (* associative list: page no -> goal no *)
 244     val mutable goal2page = []  (* the other way round *)
 245     val mutable goal2win = []   (* associative list: goal no -> scrolled win *)
 246     val mutable _metasenv = []
 247     val mutable scrolledWin: GBin.scrolled_window option = None
 248       (* scrolled window to which the sequentViewer is currently attached *)
 249
 250     method private tab_label metano =
 251       (GMisc.label ~text:(sprintf "?%d" metano) ~show:true ())#coerce
 252
 253     method reset =
 254       (match scrolledWin with
 255       | Some w ->
 256           (* removing page from the notebook will destroy all contained widget,
 257           * we do not want the sequentViewer to be destroyed as well *)
 258           w#remove sequentViewer#coerce;
 259           scrolledWin <- None
 260       | None -> ());
 261       for i = 1 to pages do notebook#remove_page 0 done;
 262       pages <- 0;
 263       page2goal <- [];
 264       goal2page <- [];
 265       goal2win <- [];
 266       _metasenv <- [];
 267       self#script#setGoal ~-1;
 268       (match switch_page_callback with
 269       | Some id ->
 270           GtkSignal.disconnect notebook#as_widget id;
 271           switch_page_callback <- None
 272       | None -> ())
 273
 274     method load_sequents (status: ProofEngineTypes.status) =
 275       let ((_, metasenv, _, _), goal) = status in
 276       let sequents_no = List.length metasenv in
 277       _metasenv <- metasenv;
 278       pages <- sequents_no;
 279       self#script#setGoal goal;
 280       let win metano =
 281         let w =
 282           GBin.scrolled_window ~hpolicy:`AUTOMATIC ~vpolicy:`AUTOMATIC
 283             ~shadow_type:`IN ~show:true ()
 284         in
 285         let reparent () =
 286           scrolledWin <- Some w;
 287           match sequentViewer#misc#parent with
 288           | None -> w#add sequentViewer#coerce
 289           | Some _ -> sequentViewer#misc#reparent w#coerce
 290         in
 291         goal2win <- (metano, reparent) :: goal2win;
 292         w#coerce
 293       in
 294       let page = ref 0 in
 295       List.iter
 296         (fun (metano, _, _) ->
 297           page2goal <- (!page, metano) :: page2goal;
 298           goal2page <- (metano, !page) :: goal2page;
 299           incr page;
 300           notebook#append_page ~tab_label:(self#tab_label metano) (win metano))
 301         metasenv;
 302       switch_page_callback <-
 303         Some (notebook#connect#switch_page ~callback:(fun page ->
 304           let goal =
 305             try
 306               List.assoc page page2goal
 307             with Not_found -> assert false
 308           in
 309           self#script#setGoal goal;
 310           self#render_page ~page ~goal))
 311
 312     method private render_page ~page ~goal =
 313       sequentViewer#load_sequent _metasenv goal;
 314       try
 315         List.assoc goal goal2win ();
 316         sequentViewer#set_selection None
 317       with Not_found -> assert false
 318
 319     method goto_sequent goal =
 320       let page =
 321         try
 322           List.assoc goal goal2page
 323         with Not_found -> assert false
 324       in
 325       notebook#goto_page page;
 326       self#render_page page goal
 327
 328   end
 329
 330  (** constructors *)
 331
 332 type 'widget constructor =
 333   ?hadjustment:GData.adjustment ->
 334   ?vadjustment:GData.adjustment ->
 335   ?font_size:int ->
 336   ?log_verbosity:int ->
 337   ?width:int ->
 338   ?height:int ->
 339   ?packing:(GObj.widget -> unit) ->
 340   ?show:bool ->
 341   unit ->
 342     'widget
 343
 344 let sequentViewer ?hadjustment ?vadjustment ?font_size ?log_verbosity =
 345   GtkBase.Widget.size_params
 346     ~cont:(OgtkMathViewProps.pack_return (fun p ->
 347       OgtkMathViewProps.set_params
 348         (new sequentViewer (GtkMathViewProps.MathView_GMetaDOM.create p))
 349         ~font_size ~log_verbosity))
 350     []
 351
 352 let blank_uri = BuildTimeConf.blank_uri
 353 let current_proof_uri = BuildTimeConf.current_proof_uri
 354
 355 type term_source =
 356   [ `Ast of DisambiguateTypes.term
 357   | `Cic of Cic.term * Cic.metasenv
 358   | `String of string
 359   ]
 360
 361 class type cicBrowser =
 362 object
 363   method load: MatitaTypes.mathViewer_entry -> unit
 364   (* method loadList: string list -> MatitaTypes.mathViewer_entry-> unit *)
 365   method loadInput: string -> unit
 366 end
 367
 368 let reloadable = function
 369   | `About `Current_proof
 370   | `Dir _ ->
 371       true
 372   | _ -> false
 373
 374 class cicBrowser_impl ~(history:MatitaTypes.mathViewer_entry MatitaMisc.history)
 375   ()
 376 =
 377   let term_RE = Pcre.regexp "^term:(.*)" in
 378   let whelp_RE = Pcre.regexp "^\\s*whelp" in
 379   let uri_RE =
 380     Pcre.regexp
 381       "^cic:/([^/]+/)*[^/]+\\.(con|ind|var)(#xpointer\\(\\d+(/\\d+)+\\))?$"
 382   in
 383   let dir_RE = Pcre.regexp "^cic:((/([^/]+/)*[^/]+(/)?)|/|)$" in
 384   let whelp_query_RE = Pcre.regexp "^\\s*whelp\\s+([^\\s]+)\\s+(.*)$" in
 385   let trailing_slash_RE = Pcre.regexp "/$" in
 386   let has_xpointer_RE = Pcre.regexp "#xpointer\\(\\d+/\\d+(/\\d+)?\\)$" in
 387   let is_whelp txt = Pcre.pmatch ~rex:whelp_RE txt in
 388   let is_uri txt = Pcre.pmatch ~rex:uri_RE txt in
 389   let is_dir txt = Pcre.pmatch ~rex:dir_RE txt in
 390   let gui = MatitaGui.instance () in
 391   let win = gui#newBrowserWin () in
 392   let queries = ["Locate";"Hint";"Match";"Elim";"Instance"] in
 393   let combo,_ = GEdit.combo_box_text ~strings:queries () in
 394   let activate_combo_query input q =
 395     let q' = String.lowercase q in
 396     let rec aux i = function
 397       | [] -> failwith ("Whelp query '" ^ q ^ "' not found")
 398       | h::_ when String.lowercase h = q' -> i
 399       | _::tl -> aux (i+1) tl
 400     in
 401     combo#set_active (aux 0 queries);
 402     win#queryInputText#set_text input
 403   in
 404   let set_whelp_query txt =
 405     let query, arg =
 406       try
 407         let q = Pcre.extract ~rex:whelp_query_RE txt in
 408         q.(1), q.(2)
 409       with Invalid_argument _ -> failwith "Malformed Whelp query"
 410     in
 411     activate_combo_query arg query
 412   in
 413   let toplevel = win#toplevel in
 414   let mathView = sequentViewer ~packing:win#scrolledBrowser#add () in
 415   let fail message =
 416     MatitaGtkMisc.report_error ~title:"Cic browser" ~message
 417       ~parent:toplevel ()
 418   in
 419   let tags =
 420     [ "dir", GdkPixbuf.from_file (MatitaMisc.image_path "matita-folder.png");
 421       "obj", GdkPixbuf.from_file (MatitaMisc.image_path "matita-object.png") ]
 422   in
 423   let handle_error f =
 424     try
 425       f ()
 426     with exn -> fail (MatitaExcPp.to_string exn)
 427   in
 428   let handle_error' f = (fun () -> handle_error (fun () -> f ())) in
 429   object (self)
 430     inherit scriptAccessor
 431
 432     (* Whelp bar queries *)
 433
 434     initializer
 435       activate_combo_query "" "locate";
 436       win#whelpBarComboVbox#add combo#coerce;
 437       let start_query () =
 438         let query = String.lowercase (List.nth queries combo#active) in
 439         let input = win#queryInputText#text in
 440         let statement = "whelp " ^ query ^ " " ^ input ^ "." in
 441         (MatitaScript.instance ())#advance ~statement ()
 442       in
 443       ignore(win#queryInputText#connect#activate ~callback:start_query);
 444       ignore(combo#connect#changed ~callback:start_query);
 445       win#whelpBarImage#set_file (MatitaMisc.image_path "whelp.png");
 446       win#mathOrListNotebook#set_show_tabs false;
 447
 448       win#browserForwardButton#misc#set_sensitive false;
 449       win#browserBackButton#misc#set_sensitive false;
 450       ignore (win#browserUri#entry#connect#activate (handle_error' (fun () ->
 451         self#loadInput win#browserUri#entry#text)));
 452       ignore (win#browserHomeButton#connect#clicked (handle_error' (fun () ->
 453         self#load (`About `Current_proof))));
 454       ignore (win#browserRefreshButton#connect#clicked
 455         (handle_error' self#refresh));
 456       ignore (win#browserBackButton#connect#clicked (handle_error' self#back));
 457       ignore (win#browserForwardButton#connect#clicked
 458         (handle_error' self#forward));
 459       ignore (win#toplevel#event#connect#delete (fun _ ->
 460         let my_id = Oo.id self in
 461         cicBrowsers := List.filter (fun b -> Oo.id b <> my_id) !cicBrowsers;
 462         if !cicBrowsers = [] &&
 463           Helm_registry.get "matita.mode" = "cicbrowser"
 464         then
 465           GMain.quit ();
 466         false));
 467       ignore(win#whelpResultTreeview#connect#row_activated
 468         ~callback:(fun _ _ ->
 469           handle_error (fun () -> self#loadInput (self#_getSelectedUri ()))));
 470       mathView#set_href_callback (Some (fun uri ->
 471         handle_error (fun () ->
 472           self#load (`Uri (UriManager.uri_of_string uri)))));
 473       self#_load (`About `Blank);
 474       toplevel#show ()
 475
 476     val mutable current_entry = `About `Blank
 477     val mutable current_infos = None
 478     val mutable current_mathml = None
 479
 480     val model =
 481       new MatitaGtkMisc.taggedStringListModel tags win#whelpResultTreeview
 482
 483     val mutable lastDir = ""  (* last loaded "directory" *)
 484
 485     method private _getSelectedUri () =
 486       match model#easy_selection () with
 487       | [sel] when is_uri sel -> sel  (* absolute URI selected *)
 488 (*       | [sel] -> win#browserUri#entry#text ^ sel  |+ relative URI selected +| *)
 489       | [sel] -> lastDir ^ sel
 490       | _ -> assert false
 491
 492     (** history RATIONALE
 493      *
 494      * All operations about history are done using _historyFoo.
 495      * Only toplevel functions (ATM load and loadInput) call _historyAdd.
 496      *)
 497
 498     method private _historyAdd item =
 499       history#add item;
 500       win#browserBackButton#misc#set_sensitive true;
 501       win#browserForwardButton#misc#set_sensitive false
 502
 503     method private _historyPrev () =
 504       let item = history#previous in
 505       if history#is_begin then win#browserBackButton#misc#set_sensitive false;
 506       win#browserForwardButton#misc#set_sensitive true;
 507       item
 508
 509     method private _historyNext () =
 510       let item = history#next in
 511       if history#is_end then win#browserForwardButton#misc#set_sensitive false;
 512       win#browserBackButton#misc#set_sensitive true;
 513       item
 514
 515     (** notebook RATIONALE
 516      *
 517      * Use only these functions to switch between the tabs
 518      *)
 519     method private _showList = win#mathOrListNotebook#goto_page 1
 520     method private _showMath = win#mathOrListNotebook#goto_page 0
 521
 522     method private back () =
 523       try
 524         self#_load (self#_historyPrev ())
 525       with MatitaMisc.History_failure -> ()
 526
 527     method private forward () =
 528       try
 529         self#_load (self#_historyNext ())
 530       with MatitaMisc.History_failure -> ()
 531
 532       (* loads a uri which can be a cic uri or an about:* uri
 533       * @param uri string *)
 534     method private _load entry =
 535       try
 536         if entry <> current_entry || reloadable entry then begin
 537           (match entry with
 538           | `About `Current_proof -> self#home ()
 539           | `About `Blank -> self#blank ()
 540           | `About `Us -> () (* TODO implement easter egg here :-] *)
 541           | `Check term -> self#_loadCheck term
 542           | `Cic (term, metasenv) -> self#_loadTermCic term metasenv
 543           | `Dir dir -> self#_loadDir dir
 544           | `Uri uri -> self#_loadUriManagerUri uri
 545           | `Whelp (query, results) ->
 546               set_whelp_query query;
 547               self#_loadList (List.map (fun r -> "obj",
 548                 UriManager.string_of_uri r) results));
 549           self#setEntry entry
 550         end
 551       with exn -> fail (MatitaExcPp.to_string exn)
 552
 553     method private blank () =
 554       self#_showMath;
 555       mathView#load_root (MatitaMisc.empty_mathml ())#get_documentElement
 556
 557     method private _loadCheck term =
 558       failwith "not implemented _loadCheck";
 559       self#_showMath
 560
 561     method private home () =
 562       self#_showMath;
 563       match self#script#status.proof_status with
 564       | Proof  (uri, metasenv, bo, ty) ->
 565           let name = UriManager.name_of_uri (MatitaMisc.unopt uri) in
 566           let obj = Cic.CurrentProof (name, metasenv, bo, ty, [], []) in
 567           self#_loadObj obj
 568       | Incomplete_proof ((uri, metasenv, bo, ty), _) ->
 569           let name = UriManager.name_of_uri (MatitaMisc.unopt uri) in
 570           let obj = Cic.CurrentProof (name, metasenv, bo, ty, [], []) in
 571           self#_loadObj obj
 572       | _ -> self#blank ()
 573
 574       (** loads a cic uri from the environment
 575       * @param uri UriManager.uri *)
 576     method private _loadUriManagerUri uri =
 577       let uri = UriManager.strip_xpointer uri in
 578       let (obj, _) = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 579       self#_loadObj obj
 580
 581     method private _loadDir dir =
 582       let content = Http_getter.ls dir in
 583       let l =
 584         List.fast_sort
 585           Pervasives.compare
 586           (List.map
 587             (function
 588               | Http_getter_types.Ls_section s -> "dir", s
 589               | Http_getter_types.Ls_object o -> "obj", o.Http_getter_types.uri)
 590             content)
 591       in
 592       lastDir <- dir;
 593       self#_loadList l
 594
 595     method private setEntry entry =
 596       win#browserUri#entry#set_text (string_of_entry entry);
 597       current_entry <- entry
 598
 599     method private _loadObj obj =
 600       self#_showMath;
 601       (* this must be _before_ loading the document, since
 602        * if the widget is not mapped (hidden by the notebook)
 603        * the document is not rendered *)
 604       let use_diff = false in (* ZACK TODO use XmlDiff when re-rendering? *)
 605       let (mathml, (_,(ids_to_terms, ids_to_father_ids, ids_to_conjectures,
 606            ids_to_hypotheses,_,_))) =
 607         ApplyTransformation.mml_of_cic_object obj
 608       in
 609       current_infos <- Some (ids_to_terms, ids_to_father_ids,
 610         ids_to_conjectures, ids_to_hypotheses);
 611       (match current_mathml with
 612       | Some current_mathml when use_diff ->
 613           mathView#freeze;
 614           XmlDiff.update_dom ~from:current_mathml mathml;
 615           mathView#thaw
 616       |  _ ->
 617           let name = "cic_browser.xml" in
 618           prerr_endline ("cic_browser: dumping MathML to ./" ^ name);
 619           ignore (DomMisc.domImpl#saveDocumentToFile ~name ~doc:mathml ());
 620           mathView#load_root ~root:mathml#get_documentElement;
 621           current_mathml <- Some mathml);
 622
 623     method private _loadTermCic term metasenv =
 624       let context = self#script#proofContext in
 625       let dummyno = CicMkImplicit.new_meta metasenv [] in
 626       let sequent = (dummyno, context, term) in
 627       mathView#load_sequent (sequent :: metasenv) dummyno;
 628       self#_showMath
 629
 630     method private _loadList l =
 631       model#list_store#clear ();
 632       List.iter (fun (tag, s) -> model#easy_append ~tag s) l;
 633       self#_showList
 634
 635     (** { public methods, all must call _load!! } *)
 636
 637     method load entry =
 638       handle_error (fun () -> self#_load entry; self#_historyAdd entry)
 639
 640     (**  this is what the browser does when you enter a string an hit enter *)
 641     method loadInput txt =
 642       let txt = strip_blanks txt in
 643       let fix_uri txt =
 644         UriManager.string_of_uri
 645           (UriManager.strip_xpointer (UriManager.uri_of_string txt))
 646       in
 647       if is_whelp txt then begin
 648         set_whelp_query txt;
 649         (MatitaScript.instance ())#advance ~statement:(txt ^ ".") ()
 650       end else begin
 651         let entry =
 652           match txt with
 653           | txt when is_uri txt -> `Uri (UriManager.uri_of_string (fix_uri txt))
 654           | txt when is_dir txt -> `Dir (add_trailing_slash txt)
 655           | txt ->
 656               (try
 657                 entry_of_string txt
 658               with Invalid_argument _ ->
 659                 command_error (sprintf "unsupported uri: %s" txt))
 660         in
 661         self#_load entry;
 662         self#_historyAdd entry
 663       end
 664
 665       (** {2 methods accessing underlying GtkMathView} *)
 666
 667     method updateFontSize = mathView#set_font_size !current_font_size
 668
 669       (** {2 methods used by constructor only} *)
 670
 671     method win = win
 672     method history = history
 673     method currentEntry = current_entry
 674     method refresh () =
 675       if reloadable current_entry then self#_load current_entry
 676
 677   end
 678
 679 let sequentsViewer ~(notebook:GPack.notebook)
 680   ~(sequentViewer:sequentViewer) ()
 681 =
 682   new sequentsViewer ~notebook ~sequentViewer ()
 683
 684 let cicBrowser () =
 685   let size = BuildTimeConf.browser_history_size in
 686   let rec aux history =
 687     let browser = new cicBrowser_impl ~history () in
 688     let win = browser#win in
 689     ignore (win#browserNewButton#connect#clicked (fun () ->
 690       let history =
 691         new MatitaMisc.browser_history ~memento:history#save size
 692           (`About `Blank)
 693       in
 694       let newBrowser = aux history in
 695       newBrowser#load browser#currentEntry));
 696 (*
 697       (* attempt (failed) to close windows on CTRL-W ... *)
 698     MatitaGtkMisc.connect_key win#browserWinEventBox#event ~modifiers:[`CONTROL]
 699       GdkKeysyms._W (fun () -> win#toplevel#destroy ());
 700 *)
 701     cicBrowsers := browser :: !cicBrowsers;
 702     (browser :> cicBrowser)
 703   in
 704   let history = new MatitaMisc.browser_history size (`About `Blank) in
 705   aux history
 706
 707 let default_sequentViewer () = sequentViewer ~show:true ()
 708 let sequentViewer_instance = MatitaMisc.singleton default_sequentViewer
 709
 710 let default_sequentsViewer () =
 711   let gui = MatitaGui.instance () in
 712   let sequentViewer = sequentViewer_instance () in
 713   sequentsViewer ~notebook:gui#main#sequentsNotebook ~sequentViewer ()
 714 let sequentsViewer_instance = MatitaMisc.singleton default_sequentsViewer
 715
 716 let mathViewer () =
 717   object(self)
 718     method private get_browser reuse =
 719       if reuse then
 720         (match !cicBrowsers with
 721         | [] -> cicBrowser ()
 722         | b :: _ -> (b :> cicBrowser))
 723       else
 724         (cicBrowser ())
 725
 726     method show_entry ?(reuse=false) t = (self#get_browser reuse)#load t
 727
 728     method show_uri_list ?(reuse=false) ~entry l =
 729       (self#get_browser reuse)#load entry
 730   end
 731
 732 let refresh_all_browsers () = List.iter (fun b -> b#refresh ()) !cicBrowsers
 733
 734 let update_font_sizes () =
 735   List.iter (fun b -> b#updateFontSize) !cicBrowsers;
 736   (sequentViewer_instance ())#update_font_size
 737