helm/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30   (** raised when one of the script margins (top or bottom) is reached *)
  31 exception Margin
  32
  33 let safe_substring s i j =
  34   try String.sub s i j with Invalid_argument _ -> assert false
  35
  36 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  37 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  38 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  39 let newline_RE = Pcre.regexp "\n"
  40
  41 let comment str =
  42   if Pcre.pmatch ~rex:multiline_RE str then
  43     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " **)"
  44   else
  45     "\n(**\n" ^ str ^ "\n**)"
  46
  47 let first_line s =
  48   let s = Pcre.replace ~rex:heading_nl_RE s in
  49   try
  50     let nl_pos = String.index s '\n' in
  51     String.sub s 0 nl_pos
  52   with Not_found -> s
  53
  54 let prepend_text header base =
  55   if Pcre.pmatch ~rex:heading_nl_RE base then
  56     sprintf "\n%s%s" header base
  57   else
  58     sprintf "%s\n%s" header base
  59
  60   (** creates a statement AST for the Goal tactic, e.g. "goal 7" *)
  61 let goal_ast n =
  62   let module A = TacticAst in
  63   let loc = CicAst.dummy_floc in
  64   A.Executable (loc, A.Tactical (loc, A.Tactic (loc, A.Goal (loc, n))))
  65
  66 let eval_with_engine status user_goal parsed_text st =
  67   let module TA = TacticAst in
  68   let module TAPp = TacticAstPp in
  69   let parsed_text_length = String.length parsed_text in
  70   let loc, ex =
  71     match st with TA.Executable (loc,ex) -> loc, ex | _ -> assert false
  72   in
  73   let goal_changed = ref false in
  74   let status =
  75     match status.proof_status with
  76       | Incomplete_proof (_, goal) when goal <> user_goal ->
  77           goal_changed := true;
  78           MatitaEngine.eval_ast status (goal_ast user_goal)
  79       | _ -> status
  80   in
  81   let new_status = MatitaEngine.eval_ast status st in
  82   let new_aliases =
  83     match ex with
  84       | TA.Command (_, TA.Alias _) ->
  85           DisambiguateTypes.Environment.empty
  86       | _ -> MatitaSync.alias_diff ~from:status new_status
  87   in
  88   let new_text =
  89     if DisambiguateTypes.Environment.is_empty new_aliases then
  90       parsed_text
  91     else
  92       prepend_text (CicTextualParser2.EnvironmentP3.to_string new_aliases)
  93         parsed_text
  94   in
  95   let new_text =
  96     if !goal_changed then
  97       prepend_text
  98         (TAPp.pp_tactic (TA.Goal (loc, user_goal))(* ^ "\n"*))
  99         new_text
 100     else
 101       new_text
 102   in
 103     [ new_status, new_text ], parsed_text_length
 104
 105 let disambiguate term status =
 106   let module MD = MatitaDisambiguator in
 107   let dbd = MatitaDb.instance () in
 108   let metasenv = MatitaMisc.get_proof_metasenv status in
 109   let context = MatitaMisc.get_proof_context status in
 110   let aliases = MatitaMisc.get_proof_aliases status in
 111   let interps = MD.disambiguate_term dbd context metasenv aliases term in
 112   match interps with
 113   | [_,_,x,_] -> x
 114   | _ -> assert false
 115
 116 let eval_macro status (mathviewer:MatitaTypes.mathViewer) urichooser parsed_text
 117   script mac
 118 =
 119   let module TA = TacticAst in
 120   let module TAPp = TacticAstPp in
 121   let module MQ = MetadataQuery in
 122   let module MDB = MatitaDb in
 123   let module CTC = CicTypeChecker in
 124   let module CU = CicUniv in
 125   (* no idea why ocaml wants this *)
 126   let advance ?statement () = script#advance ?statement () in
 127   let parsed_text_length = String.length parsed_text in
 128   let dbd = MatitaDb.instance () in
 129   match mac with
 130   (* WHELP's stuff *)
 131   | TA.WMatch (loc, term) ->
 132       let term = disambiguate term status in
 133       let l =  MQ.match_term ~dbd term in
 134       let entry = `Whelp (TAPp.pp_macro_cic (TA.WMatch (loc, term)), l) in
 135       mathviewer#show_uri_list ~reuse:true ~entry l;
 136       [], parsed_text_length
 137   | TA.WInstance (loc, term) ->
 138       let term = disambiguate term status in
 139       let l = MQ.instance ~dbd term in
 140       let entry = `Whelp (TAPp.pp_macro_cic (TA.WInstance (loc, term)), l) in
 141       mathviewer#show_uri_list ~reuse:true ~entry l;
 142       [], parsed_text_length
 143   | TA.WLocate (loc, s) ->
 144       let l = MQ.locate ~dbd s in
 145       let entry = `Whelp (TAPp.pp_macro_cic (TA.WLocate (loc, s)), l) in
 146       mathviewer#show_uri_list ~reuse:true ~entry l;
 147       [], parsed_text_length
 148   | TA.WElim (loc, term) ->
 149       let term = disambiguate term status in
 150       let uri =
 151         match term with
 152         | Cic.MutInd (uri,n,_) -> UriManager.string_of_uriref (uri,[n])
 153         | _ -> failwith "Not a MutInd"
 154       in
 155       let l = MQ.elim ~dbd uri in
 156       let entry = `Whelp (TAPp.pp_macro_cic (TA.WElim (loc, term)), l) in
 157       mathviewer#show_uri_list ~reuse:true ~entry l;
 158       [], parsed_text_length
 159   | TA.WHint (loc, term) ->
 160       let term = disambiguate term status in
 161       let s = ((None,[0,[],term], Cic.Meta (0,[]) ,term),0) in
 162       let l = List.map fst (MQ.experimental_hint ~dbd s) in
 163       let entry = `Whelp (TAPp.pp_macro_cic (TA.WHint (loc, term)), l) in
 164       mathviewer#show_uri_list ~reuse:true ~entry l;
 165       [], parsed_text_length
 166   (* REAL macro *)
 167   | TA.Hint loc ->
 168       let s = MatitaMisc.get_proof_status status in
 169       let l = List.map fst (MQ.experimental_hint ~dbd s) in
 170       let selected = urichooser l in
 171       (match selected with
 172       | [] -> [], parsed_text_length
 173       | [uri] ->
 174         let ast =
 175           (TA.Executable (loc,
 176             (TA.Tactical (loc,
 177                TA.Tactic (loc,
 178                  TA.Apply (loc, CicAst.Uri (uri,None)))))))
 179         in
 180         let new_status = MatitaEngine.eval_ast status ast in
 181         let extra_text =
 182           comment parsed_text ^
 183           "\n" ^ TAPp.pp_statement ast
 184         in
 185         [ new_status , extra_text ], parsed_text_length
 186       | _ -> assert false)
 187   | TA.Check (_,term) ->
 188       let metasenv = MatitaMisc.get_proof_metasenv status in
 189       let context = MatitaMisc.get_proof_context status in
 190       let aliases = MatitaMisc.get_proof_aliases status in
 191       let interps =
 192         MatitaDisambiguator.disambiguate_term
 193           dbd context metasenv aliases term
 194       in
 195       let _, metasenv , term, ugraph =
 196         match interps with
 197         | [x] -> x
 198         | _ -> assert false
 199       in
 200       let ty,_ = CTC.type_of_aux' metasenv context term ugraph in
 201       let t_and_ty = Cic.Cast (term,ty) in
 202       mathviewer#show_entry (`Cic (t_and_ty,metasenv));
 203       [], parsed_text_length
 204 (*   | TA.Abort _ ->
 205       let rec go_back () =
 206         let status = script#status.proof_status in
 207         match status with
 208         | No_proof -> ()
 209         | _ -> script#retract ();go_back()
 210       in
 211       [], parsed_text_length, Some go_back
 212   | TA.Redo (_, Some i) ->  [], parsed_text_length,
 213       Some (fun () -> for j = 1 to i do advance () done)
 214   | TA.Redo (_, None) ->   [], parsed_text_length,
 215       Some (fun () -> advance ())
 216   | TA.Undo (_, Some i) ->  [], parsed_text_length,
 217       Some (fun () -> for j = 1 to i do script#retract () done)
 218   | TA.Undo (_, None) -> [], parsed_text_length,
 219       Some (fun () -> script#retract ()) *)
 220   (* TODO *)
 221   | TA.Quit _ -> failwith "not implemented"
 222   | TA.Print (_,kind) -> failwith "not implemented"
 223   | TA.Search_pat (_, search_kind, str) -> failwith "not implemented"
 224   | TA.Search_term (_, search_kind, term) -> failwith "not implemented"
 225
 226
 227 let eval_executable status (mathviewer:MatitaTypes.mathViewer) urichooser
 228 user_goal parsed_text script ex =
 229   let module TA = TacticAst in
 230   let module TAPp = TacticAstPp in
 231   let module MD = MatitaDisambiguator in
 232   let parsed_text_length = String.length parsed_text in
 233   match ex with
 234   | TA.Command (loc, _) | TA.Tactical (loc, _) ->
 235       eval_with_engine status user_goal parsed_text (TA.Executable (loc, ex))
 236   | TA.Macro (_,mac) ->
 237       eval_macro status mathviewer urichooser parsed_text script mac
 238
 239 let rec eval_statement status (mathviewer:MatitaTypes.mathViewer) urichooser
 240 user_goal script s =
 241   if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 242   let st = CicTextualParser2.parse_statement (Stream.of_string s) in
 243   let text_of_loc loc =
 244     let parsed_text_length = snd (CicAst.loc_of_floc loc) in
 245     let parsed_text = safe_substring s 0 parsed_text_length in
 246     parsed_text, parsed_text_length
 247   in
 248   match st with
 249   | TacticAst.Comment (loc,_)->
 250       let parsed_text, parsed_text_length = text_of_loc loc in
 251       let remain_len = String.length s - parsed_text_length in
 252       let s = String.sub s parsed_text_length remain_len in
 253       let s,len =
 254         eval_statement status mathviewer urichooser user_goal script s
 255       in
 256       (match s with
 257       | (status, text) :: tl ->
 258         ((status, parsed_text ^ text)::tl), (parsed_text_length + len)
 259       | [] -> [], 0)
 260   | TacticAst.Executable (loc, ex) ->
 261       let parsed_text, parsed_text_length = text_of_loc loc in
 262       eval_executable
 263         status mathviewer urichooser user_goal parsed_text script ex
 264
 265
 266 class script ~(buffer: GText.buffer) ~(init: MatitaTypes.status)
 267               ~(mathviewer: MatitaTypes.mathViewer)
 268               ~urichooser () =
 269 object (self)
 270   initializer self#reset ()
 271
 272   val mutable statements = [];    (** executed statements *)
 273   val mutable history = [ init ];
 274     (** list of states before having executed statements. Head element of this
 275       * list is the current state, last element is the state at the beginning of
 276       * the script.
 277       * Invariant: this list length is 1 + length of statements *)
 278
 279   (** goal as seen by the user (i.e. metano corresponding to current tab) *)
 280   val mutable userGoal = ~-1
 281
 282   (** text mark and tag representing locked part of a script *)
 283   val locked_mark =
 284     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 285   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 286
 287     (* history can't be empty, the invariant above grant that it contains at
 288      * least the init status *)
 289   method status = match history with hd :: _ -> hd | _ -> assert false
 290
 291   method private _advance ?statement () =
 292     let s = match statement with Some s -> s | None -> self#getFuture in
 293     MatitaLog.debug ("evaluating: " ^ first_line s ^ " ...");
 294     let (entries, parsed_len) =
 295       eval_statement self#status mathviewer urichooser userGoal self s in
 296     let (new_statuses, new_statements) = List.split entries in
 297 (*
 298 prerr_endline "evalStatement returned";
 299 List.iter (fun s -> prerr_endline ("'" ^ s ^ "'")) new_statements;
 300 *)
 301     history <- List.rev new_statuses @ history;
 302     statements <- List.rev new_statements @ statements;
 303     let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 304     if statement = None then begin
 305       let stop = start#copy#forward_chars parsed_len in
 306       buffer#delete ~start ~stop
 307     end;
 308     let new_text = String.concat "" new_statements in
 309     buffer#insert ~iter:start new_text;
 310     self#moveMark (String.length new_text)
 311
 312   method private _retract () =
 313     match statements, history with
 314     | last_statement :: _, cur_status :: prev_status :: _ ->
 315         MatitaSync.time_travel ~present:cur_status ~past:prev_status;
 316         statements <- List.tl statements;
 317         history <- List.tl history;
 318         self#moveMark (- (String.length last_statement));
 319     | _ -> raise Margin
 320
 321   method advance ?statement () =
 322     try
 323       self#_advance ?statement ()
 324     with Margin -> ()
 325
 326   method retract () = try self#_retract () with Margin -> ()
 327
 328   method private getFuture =
 329     buffer#get_text ~start:(buffer#get_iter_at_mark (`MARK locked_mark))
 330       ~stop:buffer#end_iter ()
 331
 332   (** @param rel_offset relative offset from current position of locked_mark *)
 333   method private moveMark rel_offset =
 334     let mark = `MARK locked_mark in
 335     let old_insert = buffer#get_iter_at_mark `INSERT in
 336     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 337     let current_mark_pos = buffer#get_iter_at_mark mark in
 338     let new_mark_pos =
 339       match rel_offset with
 340       | 0 -> current_mark_pos
 341       | n when n > 0 -> current_mark_pos#forward_chars n
 342       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 343     in
 344     buffer#move_mark mark ~where:new_mark_pos;
 345     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 346     buffer#move_mark `INSERT old_insert;
 347     self#notify
 348
 349   val mutable observers = []
 350
 351   method addObserver (o: MatitaTypes.status -> unit) =
 352     observers <- o :: observers
 353
 354   method private notify =
 355     let status = self#status in
 356     List.iter (fun o -> o status) observers
 357
 358   method loadFrom fname =
 359     buffer#set_text (MatitaMisc.input_file fname);
 360     self#goto_top
 361
 362   method saveTo fname =
 363     let oc = open_out fname in
 364     output_string oc (buffer#get_text ~start:buffer#start_iter
 365                         ~stop:buffer#end_iter ());
 366     close_out oc
 367
 368   method private goto_top =
 369     MatitaSync.time_travel ~present:self#status ~past:init;
 370     statements <- [];
 371     history <- [ init ];
 372     userGoal <- ~-1;
 373     self#notify;
 374     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 375     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 376
 377   method reset () =
 378     self#goto_top;
 379     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter
 380
 381   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 382     match pos with
 383     | `Top -> self#goto_top
 384     | `Bottom ->
 385         (try while true do self#_advance () done with Margin -> ())
 386     | `Cursor ->
 387         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 388         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 389         let rec forward_until_cursor () = (* go forward until locked > cursor *)
 390           self#_advance ();
 391           if (locked_iter ())#compare (cursor_iter ()) < 0 then
 392             forward_until_cursor ()
 393         in
 394         let rec back_until_cursor () = (* go backward until locked < cursor *)
 395           self#_retract ();
 396           if (locked_iter ())#compare (cursor_iter ()) > 0 then
 397             back_until_cursor ()
 398         in
 399         let cmp = (locked_iter ())#compare (cursor_iter ()) in
 400         (try
 401           if cmp < 0 then       (* locked < cursor *)
 402             forward_until_cursor ()
 403           else if cmp > 0 then  (* locked > cursor *)
 404             back_until_cursor ()
 405           else                  (* cursor = locked *)
 406               ()
 407         with Margin -> ())
 408
 409   method onGoingProof () =
 410     match self#status.proof_status with
 411     | No_proof | Proof _ -> false
 412     | Incomplete_proof _ -> true
 413     | Intermediate _ -> assert false
 414
 415   method proofStatus = MatitaMisc.get_proof_status self#status
 416   method proofMetasenv = MatitaMisc.get_proof_metasenv self#status
 417   method proofContext = MatitaMisc.get_proof_context self#status
 418   method setGoal n = userGoal <- n
 419
 420   (* debug *)
 421   method dump () =
 422     MatitaLog.debug "script status:";
 423     MatitaLog.debug ("history size: " ^ string_of_int (List.length history));
 424     MatitaLog.debug (sprintf "%d statements:" (List.length statements));
 425     List.iter MatitaLog.debug statements;
 426
 427 end
 428
 429 let _script = ref None
 430
 431 let script ~buffer ~init ~mathviewer ~urichooser () =
 432   let s = new script ~buffer ~init ~mathviewer ~urichooser () in
 433   _script := Some s;
 434   s
 435
 436 let instance () = match !_script with None -> assert false | Some s -> s
 437
 438