helm/matita/matitaTypes.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28   (** user hit the cancel button *)
  29 exception Cancel
  30
  31   (** statement invoked in the wrong context (e.g. tactic with no ongoing proof)
  32    *)
  33 exception Statement_error of string
  34 let statement_error msg = raise (Statement_error msg)
  35
  36 exception Command_error of string
  37 let command_error msg = raise (Command_error msg)
  38
  39   (** parameters are: option name, error message *)
  40 exception Option_error of string * string
  41
  42 exception Unbound_identifier of string
  43
  44 type proof_status =
  45   | No_proof
  46   | Incomplete_proof of ProofEngineTypes.status
  47   | Proof of ProofEngineTypes.proof
  48   | Intermediate of Cic.metasenv
  49       (* Status in which the proof could be while it is being processed by the
  50       * engine. No status entering/exiting the engine could be in it. *)
  51
  52 module StringMap = Map.Make (String)
  53
  54 type option_value =
  55   | String of string
  56   | Int of int
  57 type options = option_value StringMap.t
  58 let no_options = StringMap.empty
  59
  60 type status = {
  61   aliases: DisambiguateTypes.environment;   (** disambiguation aliases *)
  62   proof_status: proof_status;
  63   options: options;
  64   coercions: CoercGraph.coercions;
  65   objects: (UriManager.uri * string) list;
  66     (** in-scope objects, with their paths *)
  67 }
  68
  69 let dump_status status =
  70   MatitaLog.message "status.aliases:\n";
  71   MatitaLog.message
  72   (CicTextualParser2.EnvironmentP3.to_string status.aliases ^ "\n");
  73   MatitaLog.message "status.proof_status:";
  74   MatitaLog.message
  75     (match status.proof_status with
  76     | No_proof -> "no proof\n"
  77     | Incomplete_proof _ -> "incomplete proof\n"
  78     | Proof _ -> "proof\n"
  79     | Intermediate _ -> "Intermediate\n");
  80   MatitaLog.message "status.options\n";
  81   StringMap.iter (fun k v ->
  82     let v =
  83       match v with
  84       | String s -> s
  85       | Int i -> string_of_int i
  86     in
  87     MatitaLog.message (k ^ "::=" ^ v)) status.options;
  88   MatitaLog.message "status.coercions\n";
  89   List.iter
  90     (fun (u1,u2,u3) -> MatitaLog.message
  91      ((UriManager.string_of_uri u1) ^
  92      (UriManager.string_of_uri u2) ^
  93      (UriManager.string_of_uri u3))) status.coercions;
  94   MatitaLog.message "status.objects:\n";
  95   List.iter
  96     (fun (u,_) ->
  97       MatitaLog.message (UriManager.string_of_uri u)) status.objects
  98
  99
 100 let get_option status name =
 101   try
 102     StringMap.find name status.options
 103   with Not_found -> raise (Option_error (name, "not found"))
 104
 105 let get_string_option status name =
 106   match get_option status name with
 107   | String s -> s
 108   | _ -> raise (Option_error (name, "not a string value"))
 109
 110 let set_option status name value =
 111   let mangle_dir s =
 112     let s = Str.global_replace (Str.regexp "//+") "/" s in
 113     let s = Str.global_replace (Str.regexp "/$") "" s in
 114     s
 115   in
 116   let types =
 117     [ "baseuri", (`String, mangle_dir);
 118       "basedir", (`String, mangle_dir);
 119     ]
 120   in
 121   let ty_and_mangler =
 122     try
 123       List.assoc name types
 124     with Not_found -> command_error (sprintf "Unknown option \"%s\"" name)
 125   in
 126   let value =
 127     match ty_and_mangler with
 128     | `String, f -> String (f value)
 129     | `Int, f ->
 130         (try
 131           Int (int_of_string (f value))
 132         with Failure _ ->
 133           command_error (sprintf "Not an integer value \"%s\"" value))
 134   in
 135   { status with options = StringMap.add name value status.options }
 136
 137   (* subset of MatitaConsole.console methods needed by MatitaInterpreter *)
 138 class type console =
 139   object
 140     method clear : unit -> unit
 141     method echo_error : string -> unit
 142     method echo_message : string -> unit
 143     method wrap_exn : 'a. (unit -> 'a) -> 'a option
 144     method choose_uri : string list -> string
 145     method show : ?msg:string -> unit -> unit
 146   end
 147
 148 type abouts =
 149   [ `Blank
 150   | `Current_proof
 151   | `Us
 152   ]
 153
 154 type mathViewer_entry =
 155   [ `About of abouts  (* current proof *)
 156   | `Check of string (* term *)
 157   | `Cic of Cic.term * Cic.metasenv
 158   | `Dir of string (* "directory" in cic uris namespace *)
 159   | `Uri of string (* cic object uri *)
 160   | `Whelp of string * string list (* query and results *)
 161   ]
 162
 163 let string_of_entry = function
 164   | `About `Blank -> "about:blank"
 165   | `About `Current_proof -> "about:proof"
 166   | `About `Us -> "about:us"
 167   | `Check _ -> "check:"
 168   | `Cic (_, _) -> "term:"
 169   | `Dir uri | `Uri uri -> uri
 170   | `Whelp (query, _) -> sprintf "whelp:%s" query
 171
 172 class type mathViewer =
 173   object
 174     (** @param reuse if set reused last opened cic browser otherwise
 175      *  opens a new one. default is false
 176      *)
 177     method show_entry: ?reuse:bool -> mathViewer_entry -> unit
 178     method show_uri_list:
 179       ?reuse:bool -> entry:mathViewer_entry -> string list -> unit
 180   end
 181