helm/matita/matitaSync.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open MatitaTypes
  29
  30 let alias_diff ~from status =
  31   let module Map = DisambiguateTypes.Environment in
  32   Map.fold
  33     (fun domain_item codomain_item acc ->
  34        if not (Map.mem domain_item from.aliases) then
  35          Map.add domain_item codomain_item acc
  36        else
  37          begin
  38            try
  39             let description1 = fst(Map.find domain_item from.aliases) in
  40             let description2 = fst(Map.find domain_item status.aliases) in
  41             if description1 <> description2 then
  42               Map.add domain_item codomain_item acc
  43             else
  44               acc
  45            with Not_found -> acc
  46          end)
  47     status.aliases Map.empty
  48
  49 let set_proof_aliases status aliases =
  50  let new_status = { status with aliases = aliases } in
  51  let diff = alias_diff ~from:status new_status in
  52  let multi_aliases =
  53   DisambiguateTypes.Environment.fold DisambiguateTypes.Environment.cons
  54    diff status.multi_aliases in
  55  let new_status = { new_status with multi_aliases = multi_aliases } in
  56  if DisambiguateTypes.Environment.is_empty diff then
  57    new_status
  58  else
  59    add_moo_content (DisambiguatePp.commands_of_environment diff) new_status
  60
  61 (** given a uri and a type list (the contructors types) builds a list of pairs
  62  *  (name,uri) that is used to generate authomatic aliases **)
  63 let extract_alias types uri =
  64   fst(List.fold_left (
  65     fun (acc,i) (name, _, _, cl) ->
  66       (name, UriManager.string_of_uri (UriManager.uri_of_uriref uri i None))
  67       ::
  68       (fst(List.fold_left (
  69         fun (acc,j) (name,_) ->
  70           (((name,UriManager.string_of_uri (UriManager.uri_of_uriref uri i
  71           (Some j))) :: acc) , j+1)
  72         ) (acc,1) cl)),i+1
  73   ) ([],0) types)
  74
  75 let env_of_list l env =
  76  let l' = List.map (fun (name,suri) -> name,suri,CicUtil.term_of_uri (UriManager.uri_of_string suri)) l in
  77   DisambiguateTypes.env_of_list l' env
  78
  79 let add_aliases_for_inductive_def status types suri =
  80   let uri = UriManager.uri_of_string suri in
  81   let aliases = env_of_list (extract_alias types uri) status.aliases in
  82   set_proof_aliases status aliases
  83
  84 let add_alias_for_constant status suri =
  85  let uri = UriManager.uri_of_string suri in
  86  let name = UriManager.name_of_uri uri in
  87  let new_env = env_of_list [(name,suri)] status.aliases in
  88  set_proof_aliases status new_env
  89
  90 let add_aliases_for_object status suri =
  91  function
  92     Cic.InductiveDefinition (types,_,_,_) ->
  93      add_aliases_for_inductive_def status types suri
  94   | Cic.Constant _ -> add_alias_for_constant status suri
  95   | Cic.Variable _
  96   | Cic.CurrentProof _ -> assert false
  97
  98 let paths_and_uris_of_obj uri status =
  99   let basedir = get_string_option status "basedir" ^ "/xml" in
 100   let innertypesuri = UriManager.innertypesuri_of_uri uri in
 101   let bodyuri = UriManager.bodyuri_of_uri uri in
 102   let innertypesfilename = Str.replace_first (Str.regexp "^cic:") ""
 103         (UriManager.string_of_uri innertypesuri) ^ ".xml.gz" in
 104   let innertypespath = basedir ^ "/" ^ innertypesfilename in
 105   let xmlfilename = Str.replace_first (Str.regexp "^cic:/") ""
 106         (UriManager.string_of_uri uri) ^ ".xml.gz" in
 107   let xmlpath = basedir ^ "/" ^ xmlfilename in
 108   let xmlbodyfilename = Str.replace_first (Str.regexp "^cic:/") ""
 109         (UriManager.string_of_uri uri) ^ ".body.xml.gz" in
 110   let xmlbodypath = basedir ^ "/" ^  xmlbodyfilename in
 111   xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri
 112
 113 let save_object_to_disk status uri obj =
 114   let ensure_path_exists path =
 115     let dir = Filename.dirname path in
 116     MatitaMisc.mkdir dir
 117   in
 118   (* generate annobj, ids_to_inner_sorts and ids_to_inner_types *)
 119   let annobj,_,_,ids_to_inner_sorts,ids_to_inner_types,_,_ =
 120     Cic2acic.acic_object_of_cic_object ~eta_fix:false obj
 121   in
 122   (* prepare XML *)
 123   let xml, bodyxml =
 124    Cic2Xml.print_object uri ~ids_to_inner_sorts ~ask_dtd_to_the_getter:false
 125     annobj
 126   in
 127   let xmlinnertypes =
 128    Cic2Xml.print_inner_types uri ~ids_to_inner_sorts ~ids_to_inner_types
 129     ~ask_dtd_to_the_getter:false
 130   in
 131   let xmlpath, xmlbodypath, innertypespath, bodyuri, innertypesuri =
 132     paths_and_uris_of_obj uri status
 133   in
 134   let path_scheme_of path = "file://" ^ path in
 135   List.iter MatitaMisc.mkdir
 136     (List.map Filename.dirname [innertypespath; xmlpath]);
 137   (* now write to disk *)
 138   ensure_path_exists innertypespath;
 139   Xml.pp ~gzip:true xmlinnertypes (Some innertypespath);
 140   ensure_path_exists xmlpath;
 141   Xml.pp ~gzip:true xml (Some xmlpath) ;
 142   (* we return a list of uri,path we registered/created *)
 143   (uri,xmlpath) :: (innertypesuri,innertypespath) ::
 144     (* now the optional body, both write and register *)
 145     (match bodyxml,bodyuri with
 146        None,None -> []
 147      | Some bodyxml,Some bodyuri->
 148          ensure_path_exists xmlbodypath;
 149          Xml.pp ~gzip:true bodyxml (Some xmlbodypath);
 150          [bodyuri, xmlbodypath]
 151      | _-> assert false)
 152
 153 let add_obj uri obj status =
 154   let dbd = MatitaDb.instance () in
 155   let suri = UriManager.string_of_uri uri in
 156   if CicEnvironment.in_library uri then
 157     command_error (sprintf "%s already defined" suri)
 158   else begin
 159     CicTypeChecker.typecheck_obj uri obj; (* 1 *)
 160     try
 161       MetadataDb.index_obj ~dbd ~uri; (* 2 must be in the env *)
 162       try
 163         let new_stuff = save_object_to_disk status uri obj in (* 3 *)
 164         try
 165           MatitaLog.message (sprintf "%s defined" suri);
 166           let status = add_aliases_for_object status suri obj in
 167           { status with objects = new_stuff @ status.objects;
 168                         proof_status = No_proof }
 169         with exc ->
 170           List.iter MatitaMisc.safe_remove (List.map snd new_stuff); (* -3 *)
 171           raise exc
 172       with exc ->
 173         ignore(MatitaDb.remove_uri uri); (* -2 *)
 174         raise exc
 175     with exc ->
 176       CicEnvironment.remove_obj uri; (* -1 *)
 177       raise exc
 178   end
 179
 180 module OrderedUri =
 181 struct
 182   type t = UriManager.uri * string
 183   let compare (u1, _) (u2, _) = UriManager.compare u1 u2
 184 end
 185
 186 module OrderedId =
 187 struct
 188   type t = CicNotation.notation_id
 189   let compare = Pervasives.compare
 190 end
 191
 192 module UriSet = Set.Make (OrderedUri)
 193 module IdSet  = Set.Make (OrderedId)
 194
 195   (** @return l2 \ l1 *)
 196 let uri_list_diff l2 l1 =
 197   let module S = UriSet in
 198   let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
 199   let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
 200   let diff = S.diff s2 s1 in
 201   S.fold (fun uri uris -> uri :: uris) diff []
 202
 203   (** @return l2 \ l1 *)
 204 let id_list_diff l2 l1 =
 205   let module S = IdSet in
 206   let s1 = List.fold_left (fun set uri -> S.add uri set) S.empty l1 in
 207   let s2 = List.fold_left (fun set uri -> S.add uri set) S.empty l2 in
 208   let diff = S.diff s2 s1 in
 209   S.fold (fun uri uris -> uri :: uris) diff []
 210
 211 let remove_coercion uri =
 212   CoercDb.remove_coercion (fun (_,_,u) -> UriManager.eq u uri)
 213
 214 let time_travel ~present ~past =
 215   let objs_to_remove = uri_list_diff present.objects past.objects in
 216   let notation_to_remove =
 217     id_list_diff present.notation_ids past.notation_ids
 218   in
 219   let debug_list = ref [] in
 220   List.iter
 221     (fun (uri,p) ->
 222       MatitaMisc.safe_remove p;
 223       remove_coercion uri;
 224       (try
 225         CicEnvironment.remove_obj uri
 226       with CicEnvironment.Object_not_found _ ->
 227         MatitaLog.debug
 228           (sprintf "time_travel removes from cache %s that is not in"
 229             (UriManager.string_of_uri uri)));
 230       let l = MatitaDb.remove_uri uri in
 231       debug_list := UriManager.string_of_uri uri :: !debug_list @ l)
 232     objs_to_remove;
 233   List.iter CicNotation.remove_notation notation_to_remove
 234   (*
 235   (* this is debug code
 236   * idea: debug_list is the list of objects to be removed as computed from the
 237   * db, while list_of_objs_to_remove is the same list but computer from the
 238   * differences between statuses *)
 239   let l1 = List.sort Pervasives.compare !debug_list in
 240   let l2 = List.sort Pervasives.compare
 241     (List.map (fun (x,_) -> UriManager.string_of_uri x) list_of_objs_to_remove)
 242   in
 243   let rec uniq = function
 244     | [] -> []
 245     | h::[] -> [h]
 246     | h1::h2::tl when h1 = h2 -> uniq (h2 :: tl)
 247     | h1::tl (* when h1 <> h2 *) -> h1 :: uniq tl
 248   in
 249   let l1 =  uniq l1 in
 250   let l2 =  uniq l2 in
 251   try
 252     List.iter2 (fun x y -> if x <> y then raise Exit) l1 l2
 253   with
 254   | Invalid_argument _ | Exit ->
 255       MatitaLog.debug "It seems you garbaged something...";
 256       MatitaLog.debug "l1:";
 257       List.iter MatitaLog.debug l1;
 258       MatitaLog.debug "l2:";
 259       List.iter MatitaLog.debug l2
 260       *)
 261
 262 let remove ~verbose uri =
 263   let derived_uris_of_uri uri =
 264     UriManager.innertypesuri_of_uri uri ::
 265     (match UriManager.bodyuri_of_uri uri with
 266     | None -> []
 267     | Some u -> [u])
 268   in
 269   let to_remove =
 270     uri ::
 271     (if UriManager.uri_is_ind uri then MatitaDb.xpointers_of_ind uri else []) @
 272     derived_uris_of_uri uri
 273   in
 274   List.iter
 275     (fun uri ->
 276       (try
 277         if verbose then
 278          MatitaLog.debug ("Removing: " ^ UriManager.string_of_uri uri);
 279         MatitaMisc.safe_remove (Http_getter.resolve' uri)
 280       with Http_getter_types.Key_not_found _ -> ());
 281       remove_coercion uri;
 282       ignore (MatitaDb.remove_uri uri);
 283       CicEnvironment.remove_obj uri)
 284   to_remove