helm/ocaml/cic_notation/cicNotationMatcher.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 module Pp = CicNotationPp
  29 module Pt = CicNotationPt
  30 module Env = CicNotationEnv
  31 module Util = CicNotationUtil
  32
  33 type pattern_id = int
  34
  35 exception No_match
  36
  37 module OrderedInt =
  38 struct
  39   type t = int
  40   let compare (x1:t) (x2:t) = Pervasives.compare x2 x1  (* reverse order *)
  41 end
  42
  43 module IntSet = Set.Make (OrderedInt)
  44
  45 let int_set_of_int_list l =
  46   List.fold_left (fun acc i -> IntSet.add i acc) IntSet.empty l
  47
  48 type pattern_kind = Variable | Constructor
  49 type tag_t = int
  50
  51 module type PATTERN =
  52 sig
  53   type pattern_t
  54   type term_t
  55   val classify : pattern_t -> pattern_kind
  56   val tag_of_pattern : pattern_t -> tag_t * pattern_t list
  57   val tag_of_term : term_t -> tag_t * term_t list
  58 end
  59
  60 module Matcher (P: PATTERN) =
  61 struct
  62   type row_t = P.pattern_t list * P.pattern_t list * pattern_id
  63   type t = row_t list
  64
  65   let compatible p1 p2 = P.classify p1 = P.classify p2
  66
  67   let matched = List.map (fun (matched, _, pid) -> matched, pid)
  68
  69   let partition t pidl =
  70     let partitions = Hashtbl.create 11 in
  71     let add pid row = Hashtbl.add partitions pid row in
  72     (try
  73       List.iter2 add pidl t
  74     with Invalid_argument _ -> assert false);
  75     let pidset = int_set_of_int_list pidl in
  76     IntSet.fold
  77       (fun pid acc ->
  78         match Hashtbl.find_all partitions pid with
  79         | [] -> acc
  80         | patterns -> (pid, List.rev patterns) :: acc)
  81       pidset []
  82
  83   let are_empty t =
  84     match t with
  85     | (_, [], _) :: _ -> true
  86       (* if first row has an empty list of patterns, then others have as well *)
  87     | _ -> false
  88
  89     (* return 2 lists of rows, first one containing homogeneous rows according
  90      * to "compatible" below *)
  91   let horizontal_split t =
  92     let ap, first_row, t', first_row_class =
  93       match t with
  94       | [] -> assert false
  95       | (_, [], _) :: _ ->
  96           assert false  (* are_empty should have been invoked in advance *)
  97       | ((_, hd :: _ , _) as row) :: tl -> hd, row, tl, P.classify hd
  98     in
  99     let rec aux prev_t = function
 100       | [] -> List.rev prev_t, []
 101       | (_, [], _) :: _ -> assert false
 102       | ((_, hd :: _, _) as row) :: tl when compatible ap hd ->
 103           aux (row :: prev_t) tl
 104       | t -> List.rev prev_t, t
 105     in
 106     let rows1, rows2 = aux [first_row] t' in
 107     first_row_class, rows1, rows2
 108
 109     (* return 2 lists, first one representing first column, second one
 110      * representing a new pattern matrix where matched patterns have been moved
 111      * to decl *)
 112   let vertical_split t =
 113     List.map
 114       (function
 115         | decls, hd :: tl, pid -> hd :: decls, tl, pid
 116         | _ -> assert false)
 117       t
 118
 119   let variable_closure k =
 120     (fun matched_terms terms ->
 121       match terms with
 122       | hd :: tl -> k (hd :: matched_terms) tl
 123       | _ -> assert false)
 124
 125   let success_closure ks k =
 126     (fun matched_terms terms ->
 127        match ks matched_terms with
 128            None ->
 129              begin
 130                (* the match has failed, we rollback the last matched term
 131                 * into the unmatched ones and call the failure continuation
 132                 *)
 133                match matched_terms with
 134                    hd :: tl -> k tl (hd :: terms)
 135                  | _ -> assert false
 136              end
 137          | Some v -> Some v)
 138
 139   let constructor_closure ks k =
 140     (fun matched_terms terms ->
 141       match terms with
 142       | t :: tl ->
 143           (try
 144             let tag, subterms = P.tag_of_term t in
 145             let k' = List.assoc tag ks in
 146             k' matched_terms (subterms @ tl)
 147           with Not_found -> k matched_terms terms)
 148       | [] -> assert false)
 149
 150   let compiler rows match_cb fail_k =
 151     let rec aux t k =
 152       if t = [] then
 153         k
 154       else if are_empty t then
 155         success_closure (match_cb (matched t)) k
 156       else
 157         match horizontal_split t with
 158         | _, [], _ -> assert false
 159         | Variable, t', [] -> variable_closure (aux (vertical_split t') k)
 160         | Constructor, t', [] ->
 161             let tagl =
 162               List.map
 163                 (function
 164                   | _, p :: _, _ -> fst (P.tag_of_pattern p)
 165                   | _ -> assert false)
 166                 t'
 167             in
 168             let clusters = partition t' tagl in
 169             let ks =
 170               List.map
 171                 (fun (tag, cluster) ->
 172                   let cluster' =
 173                     List.map  (* add args as patterns heads *)
 174                       (function
 175                         | matched_p, p :: tl, pid ->
 176                             let _, subpatterns = P.tag_of_pattern p in
 177                             matched_p, subpatterns @ tl, pid
 178                         | _ -> assert false)
 179                       cluster
 180                   in
 181                   tag, aux cluster' k)
 182                 clusters
 183             in
 184             constructor_closure ks k
 185         | _, t', t'' -> aux t' (aux t'' k)
 186     in
 187     let t = List.map (fun (p, pid) -> [], [p], pid) rows in
 188     let matcher = aux t (fun _ _ -> fail_k ()) in
 189     (fun term -> matcher [] [term])
 190 end
 191
 192 module Matcher21 =
 193 struct
 194   module Pattern21 =
 195   struct
 196     type pattern_t = Pt.term
 197     type term_t = Pt.term
 198     let classify = function
 199       | Pt.Variable _ -> Variable
 200       | Pt.Magic _
 201       | Pt.Layout _
 202       | Pt.Literal _ as t -> assert false
 203       | _ -> Constructor
 204     let tag_of_pattern = CicNotationTag.get_tag
 205     let tag_of_term = CicNotationTag.get_tag
 206   end
 207
 208   module M = Matcher (Pattern21)
 209
 210   let extract_magic term =
 211     let magic_map = ref [] in
 212     let add_magic m =
 213       let name = Util.fresh_name () in
 214       magic_map := (name, m) :: !magic_map;
 215       Pt.Variable (Pt.TermVar name)
 216     in
 217     let rec aux = function
 218       | Pt.AttributedTerm (_, t) -> assert false
 219       | Pt.Literal _
 220       | Pt.Layout _ -> assert false
 221       | Pt.Variable v -> Pt.Variable v
 222       | Pt.Magic m -> add_magic m
 223       | t -> Util.visit_ast aux t
 224     in
 225     let term' = aux term in
 226     term', !magic_map
 227
 228   let env_of_matched pl tl =
 229     List.map2
 230       (fun p t ->
 231         match p, t with
 232           Pt.Variable (Pt.TermVar name), _ ->
 233             name, (Env.TermType, Env.TermValue t)
 234         | Pt.Variable (Pt.NumVar name), (Pt.Num (s, _)) ->
 235             name, (Env.NumType, Env.NumValue s)
 236         | Pt.Variable (Pt.IdentVar name), (Pt.Ident (s, None)) ->
 237             name, (Env.StringType, Env.StringValue s)
 238         | _ -> assert false)
 239       pl tl
 240
 241   let rec compiler rows =
 242     let rows', magic_maps =
 243       List.split
 244         (List.map
 245           (fun (p, pid) ->
 246             let p', map = extract_magic p in
 247             (p', pid), (pid, map))
 248           rows)
 249     in
 250     let magichecker map =
 251       List.fold_left
 252         (fun f (name, m) ->
 253           let m_checker = compile_magic m in
 254           (fun env ->
 255             match m_checker (Env.lookup_term env name) env with
 256             | None -> None
 257             | Some env' ->
 258                 f env'))
 259         (fun env -> Some env)
 260         map
 261     in
 262     let magichooser candidates =
 263       List.fold_left
 264         (fun f (pid, pl, checker) ->
 265           (fun matched_terms ->
 266             let env = env_of_matched pl matched_terms in
 267             match checker env with
 268             | None -> f matched_terms
 269             | Some env ->
 270                 let magic_map =
 271                   try List.assoc pid magic_maps with Not_found -> assert false
 272                 in
 273                 let env' = Env.remove_names env (List.map fst magic_map) in
 274                 Some (env', pid)))
 275         (fun _ -> None)
 276         (List.rev candidates)
 277     in
 278     let match_cb rows =
 279       let candidates =
 280         List.map
 281           (fun (pl, pid) ->
 282             let magic_map =
 283               try List.assoc pid magic_maps with Not_found -> assert false
 284             in
 285             pid, pl, magichecker magic_map)
 286           rows
 287       in
 288         magichooser candidates
 289     in
 290     M.compiler rows' match_cb (fun _ -> None)
 291
 292   and compile_magic = function
 293     | Pt.Fold (kind, p_base, names, p_rec) ->
 294         let p_rec_decls = Env.declarations_of_term p_rec in
 295           (* LUCA: p_rec_decls should not contain "names" *)
 296         let acc_name = try List.hd names with Failure _ -> assert false in
 297         let compiled_base = compiler [p_base, 0]
 298         and compiled_rec = compiler [p_rec, 0] in
 299           (fun term env ->
 300              let aux_base term =
 301                match compiled_base term with
 302                  | None -> None
 303                  | Some (env', _) -> Some (env', [])
 304              in
 305              let rec aux term =
 306                match compiled_rec term with
 307                  | None -> aux_base term
 308                  | Some (env', _) ->
 309                      begin
 310                        let acc = Env.lookup_term env' acc_name in
 311                        let env'' = Env.remove_name env' acc_name in
 312                          match aux acc with
 313                            | None -> aux_base term
 314                            | Some (base_env, rec_envl) ->
 315                                Some (base_env, env'' :: rec_envl)
 316                      end
 317              in
 318                match aux term with
 319                  | None -> None
 320                  | Some (base_env, rec_envl) ->
 321                      Some (base_env @ Env.coalesce_env p_rec_decls rec_envl @ env)) (* @ env LUCA!!! *)
 322
 323     | Pt.Default (p_some, p_none) ->  (* p_none can't bound names *)
 324         let p_some_decls = Env.declarations_of_term p_some in
 325         let none_env = List.map Env.opt_binding_of_name p_some_decls in
 326         let compiled = compiler [p_some, 0] in
 327         (fun term env ->
 328           match compiled term with
 329           | None -> Some none_env (* LUCA: @ env ??? *)
 330           | Some (env', 0) -> Some (List.map Env.opt_binding_some env' @ env)
 331           | _ -> assert false)
 332
 333     | Pt.If (p_test, p_true, p_false) ->
 334         let compiled_test = compiler [p_test, 0]
 335         and compiled_true = compiler [p_true, 0]
 336         and compiled_false = compiler [p_false, 0] in
 337           (fun term env ->
 338              let branch =
 339                match compiled_test term with
 340                  | None -> compiled_false
 341                  | Some _ -> compiled_true
 342              in
 343                match branch term with
 344                  | None -> None
 345                  | Some (env', _) -> Some (env' @ env))
 346
 347     | Pt.Fail -> (fun _ _ -> None)
 348
 349     | _ -> assert false
 350 end
 351
 352 module Matcher32 =
 353 struct
 354   module Pattern32 =
 355   struct
 356     type cic_mask_t =
 357       Blob
 358     | Uri of UriManager.uri
 359     | Appl of cic_mask_t list
 360
 361     let uri_of_term t = CicUtil.uri_of_term (Deannotate.deannotate_term t)
 362
 363     let mask_of_cic = function
 364       | Cic.AAppl (_, tl) -> Appl (List.map (fun _ -> Blob) tl), tl
 365       | Cic.AConst (_, _, [])
 366       | Cic.AVar (_, _, [])
 367       | Cic.AMutInd (_, _, _, [])
 368       | Cic.AMutConstruct (_, _, _, _, []) as t -> Uri (uri_of_term t), []
 369       | _ -> Blob, []
 370
 371     let tag_of_term t =
 372       let mask, tl = mask_of_cic t in
 373       Hashtbl.hash mask, tl
 374
 375     let mask_of_appl_pattern = function
 376       | Pt.UriPattern uri -> Uri uri, []
 377       | Pt.VarPattern _ -> Blob, []
 378       | Pt.ApplPattern pl -> Appl (List.map (fun _ -> Blob) pl), pl
 379
 380     let tag_of_pattern p =
 381       let mask, pl = mask_of_appl_pattern p in
 382       Hashtbl.hash mask, pl
 383
 384     type pattern_t = Pt.cic_appl_pattern
 385     type term_t = Cic.annterm
 386
 387     let classify = function
 388       | Pt.VarPattern _ -> Variable
 389       | _ -> Constructor
 390   end
 391
 392   module M = Matcher (Pattern32)
 393
 394   let compiler rows =
 395     let match_cb rows =
 396       let pl, pid = try List.hd rows with Not_found -> assert false in
 397       (fun matched_terms ->
 398         let env =
 399           List.map2
 400             (fun p t ->
 401               match p with
 402               | Pt.VarPattern name -> name, t
 403               | _ -> assert false)
 404             pl matched_terms
 405         in
 406         Some (env, pid))
 407     in
 408     M.compiler rows match_cb (fun () -> None)
 409 end
 410