helm/ocaml/cic_disambiguation/disambiguate.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open DisambiguateTypes
  29 open UriManager
  30
  31 exception No_choices of domain_item
  32 exception NoWellTypedInterpretation
  33
  34   (** raised when an environment is not enough informative to decide *)
  35 exception Try_again
  36
  37 let debug = true
  38 let debug_print = if debug then prerr_endline else ignore
  39
  40 let descr_of_domain_item = function
  41  | Id s -> s
  42  | Symbol (s, _) -> s
  43  | Num i -> string_of_int i
  44
  45 type test_result =
  46   | Ok of Cic.term * Cic.metasenv
  47   | Ko
  48   | Uncertain
  49
  50 let refine metasenv context term =
  51   let metasenv, term = CicMkImplicit.expand_implicits metasenv context term in
  52   debug_print (sprintf "TEST_INTERPRETATION: %s" (CicPp.ppterm term));
  53   try
  54     let term', _, metasenv' = CicRefine.type_of_aux' metasenv context term in
  55     Ok (term', metasenv')
  56   with
  57     | CicRefine.Uncertain _ ->
  58         debug_print ("%%% UNCERTAIN!!! " ^ CicPp.ppterm term) ;
  59         Uncertain
  60     | _ ->
  61         (* TODO we should catch only the RefineFailure excecption *)
  62         debug_print ("%%% PRUNED!!! " ^ CicPp.ppterm term) ;
  63         Ko
  64
  65 let resolve (env: environment) (item: domain_item) ?(num = "") ?(args = []) () =
  66   try
  67     snd (Environment.find item env) env num args
  68   with Not_found -> assert false
  69
  70   (* TODO move it to Cic *)
  71 let find_in_environment name context =
  72   let rec aux acc = function
  73     | [] -> raise Not_found
  74     | Cic.Name hd :: tl when hd = name -> acc
  75     | _ :: tl ->  aux (acc + 1) tl
  76   in
  77   aux 1 context
  78
  79 let interpretate ~context ~env ast =
  80   let rec aux loc context = function
  81     | CicAst.AttributedTerm (`Loc loc, term) ->
  82         aux loc context term
  83     | CicAst.AttributedTerm (_, term) -> aux loc context term
  84     | CicAst.Appl (CicAst.Symbol (symb, i) :: args) ->
  85         let cic_args = List.map (aux loc context) args in
  86         resolve env (Symbol (symb, i)) ~args:cic_args ()
  87     | CicAst.Appl terms -> Cic.Appl (List.map (aux loc context) terms)
  88     | CicAst.Binder (binder_kind, (var, typ), body) ->
  89         let cic_type = aux_option loc context typ in
  90         let cic_body = aux loc (var :: context) body in
  91         (match binder_kind with
  92         | `Lambda -> Cic.Lambda (var, cic_type, cic_body)
  93         | `Pi | `Forall -> Cic.Prod (var, cic_type, cic_body)
  94         | `Exists ->
  95             resolve env (Symbol ("exists", 0))
  96               ~args:[ cic_type; Cic.Lambda (var, cic_type, cic_body) ] ())
  97     | CicAst.Case (term, indty_ident, outtype, branches) ->
  98         let cic_term = aux loc context term in
  99         let cic_outtype = aux_option loc context outtype in
 100         let do_branch ((head, args), term) =
 101           let rec do_branch' context = function
 102             | [] -> aux loc context term
 103             | (name, typ) :: tl ->
 104                 let cic_body = do_branch' (name :: context) tl in
 105                 let typ =
 106                   match typ with
 107                   | None -> Cic.Implicit (Some `Type)
 108                   | Some typ -> aux loc context typ
 109                 in
 110                 Cic.Lambda (name, typ, cic_body)
 111           in
 112           do_branch' context args
 113         in
 114         let (indtype_uri, indtype_no) =
 115           match indty_ident with
 116           | Some indty_ident ->
 117               (match resolve env (Id indty_ident) () with
 118               | Cic.MutInd (uri, tyno, _) -> (uri, tyno)
 119               | Cic.Implicit _ -> raise Try_again
 120               | _ -> raise DisambiguateChoices.Invalid_choice)
 121           | None ->
 122               let fst_constructor =
 123                 match branches with
 124                 | ((head, _), _) :: _ -> head
 125                 | [] -> raise DisambiguateChoices.Invalid_choice
 126               in
 127               (match resolve env (Id fst_constructor) () with
 128               | Cic.MutConstruct (indtype_uri, indtype_no, _, _) ->
 129                   (indtype_uri, indtype_no)
 130               | Cic.Implicit _ -> raise Try_again
 131               | _ -> raise DisambiguateChoices.Invalid_choice)
 132         in
 133         Cic.MutCase (indtype_uri, indtype_no, cic_outtype, cic_term,
 134           (List.map do_branch branches))
 135     | CicAst.LetIn ((name, typ), def, body) ->
 136         let cic_def = aux loc context def in
 137         let cic_def =
 138           match typ with
 139           | None -> cic_def
 140           | Some t -> Cic.Cast (cic_def, aux loc context t)
 141         in
 142         let cic_body = aux loc (name :: context) body in
 143         Cic.LetIn (name, cic_def, cic_body)
 144     | CicAst.LetRec (kind, defs, body) ->
 145         let context' =
 146           List.fold_left (fun acc ((name, _), _, _) -> name :: acc)
 147             context defs
 148         in
 149         let cic_body = aux loc context' body in
 150         let inductiveFuns =
 151           List.map
 152             (fun ((name, typ), body, decr_idx) ->
 153               let cic_body = aux loc context' body in
 154               let cic_type = aux_option loc context typ in
 155               let name =
 156                 match name with
 157                 | Cic.Anonymous ->
 158                     CicTextualParser2.fail loc
 159                       "Recursive functions cannot be anonymous"
 160                 | Cic.Name name -> name
 161               in
 162               (name, decr_idx, cic_type, cic_body))
 163             defs
 164         in
 165         let counter = ref ~-1 in
 166         let build_term funs =
 167           (* this is the body of the fold_right function below. Rationale: Fix
 168            * and CoFix cases differs only in an additional index in the
 169            * inductiveFun list, see Cic.term *)
 170           match kind with
 171           | `Inductive ->
 172               (fun (var, _, _, _) cic ->
 173                 incr counter;
 174                 Cic.LetIn (Cic.Name var, Cic.Fix (!counter, funs), cic))
 175           | `CoInductive ->
 176               let funs =
 177                 List.map (fun (name, _, typ, body) -> (name, typ, body)) funs
 178               in
 179               (fun (var, _, _, _) cic ->
 180                 incr counter;
 181                 Cic.LetIn (Cic.Name var, Cic.CoFix (!counter, funs), cic))
 182         in
 183         List.fold_right (build_term inductiveFuns) inductiveFuns cic_body
 184     | CicAst.Ident (name, subst) ->
 185         (try
 186           let index = find_in_environment name context in
 187           if subst <> None then
 188             CicTextualParser2.fail loc
 189               "Explicit substitutions not allowed here";
 190           Cic.Rel index
 191         with Not_found ->
 192           let cic = resolve env (Id name) () in
 193           let mk_subst uris =
 194             let ids_to_uris =
 195               List.map (fun uri -> UriManager.name_of_uri uri, uri) uris
 196             in
 197             (match subst with
 198             | Some subst ->
 199                 List.map
 200                   (fun (s, term) ->
 201                     (try
 202                       List.assoc s ids_to_uris, aux loc context term
 203                      with Not_found ->
 204                        raise DisambiguateChoices.Invalid_choice))
 205                   subst
 206             | None -> List.map (fun uri -> uri, Cic.Implicit None) uris)
 207          in
 208           (match cic with
 209           | Cic.Const (uri, []) ->
 210               let uris =
 211                 match CicEnvironment.get_obj uri with
 212                 | Cic.Constant (_, _, _, uris) -> uris
 213                 | _ -> assert false
 214               in
 215               Cic.Const (uri, mk_subst uris)
 216           | Cic.Var (uri, []) ->
 217               let uris =
 218                 match CicEnvironment.get_obj uri with
 219                 | Cic.Variable (_, _, _, uris) -> uris
 220                 | _ -> assert false
 221               in
 222               Cic.Var (uri, mk_subst uris)
 223           | Cic.MutInd (uri, i, []) ->
 224               let uris =
 225                 match CicEnvironment.get_obj uri with
 226                 | Cic.InductiveDefinition (_, uris, _) -> uris
 227                 | _ -> assert false
 228               in
 229               Cic.MutInd (uri, i, mk_subst uris)
 230           | Cic.MutConstruct (uri, i, j, []) ->
 231               let uris =
 232                 match CicEnvironment.get_obj uri with
 233                 | Cic.InductiveDefinition (_, uris, _) -> uris
 234                 | _ -> assert false
 235               in
 236               Cic.MutConstruct (uri, i, j, mk_subst uris)
 237           | Cic.Meta _ | Cic.Implicit _ as t ->
 238 (*
 239               prerr_endline (sprintf
 240                 "Warning: %s must be instantiated with _[%s] but we do not enforce it"
 241                 (CicPp.ppterm t)
 242                 (String.concat "; "
 243                   (List.map
 244                     (fun (s, term) -> s ^ " := " ^ CicAstPp.pp_term term)
 245                     subst)));
 246 *)
 247               t
 248           | _ ->
 249               raise DisambiguateChoices.Invalid_choice))
 250     | CicAst.Implicit -> Cic.Implicit None
 251     | CicAst.Num (num, i) -> resolve env (Num i) ~num ()
 252     | CicAst.Meta (index, subst) ->
 253         let cic_subst =
 254           List.map
 255             (function None -> None | Some term -> Some (aux loc context term))
 256             subst
 257         in
 258         Cic.Meta (index, cic_subst)
 259     | CicAst.Sort `Prop -> Cic.Sort Cic.Prop
 260     | CicAst.Sort `Set -> Cic.Sort Cic.Set
 261     | CicAst.Sort `Type -> Cic.Sort Cic.Type
 262     | CicAst.Sort `CProp -> Cic.Sort Cic.CProp
 263     | CicAst.Symbol (symbol, instance) ->
 264         resolve env (Symbol (symbol, instance)) ()
 265   and aux_option loc context = function
 266     | None -> Cic.Implicit (Some `Type)
 267     | Some term -> aux loc context term
 268   in
 269   match ast with
 270   | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 271   | term -> aux (-1, -1) context term
 272
 273 let domain_of_term ~context ast =
 274     (* "aux" keeps domain in reverse order and doesn't care about duplicates.
 275      * Domain item more in deep in the list will be processed first.
 276      *)
 277   let rec aux loc context = function
 278     | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 279     | CicAst.AttributedTerm (_, term) -> aux loc context term
 280     | CicAst.Appl terms ->
 281         List.fold_left (fun dom term -> aux loc context term @ dom) [] terms
 282     | CicAst.Binder (kind, (var, typ), body) ->
 283         let kind_dom =
 284           match kind with
 285           | `Exists -> [ Symbol ("exists", 0) ]
 286           | _ -> []
 287         in
 288         let type_dom = aux_option loc context typ in
 289         let body_dom = aux loc (var :: context) body in
 290         body_dom @ type_dom @ kind_dom
 291     | CicAst.Case (term, indty_ident, outtype, branches) ->
 292         let term_dom = aux loc context term in
 293         let outtype_dom = aux_option loc context outtype in
 294         let do_branch ((head, args), term) =
 295           let (term_context, args_domain) =
 296             List.fold_left
 297               (fun (cont, dom) (name, typ) ->
 298                 (name :: cont,
 299                  (match typ with
 300                  | None -> dom
 301                  | Some typ -> aux loc cont typ @ dom)))
 302               (context, []) args
 303           in
 304           args_domain @ aux loc term_context term
 305         in
 306         let branches_dom =
 307           List.fold_left (fun dom branch -> do_branch branch @ dom) [] branches
 308         in
 309         branches_dom @ outtype_dom @ term_dom @
 310         (match indty_ident with None -> [] | Some ident -> [ Id ident ])
 311     | CicAst.LetIn ((var, typ), body, where) ->
 312         let body_dom = aux loc context body in
 313         let type_dom = aux_option loc context typ in
 314         let where_dom = aux loc (var :: context) where in
 315         where_dom @ type_dom @ body_dom
 316     | CicAst.LetRec (kind, defs, where) ->
 317         let context' =
 318           List.fold_left (fun acc ((var, typ), _, _) -> var :: acc)
 319             context defs
 320         in
 321         let where_dom = aux loc context' where in
 322         let defs_dom =
 323           List.fold_left
 324             (fun dom ((_, typ), body, _) ->
 325               aux loc context' body @ aux_option loc context typ)
 326             [] defs
 327         in
 328         where_dom @ defs_dom
 329     | CicAst.Ident (name, subst) ->
 330         (try
 331           let index = find_in_environment name context in
 332           if subst <> None then
 333             CicTextualParser2.fail loc
 334               "Explicit substitutions not allowed here"
 335           else
 336             []
 337         with Not_found ->
 338           (match subst with
 339           | None -> [Id name]
 340           | Some subst ->
 341               List.fold_left
 342                 (fun dom (_, term) ->
 343                   let dom' = aux loc context term in
 344                   dom' @ dom)
 345                 [Id name] subst))
 346     | CicAst.Implicit -> []
 347     | CicAst.Num (num, i) -> [ Num i ]
 348     | CicAst.Meta (index, local_context) ->
 349         List.fold_left (fun dom term -> aux_option loc context term @ dom) []
 350           local_context
 351     | CicAst.Sort _ -> []
 352     | CicAst.Symbol (symbol, instance) -> [ Symbol (symbol, instance) ]
 353
 354   and aux_option loc context = function
 355     | None -> []
 356     | Some t -> aux loc context t
 357   in
 358
 359     (* e.g. [5;1;1;1;2;3;4;1;2] -> [2;1;4;3;5] *)
 360   let rev_uniq =
 361     let module SortedItem =
 362       struct
 363         type t = DisambiguateTypes.domain_item
 364         let compare = Pervasives.compare
 365       end
 366     in
 367     let module Set = Set.Make (SortedItem) in
 368     fun l ->
 369       let rev_l = List.rev l in
 370       let (_, uniq_rev_l) =
 371         List.fold_left
 372           (fun (members, rev_l) elt ->
 373             if Set.mem elt members then
 374               (members, rev_l)
 375             else
 376               Set.add elt members, elt :: rev_l)
 377           (Set.empty, []) rev_l
 378       in
 379       List.rev uniq_rev_l
 380   in
 381
 382   rev_uniq
 383     (match ast with
 384     | CicAst.AttributedTerm (`Loc loc, term) -> aux loc context term
 385     | term -> aux (-1, -1) context term)
 386
 387
 388   (* dom1 \ dom2 *)
 389 let domain_diff dom1 dom2 =
 390 (* let domain_diff = Domain.diff *)
 391   let is_in_dom2 =
 392     List.fold_left (fun pred elt -> (fun elt' -> elt' = elt || pred elt'))
 393       (fun _ -> false) dom2
 394   in
 395   List.filter (fun elt -> not (is_in_dom2 elt)) dom1
 396
 397 module Make (C: Callbacks) =
 398   struct
 399     let choices_of_id mqi_handle id =
 400      let query  =  MQueryGenerator.locate id in
 401      let result = MQueryInterpreter.execute mqi_handle query in
 402      let uris =
 403       List.map
 404        (function uri,_ ->
 405          MQueryMisc.wrong_xpointer_format_from_wrong_xpointer_format' uri
 406        ) result in
 407       HelmLogger.log (`Msg (`T "Locate query:"));
 408       MQueryUtil.text_of_query
 409        (fun s -> HelmLogger.log ~append_NL:false (`Msg (`T s)))
 410        "" query;
 411       HelmLogger.log (`Msg (`T "Result:"));
 412       MQueryUtil.text_of_result
 413         (fun s -> HelmLogger.log (`Msg (`T s))) "" result;
 414       let uris' =
 415        match uris with
 416         | [] ->
 417            [UriManager.string_of_uri (C.input_or_locate_uri
 418             ~title:("URI matching \"" ^ id ^ "\" unknown."))]
 419         | [uri] -> [uri]
 420         | _ ->
 421             C.interactive_user_uri_choice ~selection_mode:`MULTIPLE
 422              ~ok:"Try selected." ~enable_button_for_non_vars:true
 423              ~title:"Ambiguous input." ~id
 424              ~msg: ("Ambiguous input \"" ^ id ^
 425                 "\". Please, choose one or more interpretations:")
 426              uris
 427       in
 428       List.map
 429         (fun uri ->
 430           (uri,
 431            let term =
 432              try
 433                HelmLibraryObjects.term_of_uri (UriManager.uri_of_string uri)
 434              with _ -> assert false
 435             in
 436            fun _ _ _ -> term))
 437         uris'
 438
 439     let disambiguate_term mqi_handle context metasenv term ~aliases:current_env
 440     =
 441       debug_print "NEW DISAMBIGUATE INPUT";
 442       let disambiguate_context =  (* cic context -> disambiguate context *)
 443         List.map
 444           (function None -> Cic.Anonymous | Some (name, _) -> name)
 445           context
 446       in
 447       let term_dom = domain_of_term ~context:disambiguate_context term in
 448       debug_print (sprintf "DISAMBIGUATION DOMAIN: %s"
 449         (string_of_domain term_dom));
 450       let current_dom =
 451         Environment.fold (fun item _ dom -> item :: dom) current_env []
 452       in
 453       let todo_dom = domain_diff term_dom current_dom in
 454       (* (2) lookup function for any item (Id/Symbol/Num) *)
 455       let lookup_choices =
 456         let id_choices = Hashtbl.create 1023 in
 457         fun item ->
 458         let choices =
 459           match item with
 460           | Id id ->
 461               (try
 462                 Hashtbl.find id_choices id
 463               with Not_found ->
 464                 let choices = choices_of_id mqi_handle id in
 465                 Hashtbl.add id_choices id choices;
 466                 choices)
 467           | Symbol (symb, _) -> DisambiguateChoices.lookup_symbol_choices symb
 468           | Num instance -> DisambiguateChoices.lookup_num_choices ()
 469         in
 470         if choices = [] then raise (No_choices item);
 471         choices
 472       in
 473       (* (3) test an interpretation filling with meta uninterpreted identifiers
 474        *)
 475       let test_env current_env todo_dom =
 476         let filled_env =
 477           List.fold_left
 478             (fun env item ->
 479               Environment.add item
 480                 ("Implicit",
 481                  (match item with
 482                  | Id _ | Num _ -> (fun _ _ _ -> Cic.Implicit (Some `Closed))
 483                  | Symbol _ -> (fun _ _ _ -> Cic.Implicit None))) env)
 484             current_env todo_dom
 485         in
 486         try
 487           let cic_term =
 488             interpretate ~context:disambiguate_context ~env:filled_env term
 489           in
 490           refine metasenv context cic_term
 491         with
 492         | Try_again -> Uncertain
 493         | DisambiguateChoices.Invalid_choice -> Ko
 494       in
 495       (* (4) build all possible interpretations *)
 496       let rec aux current_env todo_dom =
 497         match todo_dom with
 498         | [] ->
 499             (match test_env current_env [] with
 500             | Ok (term, metasenv) -> [ current_env, metasenv, term ]
 501             | Ko | Uncertain -> [])
 502         | item :: remaining_dom ->
 503             debug_print (sprintf "CHOOSED ITEM: %s"
 504               (string_of_domain_item item));
 505             let choices = lookup_choices item in
 506             let rec filter = function
 507               | [] -> []
 508               | codomain_item :: tl ->
 509                   debug_print (sprintf "%s CHOSEN" (fst codomain_item)) ;
 510                   let new_env =
 511                     Environment.add item codomain_item current_env
 512                   in
 513                   (match test_env new_env remaining_dom with
 514                   | Ok (term, metasenv) ->
 515                       (match remaining_dom with
 516                       | [] -> [ new_env, metasenv, term ]
 517                       | _ -> aux new_env remaining_dom) @ filter tl
 518                   | Uncertain ->
 519                       (match remaining_dom with
 520                       | [] -> []
 521                       | _ -> aux new_env remaining_dom) @ filter tl
 522                   | Ko -> filter tl)
 523             in
 524             filter choices
 525       in
 526        match aux current_env todo_dom with
 527        | [] -> raise NoWellTypedInterpretation
 528        | [ _ ] as l ->
 529            debug_print "UNA SOLA SCELTA";
 530            l
 531        | l ->
 532            debug_print (sprintf "PIU' SCELTE (%d)" (List.length l));
 533            let choices =
 534              List.map
 535                (fun (env, _, _) ->
 536                  List.map
 537                    (fun domain_item ->
 538                      let description =
 539                        fst (Environment.find domain_item env)
 540                      in
 541                      (descr_of_domain_item domain_item, description))
 542                    term_dom)
 543                l
 544            in
 545            let choosed = C.interactive_interpretation_choice choices in
 546             List.map (List.nth l) choosed
 547
 548   end
 549