helm/ocaml/cic_notation/cicNotationLexer.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 exception Error of int * int * string
  29
  30 let regexp number = xml_digit+
  31
  32 let regexp ident_decoration = '\'' | '!' | '?' | '`'
  33 let regexp ident_cont = xml_letter | xml_digit | '_'
  34 let regexp ident = xml_letter ident_cont* ident_decoration*
  35
  36 let regexp tex_token = '\\' ident
  37
  38 let regexp delim_begin = "\\["
  39 let regexp delim_end = "\\]"
  40
  41 let regexp keyword = '"' ident '"'
  42
  43 let regexp implicit = '?'
  44 let regexp meta = implicit number
  45
  46 let regexp uri =
  47   ("cic:/" | "theory:/")              (* schema *)
  48   ident ('/' ident)*                  (* path *)
  49   ('.' ident)+                        (* ext *)
  50   ("#xpointer(" number ('/' number)+ ")")?  (* xpointer *)
  51
  52 let error lexbuf msg =
  53   let begin_cnum, end_cnum = Ulexing.loc lexbuf in
  54   raise (Error (begin_cnum, end_cnum, msg))
  55 let error_at_end lexbuf msg =
  56   let begin_cnum, end_cnum = Ulexing.loc lexbuf in
  57   raise (Error (begin_cnum, end_cnum, msg))
  58
  59 let return lexbuf token =
  60   let begin_cnum, end_cnum = Ulexing.loc lexbuf in
  61   (* TODO handle line/column numbers *)
  62   let flocation_begin =
  63     { Lexing.pos_fname = "";
  64       Lexing.pos_lnum = -1; Lexing.pos_bol = -1;
  65       Lexing.pos_cnum = begin_cnum }
  66   in
  67   let flocation_end = { flocation_begin with Lexing.pos_cnum = end_cnum } in
  68   (token, (flocation_begin, flocation_end))
  69
  70 let return_lexeme lexbuf name = return lexbuf (name, Ulexing.utf8_lexeme lexbuf)
  71
  72 let remove_quotes s = String.sub s 1 (String.length s - 2)
  73
  74 let mk_lexer token =
  75   let tok_func stream =
  76     let lexbuf = Ulexing.from_utf8_stream stream in
  77     Token.make_stream_and_flocation
  78       (fun () ->
  79         try
  80           token lexbuf
  81         with
  82         | Ulexing.Error -> error_at_end lexbuf "Unexpected character"
  83         | Ulexing.InvalidCodepoint p ->
  84             error_at_end lexbuf (sprintf "Invalid code point: %d" p))
  85   in
  86   {
  87     Token.tok_func = tok_func;
  88     Token.tok_using = (fun _ -> ());
  89     Token.tok_removing = (fun _ -> ());
  90     Token.tok_match = Token.default_match;
  91     Token.tok_text = Token.lexer_text;
  92     Token.tok_comm = None;
  93   }
  94
  95 let expand_macro lexbuf =
  96   let macro =
  97     Ulexing.utf8_sub_lexeme lexbuf 1 (Ulexing.lexeme_length lexbuf - 1)
  98   in
  99   try
 100     ("SYMBOL", Utf8Macro.expand macro)
 101   with Utf8Macro.Macro_not_found _ -> "SYMBOL", Ulexing.utf8_lexeme lexbuf
 102
 103 let keyword lexbuf = "KEYWORD", remove_quotes (Ulexing.utf8_lexeme lexbuf)
 104
 105 let rec token = lexer
 106   | xml_blank+ -> token lexbuf
 107   | meta -> return lexbuf ("META", Ulexing.utf8_lexeme lexbuf)
 108   | implicit -> return lexbuf ("IMPLICIT", Ulexing.utf8_lexeme lexbuf)
 109   | ident -> return lexbuf ("IDENT", Ulexing.utf8_lexeme lexbuf)
 110   | number -> return lexbuf ("NUMBER", Ulexing.utf8_lexeme lexbuf)
 111   | keyword -> return lexbuf (keyword lexbuf)
 112   | delim_begin -> return lexbuf ("DELIM", Ulexing.utf8_lexeme lexbuf)
 113   | delim_end -> return lexbuf ("DELIM",  Ulexing.utf8_lexeme lexbuf)
 114   | tex_token -> return lexbuf (expand_macro lexbuf)
 115   | uri -> return lexbuf ("URI", Ulexing.utf8_lexeme lexbuf)
 116   | eof -> return lexbuf ("EOI", "")
 117   | _ -> return lexbuf ("SYMBOL", Ulexing.utf8_lexeme lexbuf)
 118
 119 (* API implementation *)
 120
 121 let notation_lexer = mk_lexer token
 122