helm/matita/matitaMisc.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27 open MatitaTypes
  28
  29 (** Functions "imported" from Http_getter_misc *)
  30
  31 let strip_trailing_slash = Http_getter_misc.strip_trailing_slash
  32 let normalize_dir = Http_getter_misc.normalize_dir
  33 let strip_suffix = Http_getter_misc.strip_suffix
  34
  35 let baseuri_of_baseuri_decl st =
  36   match st with
  37   | GrafiteAst.Executable (_, GrafiteAst.Command (_, GrafiteAst.Set (_, "baseuri", buri))) ->
  38       Some buri
  39   | _ -> None
  40
  41 let baseuri_of_file file =
  42   let uri = ref None in
  43   let ic = open_in file in
  44   let istream = Ulexing.from_utf8_channel ic in
  45   (try
  46     while true do
  47       try
  48         let stm = GrafiteParser.parse_statement istream in
  49         match baseuri_of_baseuri_decl stm with
  50         | Some buri ->
  51             let u = strip_trailing_slash buri in
  52             if String.length u < 5 || String.sub u 0 5 <> "cic:/" then
  53               MatitaLog.error (file ^ " sets an incorrect baseuri: " ^ buri);
  54             (try
  55               ignore(Http_getter.resolve u)
  56             with
  57             | Http_getter_types.Unresolvable_URI _ ->
  58                 MatitaLog.error (file ^ " sets an unresolvable baseuri: "^buri)
  59             | Http_getter_types.Key_not_found _ -> ());
  60             uri := Some u;
  61             raise End_of_file
  62         | None -> ()
  63       with
  64         CicNotationParser.Parse_error _ as exn ->
  65           prerr_endline ("Unable to parse: " ^ file);
  66           prerr_endline (MatitaExcPp.to_string exn);
  67           ()
  68     done
  69   with End_of_file -> close_in ic);
  70   match !uri with
  71   | Some uri -> uri
  72   | None -> failwith ("No baseuri defined in " ^ file)
  73
  74 let is_empty buri =
  75  List.for_all
  76   (function
  77       Http_getter_types.Ls_section _ -> true
  78     | Http_getter_types.Ls_object _ -> false)
  79   (Http_getter.ls (Http_getter_misc.strip_trailing_slash buri ^ "/"))
  80
  81 let safe_remove fname = if Sys.file_exists fname then Sys.remove fname
  82
  83 let is_dir_empty d =
  84   try
  85     let od = Unix.opendir d in
  86     try
  87       ignore (Unix.readdir od);
  88       ignore (Unix.readdir od);
  89       ignore (Unix.readdir od);
  90       Unix.closedir od;
  91       false
  92     with End_of_file ->
  93       Unix.closedir od;
  94       true
  95   with Unix.Unix_error _ -> true
  96
  97 let safe_rmdir d = try Unix.rmdir d with Unix.Unix_error _ -> ()
  98
  99 let rec rmdir_descend d =
 100   if is_dir_empty d then
 101     begin
 102       safe_rmdir d;
 103       rmdir_descend (Filename.dirname d)
 104     end
 105
 106 let absolute_path file =
 107   if file.[0] = '/' then file else Unix.getcwd () ^ "/" ^ file
 108
 109 let is_proof_script fname = true  (** TODO Zack *)
 110 let is_proof_object fname = true  (** TODO Zack *)
 111
 112 let append_phrase_sep s =
 113   if not (Pcre.pmatch ~pat:(sprintf "%s$" BuildTimeConf.phrase_sep) s) then
 114     s ^ BuildTimeConf.phrase_sep
 115   else
 116     s
 117
 118 let empty_mathml () =
 119   DomMisc.domImpl#createDocument ~namespaceURI:(Some DomMisc.mathml_ns)
 120     ~qualifiedName:(Gdome.domString "math") ~doctype:None
 121
 122 let empty_boxml () =
 123   DomMisc.domImpl#createDocument ~namespaceURI:(Some DomMisc.boxml_ns)
 124     ~qualifiedName:(Gdome.domString "box") ~doctype:None
 125
 126 exception History_failure
 127
 128 type 'a memento = 'a array * int * int * int  (* data, hd, tl, cur *)
 129
 130 class type ['a] history =
 131   object
 132     method add : 'a -> unit
 133     method next : 'a
 134     method previous : 'a
 135     method load: 'a memento -> unit
 136     method save: 'a memento
 137     method is_begin: bool
 138     method is_end: bool
 139   end
 140
 141 class basic_history (head, tail, cur) =
 142   object
 143     val mutable hd = head  (* insertion point *)
 144     val mutable tl = tail (* oldest inserted item *)
 145     val mutable cur = cur  (* current item for the history *)
 146
 147     method is_begin = cur <= tl
 148     method is_end = cur >= hd
 149   end
 150
 151
 152 class shell_history size =
 153   let size = size + 1 in
 154   let decr x = let x' = x - 1 in if x' < 0 then size + x' else x' in
 155   let incr x = (x + 1) mod size in
 156   object (self)
 157     val data = Array.create size ""
 158
 159     inherit basic_history (0, -1 , -1)
 160
 161     method add s =
 162       data.(hd) <- s;
 163       if tl = -1 then tl <- hd;
 164       hd <- incr hd;
 165       if hd = tl then tl <- incr tl;
 166       cur <- hd
 167     method previous =
 168       if cur = tl then raise History_failure;
 169       cur <- decr cur;
 170       data.(cur)
 171     method next =
 172       if cur = hd then raise History_failure;
 173       cur <- incr cur;
 174       if cur = hd then "" else data.(cur)
 175     method load (data', hd', tl', cur') =
 176       assert (Array.length data = Array.length data');
 177       hd <- hd'; tl <- tl'; cur <- cur';
 178       Array.blit data' 0 data 0 (Array.length data')
 179     method save = (Array.copy data, hd, tl, cur)
 180   end
 181
 182 class ['a] browser_history ?memento size init =
 183   object (self)
 184     initializer match memento with Some m -> self#load m | _ -> ()
 185     val data = Array.create size init
 186
 187     inherit basic_history (0, 0, 0)
 188
 189     method previous =
 190       if cur = tl then raise History_failure;
 191       cur <- cur - 1;
 192       if cur = ~-1 then cur <- size - 1;
 193       data.(cur)
 194     method next =
 195       if cur = hd then raise History_failure;
 196       cur <- cur + 1;
 197       if cur = size then cur <- 0;
 198       data.(cur)
 199     method add (e:'a) =
 200       if e <> data.(cur) then
 201         begin
 202           cur <- cur + 1;
 203           if cur = size then cur <- 0;
 204           if cur = tl then tl <- tl + 1;
 205           if tl = size then tl <- 0;
 206           hd <- cur;
 207           data.(cur) <- e
 208         end
 209     method load (data', hd', tl', cur') =
 210       assert (Array.length data = Array.length data');
 211       hd <- hd'; tl <- tl'; cur <- cur';
 212       Array.blit data' 0 data 0 (Array.length data')
 213     method save = (Array.copy data, hd, tl, cur)
 214   end
 215
 216 let singleton f =
 217   let instance = lazy (f ()) in
 218   fun () -> Lazy.force instance
 219
 220 let get_proof_status status =
 221   match status.proof_status with
 222   | Incomplete_proof s -> s
 223   | _ -> statement_error "no ongoing proof"
 224
 225 let get_proof_metasenv status =
 226   match status.proof_status with
 227   | No_proof -> []
 228   | Incomplete_proof ((_, metasenv, _, _), _) -> metasenv
 229   | Proof (_, metasenv, _, _) -> metasenv
 230   | Intermediate m -> m
 231
 232 let get_proof_context status =
 233   match status.proof_status with
 234   | Incomplete_proof ((_, metasenv, _, _), goal) ->
 235       let (_, context, _) = CicUtil.lookup_meta goal metasenv in
 236       context
 237   | _ -> []
 238
 239 let get_proof_conclusion status =
 240   match status.proof_status with
 241   | Incomplete_proof ((_, metasenv, _, _), goal) ->
 242       let (_, _, conclusion) = CicUtil.lookup_meta goal metasenv in
 243       conclusion
 244   | _ -> statement_error "no ongoing proof"
 245
 246 let qualify status name = get_string_option status "baseuri" ^ "/" ^ name
 247
 248 let image_path n = sprintf "%s/%s" BuildTimeConf.images_dir n
 249
 250 let end_ma_RE = Pcre.regexp "\\.ma$"
 251
 252 let obj_file_of_baseuri baseuri =
 253  let path =
 254   Helm_registry.get "matita.basedir" ^ "/xml" ^
 255    Pcre.replace ~pat:"^cic:" ~templ:"" baseuri
 256  in
 257   path ^ ".moo"
 258
 259 let obj_file_of_script f =
 260  if f = "coq.ma" then BuildTimeConf.coq_notation_script else
 261   let baseuri = baseuri_of_file f in
 262    obj_file_of_baseuri baseuri
 263
 264 let list_tl_at ?(equality=(==)) e l =
 265   let rec aux =
 266     function
 267     | [] -> raise Not_found
 268     | hd :: tl as l when equality hd e -> l
 269     | hd :: tl -> aux tl
 270   in
 271   aux l
 272