helm/ocaml/cic_annotations/cicXPath.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (******************************************************************************)
  27 (*                                                                            *)
  28 (*                               PROJECT HELM                                 *)
  29 (*                                                                            *)
  30 (*                Claudio Sacerdoti Coen <sacerdot@cs.unibo.it>               *)
  31 (*                                 14/06/2000                                 *)
  32 (*                                                                            *)
  33 (*                                                                            *)
  34 (******************************************************************************)
  35
  36 let get_annotation ids_to_annotations xpath =
  37  try
  38   Some (Hashtbl.find ids_to_annotations xpath)
  39  with
  40   Not_found -> None
  41 ;;
  42
  43 exception MoreThanOneTargetFor of Cic.id;;
  44
  45 (* creates a hashtable mapping each unique id to a node of the annotated
  46 object *)
  47 let get_ids_to_targets annobj =
  48  let module C = Cic in
  49   let ids_to_targets = Hashtbl.create 503 in
  50    let set_target id target =
  51     try
  52      ignore (Hashtbl.find ids_to_targets id) ;
  53      raise (MoreThanOneTargetFor id)
  54     with
  55      Not_found -> Hashtbl.add ids_to_targets id target
  56    in
  57     let rec add_target_term t =
  58      match t with
  59         C.ARel (id,_,_)
  60       | C.AVar (id,_)
  61       | C.AMeta (id,_,_)
  62       | C.ASort (id,_)
  63       | C.AImplicit id ->
  64          set_target id (C.Term t)
  65       | C.ACast (id,va,ty) ->
  66          set_target id (C.Term t) ;
  67          add_target_term va ;
  68          add_target_term ty
  69       | C.AProd (id,_,so,ta)
  70       | C.ALambda (id,_,so,ta)
  71       | C.ALetIn (id,_,so,ta) ->
  72          set_target id (C.Term t) ;
  73          add_target_term so ;
  74          add_target_term ta
  75       | C.AAppl (id,l) ->
  76          set_target id (C.Term t) ;
  77          List.iter add_target_term l
  78       | C.AConst (id,_,_)
  79       | C.AMutInd (id,_,_,_)
  80       | C.AMutConstruct (id,_,_,_,_) ->
  81          set_target id (C.Term t)
  82       | C.AMutCase (id,_,_,_,ot,it,pl) ->
  83          set_target id (C.Term t) ;
  84          List.iter add_target_term (ot::it::pl)
  85       | C.AFix (id,_,ifl) ->
  86          set_target id (C.Term t) ;
  87          List.iter
  88           (function (_,_,ty,bo) ->
  89             add_target_term ty ;
  90             add_target_term bo
  91           ) ifl
  92       | C.ACoFix (id,_,cfl) ->
  93          set_target id (C.Term t) ;
  94          List.iter
  95           (function (_,ty,bo) ->
  96             add_target_term ty ;
  97             add_target_term bo
  98           ) cfl
  99     in
 100      let add_target_obj annobj =
 101       match annobj with
 102         C.ADefinition (id,_,bo,ty,_) ->
 103          set_target id (C.Object annobj) ;
 104          add_target_term bo ;
 105          add_target_term ty
 106       | C.AAxiom (id,_,ty,_) ->
 107          set_target id (C.Object annobj) ;
 108          add_target_term ty
 109       | C.AVariable (id,_,None,ty) ->
 110          set_target id (C.Object annobj) ;
 111          add_target_term ty
 112       | C.AVariable (id,_,Some bo,ty) ->
 113          set_target id (C.Object annobj) ;
 114          add_target_term bo ;
 115          add_target_term ty
 116       | C.ACurrentProof (id,_,cl,bo,ty) ->
 117          set_target id (C.Object annobj) ;
 118          List.iter (function (cid,_,context, t) as annconj ->
 119            set_target cid (C.Conjecture annconj) ;
 120            List.iter
 121              (function ((hid,h) as annhyp) ->
 122                set_target hid (C.Hypothesis annhyp) ;
 123                match h with
 124                   Some (_,C.ADecl at) -> add_target_term at
 125                 | Some (_,C.ADef at) -> add_target_term at
 126                 | None -> ()
 127              ) context;
 128            add_target_term t) cl ;
 129          add_target_term bo ;
 130          add_target_term ty
 131       | C.AInductiveDefinition (id,itl,_,_) ->
 132          set_target id (C.Object annobj) ;
 133          List.iter
 134           (function (_,_,arity,cl) ->
 135             add_target_term arity ;
 136             List.iter (function (_,ty,_) -> add_target_term ty) cl
 137           ) itl
 138      in
 139       add_target_obj annobj ;
 140       ids_to_targets
 141 ;;