helm/ocaml/cic_disambiguation/disambiguate.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open DisambiguateTypes
  29 open UriManager
  30
  31 exception No_choices of domain_item
  32 exception NoWellTypedInterpretation
  33
  34   (** raised when an environment is not enough informative to decide *)
  35 exception Try_again
  36
  37 let debug = false
  38 let debug_print = if debug then prerr_endline else ignore
  39
  40 (*
  41   (** print benchmark information *)
  42 let benchmark = true
  43 let max_refinements = ref 0       (* benchmarking is not thread safe *)
  44 let actual_refinements = ref 0
  45 let domain_size = ref 0
  46 let choices_avg = ref 0.
  47 *)
  48
  49 let descr_of_domain_item = function
  50  | Id s -> s
  51  | Symbol (s, _) -> s
  52  | Num i -> string_of_int i
  53
  54 type test_result =
  55   | Ok of Cic.term * Cic.metasenv
  56   | Ko
  57   | Uncertain
  58
  59 let refine metasenv context term ugraph =
  60 (*   if benchmark then incr actual_refinements; *)
  61   let metasenv, term =
  62     CicMkImplicit.expand_implicits metasenv [] context term in
  63     debug_print (sprintf "TEST_INTERPRETATION: %s" (CicPp.ppterm term));
  64     try
  65       let term', _, metasenv',ugraph1 =
  66         CicRefine.type_of_aux' metasenv context term ugraph in
  67         (Ok (term', metasenv')),ugraph1
  68     with
  69       | CicRefine.Uncertain _ ->
  70           debug_print ("UNCERTAIN!!! " ^ CicPp.ppterm term) ;
  71           Uncertain,ugraph
  72       | CicRefine.RefineFailure msg ->
  73           debug_print (sprintf "PRUNED!!!\nterm%s\nmessage:%s"
  74             (CicPp.ppterm term) msg);
  75           Ko,ugraph
  76
  77 let resolve (env: environment) (item: domain_item) ?(num = "") ?(args = []) () =
  78   try
  79     snd (Environment.find item env) env num args
  80   with Not_found ->
  81     failwith ("Domain item not found: " ^
  82       (DisambiguateTypes.string_of_domain_item item))
  83
  84   (* TODO move it to Cic *)
  85 let find_in_environment name context =
  86   let rec aux acc = function
  87     | [] -> raise Not_found
  88     | Cic.Name hd :: tl when hd = name -> acc
  89     | _ :: tl ->  aux (acc + 1) tl
  90   in
  91   aux 1 context
  92
  93 let interpretate ~context ~env ast =
  94   let rec aux loc context = function
  95     | CicAst.AttributedTerm (`Loc loc, term) ->
  96         aux loc context term
  97     | CicAst.AttributedTerm (_, term) -> aux loc context term
  98     | CicAst.Appl (CicAst.Symbol (symb, i) :: args) ->
  99         let cic_args = List.map (aux loc context) args in
 100         resolve env (Symbol (symb, i)) ~args:cic_args ()
 101     | CicAst.Appl terms -> Cic.Appl (List.map (aux loc context) terms)
 102     | CicAst.Binder (binder_kind, (var, typ), body) ->
 103         let cic_type = aux_option loc context typ in
 104         let cic_body = aux loc (var :: context) body in
 105         (match binder_kind with
 106         | `Lambda -> Cic.Lambda (var, cic_type, cic_body)
 107         | `Pi | `Forall -> Cic.Prod (var, cic_type, cic_body)
 108         | `Exists ->
 109             resolve env (Symbol ("exists", 0))
 110               ~args:[ cic_type; Cic.Lambda (var, cic_type, cic_body) ] ())
 111     | CicAst.Case (term, indty_ident, outtype, branches) ->
 112         let cic_term = aux loc context term in
 113         let cic_outtype = aux_option loc context outtype in
 114         let do_branch ((head, args), term) =
 115           let rec do_branch' context = function
 116             | [] -> aux loc context term
 117             | (name, typ) :: tl ->
 118                 let cic_body = do_branch' (name :: context) tl in
 119                 let typ =
 120                   match typ with
 121                   | None -> Cic.Implicit (Some `Type)
 122                   | Some typ -> aux loc context typ
 123                 in
 124                 Cic.Lambda (name, typ, cic_body)
 125           in
 126           do_branch' context args
 127         in
 128         let (indtype_uri, indtype_no) =
 129           match indty_ident with
 130           | Some indty_ident ->
 131               (match resolve env (Id indty_ident) () with
 132               | Cic.MutInd (uri, tyno, _) -> (uri, tyno)
 133               | Cic.Implicit _ -> raise Try_again
 134               | _ -> raise DisambiguateChoices.Invalid_choice)
 135           | None ->
 136               let fst_constructor =
 137                 match branches with
 138                 | ((head, _), _) :: _ -> head
 139                 | [] -> raise DisambiguateChoices.Invalid_choice
 140               in
 141               (match resolve env (Id fst_constructor) () with
 142               | Cic.MutConstruct (indtype_uri, indtype_no, _, _) ->
 143                   (indtype_uri, indtype_no)
 144               | Cic.Implicit _ -> raise Try_again
 145               | _ -> raise DisambiguateChoices.Invalid_choice)
 146         in
 147         Cic.MutCase (indtype_uri, indtype_no, cic_outtype, cic_term,
 148           (List.map do_branch branches))
 149     | CicAst.LetIn ((name, typ), def, body) ->
 150         let cic_def = aux loc context def in
 151         let cic_def =
 152           match typ with
 153           | None -> cic_def
 154           | Some t -> Cic.Cast (cic_def, aux loc context t)
 155         in
 156         let cic_body = aux loc (name :: context) body in
 157         Cic.LetIn (name, cic_def, cic_body)
 158     | CicAst.LetRec (kind, defs, body) ->
 159         let context' =
 160           List.fold_left (fun acc ((name, _), _, _) -> name :: acc)
 161             context defs
 162         in
 163         let cic_body = aux loc context' body in
 164         let inductiveFuns =
 165           List.map
 166             (fun ((name, typ), body, decr_idx) ->
 167               let cic_body = aux loc context' body in
 168               let cic_type = aux_option loc context typ in
 169               let name =
 170                 match name with
 171                 | Cic.Anonymous ->
 172                     CicTextualParser2.fail loc
 173                       "Recursive functions cannot be anonymous"
 174                 | Cic.Name name -> name
 175               in
 176               (name, decr_idx, cic_type, cic_body))
 177             defs
 178         in
 179         let counter = ref ~-1 in
 180         let build_term funs =
 181           (* this is the body of the fold_right function below. Rationale: Fix
 182            * and CoFix cases differs only in an additional index in the
 183            * inductiveFun list, see Cic.term *)
 184           match kind with
 185           | `Inductive ->
 186               (fun (var, _, _, _) cic ->
 187                 incr counter;
 188                 Cic.LetIn (Cic.Name var, Cic.Fix (!counter, funs), cic))
 189           | `CoInductive ->
 190               let funs =
 191                 List.map (fun (name, _, typ, body) -> (name, typ, body)) funs
 192               in
 193               (fun (var, _, _, _) cic ->
 194                 incr counter;
 195                 Cic.LetIn (Cic.Name var, Cic.CoFix (!counter, funs), cic))
 196         in
 197         List.fold_right (build_term inductiveFuns) inductiveFuns cic_body
 198     | CicAst.Ident (name, subst)
 199     | CicAst.Uri (name, subst) as ast ->
 200         let is_uri = function CicAst.Uri _ -> true | _ -> false in
 201         (try
 202           if is_uri ast then raise Not_found;(* don't search the env for URIs *)
 203           let index = find_in_environment name context in
 204           if subst <> None then
 205             CicTextualParser2.fail loc
 206               "Explicit substitutions not allowed here";
 207           Cic.Rel index
 208         with Not_found ->
 209           let cic =
 210             if is_uri ast then  (* we have the URI, build the term out of it *)
 211               try
 212                 CicUtil.term_of_uri name
 213               with UriManager.IllFormedUri _ ->
 214                 CicTextualParser2.fail loc "Ill formed URI"
 215             else
 216               resolve env (Id name) ()
 217           in
 218           let mk_subst uris =
 219             let ids_to_uris =
 220               List.map (fun uri -> UriManager.name_of_uri uri, uri) uris
 221             in
 222             (match subst with
 223             | Some subst ->
 224                 List.map
 225                   (fun (s, term) ->
 226                     (try
 227                       List.assoc s ids_to_uris, aux loc context term
 228                      with Not_found ->
 229                        raise DisambiguateChoices.Invalid_choice))
 230                   subst
 231             | None -> List.map (fun uri -> uri, Cic.Implicit None) uris)
 232           in
 233           (try
 234             match cic with
 235             | Cic.Const (uri, []) ->
 236                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 237                 let uris = CicUtil.params_of_obj o in
 238                 Cic.Const (uri, mk_subst uris)
 239             | Cic.Var (uri, []) ->
 240                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 241                 let uris = CicUtil.params_of_obj o in
 242                 Cic.Var (uri, mk_subst uris)
 243             | Cic.MutInd (uri, i, []) ->
 244                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 245                 let uris = CicUtil.params_of_obj o in
 246                 Cic.MutInd (uri, i, mk_subst uris)
 247             | Cic.MutConstruct (uri, i, j, []) ->
 248                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 249                 let uris = CicUtil.params_of_obj o in
 250                 Cic.MutConstruct (uri, i, j, mk_subst uris)
 251             | Cic.Meta _ | Cic.Implicit _ as t ->
 252 (*
 253                 prerr_endline (sprintf
 254                   "Warning: %s must be instantiated with _[%s] but we do not enforce it"
 255                   (CicPp.ppterm t)
 256                   (String.concat "; "
 257                     (List.map
 258                       (fun (s, term) -> s ^ " := " ^ CicAstPp.pp_term term)
 259                       subst)));
 260 *)
 261                 t
 262             | _ ->
 263               raise DisambiguateChoices.Invalid_choice
 264            with
 265              CicEnvironment.CircularDependency _ ->
 266                raise DisambiguateChoices.Invalid_choice))
 267     | CicAst.Implicit -> Cic.Implicit None
 268     | CicAst.Num (num, i) -> resolve env (Num i) ~num ()
 269     | CicAst.Meta (index, subst) ->
 270         let cic_subst =
 271           List.map
 272             (function None -> None | Some term -> Some (aux loc context term))
 273             subst
 274         in
 275         Cic.Meta (index, cic_subst)
 276     | CicAst.Sort `Prop -> Cic.Sort Cic.Prop
 277     | CicAst.Sort `Set -> Cic.Sort Cic.Set
 278     | CicAst.Sort `Type -> Cic.Sort (Cic.Type (CicUniv.fresh())) (* TASSI *)
 279     | CicAst.Sort `CProp -> Cic.Sort Cic.CProp
 280     | CicAst.Symbol (symbol, instance) ->
 281         resolve env (Symbol (symbol, instance)) ()
 282     | CicAst.UserInput -> assert false
 283   and aux_option loc context = function
 284     | None -> Cic.Implicit (Some `Type)
 285     | Some term -> aux loc context term
 286   in
 287   match ast with
 288   | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 289   | term -> aux CicAst.dummy_floc context term
 290
 291 let domain_of_term ~context ast =
 292     (* "aux" keeps domain in reverse order and doesn't care about duplicates.
 293      * Domain item more in deep in the list will be processed first.
 294      *)
 295   let rec aux loc context = function
 296     | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 297     | CicAst.AttributedTerm (_, term) -> aux loc context term
 298     | CicAst.Appl terms ->
 299         List.fold_left (fun dom term -> aux loc context term @ dom) [] terms
 300     | CicAst.Binder (kind, (var, typ), body) ->
 301         let kind_dom =
 302           match kind with
 303           | `Exists -> [ Symbol ("exists", 0) ]
 304           | _ -> []
 305         in
 306         let type_dom = aux_option loc context typ in
 307         let body_dom = aux loc (var :: context) body in
 308         body_dom @ type_dom @ kind_dom
 309     | CicAst.Case (term, indty_ident, outtype, branches) ->
 310         let term_dom = aux loc context term in
 311         let outtype_dom = aux_option loc context outtype in
 312         let get_first_constructor = function
 313           | [] -> []
 314           | ((head, _), _) :: _ -> [ Id head ]
 315         in
 316         let do_branch ((head, args), term) =
 317           let (term_context, args_domain) =
 318             List.fold_left
 319               (fun (cont, dom) (name, typ) ->
 320                 (name :: cont,
 321                  (match typ with
 322                  | None -> dom
 323                  | Some typ -> aux loc cont typ @ dom)))
 324               (context, []) args
 325           in
 326           args_domain @ aux loc term_context term
 327         in
 328         let branches_dom =
 329           List.fold_left (fun dom branch -> do_branch branch @ dom) [] branches
 330         in
 331         branches_dom @ outtype_dom @ term_dom @
 332         (match indty_ident with
 333          | None -> get_first_constructor branches
 334          | Some ident -> [ Id ident ])
 335     | CicAst.LetIn ((var, typ), body, where) ->
 336         let body_dom = aux loc context body in
 337         let type_dom = aux_option loc context typ in
 338         let where_dom = aux loc (var :: context) where in
 339         where_dom @ type_dom @ body_dom
 340     | CicAst.LetRec (kind, defs, where) ->
 341         let context' =
 342           List.fold_left (fun acc ((var, typ), _, _) -> var :: acc)
 343             context defs
 344         in
 345         let where_dom = aux loc context' where in
 346         let defs_dom =
 347           List.fold_left
 348             (fun dom ((_, typ), body, _) ->
 349               aux loc context' body @ aux_option loc context typ)
 350             [] defs
 351         in
 352         where_dom @ defs_dom
 353     | CicAst.Ident (name, subst) ->
 354         (try
 355           let index = find_in_environment name context in
 356           if subst <> None then
 357             CicTextualParser2.fail loc
 358               "Explicit substitutions not allowed here"
 359           else
 360             []
 361         with Not_found ->
 362           (match subst with
 363           | None -> [Id name]
 364           | Some subst ->
 365               List.fold_left
 366                 (fun dom (_, term) ->
 367                   let dom' = aux loc context term in
 368                   dom' @ dom)
 369                 [Id name] subst))
 370     | CicAst.Uri _ -> []
 371     | CicAst.Implicit -> []
 372     | CicAst.Num (num, i) -> [ Num i ]
 373     | CicAst.Meta (index, local_context) ->
 374         List.fold_left (fun dom term -> aux_option loc context term @ dom) []
 375           local_context
 376     | CicAst.Sort _ -> []
 377     | CicAst.Symbol (symbol, instance) -> [ Symbol (symbol, instance) ]
 378     | CicAst.UserInput -> assert false
 379
 380   and aux_option loc context = function
 381     | None -> []
 382     | Some t -> aux loc context t
 383   in
 384
 385     (* e.g. [5;1;1;1;2;3;4;1;2] -> [2;1;4;3;5] *)
 386   let rev_uniq =
 387     let module SortedItem =
 388       struct
 389         type t = DisambiguateTypes.domain_item
 390         let compare = Pervasives.compare
 391       end
 392     in
 393     let module Set = Set.Make (SortedItem) in
 394     fun l ->
 395       let rev_l = List.rev l in
 396       let (_, uniq_rev_l) =
 397         List.fold_left
 398           (fun (members, rev_l) elt ->
 399             if Set.mem elt members then
 400               (members, rev_l)
 401             else
 402               Set.add elt members, elt :: rev_l)
 403           (Set.empty, []) rev_l
 404       in
 405       List.rev uniq_rev_l
 406   in
 407
 408   rev_uniq
 409     (match ast with
 410     | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 411     | term -> aux CicAst.dummy_floc context term)
 412
 413
 414   (* dom1 \ dom2 *)
 415 let domain_diff dom1 dom2 =
 416 (* let domain_diff = Domain.diff *)
 417   let is_in_dom2 =
 418     List.fold_left (fun pred elt -> (fun elt' -> elt' = elt || pred elt'))
 419       (fun _ -> false) dom2
 420   in
 421   List.filter (fun elt -> not (is_in_dom2 elt)) dom1
 422
 423 module type Disambiguator =
 424 sig
 425   val disambiguate_term :
 426     dbd:Mysql.dbd ->
 427     context:Cic.context ->
 428     metasenv:Cic.metasenv ->
 429     ?initial_ugraph:CicUniv.universe_graph ->
 430     aliases:environment ->  (* previous interpretation status *)
 431     CicAst.term ->
 432     (environment *                   (* new interpretation status *)
 433      Cic.metasenv *                  (* new metasenv *)
 434      Cic.term*
 435      CicUniv.universe_graph) list    (* disambiguated term *)
 436 end
 437
 438 module Make (C: Callbacks) =
 439   struct
 440     let choices_of_id dbd id =
 441       let uris = MetadataQuery.locate ~dbd id in
 442       let uris =
 443        match uris with
 444         | [] ->
 445            [UriManager.string_of_uri (C.input_or_locate_uri
 446             ~title:("URI matching \"" ^ id ^ "\" unknown.") ~id ())]
 447         | [uri] -> [uri]
 448         | _ ->
 449             C.interactive_user_uri_choice ~selection_mode:`MULTIPLE
 450              ~ok:"Try selected." ~enable_button_for_non_vars:true
 451              ~title:"Ambiguous input." ~id
 452              ~msg: ("Ambiguous input \"" ^ id ^
 453                 "\". Please, choose one or more interpretations:")
 454              uris
 455       in
 456       List.map
 457         (fun uri ->
 458           (uri,
 459            let term =
 460              try
 461                CicUtil.term_of_uri uri
 462              with exn ->
 463                prerr_endline uri;
 464                prerr_endline (Printexc.to_string exn);
 465                assert false
 466             in
 467            fun _ _ _ -> term))
 468         uris
 469
 470     let disambiguate_term ~(dbd:Mysql.dbd) ~context ~metasenv
 471       ?(initial_ugraph = CicUniv.empty_ugraph) ~aliases:current_env
 472       term
 473     =
 474       debug_print "NEW DISAMBIGUATE INPUT";
 475       let disambiguate_context =  (* cic context -> disambiguate context *)
 476         List.map
 477           (function None -> Cic.Anonymous | Some (name, _) -> name)
 478           context
 479       in
 480       debug_print ("TERM IS: " ^ (CicAstPp.pp_term term));
 481       let term_dom = domain_of_term ~context:disambiguate_context term in
 482       debug_print (sprintf "DISAMBIGUATION DOMAIN: %s"
 483         (string_of_domain term_dom));
 484       let current_dom =
 485         Environment.fold (fun item _ dom -> item :: dom) current_env []
 486       in
 487       let todo_dom = domain_diff term_dom current_dom in
 488       (* (2) lookup function for any item (Id/Symbol/Num) *)
 489       let lookup_choices =
 490         let id_choices = Hashtbl.create 1023 in
 491         fun item ->
 492         let choices =
 493           match item with
 494           | Id id ->
 495               (try
 496                 Hashtbl.find id_choices id
 497               with Not_found ->
 498                 let choices = choices_of_id dbd id in
 499                 Hashtbl.add id_choices id choices;
 500                 choices)
 501           | Symbol (symb, _) -> DisambiguateChoices.lookup_symbol_choices symb
 502           | Num instance -> DisambiguateChoices.lookup_num_choices ()
 503         in
 504         if choices = [] then raise (No_choices item);
 505         choices
 506       in
 507
 508 (*
 509       (* <benchmark> *)
 510       let _ =
 511         if benchmark then begin
 512           let per_item_choices =
 513             List.map
 514               (fun dom_item ->
 515                 try
 516                   let len = List.length (lookup_choices dom_item) in
 517                   prerr_endline (sprintf "BENCHMARK %s: %d"
 518                     (string_of_domain_item dom_item) len);
 519                   len
 520                 with No_choices _ -> 0)
 521               term_dom
 522           in
 523           max_refinements := List.fold_left ( * ) 1 per_item_choices;
 524           actual_refinements := 0;
 525           domain_size := List.length term_dom;
 526           choices_avg :=
 527             (float_of_int !max_refinements) ** (1. /. float_of_int !domain_size)
 528         end
 529       in
 530       (* </benchmark> *)
 531 *)
 532
 533       (* (3) test an interpretation filling with meta uninterpreted identifiers
 534        *)
 535       let test_env current_env todo_dom ugraph =
 536         let filled_env =
 537           List.fold_left
 538             (fun env item ->
 539                Environment.add item
 540                ("Implicit",
 541                  (match item with
 542                     | Id _ | Num _ -> (fun _ _ _ -> Cic.Implicit (Some `Closed))
 543                     | Symbol _ -> (fun _ _ _ -> Cic.Implicit None))) env)
 544             current_env todo_dom
 545         in
 546         try
 547           let cic_term =
 548             interpretate ~context:disambiguate_context ~env:filled_env term
 549           in
 550           let k,ugraph1 = refine metasenv context cic_term ugraph in
 551             (k , ugraph1 )
 552         with
 553         | Try_again -> Uncertain,ugraph
 554         | DisambiguateChoices.Invalid_choice -> Ko,ugraph
 555       in
 556       (* (4) build all possible interpretations *)
 557       let rec aux current_env todo_dom base_univ =
 558         match todo_dom with
 559         | [] ->
 560             (match test_env current_env [] base_univ with
 561             | Ok (term, metasenv),new_univ ->
 562                                [ current_env, metasenv, term, new_univ ]
 563             | Ko,_ | Uncertain,_ -> [])
 564         | item :: remaining_dom ->
 565             debug_print (sprintf "CHOOSED ITEM: %s"
 566              (string_of_domain_item item));
 567             let choices = lookup_choices item in
 568             let rec filter univ = function
 569               | [] -> []
 570               | codomain_item :: tl ->
 571                   debug_print (sprintf "%s CHOSEN" (fst codomain_item)) ;
 572                   let new_env =
 573                     Environment.add item codomain_item current_env
 574                   in
 575                   (match test_env new_env remaining_dom univ with
 576                   | Ok (term, metasenv),new_univ ->
 577                       (match remaining_dom with
 578                       | [] -> [ new_env, metasenv, term, new_univ ]
 579                       | _ -> aux new_env remaining_dom new_univ )@
 580                         filter univ tl
 581                   | Uncertain,new_univ ->
 582                       (match remaining_dom with
 583                       | [] -> []
 584                       | _ -> aux new_env remaining_dom new_univ )@
 585                         filter univ tl
 586                   | Ko,_ -> filter univ tl)
 587             in
 588             filter base_univ choices
 589       in
 590       let base_univ = initial_ugraph in
 591       try
 592         let res =
 593          match aux current_env todo_dom base_univ with
 594          | [] -> raise NoWellTypedInterpretation
 595          | [ e,me,t,u ] as l ->
 596              debug_print "UNA SOLA SCELTA";
 597              [ e,me,t,u]
 598          | l ->
 599              debug_print (sprintf "PIU' SCELTE (%d)" (List.length l));
 600              let choices =
 601                List.map
 602                  (fun (env, _, _, _) ->
 603                    List.map
 604                      (fun domain_item ->
 605                        let description =
 606                          fst (Environment.find domain_item env)
 607                        in
 608                        (descr_of_domain_item domain_item, description))
 609                      term_dom)
 610                  l
 611              in
 612              let choosed = C.interactive_interpretation_choice choices in
 613              List.map (List.nth l) choosed
 614         in
 615 (*
 616         (if benchmark then
 617           let res_size = List.length res in
 618           prerr_endline (sprintf
 619             ("BENCHMARK: %d/%d refinements performed, domain size %d, interps %d, k %.2f\n" ^^
 620             "BENCHMARK:   estimated %.2f")
 621             !actual_refinements !max_refinements !domain_size res_size
 622             !choices_avg
 623             (float_of_int (!domain_size - 1) *. !choices_avg *. (float_of_int res_size) +. !choices_avg)));
 624 *)
 625         res
 626      with
 627       CicEnvironment.CircularDependency s ->
 628         failwith "Disambiguate: circular dependency"
 629   end
 630
 631 module Trivial =
 632 struct
 633   exception Ambiguous_term of string
 634   exception Exit
 635   module Callbacks =
 636   struct
 637     let interactive_user_uri_choice ~selection_mode ?ok
 638           ?(enable_button_for_non_vars = true) ~title ~msg ~id uris =
 639               raise Exit
 640     let interactive_interpretation_choice interp = raise Exit
 641     let input_or_locate_uri ~(title:string) ?id = raise Exit
 642   end
 643   module Disambiguator = Make (Callbacks)
 644   let disambiguate_string ~dbd ?(context=[]) ?(metasenv=[]) ?initial_ugraph
 645         ?(aliases=DisambiguateTypes.Environment.empty) term =
 646     let ast = CicTextualParser2.parse_term (Stream.of_string term) in
 647     try
 648       Disambiguator.disambiguate_term ~dbd ~context ~metasenv ast
 649         ?initial_ugraph ~aliases
 650     with Exit -> raise (Ambiguous_term term)
 651 end
 652