helm/mowgli/home/xsl/site.xsl

   1 <?xml version="1.0"?>
   2
   3 <xsl:stylesheet version="1.0"
   4                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   5
   6 <xsl:import href="common.xsl"/>
   7
   8 <xsl:output method="html"/>
   9
  10 <xsl:template match="/">
  11  <html>
  12   <head>
  13    <title><xsl:value-of select="site/name"/></title>
  14    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
  15    <link rel="stylesheet" href="../../style/mowgli.css" type="text/css"/>
  16   </head>
  17   <body>
  18    <blockquote>
  19     <xsl:call-template name="head">
  20      <xsl:with-param name="path_to_top" select="'..'"/>
  21     </xsl:call-template>
  22     <xsl:apply-templates/>
  23     <xsl:call-template name="foot">
  24      <xsl:with-param name="path_to_top" select="'..'"/>
  25     </xsl:call-template>
  26    </blockquote>
  27   </body>
  28  </html>
  29 </xsl:template>
  30
  31 <xsl:template match="site|subsite">
  32  <xsl:choose>
  33   <xsl:when test="subsite">
  34    <p>This is an aggregate site, whose members are:</p>
  35    <ul>
  36     <xsl:for-each select="subsite">
  37      <li>
  38       <a href="#{generate-id()}">
  39        <xsl:value-of select="name"/>
  40       </a>
  41      </li>
  42     </xsl:for-each>
  43    </ul>
  44    <xsl:for-each select="subsite">
  45     <hr />
  46     <a name="{generate-id()}"/>
  47     <xsl:apply-templates select="."/>
  48    </xsl:for-each>
  49   </xsl:when>
  50   <xsl:otherwise>
  51    <h1><xsl:value-of select="name"/></h1>
  52    <h2><xsl:value-of select="country"/></h2>
  53    <p><xsl:value-of select="address"/></p>
  54    <p><a href="{url}">Visit the institution home page.</a></p>
  55    <p>
  56     <xsl:text>Site responsible: </xsl:text>
  57     <a href="../people/{responsible/@file}.html">
  58      <xsl:call-template name="person-name">
  59       <xsl:with-param name="file" select="responsible/@file"/>
  60      </xsl:call-template>
  61     </a>
  62     <xsl:text>.</xsl:text>
  63    </p>
  64    <xsl:copy-of select="description/*"/>
  65    <xsl:if test="project">
  66     <h1>Projects developed by this site related to MOWGLI:</h1>
  67    </xsl:if>
  68    <xsl:apply-templates select="project"/>
  69   </xsl:otherwise>
  70  </xsl:choose>
  71 </xsl:template>
  72
  73 <xsl:template match="project">
  74  <h2>
  75   <xsl:value-of select="name"/>
  76   <xsl:if test="acronym">
  77    <xsl:text> (</xsl:text>
  78    <xsl:value-of select="acronym"/>
  79    <xsl:text>)</xsl:text>
  80   </xsl:if>
  81  </h2>
  82  <p><a href="{url}">Visit the project home page.</a></p>
  83  <p>Members of the project also involved in MOWGLI:</p>
  84  <ul>
  85   <xsl:for-each select="member">
  86    <li>
  87     <a href="../people/{@file}.html">
  88      <xsl:call-template name="person-name">
  89       <xsl:with-param name="file" select="@file"/>
  90      </xsl:call-template>
  91     </a>
  92    </li>
  93   </xsl:for-each>
  94  </ul>
  95  <xsl:copy-of select="description/*"/>
  96 </xsl:template>
  97
  98 </xsl:stylesheet>