helm/mowgli/home/xsl/person.xsl

   1 <?xml version="1.0"?>
   2
   3 <xsl:stylesheet version="1.0"
   4                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   5
   6 <xsl:import href="common.xsl"/>
   7
   8 <xsl:output method="html"/>
   9
  10 <xsl:template match="/">
  11  <html>
  12   <head>
  13    <title>
  14     <xsl:call-template name="qualified-name">
  15      <xsl:with-param name="qualification"
  16                      select="person/qualification"/>
  17      <xsl:with-param name="name"
  18                      select="person/name"/>
  19      <xsl:with-param name="surname"
  20                      select="person/surname"/>
  21     </xsl:call-template>
  22    </title>
  23    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
  24    <link rel="stylesheet" href="../../../style/mowgli.css" type="text/css"/>
  25   </head>
  26   <body>
  27    <blockquote>
  28     <xsl:call-template name="head">
  29      <xsl:with-param name="path_to_top" select="'../..'"/>
  30     </xsl:call-template>
  31     <xsl:apply-templates/>
  32     <xsl:call-template name="foot">
  33      <xsl:with-param name="path_to_top" select="'../..'"/>
  34     </xsl:call-template>
  35    </blockquote>
  36   </body>
  37  </html>
  38 </xsl:template>
  39
  40 <xsl:template name="qualified-name">
  41  <xsl:param name="qualification" select="/.."/>
  42  <xsl:param name="name"/>
  43  <xsl:param name="surname"/>
  44  <xsl:if test="qualification">
  45   <xsl:value-of select="$qualification"/>
  46   <xsl:text> </xsl:text>
  47  </xsl:if>
  48  <xsl:value-of select="$name"/>
  49  <xsl:text> </xsl:text>
  50  <xsl:value-of select="$surname"/>
  51 </xsl:template>
  52
  53 <xsl:template match="person">
  54  <h1>
  55   <xsl:call-template name="qualified-name">
  56    <xsl:with-param name="qualification"
  57                    select="qualification"/>
  58    <xsl:with-param name="name"
  59                    select="name"/>
  60    <xsl:with-param name="surname"
  61                    select="surname"/>
  62   </xsl:call-template>
  63  </h1>
  64  <xsl:choose>
  65   <xsl:when test="count(position) &gt; 1">
  66    <ul>
  67     <xsl:for-each select="position">
  68      <li><xsl:value-of select="."/></li>
  69     </xsl:for-each>
  70    </ul>
  71   </xsl:when>
  72   <xsl:when test="count(position) = 1">
  73    <p><xsl:value-of select="position"/></p>
  74   </xsl:when>
  75  </xsl:choose>
  76  <p>
  77   <xsl:text>e-mail: </xsl:text>
  78   <a href="mailto:{e-mail}">
  79    <xsl:value-of select="e-mail"/>
  80   </a>
  81  </p>
  82  <xsl:if test="url">
  83   <p>
  84    <xsl:text>Home Page: </xsl:text>
  85    <a target="_top" href="{url}">
  86     <xsl:value-of select="url"/>
  87    </a>
  88   </p>
  89  </xsl:if>
  90  <xsl:if test="address">
  91   <p>
  92    <xsl:text>Address: </xsl:text>
  93    <xsl:value-of select="address"/>
  94   </p>
  95  </xsl:if>
  96  <xsl:if test="telephone">
  97   <p>
  98    <xsl:text>Telephone number: </xsl:text>
  99    <xsl:value-of select="telephone"/>
 100   </p>
 101  </xsl:if>
 102  <xsl:if test="curriculum">
 103   <h2>Short Curriculum Vitae:</h2>
 104   <xsl:copy-of select="curriculum/*"/>
 105  </xsl:if>
 106  <xsl:if test="research-interests">
 107   <h2>Research Interests:</h2>
 108   <xsl:copy-of select="research-interests/*"/>
 109  </xsl:if>
 110  <xsl:if test="selected-publication">
 111   <h2>Selected Publications:</h2>
 112   <ul>
 113    <xsl:for-each select="selected-publication">
 114     <li>
 115      <a href="../../publications/{@file}.html">
 116       <xsl:value-of select="@file"/>
 117      </a>
 118     </li>
 119    </xsl:for-each>
 120   </ul>
 121  </xsl:if>
 122 </xsl:template>
 123
 124 </xsl:stylesheet>