helm/ocaml/cic_disambiguation/cicTextualParser2.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 let debug = false
  27 let debug_print s =
  28   if debug then begin
  29     prerr_endline "<NEW_TEXTUAL_PARSER>";
  30     prerr_endline s;
  31     prerr_endline "</NEW_TEXTUAL_PARSER>"
  32   end
  33
  34   (** if set to true each number will have a different insance number and can
  35   * thus be interpreted differently than others *)
  36 let use_fresh_num_instances = false
  37
  38   (** does the lexer return COMMENT tokens? *)
  39 let return_comments = false
  40
  41 open Printf
  42
  43 open DisambiguateTypes
  44
  45 exception Parse_error of Token.flocation * string
  46
  47 let cic_lexer = CicTextualLexer2.cic_lexer ~comments:return_comments ()
  48
  49 let fresh_num_instance =
  50   let n = ref 0 in
  51   if use_fresh_num_instances then
  52     (fun () -> incr n; !n)
  53   else
  54     (fun () -> 0)
  55
  56 let choice_of_uri suri =
  57   let term = CicUtil.term_of_uri (UriManager.uri_of_string suri) in
  58   (suri, (fun _ _ _ -> term))
  59
  60 let grammar = Grammar.gcreate cic_lexer
  61
  62 let term = Grammar.Entry.create grammar "term"
  63 let term0 = Grammar.Entry.create grammar "term0"
  64 let tactic = Grammar.Entry.create grammar "tactic"
  65 let tactical = Grammar.Entry.create grammar "tactical"
  66 let tactical0 = Grammar.Entry.create grammar "tactical0"
  67 let command = Grammar.Entry.create grammar "command"
  68 let alias_spec = Grammar.Entry.create grammar "alias_spec"
  69 let macro = Grammar.Entry.create grammar "macro"
  70 let script = Grammar.Entry.create grammar "script"
  71 let statement = Grammar.Entry.create grammar "statement"
  72 let statements = Grammar.Entry.create grammar "statements"
  73
  74 let return_term loc term = CicAst.AttributedTerm (`Loc loc, term)
  75
  76 let fail floc msg =
  77   let (x, y) = CicAst.loc_of_floc floc in
  78   failwith (Printf.sprintf "Error at characters %d - %d: %s" x y msg)
  79
  80 let name_of_string = function
  81   | "_" -> Cic.Anonymous
  82   | s -> Cic.Name s
  83
  84 let string_of_name = function
  85   | Cic.Anonymous -> "_"
  86   | Cic.Name s -> s
  87
  88 let int_opt = function
  89   | None -> None
  90   | Some lexeme -> Some (int_of_string lexeme)
  91
  92 let int_of_string s =
  93   try
  94     Pervasives.int_of_string s
  95   with Failure _ ->
  96     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  97
  98   (** the uri of an inductive type (a ".ind" uri) is not meaningful without an
  99   * xpointer. Still, it's likely that an user who wrote "cic:/blabla/foo.ind"
 100   * actually meant "cic:/blabla/foo.ind#xpointer(1/1)", i.e. the first inductive
 101   * type in a block of mutual inductive types.
 102   *
 103   * This function performs the expansion foo.ind -> foo#xpointer..., if needed
 104   *)
 105 let ind_expansion uri =
 106   let len = String.length uri in
 107   if len >= 4 && String.sub uri (len - 4) 4 = ".ind" then
 108     uri ^ "#xpointer(1/1)"
 109   else
 110     uri
 111
 112 let mk_binder_ast binder typ vars body =
 113   List.fold_right
 114     (fun var body ->
 115        let name = name_of_string var in
 116        CicAst.Binder (binder, (name, typ), body))
 117     vars body
 118
 119 EXTEND
 120   GLOBAL: term term0 statement statements;
 121   int: [
 122     [ num = NUM ->
 123         try
 124           int_of_string num
 125         with Failure _ -> raise (Parse_error (loc, "integer literal expected"))
 126     ]
 127   ];
 128   meta_subst: [
 129     [ s = SYMBOL "_" -> None
 130     | t = term -> Some t ]
 131   ];
 132   binder_low: [
 133     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 134     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 135     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall ]
 136   ];
 137   binder_high: [ [ SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda ] ];
 138   sort: [
 139     [ "Prop" -> `Prop
 140     | "Set" -> `Set
 141     | "Type" -> `Type
 142     | "CProp" -> `CProp ]
 143   ];
 144   typed_name: [
 145     [ PAREN "("; i = IDENT; SYMBOL ":"; typ = term; PAREN ")" ->
 146         (Cic.Name i, Some typ)
 147     | i = IDENT -> (Cic.Name i, None)
 148     ]
 149   ];
 150   subst: [
 151     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 152       PAREN "[";
 153       substs = LIST1 [
 154         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 155       ] SEP SYMBOL ";";
 156       PAREN "]" ->
 157         substs
 158     ]
 159   ];
 160   substituted_name: [ (* a subs.name is an explicit substitution subject *)
 161     [ s = IDENT; subst = OPT subst -> CicAst.Ident (s, subst)
 162     | s = URI; subst = OPT subst -> CicAst.Uri (ind_expansion s, subst)
 163     ]
 164   ];
 165   name: [ (* as substituted_name with no explicit substitution *)
 166     [ s = [ IDENT | SYMBOL ] -> s ]
 167   ];
 168   pattern: [
 169     [ n = name -> (n, [])
 170     | PAREN "("; head = name; vars = LIST1 typed_name; PAREN ")" ->
 171         (head, vars)
 172     ]
 173   ];
 174   arg: [
 175    [ PAREN "(" ; names = LIST1 IDENT SEP SYMBOL ",";
 176       SYMBOL ":"; ty = term; PAREN ")" -> names,ty
 177    | name = IDENT -> [name],CicAst.Implicit
 178    ]
 179   ];
 180   let_defs:[
 181     [ defs = LIST1 [
 182         name = IDENT;
 183         args = LIST1 [arg = arg -> arg];
 184         index_name = OPT [ IDENT "on"; idx = IDENT -> idx ];
 185         ty = OPT [ SYMBOL ":" ; t = term -> t ];
 186         SYMBOL <:unicode<def>> (* ≝ *);
 187         t1 = term ->
 188           let rec list_of_binder binder ty final_term = function
 189             | [] -> final_term
 190             | name::tl ->
 191                 CicAst.Binder (binder, (Cic.Name name, Some ty),
 192                   list_of_binder binder ty final_term tl)
 193           in
 194           let rec binder_of_arg_list binder final_term = function
 195             | [] -> final_term
 196             | (l,ty)::tl ->
 197                 list_of_binder binder ty
 198                   (binder_of_arg_list binder final_term tl) l
 199           in
 200           let t1' = binder_of_arg_list `Lambda t1 args in
 201           let ty' =
 202             match ty with
 203             | None -> None
 204             | Some ty -> Some (binder_of_arg_list `Pi ty args)
 205           in
 206           let rec get_position_of name n = function
 207             | [] -> (None,n)
 208             | nam::tl ->
 209                 if nam = name then
 210                   (Some n,n)
 211                 else
 212                   (get_position_of name (n+1) tl)
 213           in
 214           let rec find_arg name n = function
 215             | [] -> (fail loc (sprintf "Argument %s not found" name))
 216             | (l,_)::tl ->
 217                 let (got,len) = get_position_of name 0 l in
 218                 (match got with
 219                 | None -> (find_arg name (n+len) tl)
 220                 | Some where -> n + where)
 221           in
 222           let index =
 223             (match index_name with
 224              | None -> 0
 225              | (Some name) -> find_arg name 0 args)
 226           in
 227           ((Cic.Name name,ty'), t1', index)
 228       ] SEP "and" -> defs
 229     ]];
 230   constructor: [ [ name = IDENT; SYMBOL ":"; typ = term -> (name, typ) ] ];
 231   binder_vars: [
 232       [ vars = [ l = LIST1 IDENT SEP SYMBOL "," -> l | SYMBOL "_" -> ["_"]];
 233         typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 234       | PAREN "(";
 235           vars = [ l =  LIST1 IDENT SEP SYMBOL "," -> l | SYMBOL "_" -> ["_"]];
 236           typ = OPT [ SYMBOL ":"; t = term -> t ];
 237         PAREN ")" -> (vars, typ)
 238       ]
 239   ];
 240   term0: [ [ t = term; EOI -> return_term loc t ] ];
 241   term:
 242     [ "letin" NONA
 243       [ "let"; var = typed_name;
 244         SYMBOL <:unicode<def>> (* ≝ *);
 245         t1 = term; "in"; t2 = term ->
 246           return_term loc (CicAst.LetIn (var, t1, t2))
 247       | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 248         defs = let_defs; "in"; body = term ->
 249             return_term loc (CicAst.LetRec (ind_kind, defs, body))
 250       ]
 251     | "binder" RIGHTA
 252       [
 253         b = binder_low; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 254           let binder = mk_binder_ast b typ vars body in
 255           return_term loc binder
 256       | b = binder_high; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 257           let binder = mk_binder_ast b typ vars body in
 258           return_term loc binder
 259       | t1 = term; SYMBOL <:unicode<to>> (* → *); t2 = term ->
 260           return_term loc (CicAst.Binder (`Pi, (Cic.Anonymous, Some t1), t2))
 261       ]
 262     | "logic_add" LEFTA   [ (* nothing here by default *) ]
 263     | "logic_mult" LEFTA  [ (* nothing here by default *) ]
 264     | "logic_inv" NONA    [ (* nothing here by default *) ]
 265     | "relop" LEFTA
 266       [ t1 = term; SYMBOL "="; t2 = term ->
 267         return_term loc (CicAst.Appl [CicAst.Symbol ("eq", 0); t1; t2])
 268       ]
 269     | "add" LEFTA     [ (* nothing here by default *) ]
 270     | "mult" LEFTA    [ (* nothing here by default *) ]
 271     | "power" LEFTA   [ (* nothing here by default *) ]
 272     | "inv" NONA      [ (* nothing here by default *) ]
 273     | "apply" LEFTA
 274       [ t1 = term; t2 = term ->
 275         let rec aux = function
 276           | CicAst.Appl (hd :: tl) -> aux hd @ tl
 277           | term -> [term]
 278         in
 279         CicAst.Appl (aux t1 @ [t2])
 280       ]
 281     | "simple" NONA
 282       [ sort = sort -> CicAst.Sort sort
 283       | n = substituted_name -> return_term loc n
 284       | i = NUM -> return_term loc (CicAst.Num (i, (fresh_num_instance ())))
 285       | IMPLICIT -> return_term loc CicAst.Implicit
 286       | PLACEHOLDER -> return_term loc CicAst.UserInput
 287       | m = META;
 288         substs = [
 289           PAREN "["; substs = LIST0 meta_subst SEP SYMBOL ";" ; PAREN "]" ->
 290             substs
 291         ] ->
 292             let index =
 293               try
 294                 int_of_string (String.sub m 1 (String.length m - 1))
 295               with Failure "int_of_string" ->
 296                 fail loc ("Invalid meta variable number: " ^ m)
 297             in
 298             return_term loc (CicAst.Meta (index, substs))
 299       | outtyp = OPT [ PAREN "["; typ = term; PAREN "]" -> typ ];
 300         "match"; t = term;
 301         indty_ident = OPT ["in" ; id = IDENT -> id ];
 302         "with";
 303         PAREN "[";
 304         patterns = LIST0 [
 305           lhs = pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *); rhs = term
 306           ->
 307             ((lhs: CicAst.case_pattern), rhs)
 308         ] SEP SYMBOL "|";
 309         PAREN "]" ->
 310           return_term loc
 311             (CicAst.Case (t, indty_ident, outtyp, patterns))
 312       | PAREN "("; t1 = term; SYMBOL ":"; t2 = term; PAREN ")" ->
 313           return_term loc (CicAst.Appl [CicAst.Symbol ("cast", 0); t1; t2])
 314       | PAREN "("; t = term; PAREN ")" -> return_term loc t
 315       ]
 316     ];
 317   tactic_term: [ [ t = term -> t ] ];
 318   ident_list0: [
 319     [ PAREN "["; idents = LIST0 IDENT SEP SYMBOL ";"; PAREN "]" -> idents ]
 320   ];
 321   reduction_kind: [
 322     [ [ IDENT "reduce" ] -> `Reduce
 323     | [ IDENT "simplify" ] -> `Simpl
 324     | [ IDENT "whd" ] -> `Whd
 325     | [ IDENT "normalize" ] -> `Normalize ]
 326   ];
 327   pattern_spec: [
 328     [ "in";
 329       hyp_paths =
 330        LIST0
 331         [ id = IDENT ;
 332           path = OPT [SYMBOL ":" ; path = term -> path ] ->
 333           (id,match path with Some p -> p | None -> CicAst.UserInput) ]
 334         SEP SYMBOL ";";
 335       goal_path = OPT [ SYMBOL <:unicode<vdash>>; term = term -> term ] ->
 336         (hyp_paths, goal_path) ]
 337   ];
 338   direction: [
 339     [ IDENT "left" -> `Left
 340     | SYMBOL ">" -> `Left
 341     | IDENT "right" -> `Right
 342     | SYMBOL "<" -> `Right ]
 343   ];
 344   tactic: [
 345     [ IDENT "absurd"; t = tactic_term ->
 346         TacticAst.Absurd (loc, t)
 347     | IDENT "apply"; t = tactic_term ->
 348         TacticAst.Apply (loc, t)
 349     | IDENT "assumption" ->
 350         TacticAst.Assumption loc
 351     | IDENT "auto";
 352       depth = OPT [ IDENT "depth"; SYMBOL "="; i = NUM -> int_of_string i ];
 353       width = OPT [ IDENT "depth"; SYMBOL "="; i = NUM -> int_of_string i ] ->
 354           TacticAst.Auto (loc,depth,width)
 355     | IDENT "clear"; id = IDENT ->
 356         TacticAst.Clear (loc,id)
 357     | IDENT "clearbody"; id = IDENT ->
 358         TacticAst.ClearBody (loc,id)
 359     | IDENT "change"; t1 = tactic_term; "with"; t2 = tactic_term; "in";
 360       where = pattern_spec ->
 361         TacticAst.Change (loc, t1, t2, where)
 362     | IDENT "compare"; t = tactic_term ->
 363         TacticAst.Compare (loc,t)
 364     | IDENT "constructor"; n = NUM ->
 365         TacticAst.Constructor (loc,int_of_string n)
 366     | IDENT "contradiction" ->
 367         TacticAst.Contradiction loc
 368     | IDENT "cut"; t = tactic_term; ident = OPT [ "as"; id = IDENT -> id] ->
 369         TacticAst.Cut (loc, ident, t)
 370     | IDENT "decide"; IDENT "equality" ->
 371         TacticAst.DecideEquality loc
 372     | IDENT "decompose"; where = term ->
 373         TacticAst.Decompose (loc, where)
 374     | IDENT "discriminate"; t = tactic_term ->
 375         TacticAst.Discriminate (loc, t)
 376     | IDENT "elim"; t1 = tactic_term;
 377       using = OPT [ "using"; using = tactic_term -> using ] ->
 378         TacticAst.Elim (loc, t1, using)
 379     | IDENT "elimType"; t = tactic_term ->
 380         TacticAst.ElimType (loc, t)
 381     | IDENT "exact"; t = tactic_term ->
 382         TacticAst.Exact (loc, t)
 383     | IDENT "exists" ->
 384         TacticAst.Exists loc
 385     | IDENT "fail" -> TacticAst.Fail loc
 386     | IDENT "fold"; kind = reduction_kind; t = tactic_term;
 387       p = OPT [ pattern_spec ] ->
 388         let p = match p with None -> [], None | Some p -> p in
 389         TacticAst.Fold (loc, kind, t, p)
 390     | IDENT "fourier" ->
 391         TacticAst.Fourier loc
 392     | IDENT "fwd"; t = term ->
 393         TacticAst.FwdSimpl (loc, t)
 394     | IDENT "generalize"; t = tactic_term;
 395        id = OPT [ "as" ; id = IDENT -> id ];
 396        p = OPT [ pattern_spec ] ->
 397        let p = match p with None -> [], None | Some p -> p in
 398        TacticAst.Generalize (loc,t,id,p)
 399     | IDENT "goal"; n = NUM ->
 400         TacticAst.Goal (loc, int_of_string n)
 401     | IDENT "id" -> TacticAst.IdTac loc
 402     | IDENT "injection"; t = term ->
 403         TacticAst.Injection (loc, t)
 404     | IDENT "intros"; num = OPT [num = int -> num]; idents = OPT ident_list0 ->
 405         let idents = match idents with None -> [] | Some idents -> idents in
 406         TacticAst.Intros (loc, num, idents)
 407     | IDENT "intro"; ident = OPT IDENT ->
 408         let idents = match ident with None -> [] | Some id -> [id] in
 409         TacticAst.Intros (loc, Some 1, idents)
 410     | IDENT "lapply"; what = tactic_term;
 411       to_what = OPT [ "to" ; t = tactic_term -> t ];
 412       ident = OPT [ "using" ; id = IDENT -> id ] ->
 413         TacticAst.LApply (loc, to_what, what, ident)
 414     | IDENT "left" -> TacticAst.Left loc
 415     | IDENT "letin"; where = IDENT ; SYMBOL <:unicode<def>> ; t = tactic_term ->
 416         TacticAst.LetIn (loc, t, where)
 417     | kind = reduction_kind; p = OPT [ pattern_spec ] ->
 418         let p = match p with None -> [], None | Some p -> p in
 419         TacticAst.Reduce (loc, kind, p)
 420     | IDENT "reflexivity" ->
 421         TacticAst.Reflexivity loc
 422     | IDENT "replace"; p = OPT [ pattern_spec ]; "with"; t = tactic_term ->
 423         let p = match p with None -> [], None | Some p -> p in
 424         TacticAst.Replace (loc, p, t)
 425     | IDENT "rewrite" ; d = direction; t = term ; p = OPT [ pattern_spec ] ->
 426         let p = match p with None -> [], None | Some p -> p in
 427         TacticAst.Rewrite (loc, d, t, p)
 428     | IDENT "right" ->
 429         TacticAst.Right loc
 430     | IDENT "ring" ->
 431         TacticAst.Ring loc
 432     | IDENT "split" ->
 433         TacticAst.Split loc
 434     | IDENT "symmetry" ->
 435         TacticAst.Symmetry loc
 436     | IDENT "transitivity"; t = tactic_term ->
 437         TacticAst.Transitivity (loc, t)
 438     ]
 439   ];
 440   tactical:
 441     [ "sequence" LEFTA
 442       [ tacticals = LIST1 NEXT SEP SYMBOL ";" ->
 443           TacticAst.Seq (loc, tacticals)
 444       ]
 445     | "then" NONA
 446       [ tac = tactical;
 447         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 448           (TacticAst.Then (loc, tac, tacs))
 449       ]
 450     | "loops" RIGHTA
 451       [ [ IDENT "do" ]; count = int; tac = tactical ->
 452           TacticAst.Do (loc, count, tac)
 453       | [ IDENT "repeat" ]; tac = tactical ->
 454           TacticAst.Repeat (loc, tac)
 455       ]
 456     | "simple" NONA
 457       [ IDENT "tries";
 458         PAREN "["; tacs = LIST0 tactical SEP SYMBOL ";"; PAREN "]" ->
 459           TacticAst.Tries (loc, tacs)
 460       | IDENT "try"; tac = NEXT ->
 461           TacticAst.Try (loc, tac)
 462       | PAREN "("; tac = tactical; PAREN ")" -> tac
 463       | tac = tactic -> TacticAst.Tactic (loc, tac)
 464       ]
 465     ];
 466   theorem_flavour: [
 467     [ [ IDENT "definition"  ] -> `Definition
 468     | [ IDENT "fact"        ] -> `Fact
 469     | [ IDENT "lemma"       ] -> `Lemma
 470     | [ IDENT "remark"      ] -> `Remark
 471     | [ IDENT "theorem"     ] -> `Theorem
 472     ]
 473   ];
 474   inductive_spec: [ [
 475     fst_name = IDENT; params = LIST0 [ arg=arg -> arg ];
 476     SYMBOL ":"; fst_typ = term; SYMBOL <:unicode<def>>; OPT SYMBOL "|";
 477     fst_constructors = LIST0 constructor SEP SYMBOL "|";
 478     tl = OPT [ "with";
 479       types = LIST1 [
 480         name = IDENT; SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>;
 481        OPT SYMBOL "|"; constructors = LIST0 constructor SEP SYMBOL "|" ->
 482           (name, true, typ, constructors) ] SEP "with" -> types
 483     ] ->
 484       let params =
 485         List.fold_right
 486           (fun (names, typ) acc ->
 487             (List.map (fun name -> (name, typ)) names) @ acc)
 488           params []
 489       in
 490       let fst_ind_type = (fst_name, true, fst_typ, fst_constructors) in
 491       let tl_ind_types = match tl with None -> [] | Some types -> types in
 492       let ind_types = fst_ind_type :: tl_ind_types in
 493       (params, ind_types)
 494   ] ];
 495
 496   record_spec: [ [
 497     name = IDENT; params = LIST0 [ arg = arg -> arg ] ;
 498      SYMBOL ":"; typ = term; SYMBOL <:unicode<def>>; PAREN "{" ;
 499      fields = LIST0 [
 500        name = IDENT ; SYMBOL ":" ; ty = term -> (name,ty)
 501      ] SEP SYMBOL ";"; PAREN "}" ->
 502       let params =
 503         List.fold_right
 504           (fun (names, typ) acc ->
 505             (List.map (fun name -> (name, typ)) names) @ acc)
 506           params []
 507       in
 508       (params,name,typ,fields)
 509   ] ];
 510
 511   macro: [
 512     [ [ IDENT "quit"  ] -> TacticAst.Quit loc
 513 (*     | [ IDENT "abort" ] -> TacticAst.Abort loc *)
 514     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 515 (*     | [ IDENT "undo"   ]; steps = OPT NUM ->
 516         TacticAst.Undo (loc, int_opt steps)
 517     | [ IDENT "redo"   ]; steps = OPT NUM ->
 518         TacticAst.Redo (loc, int_opt steps) *)
 519     | [ IDENT "check"   ]; t = term ->
 520         TacticAst.Check (loc, t)
 521     | [ IDENT "hint" ] -> TacticAst.Hint loc
 522     | [ IDENT "whelp"; "match" ] ; t = term ->
 523         TacticAst.WMatch (loc,t)
 524     | [ IDENT "whelp"; IDENT "instance" ] ; t = term ->
 525         TacticAst.WInstance (loc,t)
 526     | [ IDENT "whelp"; IDENT "locate" ] ; id = IDENT ->
 527         TacticAst.WLocate (loc,id)
 528     | [ IDENT "whelp"; IDENT "elim" ] ; t = term ->
 529         TacticAst.WElim (loc, t)
 530     | [ IDENT "whelp"; IDENT "hint" ] ; t = term ->
 531         TacticAst.WHint (loc,t)
 532     | [ IDENT "print" ]; name = QSTRING -> TacticAst.Print (loc, name)
 533     ]
 534   ];
 535
 536   alias_spec: [
 537     [ IDENT "id"; id = QSTRING; SYMBOL "="; uri = QSTRING ->
 538       let alpha = "[a-zA-Z]" in
 539       let num = "[0-9]+" in
 540       let ident_cont = "\\("^alpha^"\\|"^num^"\\|_\\|\\\\\\)" in
 541       let ident = "\\("^alpha^ident_cont^"*\\|_"^ident_cont^"+\\)" in
 542       let rex = Str.regexp ("^"^ident^"$") in
 543       if Str.string_match rex id 0 then
 544         let rex = Str.regexp
 545           ("^\\(cic:/\\|theory:/\\)"^ident^
 546            "\\(/"^ident^"+\\)*\\(\\."^ident^"\\)+"^
 547            "\\(#xpointer("^ num^"\\(/"^num^"\\)+)\\)?$")
 548         in
 549         if Str.string_match rex uri 0 then
 550           TacticAst.Ident_alias (id, uri)
 551         else
 552           raise (Parse_error (loc,sprintf "Not a valid uri: %s" uri))
 553       else
 554         raise (Parse_error (loc,sprintf "Not a valid identifier: %s" id))
 555     | IDENT "symbol"; symbol = QSTRING;
 556       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 557       SYMBOL "="; dsc = QSTRING ->
 558         let instance =
 559           match instance with Some i -> int_of_string i | None -> 0
 560         in
 561         TacticAst.Symbol_alias (symbol, instance, dsc)
 562     | IDENT "num";
 563       instance = OPT [ PAREN "("; IDENT "instance"; n = NUM; PAREN ")" -> n ];
 564       SYMBOL "="; dsc = QSTRING ->
 565         let instance =
 566           match instance with Some i -> int_of_string i | None -> 0
 567         in
 568         TacticAst.Number_alias (instance, dsc)
 569     ]
 570   ];
 571
 572   command: [[
 573        [ IDENT "set" ]; n = QSTRING; v = QSTRING ->
 574         TacticAst.Set (loc, n, v)
 575     |  [ IDENT "drop" ] -> TacticAst.Drop loc
 576     | [ IDENT "qed"   ] -> TacticAst.Qed loc
 577     | flavour = theorem_flavour; name = IDENT; SYMBOL ":"; typ = term;
 578       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 579         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, typ, body))
 580     | flavour = theorem_flavour; name = IDENT;
 581       body = OPT [ SYMBOL <:unicode<def>> (* ≝ *); body = term -> body ] ->
 582         TacticAst.Obj (loc,TacticAst.Theorem (flavour, name, CicAst.Implicit, body))
 583     | "let"; ind_kind = [ "corec" -> `CoInductive | "rec"-> `Inductive ];
 584         defs = let_defs ->
 585           let name,ty =
 586             match defs with
 587             | ((Cic.Name name,Some ty),_,_) :: _ -> name,ty
 588             | ((Cic.Name name,None),_,_) :: _ -> name,CicAst.Implicit
 589             | _ -> assert false
 590           in
 591           let body = CicAst.Ident (name,None) in
 592           TacticAst.Obj (loc,TacticAst.Theorem(`Definition, name, ty,
 593             Some (CicAst.LetRec (ind_kind, defs, body))))
 594
 595     | [ IDENT "inductive" ]; spec = inductive_spec ->
 596         let (params, ind_types) = spec in
 597         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 598     | [ IDENT "coinductive" ]; spec = inductive_spec ->
 599         let (params, ind_types) = spec in
 600         let ind_types = (* set inductive flags to false (coinductive) *)
 601           List.map (fun (name, _, term, ctors) -> (name, false, term, ctors))
 602             ind_types
 603         in
 604         TacticAst.Obj (loc,TacticAst.Inductive (params, ind_types))
 605     | [ IDENT "coercion" ] ; name = IDENT ->
 606         TacticAst.Coercion (loc, CicAst.Ident (name,Some []))
 607     | [ IDENT "coercion" ] ; name = URI ->
 608         TacticAst.Coercion (loc, CicAst.Uri (name,Some []))
 609     | [ IDENT "alias"   ]; spec = alias_spec ->
 610         TacticAst.Alias (loc, spec)
 611     | [ IDENT "record" ]; (params,name,ty,fields) = record_spec ->
 612         TacticAst.Obj (loc,TacticAst.Record (params,name,ty,fields))
 613   ]];
 614
 615   executable: [
 616     [ cmd = command; SYMBOL "." -> TacticAst.Command (loc, cmd)
 617     | tac = tactical; SYMBOL "." -> TacticAst.Tactical (loc, tac)
 618     | mac = macro; SYMBOL "." -> TacticAst.Macro (loc, mac)
 619     ]
 620   ];
 621
 622   comment: [
 623     [ BEGINCOMMENT ; ex = executable ; ENDCOMMENT ->
 624        TacticAst.Code (loc, ex)
 625     | str = NOTE ->
 626        TacticAst.Note (loc, str)
 627     ]
 628   ];
 629
 630   statement: [
 631     [ ex = executable -> TacticAst.Executable (loc,ex)
 632     | com = comment -> TacticAst.Comment (loc, com)
 633     ]
 634   ];
 635   statements: [
 636     [ l = LIST0 statement ; EOI -> l
 637     ]
 638   ];
 639 END
 640
 641 let exc_located_wrapper f =
 642   try
 643     f ()
 644   with
 645   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 646       raise (Parse_error (floc, msg))
 647   | Stdpp.Exc_located (floc, exn) ->
 648       raise (Parse_error (floc, (Printexc.to_string exn)))
 649
 650 let parse_term stream =
 651   exc_located_wrapper (fun () -> (Grammar.Entry.parse term0 stream))
 652 let parse_statement stream =
 653   exc_located_wrapper (fun () -> (Grammar.Entry.parse statement stream))
 654 let parse_statements stream =
 655   exc_located_wrapper (fun () -> (Grammar.Entry.parse statements stream))
 656
 657
 658 (**/**)
 659
 660 (** {2 Interface for gTopLevel} *)
 661
 662 module EnvironmentP3 =
 663   struct
 664     type t = environment
 665
 666     let empty = ""
 667
 668     let aliases_grammar = Grammar.gcreate cic_lexer
 669     let aliases = Grammar.Entry.create aliases_grammar "aliases"
 670
 671     let to_string env =
 672       let aliases =
 673         Environment.fold
 674           (fun domain_item (dsc, _) acc ->
 675             let s =
 676               match domain_item with
 677               | Id id ->
 678                   TacticAstPp.pp_alias (TacticAst.Ident_alias (id, dsc)) ^ "."
 679               | Symbol (symb, i) ->
 680                   TacticAstPp.pp_alias (TacticAst.Symbol_alias (symb, i, dsc))
 681                   ^ "."
 682               | Num i ->
 683                   TacticAstPp.pp_alias (TacticAst.Number_alias (i, dsc)) ^ "."
 684             in
 685             s :: acc)
 686           env []
 687       in
 688       String.concat "\n" (List.sort compare aliases)
 689
 690     EXTEND
 691       GLOBAL: aliases;
 692       aliases: [  (* build an environment from an aliases list *)
 693         [ aliases = LIST0 alias; EOI ->
 694             List.fold_left
 695               (fun env (domain_item, codomain_item) ->
 696                 Environment.add domain_item codomain_item env)
 697               Environment.empty aliases
 698         ]
 699       ];
 700       alias: [  (* return a pair <domain_item, codomain_item> from an alias *)
 701         [ IDENT "alias";
 702           choice =
 703             [ IDENT "id"; id = IDENT; SYMBOL "="; suri = URI ->
 704                 (Id id, choice_of_uri suri)
 705             | IDENT "symbol"; symbol = QSTRING;
 706               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 707               SYMBOL "="; dsc = QSTRING ->
 708                 (Symbol (symbol, int_of_string instance),
 709                  DisambiguateChoices.lookup_symbol_by_dsc symbol dsc)
 710             | IDENT "num";
 711               PAREN "("; IDENT "instance"; instance = NUM; PAREN ")";
 712               SYMBOL "="; dsc = QSTRING ->
 713                 (Num (int_of_string instance),
 714                  DisambiguateChoices.lookup_num_by_dsc dsc)
 715             ] -> choice ]
 716       ];
 717     END
 718
 719     let of_string s =
 720       if s = empty then
 721         Environment.empty
 722       else
 723         exc_located_wrapper
 724           (fun () -> Grammar.Entry.parse aliases (Stream.of_string s))
 725   end
 726
 727 (* vim:set encoding=utf8: *)