helm/ocaml/cic_notation/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open CicNotationEnv
  29 open CicNotationPt
  30
  31 exception Parse_error of Token.flocation * string
  32 exception Level_not_found of int
  33
  34 let level1_pattern_grammar =
  35   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  36 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  37 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  38
  39 let min_precedence = 0
  40 let max_precedence = 100
  41 let default_precedence = 50
  42
  43 let let_in_prec = 10
  44 let binder_prec = 20
  45 let apply_prec = 70
  46 let simple_prec = 90
  47
  48 let let_in_assoc = Gramext.NonA
  49 let binder_assoc = Gramext.RightA
  50 let apply_assoc = Gramext.LeftA
  51 let simple_assoc = Gramext.NonA
  52
  53 let level1_pattern =
  54   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  55 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  56 let term = Grammar.Entry.create level2_ast_grammar "term"
  57 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  58
  59 let level3_term = Grammar.Entry.create level2_ast_grammar "level3_term"
  60 let notation =  (* level1 <-> level 2 *)
  61   Grammar.Entry.create level2_ast_grammar "notation"
  62 let interpretation =    (* level2 <-> level 3 *)
  63   Grammar.Entry.create level2_ast_grammar "interpretation"
  64 let phrase = Grammar.Entry.create level2_ast_grammar "phrase"
  65
  66 let return_term loc term = ()
  67
  68 let fail floc msg =
  69   let (x, y) = loc_of_floc floc in
  70   failwith (sprintf "Error at characters %d - %d: %s" x y msg)
  71
  72 let int_of_string s =
  73   try
  74     Pervasives.int_of_string s
  75   with Failure _ ->
  76     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  77
  78 (** {2 Grammar extension} *)
  79
  80 let symbol s = Gramext.Stoken ("SYMBOL", s)
  81 let ident s = Gramext.Stoken ("IDENT", s)
  82 let number s = Gramext.Stoken ("NUMBER", s)
  83
  84 let g_symbol_of_literal =
  85   function
  86   | `Symbol s -> symbol s
  87   | `Keyword s -> ident s
  88   | `Number s -> number s
  89
  90 type binding =
  91   | NoBinding
  92   | Binding of string * value_type
  93   | Env of (string * value_type) list
  94
  95 let make_action action bindings =
  96   let rec aux (vl : CicNotationEnv.t) =
  97     function
  98       [] -> Gramext.action (fun (loc: location) -> action vl loc)
  99     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
 100     (* LUCA: DEFCON 5 BEGIN *)
 101     | Binding (name, TermType) :: tl ->
 102         Gramext.action
 103           (fun (v:term) -> aux ((name, (TermType, TermValue v))::vl) tl)
 104     | Binding (name, StringType) :: tl ->
 105         Gramext.action
 106           (fun (v:string) ->
 107             aux ((name, (StringType, StringValue v)) :: vl) tl)
 108     | Binding (name, NumType) :: tl ->
 109         Gramext.action
 110           (fun (v:string) -> aux ((name, (NumType, NumValue v)) :: vl) tl)
 111     | Binding (name, OptType t) :: tl ->
 112         Gramext.action
 113           (fun (v:'a option) ->
 114             aux ((name, (OptType t, OptValue v)) :: vl) tl)
 115     | Binding (name, ListType t) :: tl ->
 116         Gramext.action
 117           (fun (v:'a list) ->
 118             aux ((name, (ListType t, ListValue v)) :: vl) tl)
 119     | Env _ :: tl ->
 120         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 121     (* LUCA: DEFCON 5 END *)
 122   in
 123     aux [] (List.rev bindings)
 124
 125 let flatten_opt =
 126   let rec aux acc =
 127     function
 128       [] -> List.rev acc
 129     | NoBinding :: tl -> aux acc tl
 130     | Env names :: tl -> aux (List.rev names @ acc) tl
 131     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 132   in
 133   aux []
 134
 135   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 136 let extract_term_production pattern =
 137   let rec aux = function
 138     | AttributedTerm (_, t) -> aux t
 139     | Literal l -> aux_literal l
 140     | Layout l -> aux_layout l
 141     | Magic m -> aux_magic m
 142     | Variable v -> aux_variable v
 143     | t ->
 144         prerr_endline (CicNotationPp.pp_term t);
 145         assert false
 146   and aux_literal =
 147     function
 148     | `Symbol s -> [NoBinding, symbol s]
 149     | `Keyword s -> [NoBinding, ident s]
 150     | `Number s -> [NoBinding, number s]
 151   and aux_layout = function
 152     | Sub (p1, p2) -> aux p1 @ [NoBinding, symbol "\\sub"] @ aux p2
 153     | Sup (p1, p2) -> aux p1 @ [NoBinding, symbol "\\sup"] @ aux p2
 154     | Below (p1, p2) -> aux p1 @ [NoBinding, symbol "\\below"] @ aux p2
 155     | Above (p1, p2) -> aux p1 @ [NoBinding, symbol "\\above"] @ aux p2
 156     | Frac (p1, p2) -> aux p1 @ [NoBinding, symbol "\\frac"] @ aux p2
 157     | Atop (p1, p2) -> aux p1 @ [NoBinding, symbol "\\atop"] @ aux p2
 158     | Over (p1, p2) -> aux p1 @ [NoBinding, symbol "\\over"] @ aux p2
 159     | Root (p1, p2) ->
 160         [NoBinding, symbol "\\root"] @ aux p2 @ [NoBinding, symbol "\\of"]
 161         @ aux p1
 162     | Sqrt p -> [NoBinding, symbol "\\sqrt"] @ aux p
 163     | Break -> []
 164     | Box (_, pl) -> List.flatten (List.map aux pl)
 165   and aux_magic magic =
 166     match magic with
 167     | Opt p ->
 168         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 169         let action (env_opt : CicNotationEnv.t option) (loc : location) =
 170           match env_opt with
 171           | Some env -> List.map opt_binding_some env
 172           | None -> List.map opt_binding_of_name p_names
 173         in
 174         [ Env (List.map opt_declaration p_names),
 175           Gramext.srules
 176             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 177               Gramext.action action ] ]
 178     | List0 (p, _)
 179     | List1 (p, _) ->
 180         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 181 (*         let env0 = List.map list_binding_of_name p_names in
 182         let grow_env_entry env n v =
 183           List.map
 184             (function
 185               | (n', (ty, ListValue vl)) as entry ->
 186                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 187               | _ -> assert false)
 188             env
 189         in
 190         let grow_env env_i env =
 191           List.fold_left
 192             (fun env (n, (_, v)) -> grow_env_entry env n v)
 193             env env_i
 194         in *)
 195         let action (env_list : CicNotationEnv.t list) (loc : location) =
 196           CicNotationEnv.coalesce_env p_names env_list
 197         in
 198         let g_symbol s =
 199           match magic with
 200           | List0 (_, None) -> Gramext.Slist0 s
 201           | List1 (_, None) -> Gramext.Slist1 s
 202           | List0 (_, Some l) -> Gramext.Slist0sep (s, g_symbol_of_literal l)
 203           | List1 (_, Some l) -> Gramext.Slist1sep (s, g_symbol_of_literal l)
 204           | _ -> assert false
 205         in
 206         [ Env (List.map list_declaration p_names),
 207           Gramext.srules
 208             [ [ g_symbol (Gramext.srules [ p_atoms, p_action ]) ],
 209               Gramext.action action ] ]
 210     | _ -> assert false
 211   and aux_variable =
 212     function
 213     | NumVar s -> [Binding (s, NumType), number ""]
 214     | TermVar s -> [Binding (s, TermType), Gramext.Sself]
 215     | IdentVar s -> [Binding (s, StringType), ident ""]
 216     | Ascription (p, s) -> assert false (* TODO *)
 217     | FreshVar _ -> assert false
 218   and inner_pattern p =
 219     let p_bindings, p_atoms = List.split (aux p) in
 220     let p_names = flatten_opt p_bindings in
 221     let action =
 222       make_action (fun (env : CicNotationEnv.t) (loc : location) -> env)
 223         p_bindings
 224     in
 225     p_bindings, p_atoms, p_names, action
 226   in
 227   aux pattern
 228
 229 let level_of_int precedence =
 230   if precedence < min_precedence || precedence > max_precedence then
 231     raise (Level_not_found precedence);
 232   string_of_int precedence
 233
 234 type rule_id = Token.t Gramext.g_symbol list
 235
 236 let extend level1_pattern ?(precedence = default_precedence)
 237   ?associativity action
 238 =
 239   let p_bindings, p_atoms =
 240     List.split (extract_term_production level1_pattern)
 241   in
 242   let level = level_of_int precedence in
 243   let p_names = flatten_opt p_bindings in
 244   let _ =
 245     Grammar.extend
 246       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 247         Some (Gramext.Level level),
 248         [ None,
 249           associativity,
 250           [ p_atoms,
 251             (make_action
 252               (fun (env: CicNotationEnv.t) (loc: location) -> (action env loc))
 253               p_bindings) ]]]
 254   in
 255   p_atoms
 256
 257 let delete atoms = Grammar.delete_rule term atoms
 258
 259 (** {2 Grammar} *)
 260
 261 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 262 let parse_level2_ast_ref = ref (fun _ -> assert false)
 263 let parse_level2_meta_ref = ref (fun _ -> assert false)
 264
 265 let fold_binder binder pt_names body =
 266   let fold_cluster binder terms ty body =
 267     List.fold_right
 268       (fun term body -> Binder (binder, (term, ty), body))
 269       terms body  (* terms are names: either Ident or FreshVar *)
 270   in
 271   List.fold_right
 272     (fun (names, ty) body -> fold_cluster binder names ty body)
 273     pt_names body
 274
 275 let return_term loc term = AttributedTerm (`Loc loc, term)
 276
 277 let _ = (* create empty precedence level for "term" *)
 278   let mk_level_list first last =
 279     let rec aux acc = function
 280       | i when i < first -> acc
 281       | i -> aux ((Some (string_of_int i), None, []) :: acc) (i - 1)
 282     in
 283     aux [] last
 284   in
 285   Grammar.extend
 286     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 287       None,
 288       mk_level_list min_precedence max_precedence ]
 289
 290 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 291 EXTEND
 292   GLOBAL: level1_pattern;
 293
 294   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 295   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 296   literal: [
 297     [ s = SYMBOL -> `Symbol s
 298     | k = QKEYWORD -> `Keyword k
 299     | n = NUMBER -> `Number n
 300     ]
 301   ];
 302   sep:       [ [ "sep";      sep = literal -> sep ] ];
 303 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 304   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 305   l1_magic_pattern: [
 306     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> List0 (p, sep)
 307     | "list1"; p = l1_simple_pattern; sep = OPT sep -> List1 (p, sep)
 308     | "opt";   p = l1_simple_pattern -> Opt p
 309     ]
 310   ];
 311   l1_pattern_variable: [
 312     [ "term"; id = IDENT -> TermVar id
 313     | "number"; id = IDENT -> NumVar id
 314     | "ident"; id = IDENT -> IdentVar id
 315     ]
 316   ];
 317   l1_simple_pattern:
 318     [ "layout" LEFTA
 319       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 320           return_term loc (Layout (Sub (p1, p2)))
 321       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 322           return_term loc (Layout (Sup (p1, p2)))
 323       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 324           return_term loc (Layout (Below (p1, p2)))
 325       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 326           return_term loc (Layout (Above (p1, p2)))
 327       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 328           return_term loc (Layout (Over (p1, p2)))
 329       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 330           return_term loc (Layout (Atop (p1, p2)))
 331 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 332           return_term loc (Array (p, csep, rsep)) *)
 333       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 334           return_term loc (Layout (Frac (p1, p2)))
 335       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Layout (Sqrt p))
 336       | SYMBOL "\\root"; index = SELF; SYMBOL "\\OF"; arg = SELF ->
 337           return_term loc (Layout (Root (arg, index)))
 338       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 339           return_term loc (CicNotationUtil.boxify p)
 340       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 341           return_term loc (CicNotationUtil.boxify p)
 342       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 343           return_term loc (CicNotationUtil.boxify p)
 344       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 345           return_term loc (CicNotationUtil.boxify p)
 346       | "break" -> return_term loc (Layout Break)
 347 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 348       | "LPAREN"; p = l1_pattern; "RPAREN" ->
 349           return_term loc (CicNotationUtil.boxify p)
 350       ]
 351     | "simple" NONA
 352       [ i = IDENT -> return_term loc (Variable (TermVar i))
 353       | m = l1_magic_pattern -> return_term loc (Magic m)
 354       | v = l1_pattern_variable -> return_term loc (Variable v)
 355       | l = literal -> return_term loc (Literal l)
 356       ]
 357     ];
 358   END
 359 (* }}} *)
 360
 361
 362 EXTEND
 363   GLOBAL: level2_meta;
 364   l2_variable: [
 365     [ "term"; id = IDENT -> TermVar id
 366     | "number"; id = IDENT -> NumVar id
 367     | "ident"; id = IDENT -> IdentVar id
 368     | "fresh"; id = IDENT -> FreshVar id
 369     | "anonymous" -> TermVar "_"
 370     | id = IDENT -> TermVar id
 371     ]
 372   ];
 373   l2_magic: [
 374     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 375       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 376         Fold (kind, base, [id], recursive)
 377     | "default"; some = level2_meta; none = level2_meta -> Default (some, none)
 378     | "if"; p_test = level2_meta;
 379       "then"; p_true = level2_meta;
 380       "else"; p_false = level2_meta ->
 381         If (p_test, p_true, p_false)
 382     | "fail" -> Fail
 383     ]
 384   ];
 385   level2_meta: [
 386     [ magic = l2_magic -> Magic magic
 387     | var = l2_variable -> Variable var
 388     | blob = UNPARSED_AST -> !parse_level2_ast_ref (Stream.of_string blob)
 389     ]
 390   ];
 391 END
 392
 393 EXTEND
 394   GLOBAL: level2_ast term
 395           level3_term
 396           notation interpretation
 397           phrase;
 398 (* {{{ Grammar for ast patterns, notation level 2 *)
 399   level2_ast: [ [ p = term -> p ] ];
 400   sort: [
 401     [ IDENT "Prop" -> `Prop
 402     | IDENT "Set" -> `Set
 403     | IDENT "Type" -> `Type
 404     ]
 405   ];
 406   explicit_subst: [
 407     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 408       SYMBOL "[";
 409       substs = LIST1 [
 410         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 411       ] SEP SYMBOL ";";
 412       SYMBOL "]" ->
 413         substs
 414     ]
 415   ];
 416   meta_subst: [
 417     [ s = SYMBOL "_" -> None
 418     | p = term -> Some p ]
 419   ];
 420   meta_substs: [
 421     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 422   ];
 423   possibly_typed_name: [
 424     [ LPAREN; id = bound_name; SYMBOL ":"; typ = term; RPAREN ->
 425         id, Some typ
 426     | id = bound_name -> id, None
 427     ]
 428   ];
 429   match_pattern: [
 430     [ id = IDENT -> id, []
 431     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 432         id, vars
 433     ]
 434   ];
 435   binder: [
 436     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 437     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 438     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 439     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 440     ]
 441   ];
 442   bound_name: [
 443     [ i = IDENT -> Ident (i, None)
 444     | SYMBOL "\\FRESH"; i = IDENT -> Variable (FreshVar i)
 445     ]
 446   ];
 447   bound_names: [
 448     [ vars = LIST1 bound_name SEP SYMBOL ",";
 449       ty = OPT [ SYMBOL ":"; p = term -> p ] ->
 450         [ vars, ty ]
 451     | clusters = LIST1 [
 452         LPAREN;
 453         vars = LIST1 bound_name SEP SYMBOL ",";
 454         ty = OPT [ SYMBOL ":"; p = term -> p ];
 455         RPAREN ->
 456           vars, ty
 457       ] ->
 458         clusters
 459     ]
 460   ];
 461   induction_kind: [
 462     [ IDENT "rec" -> `Inductive
 463     | IDENT "corec" -> `CoInductive
 464     ]
 465   ];
 466   let_defs: [
 467     [ defs = LIST1 [
 468         name = bound_name; args = bound_names;
 469         index_name = OPT [ IDENT "on"; id = bound_name -> id ];
 470         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 471         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 472           let body = fold_binder `Lambda args body in
 473           let ty =
 474             match ty with
 475             | None -> None
 476             | Some ty -> Some (fold_binder `Pi args ty)
 477           in
 478           let rec position_of name p = function
 479             | [] -> None, p
 480             | n :: _ when n = name -> Some p, p
 481             | _ :: tl -> position_of name (p + 1) tl
 482           in
 483           let rec find_arg name n = function
 484             | [] ->
 485                 fail loc (sprintf "Argument %s not found"
 486                   (CicNotationPp.pp_term name))
 487             | (l,_) :: tl ->
 488                 (match position_of name 0 l with
 489                 | None, len -> find_arg name (n + len) tl
 490                 | Some where, len -> n + where)
 491           in
 492           let index =
 493             match index_name with
 494             | None -> 0
 495             | Some name -> find_arg name 0 args
 496           in
 497           (name, ty), body, index
 498       ] SEP IDENT "and" ->
 499         defs
 500     ]
 501   ];
 502   term: LEVEL "10"  (* let in *)
 503     [ "10" NONA
 504       [ IDENT "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 505         p1 = term; "in"; p2 = term ->
 506           return_term loc (LetIn (var, p1, p2))
 507       | IDENT "let"; k = induction_kind; defs = let_defs; IDENT "in";
 508         body = term ->
 509           return_term loc (LetRec (k, defs, body))
 510       ]
 511     ];
 512   term: LEVEL "20"  (* binder *)
 513     [ "20" RIGHTA
 514       [ b = binder; names = bound_names; SYMBOL "."; body = term ->
 515           return_term loc (fold_binder b names body)
 516       ]
 517     ];
 518   term: LEVEL "70"  (* apply *)
 519     [ "70" LEFTA
 520       [ p1 = term; p2 = term ->
 521           let rec aux = function
 522             | Appl (hd :: tl)
 523             | AttributedTerm (_, Appl (hd :: tl)) ->
 524                 aux hd @ tl
 525             | term -> [term]
 526           in
 527           return_term loc (Appl (aux p1 @ [p2]))
 528       ]
 529     ];
 530   term: LEVEL "90"  (* simple *)
 531     [ "90" NONA
 532       [ id = IDENT -> return_term loc (Ident (id, None))
 533       | id = IDENT; s = explicit_subst -> return_term loc (Ident (id, Some s))
 534       | s = CSYMBOL -> return_term loc (Symbol (s, 0))
 535       | u = URI -> return_term loc (Uri (u, None))
 536       | n = NUMBER -> return_term loc (Num (n, 0))
 537       | IMPLICIT -> return_term loc (Implicit)
 538       | m = META -> return_term loc (Meta (int_of_string m, []))
 539       | m = META; s = meta_substs -> return_term loc (Meta (int_of_string m, s))
 540       | s = sort -> return_term loc (Sort s)
 541       | outtyp = OPT [ SYMBOL "["; ty = term; SYMBOL "]" -> ty ];
 542         IDENT "match"; t = term;
 543         indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
 544         IDENT "with"; SYMBOL "[";
 545         patterns = LIST0 [
 546           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 547           rhs = term ->
 548             lhs, rhs
 549         ] SEP SYMBOL "|";
 550         SYMBOL "]" ->
 551           return_term loc (Case (t, indty_ident, outtyp, patterns))
 552       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 553           return_term loc (Appl [ Symbol ("cast", 0); p1; p2 ])
 554       | LPAREN; p = term; RPAREN -> p
 555       | blob = UNPARSED_META -> !parse_level2_meta_ref (Stream.of_string blob)
 556       ]
 557     ];
 558 (* }}} *)
 559 (* {{{ Grammar for interpretation, notation level 3 *)
 560   argument: [
 561     [ id = IDENT -> IdentArg (0, id)
 562     | l = LIST1 [ SYMBOL <:unicode<eta>> (* η *) -> () ] SEP SYMBOL ".";
 563       SYMBOL "."; id = IDENT ->
 564         IdentArg (List.length l, id)
 565     ]
 566   ];
 567   level3_term: [
 568     [ u = URI -> UriPattern (UriManager.uri_of_string u)
 569     | id = IDENT -> VarPattern id
 570     | LPAREN; terms = LIST1 SELF; RPAREN ->
 571         (match terms with
 572         | [] -> assert false
 573         | [term] -> term
 574         | terms -> ApplPattern terms)
 575     ]
 576   ];
 577 (* }}} *)
 578 (* {{{ Notation glues *)
 579   associativity: [
 580     [ IDENT "left";  IDENT "associative" -> Gramext.LeftA
 581     | IDENT "right"; IDENT "associative" -> Gramext.RightA
 582     | IDENT "non"; IDENT "associative" -> Gramext.NonA
 583     ]
 584   ];
 585   precedence: [
 586     [ IDENT "with"; IDENT "precedence"; n = NUMBER -> int_of_string n ]
 587   ];
 588   notation: [
 589     [ s = QSTRING;
 590       assoc = OPT associativity; prec = OPT precedence;
 591       IDENT "for";
 592       p2 =
 593         [ blob = UNPARSED_AST -> !parse_level2_ast_ref (Stream.of_string blob)
 594         | blob = UNPARSED_META ->
 595             !parse_level2_meta_ref (Stream.of_string blob) ]
 596       ->
 597         (!parse_level1_pattern_ref (Stream.of_string s), assoc, prec, p2)
 598     ]
 599   ];
 600   interpretation: [
 601     [ s = CSYMBOL; args = LIST1 argument; SYMBOL "="; t = level3_term ->
 602         (s, args, t)
 603     ]
 604   ];
 605 (* }}} *)
 606 (* {{{ Top-level phrases *)
 607   phrase: [
 608     [ IDENT "print"; t = term; SYMBOL "." -> Print t
 609     | IDENT "notation"; (l1, assoc, prec, l2) = notation; SYMBOL "." ->
 610         Notation (l1, assoc, prec, l2)
 611     | IDENT "interpretation"; (symbol, args, l3) = interpretation; SYMBOL "." ->
 612         Interpretation ((symbol, args), l3)
 613     | IDENT "render"; u = URI; SYMBOL "." -> Render (UriManager.uri_of_string u)
 614     ]
 615   ];
 616 (* }}} *)
 617 END
 618
 619 (** {2 API implementation} *)
 620
 621 let exc_located_wrapper f =
 622   try
 623     f ()
 624   with
 625   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 626       raise (Parse_error (floc, msg))
 627   | Stdpp.Exc_located (floc, exn) ->
 628       raise (Parse_error (floc, (Printexc.to_string exn)))
 629
 630 let parse_level1_pattern stream =
 631   exc_located_wrapper (fun () -> Grammar.Entry.parse level1_pattern stream)
 632 let parse_level2_ast stream =
 633   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_ast stream)
 634 let parse_level2_meta stream =
 635   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_meta stream)
 636 let parse_interpretation stream =
 637   exc_located_wrapper (fun () -> Grammar.Entry.parse level3_term stream)
 638 let parse_phrase stream =
 639   exc_located_wrapper (fun () -> Grammar.Entry.parse phrase stream)
 640
 641 let _ =
 642   parse_level1_pattern_ref := parse_level1_pattern;
 643   parse_level2_ast_ref := parse_level2_ast;
 644   parse_level2_meta_ref := parse_level2_meta
 645
 646 (** {2 Debugging} *)
 647
 648 let print_l2_pattern () =
 649   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 650   Format.pp_print_flush Format.std_formatter ();
 651   flush stdout
 652
 653 (* vim:set encoding=utf8 foldmethod=marker: *)