helm/ocaml/cic_notation/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 module Ast = CicNotationPt
  29 module Env = CicNotationEnv
  30
  31 exception Parse_error of Token.flocation * string
  32 exception Level_not_found of int
  33
  34 let level1_pattern_grammar =
  35   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  36 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  37 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  38
  39 let min_precedence = 0
  40 let max_precedence = 100
  41
  42 let level1_pattern =
  43   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  44 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  45 let term = Grammar.Entry.create level2_ast_grammar "term"
  46 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  47 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  48
  49 let int_of_string s =
  50   try
  51     Pervasives.int_of_string s
  52   with Failure _ ->
  53     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  54
  55 (** {2 Grammar extension} *)
  56
  57 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  58 let gram_ident s = Gramext.Stoken ("IDENT", s)
  59 let gram_number s = Gramext.Stoken ("NUMBER", s)
  60 let gram_keyword s = Gramext.Stoken ("", s)
  61 let gram_term = Gramext.Sself
  62
  63 let gram_of_literal =
  64   function
  65   | `Symbol s -> gram_symbol s
  66   | `Keyword s -> gram_keyword s
  67   | `Number s -> gram_number s
  68
  69 type binding =
  70   | NoBinding
  71   | Binding of string * Env.value_type
  72   | Env of (string * Env.value_type) list
  73
  74 let make_action action bindings =
  75   let rec aux (vl : CicNotationEnv.t) =
  76     function
  77       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  78     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  79     (* LUCA: DEFCON 3 BEGIN *)
  80     | Binding (name, Env.TermType) :: tl ->
  81         Gramext.action
  82           (fun (v:Ast.term) ->
  83             aux ((name, (Env.TermType, Env.TermValue v))::vl) tl)
  84     | Binding (name, Env.StringType) :: tl ->
  85         Gramext.action
  86           (fun (v:string) ->
  87             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
  88     | Binding (name, Env.NumType) :: tl ->
  89         Gramext.action
  90           (fun (v:string) ->
  91             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
  92     | Binding (name, Env.OptType t) :: tl ->
  93         Gramext.action
  94           (fun (v:'a option) ->
  95             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
  96     | Binding (name, Env.ListType t) :: tl ->
  97         Gramext.action
  98           (fun (v:'a list) ->
  99             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 100     | Env _ :: tl ->
 101         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 102     (* LUCA: DEFCON 3 END *)
 103   in
 104     aux [] (List.rev bindings)
 105
 106 let flatten_opt =
 107   let rec aux acc =
 108     function
 109       [] -> List.rev acc
 110     | NoBinding :: tl -> aux acc tl
 111     | Env names :: tl -> aux (List.rev names @ acc) tl
 112     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 113   in
 114   aux []
 115
 116   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 117 let extract_term_production pattern =
 118   let rec aux = function
 119     | Ast.AttributedTerm (_, t) -> aux t
 120     | Ast.Literal l -> aux_literal l
 121     | Ast.Layout l -> aux_layout l
 122     | Ast.Magic m -> aux_magic m
 123     | Ast.Variable v -> aux_variable v
 124     | t ->
 125         prerr_endline (CicNotationPp.pp_term t);
 126         assert false
 127   and aux_literal =
 128     function
 129     | `Symbol s -> [NoBinding, gram_symbol s]
 130     | `Keyword s ->
 131         (* assumption: s will be registered as a keyword with the lexer *)
 132         [NoBinding, gram_keyword s]
 133     | `Number s -> [NoBinding, gram_number s]
 134   and aux_layout = function
 135     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 136     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 137     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 138     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 139     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 140     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 141     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 142     | Ast.Root (p1, p2) ->
 143         [NoBinding, gram_symbol "\\root"] @ aux p2
 144         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 145     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 146     | Ast.Break -> []
 147     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 148     | Ast.Group pl -> List.flatten (List.map aux pl)
 149   and aux_magic magic =
 150     match magic with
 151     | Ast.Opt p ->
 152         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 153         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 154           match env_opt with
 155           | Some env -> List.map Env.opt_binding_some env
 156           | None -> List.map Env.opt_binding_of_name p_names
 157         in
 158         [ Env (List.map Env.opt_declaration p_names),
 159           Gramext.srules
 160             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 161               Gramext.action action ] ]
 162     | Ast.List0 (p, _)
 163     | Ast.List1 (p, _) ->
 164         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 165 (*         let env0 = List.map list_binding_of_name p_names in
 166         let grow_env_entry env n v =
 167           List.map
 168             (function
 169               | (n', (ty, ListValue vl)) as entry ->
 170                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 171               | _ -> assert false)
 172             env
 173         in
 174         let grow_env env_i env =
 175           List.fold_left
 176             (fun env (n, (_, v)) -> grow_env_entry env n v)
 177             env env_i
 178         in *)
 179         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 180           CicNotationEnv.coalesce_env p_names env_list
 181         in
 182         let gram_of_list s =
 183           match magic with
 184           | Ast.List0 (_, None) -> Gramext.Slist0 s
 185           | Ast.List1 (_, None) -> Gramext.Slist1 s
 186           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 187           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 188           | _ -> assert false
 189         in
 190         [ Env (List.map Env.list_declaration p_names),
 191           Gramext.srules
 192             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 193               Gramext.action action ] ]
 194     | _ -> assert false
 195   and aux_variable =
 196     function
 197     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 198     | Ast.TermVar s -> [Binding (s, Env.TermType), gram_term]
 199     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 200     | Ast.Ascription (p, s) -> assert false (* TODO *)
 201     | Ast.FreshVar _ -> assert false
 202   and inner_pattern p =
 203     let p_bindings, p_atoms = List.split (aux p) in
 204     let p_names = flatten_opt p_bindings in
 205     let action =
 206       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 207         p_bindings
 208     in
 209     p_bindings, p_atoms, p_names, action
 210   in
 211   aux pattern
 212
 213 let level_of precedence associativity =
 214   if precedence < min_precedence || precedence > max_precedence then
 215     raise (Level_not_found precedence);
 216   let assoc_string =
 217     match associativity with
 218     | Gramext.NonA -> "N"
 219     | Gramext.LeftA -> "L"
 220     | Gramext.RightA -> "R"
 221   in
 222   string_of_int precedence ^ assoc_string
 223
 224 type rule_id = Token.t Gramext.g_symbol list
 225
 226   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 227 let owned_keywords = Hashtbl.create 23
 228
 229 let extend level1_pattern ~precedence ~associativity action =
 230   let p_bindings, p_atoms =
 231     List.split (extract_term_production level1_pattern)
 232   in
 233   let level = level_of precedence associativity in
 234   let p_names = flatten_opt p_bindings in
 235   let _ =
 236     Grammar.extend
 237       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 238         Some (Gramext.Level level),
 239         [ None,
 240           Some associativity,
 241           [ p_atoms,
 242             (make_action
 243               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 244                 (action env loc))
 245               p_bindings) ]]]
 246   in
 247   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 248   let rule_id = p_atoms in
 249   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 250   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 251   rule_id
 252
 253 let delete rule_id =
 254   let atoms = rule_id in
 255   (try
 256     let keywords = Hashtbl.find owned_keywords rule_id in
 257     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 258   with Not_found -> assert false);
 259   Grammar.delete_rule term atoms
 260
 261 (** {2 Grammar} *)
 262
 263 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 264 let parse_level2_ast_ref = ref (fun _ -> assert false)
 265 let parse_level2_meta_ref = ref (fun _ -> assert false)
 266
 267 let fold_cluster binder terms ty body =
 268   List.fold_right
 269     (fun term body -> Ast.Binder (binder, (term, ty), body))
 270     terms body  (* terms are names: either Ident or FreshVar *)
 271
 272 let fold_exists terms ty body =
 273   List.fold_right
 274     (fun term body ->
 275       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 276       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 277     terms body
 278
 279 let fold_binder binder pt_names body =
 280   List.fold_right
 281     (fun (names, ty) body -> fold_cluster binder names ty body)
 282     pt_names body
 283
 284 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 285
 286   (* create empty precedence level for "term" *)
 287 let _ =
 288   let dummy_action =
 289     Gramext.action (fun _ ->
 290       failwith "internal error, lexer generated a dummy token")
 291   in
 292   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 293    * empty after the deletion. The lexer never generate the Stoken below. *)
 294   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 295   let mk_level_list first last =
 296     let rec aux acc = function
 297       | i when i < first -> acc
 298       | i ->
 299           aux
 300             ((Some (string_of_int i ^ "N"), Some Gramext.NonA, dummy_prod)
 301              :: (Some (string_of_int i ^ "L"), Some Gramext.LeftA, dummy_prod)
 302              :: (Some (string_of_int i ^ "R"), Some Gramext.RightA, dummy_prod)
 303              :: acc)
 304             (i - 1)
 305     in
 306     aux [] last
 307   in
 308   Grammar.extend
 309     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 310       None,
 311       mk_level_list min_precedence max_precedence ]
 312
 313 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 314 EXTEND
 315   GLOBAL: level1_pattern;
 316
 317   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 318   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 319   literal: [
 320     [ s = SYMBOL -> `Symbol s
 321     | k = QKEYWORD -> `Keyword k
 322     | n = NUMBER -> `Number n
 323     ]
 324   ];
 325   sep:       [ [ "sep";      sep = literal -> sep ] ];
 326 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 327   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 328   l1_magic_pattern: [
 329     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> Ast.List0 (p, sep)
 330     | "list1"; p = l1_simple_pattern; sep = OPT sep -> Ast.List1 (p, sep)
 331     | "opt";   p = l1_simple_pattern -> Ast.Opt p
 332     ]
 333   ];
 334   l1_pattern_variable: [
 335     [ "term"; id = IDENT -> Ast.TermVar id
 336     | "number"; id = IDENT -> Ast.NumVar id
 337     | "ident"; id = IDENT -> Ast.IdentVar id
 338     ]
 339   ];
 340   l1_simple_pattern:
 341     [ "layout" LEFTA
 342       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 343           return_term loc (Ast.Layout (Ast.Sub (p1, p2)))
 344       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 345           return_term loc (Ast.Layout (Ast.Sup (p1, p2)))
 346       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 347           return_term loc (Ast.Layout (Ast.Below (p1, p2)))
 348       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 349           return_term loc (Ast.Layout (Ast.Above (p1, p2)))
 350       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 351           return_term loc (Ast.Layout (Ast.Over (p1, p2)))
 352       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 353           return_term loc (Ast.Layout (Ast.Atop (p1, p2)))
 354 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 355           return_term loc (Array (p, csep, rsep)) *)
 356       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 357           return_term loc (Ast.Layout (Ast.Frac (p1, p2)))
 358       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Ast.Layout (Ast.Sqrt p))
 359       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 360           return_term loc (Ast.Layout (Ast.Root (arg, index)))
 361       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 362           return_term loc (Ast.Layout (Ast.Box ((Ast.H, false, false), p)))
 363       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 364           return_term loc (Ast.Layout (Ast.Box ((Ast.V, false, false), p)))
 365       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 366           return_term loc (Ast.Layout (Ast.Box ((Ast.HV, false, false), p)))
 367       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 368           return_term loc (Ast.Layout (Ast.Box ((Ast.HOV, false, false), p)))
 369       | "break" -> return_term loc (Ast.Layout Ast.Break)
 370 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 371       | LPAREN; p = l1_pattern; RPAREN ->
 372           return_term loc (CicNotationUtil.group p)
 373       ]
 374     | "simple" NONA
 375       [ i = IDENT -> return_term loc (Ast.Variable (Ast.TermVar i))
 376       | m = l1_magic_pattern -> return_term loc (Ast.Magic m)
 377       | v = l1_pattern_variable -> return_term loc (Ast.Variable v)
 378       | l = literal -> return_term loc (Ast.Literal l)
 379       ]
 380     ];
 381   END
 382 (* }}} *)
 383
 384 (* {{{ Grammar for ast magics, notation level 2 *)
 385 EXTEND
 386   GLOBAL: level2_meta;
 387   l2_variable: [
 388     [ "term"; id = IDENT -> Ast.TermVar id
 389     | "number"; id = IDENT -> Ast.NumVar id
 390     | "ident"; id = IDENT -> Ast.IdentVar id
 391     | "fresh"; id = IDENT -> Ast.FreshVar id
 392     | "anonymous" -> Ast.TermVar "_"
 393     | id = IDENT -> Ast.TermVar id
 394     ]
 395   ];
 396   l2_magic: [
 397     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 398       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 399         Ast.Fold (kind, base, [id], recursive)
 400     | "default"; some = level2_meta; none = level2_meta ->
 401         Ast.Default (some, none)
 402     | "if"; p_test = level2_meta;
 403       "then"; p_true = level2_meta;
 404       "else"; p_false = level2_meta ->
 405         Ast.If (p_test, p_true, p_false)
 406     | "fail" -> Ast.Fail
 407     ]
 408   ];
 409   level2_meta: [
 410     [ magic = l2_magic -> Ast.Magic magic
 411     | var = l2_variable -> Ast.Variable var
 412     | blob = UNPARSED_AST ->
 413         !parse_level2_ast_ref (Ulexing.from_utf8_string blob)
 414     ]
 415   ];
 416 END
 417 (* }}} *)
 418
 419 (* {{{ Grammar for ast patterns, notation level 2 *)
 420 EXTEND
 421   GLOBAL: level2_ast term let_defs;
 422   level2_ast: [ [ p = term -> p ] ];
 423   sort: [
 424     [ "Prop" -> `Prop
 425     | "Set" -> `Set
 426     | "Type" -> `Type (CicUniv.fresh ())
 427     | "CProp" -> `CProp
 428     ]
 429   ];
 430   explicit_subst: [
 431     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 432       SYMBOL "[";
 433       substs = LIST1 [
 434         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 435       ] SEP SYMBOL ";";
 436       SYMBOL "]" ->
 437         substs
 438     ]
 439   ];
 440   meta_subst: [
 441     [ s = SYMBOL "_" -> None
 442     | p = term -> Some p ]
 443   ];
 444   meta_substs: [
 445     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 446   ];
 447   possibly_typed_name: [
 448     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 449         id, Some typ
 450     | arg = single_arg -> arg, None
 451     ]
 452   ];
 453   match_pattern: [
 454     [ id = IDENT -> id, None, []
 455     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 456         id, None, vars
 457     ]
 458   ];
 459   binder: [
 460     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 461 (*     | SYMBOL <:unicode<exists>> |+ ∃ +| -> `Exists *)
 462     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 463     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 464     ]
 465   ];
 466   arg: [
 467     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 468       SYMBOL ":"; ty = term; RPAREN ->
 469         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 470     | name = IDENT -> [Ast.Ident (name, None)], None
 471     | blob = UNPARSED_META ->
 472         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 473         match meta with
 474         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 475         | Ast.Variable (Ast.TermVar "_") -> [Ast.Ident ("_", None)], None
 476         | _ -> failwith "Invalid bound name."
 477    ]
 478   ];
 479   single_arg: [
 480     [ name = IDENT -> Ast.Ident (name, None)
 481     | blob = UNPARSED_META ->
 482         let meta = !parse_level2_meta_ref (Ulexing.from_utf8_string blob) in
 483         match meta with
 484         | Ast.Variable (Ast.FreshVar _)
 485         | Ast.Variable (Ast.IdentVar _) -> meta
 486         | Ast.Variable (Ast.TermVar "_") -> Ast.Ident ("_", None)
 487         | _ -> failwith "Invalid index name."
 488     ]
 489   ];
 490   induction_kind: [
 491     [ "rec" -> `Inductive
 492     | "corec" -> `CoInductive
 493     ]
 494   ];
 495   let_defs: [
 496     [ defs = LIST1 [
 497         name = single_arg;
 498         args = LIST1 arg;
 499         index_name = OPT [ "on"; id = single_arg -> id ];
 500         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 501         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 502           let body = fold_binder `Lambda args body in
 503           let ty =
 504             match ty with
 505             | None -> None
 506             | Some ty -> Some (fold_binder `Pi args ty)
 507           in
 508           let rec position_of name p = function
 509             | [] -> None, p
 510             | n :: _ when n = name -> Some p, p
 511             | _ :: tl -> position_of name (p + 1) tl
 512           in
 513           let rec find_arg name n = function
 514             | [] ->
 515                 Ast.fail loc (sprintf "Argument %s not found"
 516                   (CicNotationPp.pp_term name))
 517             | (l,_) :: tl ->
 518                 (match position_of name 0 l with
 519                 | None, len -> find_arg name (n + len) tl
 520                 | Some where, len -> n + where)
 521           in
 522           let index =
 523             match index_name with
 524             | None -> 0
 525             | Some index_name -> find_arg index_name 0 args
 526           in
 527           (name, ty), body, index
 528       ] SEP "and" ->
 529         defs
 530     ]
 531   ];
 532   binder_vars: [
 533     [ vars = [
 534           l = LIST1 single_arg SEP SYMBOL "," -> l
 535         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 536       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 537     | LPAREN;
 538         vars = [
 539             l =  LIST1 single_arg SEP SYMBOL "," -> l
 540           | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 541       typ = OPT [ SYMBOL ":"; t = term -> t ];
 542       RPAREN -> (vars, typ)
 543     ]
 544   ];
 545   term: LEVEL "10N" [ (* let in *)
 546     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 547       p1 = term; "in"; p2 = term ->
 548         return_term loc (Ast.LetIn (var, p1, p2))
 549     | "let"; k = induction_kind; defs = let_defs; "in";
 550       body = term ->
 551         return_term loc (Ast.LetRec (k, defs, body))
 552     ]
 553   ];
 554   term: LEVEL "20R"  (* binder *)
 555     [
 556       [ b = binder; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 557           return_term loc (fold_cluster b vars typ body)
 558       | SYMBOL <:unicode<exists>> (* ∃ *);
 559         (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 560           return_term loc (fold_exists vars typ body)
 561       ]
 562     ];
 563   term: LEVEL "70L"  (* apply *)
 564     [
 565       [ p1 = term; p2 = term ->
 566           let rec aux = function
 567             | Ast.Appl (hd :: tl)
 568             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 569                 aux hd @ tl
 570             | term -> [term]
 571           in
 572           return_term loc (Ast.Appl (aux p1 @ [p2]))
 573       ]
 574     ];
 575   term: LEVEL "90N"  (* simple *)
 576     [
 577       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 578       | id = IDENT; s = explicit_subst ->
 579           return_term loc (Ast.Ident (id, Some s))
 580       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 581       | u = URI -> return_term loc (Ast.Uri (u, None))
 582       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 583       | IMPLICIT -> return_term loc (Ast.Implicit)
 584       | PLACEHOLDER -> return_term loc Ast.UserInput
 585       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 586       | m = META; s = meta_substs ->
 587           return_term loc (Ast.Meta (int_of_string m, s))
 588       | s = sort -> return_term loc (Ast.Sort s)
 589       | "match"; t = term;
 590         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 591         outtyp = OPT [ "return"; ty = term -> ty ];
 592         "with"; SYMBOL "[";
 593         patterns = LIST0 [
 594           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 595           rhs = term ->
 596             lhs, rhs
 597         ] SEP SYMBOL "|";
 598         SYMBOL "]" ->
 599           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 600       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 601           return_term loc (Ast.Cast (p1, p2))
 602       | LPAREN; p = term; RPAREN -> p
 603       | blob = UNPARSED_META ->
 604           !parse_level2_meta_ref (Ulexing.from_utf8_string blob)
 605       ]
 606     ];
 607 END
 608 (* }}} *)
 609
 610 (** {2 API implementation} *)
 611
 612 let exc_located_wrapper f =
 613   try
 614     f ()
 615   with
 616   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 617       raise (Parse_error (floc, msg))
 618   | Stdpp.Exc_located (floc, exn) ->
 619       raise (Parse_error (floc, (Printexc.to_string exn)))
 620
 621 let parse_level1_pattern lexbuf =
 622   exc_located_wrapper
 623     (fun () -> Grammar.Entry.parse level1_pattern (Obj.magic lexbuf))
 624
 625 let parse_level2_ast lexbuf =
 626   exc_located_wrapper
 627     (fun () -> Grammar.Entry.parse level2_ast (Obj.magic lexbuf))
 628
 629 let parse_level2_meta lexbuf =
 630   exc_located_wrapper
 631     (fun () -> Grammar.Entry.parse level2_meta (Obj.magic lexbuf))
 632
 633 let _ =
 634   parse_level1_pattern_ref := parse_level1_pattern;
 635   parse_level2_ast_ref := parse_level2_ast;
 636   parse_level2_meta_ref := parse_level2_meta
 637
 638 (** {2 Debugging} *)
 639
 640 let print_l2_pattern () =
 641   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 642   Format.pp_print_flush Format.std_formatter ();
 643   flush stdout
 644
 645 (* vim:set encoding=utf8 foldmethod=marker: *)