helm/mowgli/home/xsl/person.xsl

   1 <?xml version="1.0"?>
   2
   3 <xsl:stylesheet version="1.0"
   4                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   5
   6 <xsl:import href="common.xsl"/>
   7
   8 <xsl:output method="html"/>
   9
  10 <xsl:template match="/">
  11  <html>
  12   <head>
  13    <title>
  14     <xsl:call-template name="qualified-name">
  15      <xsl:with-param name="qualification"
  16                      select="person/qualification"/>
  17      <xsl:with-param name="name"
  18                      select="person/name"/>
  19      <xsl:with-param name="surname"
  20                      select="person/surname"/>
  21     </xsl:call-template>
  22    </title>
  23    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
  24    <link rel="stylesheet" href="../../../style/mowgli.css" type="text/css"/>
  25   </head>
  26   <body>
  27    <blockquote>
  28     <xsl:call-template name="head">
  29      <xsl:with-param name="path_to_top" select="'../..'"/>
  30     </xsl:call-template>
  31     <xsl:apply-templates/>
  32     <xsl:call-template name="foot"/>
  33    </blockquote>
  34   </body>
  35  </html>
  36 </xsl:template>
  37
  38 <xsl:template name="qualified-name">
  39  <xsl:param name="qualification" select="/.."/>
  40  <xsl:param name="name"/>
  41  <xsl:param name="surname"/>
  42  <xsl:if test="qualification">
  43   <xsl:value-of select="$qualification"/>
  44   <xsl:text> </xsl:text>
  45  </xsl:if>
  46  <xsl:value-of select="$name"/>
  47  <xsl:text> </xsl:text>
  48  <xsl:value-of select="$surname"/>
  49 </xsl:template>
  50
  51 <xsl:template match="person">
  52  <h1>
  53   <xsl:call-template name="qualified-name">
  54    <xsl:with-param name="qualification"
  55                    select="qualification"/>
  56    <xsl:with-param name="name"
  57                    select="name"/>
  58    <xsl:with-param name="surname"
  59                    select="surname"/>
  60   </xsl:call-template>
  61  </h1>
  62  <xsl:choose>
  63   <xsl:when test="count(position) &gt; 1">
  64    <ul>
  65     <xsl:for-each select="position">
  66      <li><xsl:value-of select="."/></li>
  67     </xsl:for-each>
  68    </ul>
  69   </xsl:when>
  70   <xsl:when test="count(position) = 1">
  71    <p><xsl:value-of select="position"/></p>
  72   </xsl:when>
  73  </xsl:choose>
  74  <p>
  75   <xsl:text>e-mail: </xsl:text>
  76   <a href="mailto:{e-mail}">
  77    <xsl:value-of select="e-mail"/>
  78   </a>
  79  </p>
  80  <xsl:if test="url">
  81   <p>
  82    <xsl:text>Home Page: </xsl:text>
  83    <a target="_top" href="{url}">
  84     <xsl:value-of select="url"/>
  85    </a>
  86   </p>
  87  </xsl:if>
  88  <xsl:if test="address">
  89   <p>
  90    <xsl:text>Address: </xsl:text>
  91    <xsl:value-of select="address"/>
  92   </p>
  93  </xsl:if>
  94  <xsl:if test="telephone">
  95   <p>
  96    <xsl:text>Telephone number: </xsl:text>
  97    <xsl:value-of select="telephone"/>
  98   </p>
  99  </xsl:if>
 100  <xsl:if test="curriculum">
 101   <h2>Short Curriculum Vitae:</h2>
 102   <xsl:copy-of select="curriculum/*"/>
 103  </xsl:if>
 104  <xsl:if test="research-interests">
 105   <h2>Research Interests:</h2>
 106   <xsl:copy-of select="research-interests/*"/>
 107  </xsl:if>
 108  <xsl:if test="selected-publication">
 109   <h2>Selected Publications:</h2>
 110   <ul>
 111    <xsl:for-each select="selected-publication">
 112     <li>
 113      <a href="../../publications/{@file}.html">
 114       <xsl:value-of select="@file"/>
 115      </a>
 116     </li>
 117    </xsl:for-each>
 118   </ul>
 119  </xsl:if>
 120 </xsl:template>
 121
 122 </xsl:stylesheet>