helm/matita/matitaSync.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30 let alias_diff ~from status =
  31   let module Map = DisambiguateTypes.Environment in
  32   Map.fold
  33     (fun domain_item (description1,_ as codomain_item) acc ->
  34       try
  35        let description2,_ = Map.find domain_item from.aliases in
  36         if description1 <> description2 then
  37           Map.add domain_item codomain_item acc
  38         else
  39           acc
  40       with
  41        Not_found ->
  42          Map.add domain_item codomain_item acc)
  43     status.aliases Map.empty
  44
  45 let alias_diff =
  46  let profiler = CicUtil.profile "alias_diff (conteggiato anche in include)" in
  47  fun ~from status -> profiler.CicUtil.profile (alias_diff ~from) status
  48
  49 let set_proof_aliases status aliases =
  50  let new_status = { status with aliases = aliases } in
  51  let diff = alias_diff ~from:status new_status in
  52  let multi_aliases =
  53   DisambiguateTypes.Environment.fold DisambiguateTypes.Environment.cons
  54    diff status.multi_aliases in
  55  let new_status = { new_status with multi_aliases = multi_aliases } in
  56  if DisambiguateTypes.Environment.is_empty diff then
  57    new_status
  58  else
  59    add_moo_content (DisambiguatePp.commands_of_environment diff) new_status
  60
  61 (** given a uri and a type list (the contructors types) builds a list of pairs
  62  *  (name,uri) that is used to generate authomatic aliases **)
  63 let extract_alias types uri =
  64   fst(List.fold_left (
  65     fun (acc,i) (name, _, _, cl) ->
  66       (name, UriManager.string_of_uri (UriManager.uri_of_uriref uri i None))
  67       ::
  68       (fst(List.fold_left (
  69         fun (acc,j) (name,_) ->
  70           (((name,UriManager.string_of_uri (UriManager.uri_of_uriref uri i
  71           (Some j))) :: acc) , j+1)
  72         ) (acc,1) cl)),i+1
  73   ) ([],0) types)
  74
  75 let env_of_list l env =
  76  let l' = List.map (fun (name,suri) -> name,suri,CicUtil.term_of_uri (UriManager.uri_of_string suri)) l in
  77   DisambiguateTypes.env_of_list l' env
  78
  79 let add_aliases_for_inductive_def status types suri =
  80   let uri = UriManager.uri_of_string suri in
  81   let aliases = env_of_list (extract_alias types uri) status.aliases in
  82   set_proof_aliases status aliases
  83
  84 let add_alias_for_constant status suri =
  85  let uri = UriManager.uri_of_string suri in
  86  let name = UriManager.name_of_uri uri in
  87  let new_env = env_of_list [(name,suri)] status.aliases in
  88  set_proof_aliases status new_env
  89
  90 let add_aliases_for_object status suri =
  91  function
  92     Cic.InductiveDefinition (types,_,_,_) ->
  93      add_aliases_for_inductive_def status types suri
  94   | Cic.Constant _ -> add_alias_for_constant status suri
  95   | Cic.Variable _
  96   | Cic.CurrentProof _ -> assert false
  97
  98 let paths_and_uris_of_obj uri status =
  99   let basedir = get_string_option status "basedir" ^ "/xml" in
 100   let innertypesuri = UriManager.innertypesuri_of_uri uri in
 101   let bodyuri = UriManager.bodyuri_of_uri uri in
 102   let innertypesfilename = Str.replace_first (Str.regexp "^cic:") ""
 103         (UriManager.string_of_uri innertypesuri) ^ ".xml.gz" in
 104   let innertypespath = basedir ^ "/" ^ innertypesfilename in
 105   let xmlfilename = Str.replace_first (Str.regexp "^cic:/") ""
 106         (UriManager.string_of_uri uri) ^ ".xml.gz" in
 107   let xmlpath = basedir ^ "/" ^ xmlfilename in
 108   let xmlbodyfilename = Str.replace_first (Str.regexp "^cic:/") ""
 109         (UriManager.string_of_uri uri) ^ ".body.xml.gz" in
 110   let xmlbodypath = basedir ^ "/" ^  xmlbodyfilename in
 111   xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri
 112
 113 let save_object_to_disk status uri obj =
 114   let ensure_path_exists path =
 115     let dir = Filename.dirname path in
 116     MatitaMisc.mkdir dir
 117   in
 118   (* generate annobj, ids_to_inner_sorts and ids_to_inner_types *)
 119   let annobj = Cic2acic.plain_acic_object_of_cic_object obj in
 120   (* prepare XML *)
 121   let xml, bodyxml =
 122    Cic2Xml.print_object
 123     uri ?ids_to_inner_sorts:None ~ask_dtd_to_the_getter:false annobj
 124   in
 125   let xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri =
 126     paths_and_uris_of_obj uri status
 127   in
 128   let path_scheme_of path = "file://" ^ path in
 129   List.iter MatitaMisc.mkdir
 130     (List.map Filename.dirname [innertypespath; xmlpath]);
 131   (* now write to disk *)
 132   ensure_path_exists xmlpath;
 133   Xml.pp ~gzip:true xml (Some xmlpath) ;
 134   (* we return a list of uri,path we registered/created *)
 135   (uri,xmlpath) ::
 136     (* now the optional body, both write and register *)
 137     (match bodyxml,bodyuri with
 138        None,None -> []
 139      | Some bodyxml,Some bodyuri->
 140          ensure_path_exists xmlbodypath;
 141          Xml.pp ~gzip:true bodyxml (Some xmlbodypath);
 142          [bodyuri, xmlbodypath]
 143      | _-> assert false)
 144
 145 let typecheck_obj =
 146  let profiler = CicUtil.profile "add_obj.typecheck_obj" in
 147   fun uri obj -> profiler.CicUtil.profile (CicTypeChecker.typecheck_obj uri) obj
 148
 149 let index_obj =
 150  let profiler = CicUtil.profile "add_obj.index_obj" in
 151   fun ~dbd ~uri ->
 152    profiler.CicUtil.profile (fun uri -> MetadataDb.index_obj ~dbd ~uri) uri
 153
 154 let save_object_to_disk =
 155  let profiler = CicUtil.profile "add_obj.save_object_to_disk" in
 156   fun status uri obj ->
 157    profiler.CicUtil.profile (save_object_to_disk status uri) obj
 158
 159 let add_obj uri obj status =
 160   let dbd = MatitaDb.instance () in
 161   let suri = UriManager.string_of_uri uri in
 162   if CicEnvironment.in_library uri then
 163     command_error (sprintf "%s already defined" suri)
 164   else begin
 165     typecheck_obj uri obj; (* 1 *)
 166     try
 167       index_obj ~dbd ~uri; (* 2 must be in the env *)
 168       try
 169         let new_stuff = save_object_to_disk status uri obj in (* 3 *)
 170         try
 171           MatitaLog.message (sprintf "%s defined" suri);
 172           let status = add_aliases_for_object status suri obj in
 173           { status with objects = new_stuff @ status.objects;
 174                         proof_status = No_proof }
 175         with exc ->
 176           List.iter MatitaMisc.safe_remove (List.map snd new_stuff); (* -3 *)
 177           raise exc
 178       with exc ->
 179         ignore(MatitaDb.remove_uri uri); (* -2 *)
 180         raise exc
 181     with exc ->
 182       CicEnvironment.remove_obj uri; (* -1 *)
 183       raise exc
 184   end
 185
 186 let add_obj =
 187  let profiler = CicUtil.profile "add_obj" in
 188   fun uri obj status -> profiler.CicUtil.profile (add_obj uri obj) status
 189
 190 module OrderedUri =
 191 struct
 192   type t = UriManager.uri * string
 193   let compare (u1, _) (u2, _) = UriManager.compare u1 u2
 194 end
 195
 196 module OrderedId =
 197 struct
 198   type t = CicNotation.notation_id
 199   let compare = Pervasives.compare
 200 end
 201
 202 module UriSet = Set.Make (OrderedUri)
 203 module IdSet  = Set.Make (OrderedId)
 204
 205   (** @return l2 \ l1 *)
 206 let uri_list_diff l2 l1 =
 207   let module S = UriSet in
 208   let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
 209   let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
 210   let diff = S.diff s2 s1 in
 211   S.fold (fun uri uris -> uri :: uris) diff []
 212
 213   (** @return l2 \ l1 *)
 214 let id_list_diff l2 l1 =
 215   let module S = IdSet in
 216   let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
 217   let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
 218   let diff = S.diff s2 s1 in
 219   S.fold (fun uri uris -> uri :: uris) diff []
 220
 221 let remove_coercion uri =
 222   CoercDb.remove_coercion (fun (_,_,u) -> UriManager.eq u uri)
 223
 224 let time_travel ~present ~past =
 225   let objs_to_remove = uri_list_diff present.objects past.objects in
 226   let notation_to_remove =
 227     id_list_diff present.notation_ids past.notation_ids
 228   in
 229   let debug_list = ref [] in
 230   List.iter
 231     (fun (uri,p) ->
 232       MatitaMisc.safe_remove p;
 233       remove_coercion uri;
 234       (try
 235         CicEnvironment.remove_obj uri
 236       with CicEnvironment.Object_not_found _ ->
 237         MatitaLog.debug
 238           (sprintf "time_travel removes from cache %s that is not in"
 239             (UriManager.string_of_uri uri)));
 240       let l = MatitaDb.remove_uri uri in
 241       debug_list := UriManager.string_of_uri uri :: !debug_list @ l)
 242     objs_to_remove;
 243   List.iter CicNotation.remove_notation notation_to_remove
 244   (*
 245   (* this is debug code
 246   * idea: debug_list is the list of objects to be removed as computed from the
 247   * db, while list_of_objs_to_remove is the same list but computer from the
 248   * differences between statuses *)
 249   let l1 = List.sort Pervasives.compare !debug_list in
 250   let l2 = List.sort Pervasives.compare
 251     (List.map (fun (x,_) -> UriManager.string_of_uri x) list_of_objs_to_remove)
 252   in
 253   let rec uniq = function
 254     | [] -> []
 255     | h::[] -> [h]
 256     | h1::h2::tl when h1 = h2 -> uniq (h2 :: tl)
 257     | h1::tl (* when h1 <> h2 *) -> h1 :: uniq tl
 258   in
 259   let l1 =  uniq l1 in
 260   let l2 =  uniq l2 in
 261   try
 262     List.iter2 (fun x y -> if x <> y then raise Exit) l1 l2
 263   with
 264   | Invalid_argument _ | Exit ->
 265       MatitaLog.debug "It seems you garbaged something...";
 266       MatitaLog.debug "l1:";
 267       List.iter MatitaLog.debug l1;
 268       MatitaLog.debug "l2:";
 269       List.iter MatitaLog.debug l2
 270       *)
 271
 272 let remove ~verbose uri =
 273   let derived_uris_of_uri uri =
 274     UriManager.innertypesuri_of_uri uri ::
 275     (match UriManager.bodyuri_of_uri uri with
 276     | None -> []
 277     | Some u -> [u])
 278   in
 279   let to_remove =
 280     uri ::
 281     (if UriManager.uri_is_ind uri then MatitaDb.xpointers_of_ind uri else []) @
 282     derived_uris_of_uri uri
 283   in
 284   List.iter
 285     (fun uri ->
 286       (try
 287         if verbose then
 288          MatitaLog.debug ("Removing: " ^ UriManager.string_of_uri uri);
 289         MatitaMisc.safe_remove (Http_getter.resolve' uri)
 290       with Http_getter_types.Key_not_found _ -> ());
 291       remove_coercion uri;
 292       ignore (MatitaDb.remove_uri uri);
 293       CicEnvironment.remove_obj uri)
 294   to_remove