helm/ocaml/cic_notation/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 module Ast = CicNotationPt
  29 module Env = CicNotationEnv
  30
  31 exception Parse_error of Token.flocation * string
  32 exception Level_not_found of int
  33
  34 let level1_pattern_grammar =
  35   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  36 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  37 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  38
  39 let min_precedence = 0
  40 let max_precedence = 100
  41
  42 let level1_pattern =
  43   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  44 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  45 let term = Grammar.Entry.create level2_ast_grammar "term"
  46 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  47 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  48
  49 let return_term loc term = ()
  50
  51 let int_of_string s =
  52   try
  53     Pervasives.int_of_string s
  54   with Failure _ ->
  55     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  56
  57 (** {2 Grammar extension} *)
  58
  59 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  60 let gram_ident s = Gramext.Stoken ("IDENT", s)
  61 let gram_number s = Gramext.Stoken ("NUMBER", s)
  62 let gram_keyword s = Gramext.Stoken ("", s)
  63 let gram_term = Gramext.Sself
  64
  65 let gram_of_literal =
  66   function
  67   | `Symbol s -> gram_symbol s
  68   | `Keyword s -> gram_keyword s
  69   | `Number s -> gram_number s
  70
  71 type binding =
  72   | NoBinding
  73   | Binding of string * Env.value_type
  74   | Env of (string * Env.value_type) list
  75
  76 let make_action action bindings =
  77   let rec aux (vl : CicNotationEnv.t) =
  78     function
  79       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
  80     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  81     (* LUCA: DEFCON 5 BEGIN *)
  82     | Binding (name, Env.TermType) :: tl ->
  83         Gramext.action
  84           (fun (v:Ast.term) ->
  85             aux ((name, (Env.TermType, Env.TermValue v))::vl) tl)
  86     | Binding (name, Env.StringType) :: tl ->
  87         Gramext.action
  88           (fun (v:string) ->
  89             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
  90     | Binding (name, Env.NumType) :: tl ->
  91         Gramext.action
  92           (fun (v:string) ->
  93             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
  94     | Binding (name, Env.OptType t) :: tl ->
  95         Gramext.action
  96           (fun (v:'a option) ->
  97             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
  98     | Binding (name, Env.ListType t) :: tl ->
  99         Gramext.action
 100           (fun (v:'a list) ->
 101             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 102     | Env _ :: tl ->
 103         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 104     (* LUCA: DEFCON 5 END *)
 105   in
 106     aux [] (List.rev bindings)
 107
 108 let flatten_opt =
 109   let rec aux acc =
 110     function
 111       [] -> List.rev acc
 112     | NoBinding :: tl -> aux acc tl
 113     | Env names :: tl -> aux (List.rev names @ acc) tl
 114     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 115   in
 116   aux []
 117
 118   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 119 let extract_term_production pattern =
 120   let rec aux = function
 121     | Ast.AttributedTerm (_, t) -> aux t
 122     | Ast.Literal l -> aux_literal l
 123     | Ast.Layout l -> aux_layout l
 124     | Ast.Magic m -> aux_magic m
 125     | Ast.Variable v -> aux_variable v
 126     | t ->
 127         prerr_endline (CicNotationPp.pp_term t);
 128         assert false
 129   and aux_literal =
 130     function
 131     | `Symbol s -> [NoBinding, gram_symbol s]
 132     | `Keyword s ->
 133         (* assumption: s will be registered as a keyword with the lexer *)
 134         [NoBinding, gram_keyword s]
 135     | `Number s -> [NoBinding, gram_number s]
 136   and aux_layout = function
 137     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 138     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 139     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 140     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 141     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 142     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 143     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 144     | Ast.Root (p1, p2) ->
 145         [NoBinding, gram_symbol "\\root"] @ aux p2
 146         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 147     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 148     | Ast.Break -> []
 149     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 150     | Ast.Group pl -> List.flatten (List.map aux pl)
 151   and aux_magic magic =
 152     match magic with
 153     | Ast.Opt p ->
 154         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 155         let action (env_opt : CicNotationEnv.t option) (loc : Ast.location) =
 156           match env_opt with
 157           | Some env -> List.map Env.opt_binding_some env
 158           | None -> List.map Env.opt_binding_of_name p_names
 159         in
 160         [ Env (List.map Env.opt_declaration p_names),
 161           Gramext.srules
 162             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 163               Gramext.action action ] ]
 164     | Ast.List0 (p, _)
 165     | Ast.List1 (p, _) ->
 166         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 167 (*         let env0 = List.map list_binding_of_name p_names in
 168         let grow_env_entry env n v =
 169           List.map
 170             (function
 171               | (n', (ty, ListValue vl)) as entry ->
 172                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 173               | _ -> assert false)
 174             env
 175         in
 176         let grow_env env_i env =
 177           List.fold_left
 178             (fun env (n, (_, v)) -> grow_env_entry env n v)
 179             env env_i
 180         in *)
 181         let action (env_list : CicNotationEnv.t list) (loc : Ast.location) =
 182           CicNotationEnv.coalesce_env p_names env_list
 183         in
 184         let gram_of_list s =
 185           match magic with
 186           | Ast.List0 (_, None) -> Gramext.Slist0 s
 187           | Ast.List1 (_, None) -> Gramext.Slist1 s
 188           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 189           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 190           | _ -> assert false
 191         in
 192         [ Env (List.map Env.list_declaration p_names),
 193           Gramext.srules
 194             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 195               Gramext.action action ] ]
 196     | _ -> assert false
 197   and aux_variable =
 198     function
 199     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 200     | Ast.TermVar s -> [Binding (s, Env.TermType), gram_term]
 201     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 202     | Ast.Ascription (p, s) -> assert false (* TODO *)
 203     | Ast.FreshVar _ -> assert false
 204   and inner_pattern p =
 205     let p_bindings, p_atoms = List.split (aux p) in
 206     let p_names = flatten_opt p_bindings in
 207     let action =
 208       make_action (fun (env : CicNotationEnv.t) (loc : Ast.location) -> env)
 209         p_bindings
 210     in
 211     p_bindings, p_atoms, p_names, action
 212   in
 213   aux pattern
 214
 215 let level_of precedence associativity =
 216   if precedence < min_precedence || precedence > max_precedence then
 217     raise (Level_not_found precedence);
 218   let assoc_string =
 219     match associativity with
 220     | Gramext.NonA -> "N"
 221     | Gramext.LeftA -> "L"
 222     | Gramext.RightA -> "R"
 223   in
 224   string_of_int precedence ^ assoc_string
 225
 226 type rule_id = Token.t Gramext.g_symbol list
 227
 228   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 229 let owned_keywords = Hashtbl.create 23
 230
 231 let extend level1_pattern ~precedence ~associativity action =
 232   let p_bindings, p_atoms =
 233     List.split (extract_term_production level1_pattern)
 234   in
 235   let level = level_of precedence associativity in
 236   let p_names = flatten_opt p_bindings in
 237   let _ =
 238     Grammar.extend
 239       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 240         Some (Gramext.Level level),
 241         [ None,
 242           Some associativity,
 243           [ p_atoms,
 244             (make_action
 245               (fun (env: CicNotationEnv.t) (loc: Ast.location) ->
 246                 (action env loc))
 247               p_bindings) ]]]
 248   in
 249   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 250   let rule_id = p_atoms in
 251   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 252   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 253   rule_id
 254
 255 let delete rule_id =
 256   let atoms = rule_id in
 257   (try
 258     let keywords = Hashtbl.find owned_keywords rule_id in
 259     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 260   with Not_found -> assert false);
 261   Grammar.delete_rule term atoms
 262
 263 (** {2 Grammar} *)
 264
 265 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 266 let parse_level2_ast_ref = ref (fun _ -> assert false)
 267 let parse_level2_meta_ref = ref (fun _ -> assert false)
 268
 269 let fold_cluster binder terms ty body =
 270   List.fold_right
 271     (fun term body -> Ast.Binder (binder, (term, ty), body))
 272     terms body  (* terms are names: either Ident or FreshVar *)
 273
 274 let fold_binder binder pt_names body =
 275   List.fold_right
 276     (fun (names, ty) body -> fold_cluster binder names ty body)
 277     pt_names body
 278
 279 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 280
 281   (* create empty precedence level for "term" *)
 282 let _ =
 283   let dummy_action =
 284     Gramext.action (fun _ ->
 285       failwith "internal error, lexer generated a dummy token")
 286   in
 287   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 288    * empty after the deletion. The lexer never generate the Stoken below. *)
 289   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 290   let mk_level_list first last =
 291     let rec aux acc = function
 292       | i when i < first -> acc
 293       | i ->
 294           aux
 295             ((Some (string_of_int i ^ "N"), Some Gramext.NonA, dummy_prod)
 296              :: (Some (string_of_int i ^ "L"), Some Gramext.LeftA, dummy_prod)
 297              :: (Some (string_of_int i ^ "R"), Some Gramext.RightA, dummy_prod)
 298              :: acc)
 299             (i - 1)
 300     in
 301     aux [] last
 302   in
 303   Grammar.extend
 304     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 305       None,
 306       mk_level_list min_precedence max_precedence ]
 307
 308 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 309 EXTEND
 310   GLOBAL: level1_pattern;
 311
 312   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 313   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 314   literal: [
 315     [ s = SYMBOL -> `Symbol s
 316     | k = QKEYWORD -> `Keyword k
 317     | n = NUMBER -> `Number n
 318     ]
 319   ];
 320   sep:       [ [ "sep";      sep = literal -> sep ] ];
 321 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 322   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 323   l1_magic_pattern: [
 324     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> Ast.List0 (p, sep)
 325     | "list1"; p = l1_simple_pattern; sep = OPT sep -> Ast.List1 (p, sep)
 326     | "opt";   p = l1_simple_pattern -> Ast.Opt p
 327     ]
 328   ];
 329   l1_pattern_variable: [
 330     [ "term"; id = IDENT -> Ast.TermVar id
 331     | "number"; id = IDENT -> Ast.NumVar id
 332     | "ident"; id = IDENT -> Ast.IdentVar id
 333     ]
 334   ];
 335   l1_simple_pattern:
 336     [ "layout" LEFTA
 337       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 338           return_term loc (Ast.Layout (Ast.Sub (p1, p2)))
 339       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 340           return_term loc (Ast.Layout (Ast.Sup (p1, p2)))
 341       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 342           return_term loc (Ast.Layout (Ast.Below (p1, p2)))
 343       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 344           return_term loc (Ast.Layout (Ast.Above (p1, p2)))
 345       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 346           return_term loc (Ast.Layout (Ast.Over (p1, p2)))
 347       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 348           return_term loc (Ast.Layout (Ast.Atop (p1, p2)))
 349 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 350           return_term loc (Array (p, csep, rsep)) *)
 351       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 352           return_term loc (Ast.Layout (Ast.Frac (p1, p2)))
 353       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Ast.Layout (Ast.Sqrt p))
 354       | SYMBOL "\\root"; index = SELF; SYMBOL "\\of"; arg = SELF ->
 355           return_term loc (Ast.Layout (Ast.Root (arg, index)))
 356       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 357           return_term loc (Ast.Layout (Ast.Box ((Ast.H, false, false), p)))
 358       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 359           return_term loc (Ast.Layout (Ast.Box ((Ast.V, false, false), p)))
 360       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 361           return_term loc (Ast.Layout (Ast.Box ((Ast.HV, false, false), p)))
 362       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 363           return_term loc (Ast.Layout (Ast.Box ((Ast.HOV, false, false), p)))
 364       | "break" -> return_term loc (Ast.Layout Ast.Break)
 365 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 366       | LPAREN; p = l1_pattern; RPAREN ->
 367           return_term loc (CicNotationUtil.group p)
 368       ]
 369     | "simple" NONA
 370       [ i = IDENT -> return_term loc (Ast.Variable (Ast.TermVar i))
 371       | m = l1_magic_pattern -> return_term loc (Ast.Magic m)
 372       | v = l1_pattern_variable -> return_term loc (Ast.Variable v)
 373       | l = literal -> return_term loc (Ast.Literal l)
 374       ]
 375     ];
 376   END
 377 (* }}} *)
 378
 379 (* {{{ Grammar for ast magics, notation level 2 *)
 380 EXTEND
 381   GLOBAL: level2_meta;
 382   l2_variable: [
 383     [ "term"; id = IDENT -> Ast.TermVar id
 384     | "number"; id = IDENT -> Ast.NumVar id
 385     | "ident"; id = IDENT -> Ast.IdentVar id
 386     | "fresh"; id = IDENT -> Ast.FreshVar id
 387     | "anonymous" -> Ast.TermVar "_"
 388     | id = IDENT -> Ast.TermVar id
 389     ]
 390   ];
 391   l2_magic: [
 392     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 393       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 394         Ast.Fold (kind, base, [id], recursive)
 395     | "default"; some = level2_meta; none = level2_meta ->
 396         Ast.Default (some, none)
 397     | "if"; p_test = level2_meta;
 398       "then"; p_true = level2_meta;
 399       "else"; p_false = level2_meta ->
 400         Ast.If (p_test, p_true, p_false)
 401     | "fail" -> Ast.Fail
 402     ]
 403   ];
 404   level2_meta: [
 405     [ magic = l2_magic -> Ast.Magic magic
 406     | var = l2_variable -> Ast.Variable var
 407     | blob = UNPARSED_AST -> !parse_level2_ast_ref (Stream.of_string blob)
 408     ]
 409   ];
 410 END
 411 (* }}} *)
 412
 413 (* {{{ Grammar for ast patterns, notation level 2 *)
 414 EXTEND
 415   GLOBAL: level2_ast term let_defs;
 416   level2_ast: [ [ p = term -> p ] ];
 417   sort: [
 418     [ "Prop" -> `Prop
 419     | "Set" -> `Set
 420     | "Type" -> `Type
 421     | "CProp" -> `CProp
 422     ]
 423   ];
 424   explicit_subst: [
 425     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 426       SYMBOL "[";
 427       substs = LIST1 [
 428         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 429       ] SEP SYMBOL ";";
 430       SYMBOL "]" ->
 431         substs
 432     ]
 433   ];
 434   meta_subst: [
 435     [ s = SYMBOL "_" -> None
 436     | p = term -> Some p ]
 437   ];
 438   meta_substs: [
 439     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 440   ];
 441   possibly_typed_name: [
 442     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 443         id, Some typ
 444     | arg = single_arg -> arg, None
 445     ]
 446   ];
 447   match_pattern: [
 448     [ id = IDENT -> id, None, []
 449     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 450         id, None, vars
 451     ]
 452   ];
 453   binder: [
 454     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 455     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 456     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 457     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 458     ]
 459   ];
 460   arg: [
 461     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 462       SYMBOL ":"; ty = term; RPAREN ->
 463         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 464     | name = IDENT -> [Ast.Ident (name, None)], None
 465     | blob = UNPARSED_META ->
 466         let meta = !parse_level2_meta_ref (Stream.of_string blob) in
 467         match meta with
 468         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 469         | Ast.Variable (Ast.TermVar "_") -> [Ast.Ident ("_", None)], None
 470         | _ -> failwith "Invalid bound name."
 471    ]
 472   ];
 473   single_arg: [
 474     [ name = IDENT -> Ast.Ident (name, None)
 475     | blob = UNPARSED_META ->
 476         let meta = !parse_level2_meta_ref (Stream.of_string blob) in
 477         match meta with
 478         | Ast.Variable (Ast.FreshVar _) -> meta
 479         | Ast.Variable (Ast.TermVar "_") -> Ast.Ident ("_", None)
 480         | _ -> failwith "Invalid index name."
 481     ]
 482   ];
 483   induction_kind: [
 484     [ "rec" -> `Inductive
 485     | "corec" -> `CoInductive
 486     ]
 487   ];
 488   let_defs: [
 489     [ defs = LIST1 [
 490         name = single_arg;
 491         args = LIST1 arg;
 492         index_name = OPT [ "on"; id = single_arg -> id ];
 493         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 494         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 495           let body = fold_binder `Lambda args body in
 496           let ty =
 497             match ty with
 498             | None -> None
 499             | Some ty -> Some (fold_binder `Pi args ty)
 500           in
 501           let rec position_of name p = function
 502             | [] -> None, p
 503             | n :: _ when n = name -> Some p, p
 504             | _ :: tl -> position_of name (p + 1) tl
 505           in
 506           let rec find_arg name n = function
 507             | [] ->
 508                 Ast.fail loc (sprintf "Argument %s not found"
 509                   (CicNotationPp.pp_term name))
 510             | (l,_) :: tl ->
 511                 (match position_of name 0 l with
 512                 | None, len -> find_arg name (n + len) tl
 513                 | Some where, len -> n + where)
 514           in
 515           let index =
 516             match index_name with
 517             | None -> 0
 518             | Some index_name -> find_arg index_name 0 args
 519           in
 520           (name, ty), body, index
 521       ] SEP "and" ->
 522         defs
 523     ]
 524   ];
 525   binder_vars: [
 526     [ vars = [
 527           l = LIST1 single_arg SEP SYMBOL "," -> l
 528         | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 529       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 530     | LPAREN;
 531         vars = [
 532             l =  LIST1 single_arg SEP SYMBOL "," -> l
 533           | SYMBOL "_" -> [Ast.Ident ("_", None)] ];
 534       typ = OPT [ SYMBOL ":"; t = term -> t ];
 535       RPAREN -> (vars, typ)
 536     ]
 537   ];
 538   term: LEVEL "10N" [ (* let in *)
 539     [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 540       p1 = term; "in"; p2 = term ->
 541         return_term loc (Ast.LetIn (var, p1, p2))
 542     | "let"; k = induction_kind; defs = let_defs; "in";
 543       body = term ->
 544         return_term loc (Ast.LetRec (k, defs, body))
 545     ]
 546   ];
 547   term: LEVEL "20R"  (* binder *)
 548     [
 549       [ b = binder; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 550           return_term loc (fold_cluster b vars typ body)
 551       ]
 552     ];
 553   term: LEVEL "70L"  (* apply *)
 554     [
 555       [ p1 = term; p2 = term ->
 556           let rec aux = function
 557             | Ast.Appl (hd :: tl)
 558             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 559                 aux hd @ tl
 560             | term -> [term]
 561           in
 562           return_term loc (Ast.Appl (aux p1 @ [p2]))
 563       ]
 564     ];
 565   term: LEVEL "90N"  (* simple *)
 566     [
 567       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 568       | id = IDENT; s = explicit_subst ->
 569           return_term loc (Ast.Ident (id, Some s))
 570       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 571       | u = URI -> return_term loc (Ast.Uri (u, None))
 572       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 573       | IMPLICIT -> return_term loc (Ast.Implicit)
 574       | PLACEHOLDER -> return_term loc Ast.UserInput
 575       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 576       | m = META; s = meta_substs ->
 577           return_term loc (Ast.Meta (int_of_string m, s))
 578       | s = sort -> return_term loc (Ast.Sort s)
 579       | outtyp = OPT [ SYMBOL "["; ty = term; SYMBOL "]" -> ty ];
 580         "match"; t = term;
 581         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 582         "with"; SYMBOL "[";
 583         patterns = LIST0 [
 584           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 585           rhs = term ->
 586             lhs, rhs
 587         ] SEP SYMBOL "|";
 588         SYMBOL "]" ->
 589           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 590       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 591           return_term loc (Ast.Cast (p1, p2))
 592       | LPAREN; p = term; RPAREN -> p
 593       | blob = UNPARSED_META -> !parse_level2_meta_ref (Stream.of_string blob)
 594       ]
 595     ];
 596 END
 597 (* }}} *)
 598
 599 (** {2 API implementation} *)
 600
 601 let exc_located_wrapper f =
 602   try
 603     f ()
 604   with
 605   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 606       raise (Parse_error (floc, msg))
 607   | Stdpp.Exc_located (floc, exn) ->
 608       raise (Parse_error (floc, (Printexc.to_string exn)))
 609
 610 let parse_level1_pattern stream =
 611   exc_located_wrapper (fun () -> Grammar.Entry.parse level1_pattern stream)
 612 let parse_level2_ast stream =
 613   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_ast stream)
 614 let parse_level2_meta stream =
 615   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_meta stream)
 616
 617 let _ =
 618   parse_level1_pattern_ref := parse_level1_pattern;
 619   parse_level2_ast_ref := parse_level2_ast;
 620   parse_level2_meta_ref := parse_level2_meta
 621
 622 (** {2 Debugging} *)
 623
 624 let print_l2_pattern () =
 625   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 626   Format.pp_print_flush Format.std_formatter ();
 627   flush stdout
 628
 629 (* vim:set encoding=utf8 foldmethod=marker: *)