helm/ocaml/cic_disambiguation/disambiguate.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open DisambiguateTypes
  29 open UriManager
  30
  31 exception No_choices of domain_item
  32 exception NoWellTypedInterpretation
  33
  34   (** raised when an environment is not enough informative to decide *)
  35 exception Try_again
  36
  37 let debug = false
  38 let debug_print = if debug then prerr_endline else ignore
  39
  40 (*
  41   (** print benchmark information *)
  42 let benchmark = true
  43 let max_refinements = ref 0       (* benchmarking is not thread safe *)
  44 let actual_refinements = ref 0
  45 let domain_size = ref 0
  46 let choices_avg = ref 0.
  47 *)
  48
  49 let descr_of_domain_item = function
  50  | Id s -> s
  51  | Symbol (s, _) -> s
  52  | Num i -> string_of_int i
  53
  54 type test_result =
  55   | Ok of Cic.term * Cic.metasenv
  56   | Ko
  57   | Uncertain
  58
  59 let refine metasenv context term ugraph =
  60 (*   if benchmark then incr actual_refinements; *)
  61   let metasenv, term =
  62     CicMkImplicit.expand_implicits metasenv [] context term in
  63     debug_print (sprintf "TEST_INTERPRETATION: %s" (CicPp.ppterm term));
  64     try
  65       let term', _, metasenv',ugraph1 =
  66         CicRefine.type_of_aux' metasenv context term ugraph in
  67         (Ok (term', metasenv')),ugraph1
  68     with
  69       | CicRefine.Uncertain _ ->
  70           debug_print ("UNCERTAIN!!! " ^ CicPp.ppterm term) ;
  71           Uncertain,ugraph
  72       | CicRefine.RefineFailure msg ->
  73           debug_print (sprintf "PRUNED!!!\nterm%s\nmessage:%s"
  74             (CicPp.ppterm term) msg);
  75           Ko,ugraph
  76
  77 let resolve (env: environment) (item: domain_item) ?(num = "") ?(args = []) () =
  78   try
  79     snd (Environment.find item env) env num args
  80   with Not_found ->
  81     failwith ("Domain item not found: " ^
  82       (DisambiguateTypes.string_of_domain_item item))
  83
  84   (* TODO move it to Cic *)
  85 let find_in_environment name context =
  86   let rec aux acc = function
  87     | [] -> raise Not_found
  88     | Cic.Name hd :: tl when hd = name -> acc
  89     | _ :: tl ->  aux (acc + 1) tl
  90   in
  91   aux 1 context
  92
  93 let interpretate ~context ~env ast =
  94   let rec aux loc context = function
  95     | CicAst.AttributedTerm (`Loc loc, term) ->
  96         aux loc context term
  97     | CicAst.AttributedTerm (_, term) -> aux loc context term
  98     | CicAst.Appl (CicAst.Symbol (symb, i) :: args) ->
  99         let cic_args = List.map (aux loc context) args in
 100         resolve env (Symbol (symb, i)) ~args:cic_args ()
 101     | CicAst.Appl terms -> Cic.Appl (List.map (aux loc context) terms)
 102     | CicAst.Binder (binder_kind, (var, typ), body) ->
 103         let cic_type = aux_option loc context typ in
 104         let cic_body = aux loc (var :: context) body in
 105         (match binder_kind with
 106         | `Lambda -> Cic.Lambda (var, cic_type, cic_body)
 107         | `Pi | `Forall -> Cic.Prod (var, cic_type, cic_body)
 108         | `Exists ->
 109             resolve env (Symbol ("exists", 0))
 110               ~args:[ cic_type; Cic.Lambda (var, cic_type, cic_body) ] ())
 111     | CicAst.Case (term, indty_ident, outtype, branches) ->
 112         let cic_term = aux loc context term in
 113         let cic_outtype = aux_option loc context outtype in
 114         let do_branch ((head, args), term) =
 115           let rec do_branch' context = function
 116             | [] -> aux loc context term
 117             | (name, typ) :: tl ->
 118                 let cic_body = do_branch' (name :: context) tl in
 119                 let typ =
 120                   match typ with
 121                   | None -> Cic.Implicit (Some `Type)
 122                   | Some typ -> aux loc context typ
 123                 in
 124                 Cic.Lambda (name, typ, cic_body)
 125           in
 126           do_branch' context args
 127         in
 128         let (indtype_uri, indtype_no) =
 129           match indty_ident with
 130           | Some indty_ident ->
 131               (match resolve env (Id indty_ident) () with
 132               | Cic.MutInd (uri, tyno, _) -> (uri, tyno)
 133               | Cic.Implicit _ -> raise Try_again
 134               | _ -> raise DisambiguateChoices.Invalid_choice)
 135           | None ->
 136               let fst_constructor =
 137                 match branches with
 138                 | ((head, _), _) :: _ -> head
 139                 | [] -> raise DisambiguateChoices.Invalid_choice
 140               in
 141               (match resolve env (Id fst_constructor) () with
 142               | Cic.MutConstruct (indtype_uri, indtype_no, _, _) ->
 143                   (indtype_uri, indtype_no)
 144               | Cic.Implicit _ -> raise Try_again
 145               | _ -> raise DisambiguateChoices.Invalid_choice)
 146         in
 147         Cic.MutCase (indtype_uri, indtype_no, cic_outtype, cic_term,
 148           (List.map do_branch branches))
 149     | CicAst.LetIn ((name, typ), def, body) ->
 150         let cic_def = aux loc context def in
 151         let cic_def =
 152           match typ with
 153           | None -> cic_def
 154           | Some t -> Cic.Cast (cic_def, aux loc context t)
 155         in
 156         let cic_body = aux loc (name :: context) body in
 157         Cic.LetIn (name, cic_def, cic_body)
 158     | CicAst.LetRec (kind, defs, body) ->
 159         let context' =
 160           List.fold_left (fun acc ((name, _), _, _) -> name :: acc)
 161             context defs
 162         in
 163         let cic_body = aux loc context' body in
 164         let inductiveFuns =
 165           List.map
 166             (fun ((name, typ), body, decr_idx) ->
 167               let cic_body = aux loc context' body in
 168               let cic_type = aux_option loc context typ in
 169               let name =
 170                 match name with
 171                 | Cic.Anonymous ->
 172                     CicTextualParser2.fail loc
 173                       "Recursive functions cannot be anonymous"
 174                 | Cic.Name name -> name
 175               in
 176               (name, decr_idx, cic_type, cic_body))
 177             defs
 178         in
 179         let counter = ref ~-1 in
 180         let build_term funs =
 181           (* this is the body of the fold_right function below. Rationale: Fix
 182            * and CoFix cases differs only in an additional index in the
 183            * inductiveFun list, see Cic.term *)
 184           match kind with
 185           | `Inductive ->
 186               (fun (var, _, _, _) cic ->
 187                 incr counter;
 188                 Cic.LetIn (Cic.Name var, Cic.Fix (!counter, funs), cic))
 189           | `CoInductive ->
 190               let funs =
 191                 List.map (fun (name, _, typ, body) -> (name, typ, body)) funs
 192               in
 193               (fun (var, _, _, _) cic ->
 194                 incr counter;
 195                 Cic.LetIn (Cic.Name var, Cic.CoFix (!counter, funs), cic))
 196         in
 197         List.fold_right (build_term inductiveFuns) inductiveFuns cic_body
 198     | CicAst.Ident (name, subst)
 199     | CicAst.Uri (name, subst) as ast ->
 200         let is_uri = function CicAst.Uri _ -> true | _ -> false in
 201         (try
 202           if is_uri ast then raise Not_found;(* don't search the env for URIs *)
 203           let index = find_in_environment name context in
 204           if subst <> None then
 205             CicTextualParser2.fail loc
 206               "Explicit substitutions not allowed here";
 207           Cic.Rel index
 208         with Not_found ->
 209           let cic =
 210             if is_uri ast then  (* we have the URI, build the term out of it *)
 211               try
 212                 CicUtil.term_of_uri name
 213               with UriManager.IllFormedUri _ ->
 214                 CicTextualParser2.fail loc "Ill formed URI"
 215             else
 216               resolve env (Id name) ()
 217           in
 218           let mk_subst uris =
 219             let ids_to_uris =
 220               List.map (fun uri -> UriManager.name_of_uri uri, uri) uris
 221             in
 222             (match subst with
 223             | Some subst ->
 224                 List.map
 225                   (fun (s, term) ->
 226                     (try
 227                       List.assoc s ids_to_uris, aux loc context term
 228                      with Not_found ->
 229                        raise DisambiguateChoices.Invalid_choice))
 230                   subst
 231             | None -> List.map (fun uri -> uri, Cic.Implicit None) uris)
 232           in
 233           (try
 234             match cic with
 235             | Cic.Const (uri, []) ->
 236                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 237                 let uris = CicUtil.params_of_obj o in
 238                 Cic.Const (uri, mk_subst uris)
 239             | Cic.Var (uri, []) ->
 240                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 241                 let uris = CicUtil.params_of_obj o in
 242                 Cic.Var (uri, mk_subst uris)
 243             | Cic.MutInd (uri, i, []) ->
 244                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 245                 let uris = CicUtil.params_of_obj o in
 246                 Cic.MutInd (uri, i, mk_subst uris)
 247             | Cic.MutConstruct (uri, i, j, []) ->
 248                 let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
 249                 let uris = CicUtil.params_of_obj o in
 250                 Cic.MutConstruct (uri, i, j, mk_subst uris)
 251             | Cic.Meta _ | Cic.Implicit _ as t ->
 252 (*
 253                 prerr_endline (sprintf
 254                   "Warning: %s must be instantiated with _[%s] but we do not enforce it"
 255                   (CicPp.ppterm t)
 256                   (String.concat "; "
 257                     (List.map
 258                       (fun (s, term) -> s ^ " := " ^ CicAstPp.pp_term term)
 259                       subst)));
 260 *)
 261                 t
 262             | _ ->
 263               raise DisambiguateChoices.Invalid_choice
 264            with
 265              CicEnvironment.CircularDependency _ ->
 266                raise DisambiguateChoices.Invalid_choice))
 267     | CicAst.Implicit -> Cic.Implicit None
 268     | CicAst.Num (num, i) -> resolve env (Num i) ~num ()
 269     | CicAst.Meta (index, subst) ->
 270         let cic_subst =
 271           List.map
 272             (function None -> None | Some term -> Some (aux loc context term))
 273             subst
 274         in
 275         Cic.Meta (index, cic_subst)
 276     | CicAst.Sort `Prop -> Cic.Sort Cic.Prop
 277     | CicAst.Sort `Set -> Cic.Sort Cic.Set
 278     | CicAst.Sort `Type -> Cic.Sort (Cic.Type (CicUniv.fresh())) (* TASSI *)
 279     | CicAst.Sort `CProp -> Cic.Sort Cic.CProp
 280     | CicAst.Symbol (symbol, instance) ->
 281         resolve env (Symbol (symbol, instance)) ()
 282     | CicAst.UserInput -> assert false
 283   and aux_option loc context = function
 284     | None -> Cic.Implicit (Some `Type)
 285     | Some term -> aux loc context term
 286   in
 287   match ast with
 288   | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 289   | term -> aux CicAst.dummy_floc context term
 290
 291 let domain_of_term ~context ast =
 292     (* "aux" keeps domain in reverse order and doesn't care about duplicates.
 293      * Domain item more in deep in the list will be processed first.
 294      *)
 295   let rec aux loc context = function
 296     | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 297     | CicAst.AttributedTerm (_, term) -> aux loc context term
 298     | CicAst.Appl terms ->
 299         List.fold_left (fun dom term -> aux loc context term @ dom) [] terms
 300     | CicAst.Binder (kind, (var, typ), body) ->
 301         let kind_dom =
 302           match kind with
 303           | `Exists -> [ Symbol ("exists", 0) ]
 304           | _ -> []
 305         in
 306         let type_dom = aux_option loc context typ in
 307         let body_dom = aux loc (var :: context) body in
 308         body_dom @ type_dom @ kind_dom
 309     | CicAst.Case (term, indty_ident, outtype, branches) ->
 310         let term_dom = aux loc context term in
 311         let outtype_dom = aux_option loc context outtype in
 312         let do_branch ((head, args), term) =
 313           let (term_context, args_domain) =
 314             List.fold_left
 315               (fun (cont, dom) (name, typ) ->
 316                 (name :: cont,
 317                  (match typ with
 318                  | None -> dom
 319                  | Some typ -> aux loc cont typ @ dom)))
 320               (context, []) args
 321           in
 322           args_domain @ aux loc term_context term
 323         in
 324         let branches_dom =
 325           List.fold_left (fun dom branch -> do_branch branch @ dom) [] branches
 326         in
 327         branches_dom @ outtype_dom @ term_dom @
 328         (match indty_ident with None -> [] | Some ident -> [ Id ident ])
 329     | CicAst.LetIn ((var, typ), body, where) ->
 330         let body_dom = aux loc context body in
 331         let type_dom = aux_option loc context typ in
 332         let where_dom = aux loc (var :: context) where in
 333         where_dom @ type_dom @ body_dom
 334     | CicAst.LetRec (kind, defs, where) ->
 335         let context' =
 336           List.fold_left (fun acc ((var, typ), _, _) -> var :: acc)
 337             context defs
 338         in
 339         let where_dom = aux loc context' where in
 340         let defs_dom =
 341           List.fold_left
 342             (fun dom ((_, typ), body, _) ->
 343               aux loc context' body @ aux_option loc context typ)
 344             [] defs
 345         in
 346         where_dom @ defs_dom
 347     | CicAst.Ident (name, subst) ->
 348         (try
 349           let index = find_in_environment name context in
 350           if subst <> None then
 351             CicTextualParser2.fail loc
 352               "Explicit substitutions not allowed here"
 353           else
 354             []
 355         with Not_found ->
 356           (match subst with
 357           | None -> [Id name]
 358           | Some subst ->
 359               List.fold_left
 360                 (fun dom (_, term) ->
 361                   let dom' = aux loc context term in
 362                   dom' @ dom)
 363                 [Id name] subst))
 364     | CicAst.Uri _ -> []
 365     | CicAst.Implicit -> []
 366     | CicAst.Num (num, i) -> [ Num i ]
 367     | CicAst.Meta (index, local_context) ->
 368         List.fold_left (fun dom term -> aux_option loc context term @ dom) []
 369           local_context
 370     | CicAst.Sort _ -> []
 371     | CicAst.Symbol (symbol, instance) -> [ Symbol (symbol, instance) ]
 372     | CicAst.UserInput -> assert false
 373
 374   and aux_option loc context = function
 375     | None -> []
 376     | Some t -> aux loc context t
 377   in
 378
 379     (* e.g. [5;1;1;1;2;3;4;1;2] -> [2;1;4;3;5] *)
 380   let rev_uniq =
 381     let module SortedItem =
 382       struct
 383         type t = DisambiguateTypes.domain_item
 384         let compare = Pervasives.compare
 385       end
 386     in
 387     let module Set = Set.Make (SortedItem) in
 388     fun l ->
 389       let rev_l = List.rev l in
 390       let (_, uniq_rev_l) =
 391         List.fold_left
 392           (fun (members, rev_l) elt ->
 393             if Set.mem elt members then
 394               (members, rev_l)
 395             else
 396               Set.add elt members, elt :: rev_l)
 397           (Set.empty, []) rev_l
 398       in
 399       List.rev uniq_rev_l
 400   in
 401
 402   rev_uniq
 403     (match ast with
 404     | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 405     | term -> aux CicAst.dummy_floc context term)
 406
 407
 408   (* dom1 \ dom2 *)
 409 let domain_diff dom1 dom2 =
 410 (* let domain_diff = Domain.diff *)
 411   let is_in_dom2 =
 412     List.fold_left (fun pred elt -> (fun elt' -> elt' = elt || pred elt'))
 413       (fun _ -> false) dom2
 414   in
 415   List.filter (fun elt -> not (is_in_dom2 elt)) dom1
 416
 417 module type Disambiguator =
 418 sig
 419   val disambiguate_term :
 420     dbd:Mysql.dbd ->
 421     context:Cic.context ->
 422     metasenv:Cic.metasenv ->
 423     ?initial_ugraph:CicUniv.universe_graph ->
 424     aliases:environment ->  (* previous interpretation status *)
 425     CicAst.term ->
 426     (environment *                   (* new interpretation status *)
 427      Cic.metasenv *                  (* new metasenv *)
 428      Cic.term*
 429      CicUniv.universe_graph) list    (* disambiguated term *)
 430 end
 431
 432 module Make (C: Callbacks) =
 433   struct
 434     let choices_of_id dbd id =
 435       let uris = MetadataQuery.locate ~dbd id in
 436       let uris =
 437        match uris with
 438         | [] ->
 439            [UriManager.string_of_uri (C.input_or_locate_uri
 440             ~title:("URI matching \"" ^ id ^ "\" unknown.") ~id ())]
 441         | [uri] -> [uri]
 442         | _ ->
 443             C.interactive_user_uri_choice ~selection_mode:`MULTIPLE
 444              ~ok:"Try selected." ~enable_button_for_non_vars:true
 445              ~title:"Ambiguous input." ~id
 446              ~msg: ("Ambiguous input \"" ^ id ^
 447                 "\". Please, choose one or more interpretations:")
 448              uris
 449       in
 450       List.map
 451         (fun uri ->
 452           (uri,
 453            let term =
 454              try
 455                CicUtil.term_of_uri uri
 456              with exn ->
 457                prerr_endline uri;
 458                prerr_endline (Printexc.to_string exn);
 459                assert false
 460             in
 461            fun _ _ _ -> term))
 462         uris
 463
 464     let disambiguate_term ~(dbd:Mysql.dbd) ~context ~metasenv
 465       ?(initial_ugraph = CicUniv.empty_ugraph) ~aliases:current_env
 466       term
 467     =
 468       debug_print "NEW DISAMBIGUATE INPUT";
 469       let disambiguate_context =  (* cic context -> disambiguate context *)
 470         List.map
 471           (function None -> Cic.Anonymous | Some (name, _) -> name)
 472           context
 473       in
 474       let term_dom = domain_of_term ~context:disambiguate_context term in
 475       debug_print (sprintf "DISAMBIGUATION DOMAIN: %s"
 476         (string_of_domain term_dom));
 477       let current_dom =
 478         Environment.fold (fun item _ dom -> item :: dom) current_env []
 479       in
 480       let todo_dom = domain_diff term_dom current_dom in
 481       (* (2) lookup function for any item (Id/Symbol/Num) *)
 482       let lookup_choices =
 483         let id_choices = Hashtbl.create 1023 in
 484         fun item ->
 485         let choices =
 486           match item with
 487           | Id id ->
 488               (try
 489                 Hashtbl.find id_choices id
 490               with Not_found ->
 491                 let choices = choices_of_id dbd id in
 492                 Hashtbl.add id_choices id choices;
 493                 choices)
 494           | Symbol (symb, _) -> DisambiguateChoices.lookup_symbol_choices symb
 495           | Num instance -> DisambiguateChoices.lookup_num_choices ()
 496         in
 497         if choices = [] then raise (No_choices item);
 498         choices
 499       in
 500
 501 (*
 502       (* <benchmark> *)
 503       let _ =
 504         if benchmark then begin
 505           let per_item_choices =
 506             List.map
 507               (fun dom_item ->
 508                 try
 509                   let len = List.length (lookup_choices dom_item) in
 510                   prerr_endline (sprintf "BENCHMARK %s: %d"
 511                     (string_of_domain_item dom_item) len);
 512                   len
 513                 with No_choices _ -> 0)
 514               term_dom
 515           in
 516           max_refinements := List.fold_left ( * ) 1 per_item_choices;
 517           actual_refinements := 0;
 518           domain_size := List.length term_dom;
 519           choices_avg :=
 520             (float_of_int !max_refinements) ** (1. /. float_of_int !domain_size)
 521         end
 522       in
 523       (* </benchmark> *)
 524 *)
 525
 526       (* (3) test an interpretation filling with meta uninterpreted identifiers
 527        *)
 528       let test_env current_env todo_dom ugraph =
 529         let filled_env =
 530           List.fold_left
 531             (fun env item ->
 532                Environment.add item
 533                ("Implicit",
 534                  (match item with
 535                     | Id _ | Num _ -> (fun _ _ _ -> Cic.Implicit (Some `Closed))
 536                     | Symbol _ -> (fun _ _ _ -> Cic.Implicit None))) env)
 537             current_env todo_dom
 538         in
 539         try
 540           let cic_term =
 541             interpretate ~context:disambiguate_context ~env:filled_env term
 542           in
 543           let k,ugraph1 = refine metasenv context cic_term ugraph in
 544             (k , ugraph1 )
 545         with
 546         | Try_again -> Uncertain,ugraph
 547         | DisambiguateChoices.Invalid_choice -> Ko,ugraph
 548       in
 549       (* (4) build all possible interpretations *)
 550       let rec aux current_env todo_dom base_univ =
 551         match todo_dom with
 552         | [] ->
 553             (match test_env current_env [] base_univ with
 554             | Ok (term, metasenv),new_univ ->
 555                                [ current_env, metasenv, term, new_univ ]
 556             | Ko,_ | Uncertain,_ -> [])
 557         | item :: remaining_dom ->
 558             debug_print (sprintf "CHOOSED ITEM: %s"
 559              (string_of_domain_item item));
 560             let choices = lookup_choices item in
 561             let rec filter univ = function
 562               | [] -> []
 563               | codomain_item :: tl ->
 564                   debug_print (sprintf "%s CHOSEN" (fst codomain_item)) ;
 565                   let new_env =
 566                     Environment.add item codomain_item current_env
 567                   in
 568                   (match test_env new_env remaining_dom univ with
 569                   | Ok (term, metasenv),new_univ ->
 570                       (match remaining_dom with
 571                       | [] -> [ new_env, metasenv, term, new_univ ]
 572                       | _ -> aux new_env remaining_dom new_univ )@
 573                         filter univ tl
 574                   | Uncertain,new_univ ->
 575                       (match remaining_dom with
 576                       | [] -> []
 577                       | _ -> aux new_env remaining_dom new_univ )@
 578                         filter univ tl
 579                   | Ko,_ -> filter univ tl)
 580             in
 581             filter base_univ choices
 582       in
 583       let base_univ = initial_ugraph in
 584       try
 585         let res =
 586          match aux current_env todo_dom base_univ with
 587          | [] -> raise NoWellTypedInterpretation
 588          | [ e,me,t,u ] as l ->
 589              debug_print "UNA SOLA SCELTA";
 590              [ e,me,t,u]
 591          | l ->
 592              debug_print (sprintf "PIU' SCELTE (%d)" (List.length l));
 593              let choices =
 594                List.map
 595                  (fun (env, _, _, _) ->
 596                    List.map
 597                      (fun domain_item ->
 598                        let description =
 599                          fst (Environment.find domain_item env)
 600                        in
 601                        (descr_of_domain_item domain_item, description))
 602                      term_dom)
 603                  l
 604              in
 605              let choosed = C.interactive_interpretation_choice choices in
 606              List.map (List.nth l) choosed
 607         in
 608 (*
 609         (if benchmark then
 610           let res_size = List.length res in
 611           prerr_endline (sprintf
 612             ("BENCHMARK: %d/%d refinements performed, domain size %d, interps %d, k %.2f\n" ^^
 613             "BENCHMARK:   estimated %.2f")
 614             !actual_refinements !max_refinements !domain_size res_size
 615             !choices_avg
 616             (float_of_int (!domain_size - 1) *. !choices_avg *. (float_of_int res_size) +. !choices_avg)));
 617 *)
 618         res
 619      with
 620       CicEnvironment.CircularDependency s ->
 621         failwith "Disambiguate: circular dependency"
 622   end
 623
 624 module Trivial =
 625 struct
 626   exception Ambiguous_term of string
 627   exception Exit
 628   module Callbacks =
 629   struct
 630     let interactive_user_uri_choice ~selection_mode ?ok
 631           ?(enable_button_for_non_vars = true) ~title ~msg ~id uris =
 632               raise Exit
 633     let interactive_interpretation_choice interp = raise Exit
 634     let input_or_locate_uri ~(title:string) ?id = raise Exit
 635   end
 636   module Disambiguator = Make (Callbacks)
 637   let disambiguate_string ~dbd ?(context=[]) ?(metasenv=[]) ?initial_ugraph
 638         ?(aliases=DisambiguateTypes.Environment.empty) term =
 639     let ast = CicTextualParser2.parse_term (Stream.of_string term) in
 640     try
 641       Disambiguator.disambiguate_term ~dbd ~context ~metasenv ast
 642         ?initial_ugraph ~aliases
 643     with Exit -> raise (Ambiguous_term term)
 644 end
 645