helm/ocaml/cic_notation/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open CicNotationEnv
  29 open CicNotationPt
  30
  31 exception Parse_error of Token.flocation * string
  32 exception Level_not_found of int
  33
  34 let level1_pattern_grammar =
  35   Grammar.gcreate CicNotationLexer.level1_pattern_lexer
  36 let level2_ast_grammar = Grammar.gcreate CicNotationLexer.level2_ast_lexer
  37 let level2_meta_grammar = Grammar.gcreate CicNotationLexer.level2_meta_lexer
  38
  39 let min_precedence = 0
  40 let max_precedence = 100
  41 let default_precedence = 50
  42
  43 let level1_pattern =
  44   Grammar.Entry.create level1_pattern_grammar "level1_pattern"
  45 let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast"
  46 let term = Grammar.Entry.create level2_ast_grammar "term"
  47 let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs"
  48 let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta"
  49
  50 let return_term loc term = ()
  51
  52 let int_of_string s =
  53   try
  54     Pervasives.int_of_string s
  55   with Failure _ ->
  56     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  57
  58 (** {2 Grammar extension} *)
  59
  60 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  61 let gram_ident s = Gramext.Stoken ("IDENT", s)
  62 let gram_number s = Gramext.Stoken ("NUMBER", s)
  63 let gram_keyword s = Gramext.Stoken ("", s)
  64 let gram_term = Gramext.Sself
  65
  66 let gram_of_literal =
  67   function
  68   | `Symbol s -> gram_symbol s
  69   | `Keyword s -> gram_keyword s
  70   | `Number s -> gram_number s
  71
  72 type binding =
  73   | NoBinding
  74   | Binding of string * value_type
  75   | Env of (string * value_type) list
  76
  77 let make_action action bindings =
  78   let rec aux (vl : CicNotationEnv.t) =
  79     function
  80       [] -> Gramext.action (fun (loc: location) -> action vl loc)
  81     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  82     (* LUCA: DEFCON 5 BEGIN *)
  83     | Binding (name, TermType) :: tl ->
  84         Gramext.action
  85           (fun (v:term) -> aux ((name, (TermType, TermValue v))::vl) tl)
  86     | Binding (name, StringType) :: tl ->
  87         Gramext.action
  88           (fun (v:string) ->
  89             aux ((name, (StringType, StringValue v)) :: vl) tl)
  90     | Binding (name, NumType) :: tl ->
  91         Gramext.action
  92           (fun (v:string) -> aux ((name, (NumType, NumValue v)) :: vl) tl)
  93     | Binding (name, OptType t) :: tl ->
  94         Gramext.action
  95           (fun (v:'a option) ->
  96             aux ((name, (OptType t, OptValue v)) :: vl) tl)
  97     | Binding (name, ListType t) :: tl ->
  98         Gramext.action
  99           (fun (v:'a list) ->
 100             aux ((name, (ListType t, ListValue v)) :: vl) tl)
 101     | Env _ :: tl ->
 102         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 103     (* LUCA: DEFCON 5 END *)
 104   in
 105     aux [] (List.rev bindings)
 106
 107 let flatten_opt =
 108   let rec aux acc =
 109     function
 110       [] -> List.rev acc
 111     | NoBinding :: tl -> aux acc tl
 112     | Env names :: tl -> aux (List.rev names @ acc) tl
 113     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 114   in
 115   aux []
 116
 117   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 118 let extract_term_production pattern =
 119   let rec aux = function
 120     | AttributedTerm (_, t) -> aux t
 121     | Literal l -> aux_literal l
 122     | Layout l -> aux_layout l
 123     | Magic m -> aux_magic m
 124     | Variable v -> aux_variable v
 125     | t ->
 126         prerr_endline (CicNotationPp.pp_term t);
 127         assert false
 128   and aux_literal =
 129     function
 130     | `Symbol s -> [NoBinding, gram_symbol s]
 131     | `Keyword s ->
 132         (* assumption: s will be registered as a keyword with the lexer *)
 133         [NoBinding, gram_keyword s]
 134     | `Number s -> [NoBinding, gram_number s]
 135   and aux_layout = function
 136     | Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub"] @ aux p2
 137     | Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup"] @ aux p2
 138     | Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below"] @ aux p2
 139     | Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above"] @ aux p2
 140     | Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac"] @ aux p2
 141     | Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop"] @ aux p2
 142     | Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over"] @ aux p2
 143     | Root (p1, p2) ->
 144         [NoBinding, gram_symbol "\\root"] @ aux p2
 145         @ [NoBinding, gram_symbol "\\of"] @ aux p1
 146     | Sqrt p -> [NoBinding, gram_symbol "\\sqrt"] @ aux p
 147     | Break -> []
 148     | Box (_, pl) -> List.flatten (List.map aux pl)
 149     | Group pl -> List.flatten (List.map aux pl)
 150   and aux_magic magic =
 151     match magic with
 152     | Opt p ->
 153         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 154         let action (env_opt : CicNotationEnv.t option) (loc : location) =
 155           match env_opt with
 156           | Some env -> List.map opt_binding_some env
 157           | None -> List.map opt_binding_of_name p_names
 158         in
 159         [ Env (List.map opt_declaration p_names),
 160           Gramext.srules
 161             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 162               Gramext.action action ] ]
 163     | List0 (p, _)
 164     | List1 (p, _) ->
 165         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 166 (*         let env0 = List.map list_binding_of_name p_names in
 167         let grow_env_entry env n v =
 168           List.map
 169             (function
 170               | (n', (ty, ListValue vl)) as entry ->
 171                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 172               | _ -> assert false)
 173             env
 174         in
 175         let grow_env env_i env =
 176           List.fold_left
 177             (fun env (n, (_, v)) -> grow_env_entry env n v)
 178             env env_i
 179         in *)
 180         let action (env_list : CicNotationEnv.t list) (loc : location) =
 181           CicNotationEnv.coalesce_env p_names env_list
 182         in
 183         let gram_of_list s =
 184           match magic with
 185           | List0 (_, None) -> Gramext.Slist0 s
 186           | List1 (_, None) -> Gramext.Slist1 s
 187           | List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 188           | List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 189           | _ -> assert false
 190         in
 191         [ Env (List.map list_declaration p_names),
 192           Gramext.srules
 193             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 194               Gramext.action action ] ]
 195     | _ -> assert false
 196   and aux_variable =
 197     function
 198     | NumVar s -> [Binding (s, NumType), gram_number ""]
 199     | TermVar s -> [Binding (s, TermType), gram_term]
 200     | IdentVar s -> [Binding (s, StringType), gram_ident ""]
 201     | Ascription (p, s) -> assert false (* TODO *)
 202     | FreshVar _ -> assert false
 203   and inner_pattern p =
 204     let p_bindings, p_atoms = List.split (aux p) in
 205     let p_names = flatten_opt p_bindings in
 206     let action =
 207       make_action (fun (env : CicNotationEnv.t) (loc : location) -> env)
 208         p_bindings
 209     in
 210     p_bindings, p_atoms, p_names, action
 211   in
 212   aux pattern
 213
 214 let level_of_int precedence =
 215   if precedence < min_precedence || precedence > max_precedence then
 216     raise (Level_not_found precedence);
 217   string_of_int precedence
 218
 219 type rule_id = Token.t Gramext.g_symbol list
 220
 221   (* mapping: rule_id -> owned keywords. (rule_id, string list) Hashtbl.t *)
 222 let owned_keywords = Hashtbl.create 23
 223
 224 let extend level1_pattern ?(precedence = default_precedence)
 225   ?associativity action
 226 =
 227   let p_bindings, p_atoms =
 228     List.split (extract_term_production level1_pattern)
 229   in
 230   let level = level_of_int precedence in
 231   let p_names = flatten_opt p_bindings in
 232   let _ =
 233     Grammar.extend
 234       [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 235         Some (Gramext.Level level),
 236         [ None,
 237           associativity,
 238           [ p_atoms,
 239             (make_action
 240               (fun (env: CicNotationEnv.t) (loc: location) -> (action env loc))
 241               p_bindings) ]]]
 242   in
 243   let keywords = CicNotationUtil.keywords_of_term level1_pattern in
 244   let rule_id = p_atoms in
 245   List.iter CicNotationLexer.add_level2_ast_keyword keywords;
 246   Hashtbl.add owned_keywords rule_id keywords;  (* keywords may be [] *)
 247   rule_id
 248
 249 let delete rule_id =
 250   let atoms = rule_id in
 251   (try
 252     let keywords = Hashtbl.find owned_keywords rule_id in
 253     List.iter CicNotationLexer.remove_level2_ast_keyword keywords
 254   with Not_found -> assert false);
 255   Grammar.delete_rule term atoms
 256
 257 (** {2 Grammar} *)
 258
 259 let parse_level1_pattern_ref = ref (fun _ -> assert false)
 260 let parse_level2_ast_ref = ref (fun _ -> assert false)
 261 let parse_level2_meta_ref = ref (fun _ -> assert false)
 262
 263 let fold_cluster binder terms ty body =
 264   List.fold_right
 265     (fun term body -> Binder (binder, (term, ty), body))
 266     terms body  (* terms are names: either Ident or FreshVar *)
 267
 268 let fold_binder binder pt_names body =
 269   List.fold_right
 270     (fun (names, ty) body -> fold_cluster binder names ty body)
 271     pt_names body
 272
 273 let return_term loc term = AttributedTerm (`Loc loc, term)
 274
 275 let _ = (* create empty precedence level for "term" *)
 276   let mk_level_list first last =
 277     let rec aux acc = function
 278       | i when i < first -> acc
 279       | i -> aux ((Some (string_of_int i), None, []) :: acc) (i - 1)
 280     in
 281     aux [] last
 282   in
 283   Grammar.extend
 284     [ Grammar.Entry.obj (term: 'a Grammar.Entry.e),
 285       None,
 286       mk_level_list min_precedence max_precedence ]
 287
 288 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 289 EXTEND
 290   GLOBAL: level1_pattern;
 291
 292   level1_pattern: [ [ p = l1_pattern; EOI -> CicNotationUtil.boxify p ] ];
 293   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 294   literal: [
 295     [ s = SYMBOL -> `Symbol s
 296     | k = QKEYWORD -> `Keyword k
 297     | n = NUMBER -> `Number n
 298     ]
 299   ];
 300   sep:       [ [ "sep";      sep = literal -> sep ] ];
 301 (*   row_sep:   [ [ "rowsep";   sep = literal -> sep ] ];
 302   field_sep: [ [ "fieldsep"; sep = literal -> sep ] ]; *)
 303   l1_magic_pattern: [
 304     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> List0 (p, sep)
 305     | "list1"; p = l1_simple_pattern; sep = OPT sep -> List1 (p, sep)
 306     | "opt";   p = l1_simple_pattern -> Opt p
 307     ]
 308   ];
 309   l1_pattern_variable: [
 310     [ "term"; id = IDENT -> TermVar id
 311     | "number"; id = IDENT -> NumVar id
 312     | "ident"; id = IDENT -> IdentVar id
 313     ]
 314   ];
 315   l1_simple_pattern:
 316     [ "layout" LEFTA
 317       [ p1 = SELF; SYMBOL "\\sub"; p2 = SELF ->
 318           return_term loc (Layout (Sub (p1, p2)))
 319       | p1 = SELF; SYMBOL "\\sup"; p2 = SELF ->
 320           return_term loc (Layout (Sup (p1, p2)))
 321       | p1 = SELF; SYMBOL "\\below"; p2 = SELF ->
 322           return_term loc (Layout (Below (p1, p2)))
 323       | p1 = SELF; SYMBOL "\\above"; p2 = SELF ->
 324           return_term loc (Layout (Above (p1, p2)))
 325       | p1 = SELF; SYMBOL "\\over"; p2 = SELF ->
 326           return_term loc (Layout (Over (p1, p2)))
 327       | p1 = SELF; SYMBOL "\\atop"; p2 = SELF ->
 328           return_term loc (Layout (Atop (p1, p2)))
 329 (*       | "array"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 330           return_term loc (Array (p, csep, rsep)) *)
 331       | SYMBOL "\\frac"; p1 = SELF; p2 = SELF ->
 332           return_term loc (Layout (Frac (p1, p2)))
 333       | SYMBOL "\\sqrt"; p = SELF -> return_term loc (Layout (Sqrt p))
 334       | SYMBOL "\\root"; index = SELF; SYMBOL "\\OF"; arg = SELF ->
 335           return_term loc (Layout (Root (arg, index)))
 336       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 337           return_term loc (Layout (Box ((H, false, false), p)))
 338       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 339           return_term loc (Layout (Box ((V, false, false), p)))
 340       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 341           return_term loc (Layout (Box ((HV, false, false), p)))
 342       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 343           return_term loc (Layout (Box ((HOV, false, false), p)))
 344       | "break" -> return_term loc (Layout Break)
 345 (*       | SYMBOL "\\SPACE" -> return_term loc (Layout Space) *)
 346       | LPAREN; p = l1_pattern; RPAREN ->
 347           return_term loc (CicNotationUtil.group p)
 348       ]
 349     | "simple" NONA
 350       [ i = IDENT -> return_term loc (Variable (TermVar i))
 351       | m = l1_magic_pattern -> return_term loc (Magic m)
 352       | v = l1_pattern_variable -> return_term loc (Variable v)
 353       | l = literal -> return_term loc (Literal l)
 354       ]
 355     ];
 356   END
 357 (* }}} *)
 358
 359
 360 EXTEND
 361   GLOBAL: level2_meta;
 362   l2_variable: [
 363     [ "term"; id = IDENT -> TermVar id
 364     | "number"; id = IDENT -> NumVar id
 365     | "ident"; id = IDENT -> IdentVar id
 366     | "fresh"; id = IDENT -> FreshVar id
 367     | "anonymous" -> TermVar "_"
 368     | id = IDENT -> TermVar id
 369     ]
 370   ];
 371   l2_magic: [
 372     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 373       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 374         Fold (kind, base, [id], recursive)
 375     | "default"; some = level2_meta; none = level2_meta -> Default (some, none)
 376     | "if"; p_test = level2_meta;
 377       "then"; p_true = level2_meta;
 378       "else"; p_false = level2_meta ->
 379         If (p_test, p_true, p_false)
 380     | "fail" -> Fail
 381     ]
 382   ];
 383   level2_meta: [
 384     [ magic = l2_magic -> Magic magic
 385     | var = l2_variable -> Variable var
 386     | blob = UNPARSED_AST -> !parse_level2_ast_ref (Stream.of_string blob)
 387     ]
 388   ];
 389 END
 390
 391 EXTEND
 392   GLOBAL: level2_ast term let_defs;
 393 (* {{{ Grammar for ast patterns, notation level 2 *)
 394   level2_ast: [ [ p = term -> p ] ];
 395   sort: [
 396     [ "Prop" -> `Prop
 397     | "Set" -> `Set
 398     | "Type" -> `Type
 399     ]
 400   ];
 401   explicit_subst: [
 402     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 403       SYMBOL "[";
 404       substs = LIST1 [
 405         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 406       ] SEP SYMBOL ";";
 407       SYMBOL "]" ->
 408         substs
 409     ]
 410   ];
 411   meta_subst: [
 412     [ s = SYMBOL "_" -> None
 413     | p = term -> Some p ]
 414   ];
 415   meta_substs: [
 416     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 417   ];
 418   possibly_typed_name: [
 419     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 420         id, Some typ
 421     | arg = single_arg -> arg, None
 422     ]
 423   ];
 424   match_pattern: [
 425     [ id = IDENT -> id, []
 426     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 427         id, vars
 428     ]
 429   ];
 430   binder: [
 431     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 432     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 433     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 434     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 435     ]
 436   ];
 437   arg: [
 438     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 439       SYMBOL ":"; ty = term; RPAREN ->
 440         List.map (fun n -> Ident (n, None)) names, Some ty
 441     | name = IDENT -> [Ident (name, None)], None
 442     | blob = UNPARSED_META ->
 443         let meta = !parse_level2_meta_ref (Stream.of_string blob) in
 444         match meta with
 445         | Variable (FreshVar _) -> [meta], None
 446         | Variable (TermVar "_") -> [Ident ("_", None)], None
 447         | _ -> failwith "Invalid bound name."
 448    ]
 449   ];
 450   single_arg: [
 451     [ name = IDENT -> Ident (name, None)
 452     | blob = UNPARSED_META ->
 453         let meta = !parse_level2_meta_ref (Stream.of_string blob) in
 454         match meta with
 455         | Variable (FreshVar _) -> meta
 456         | Variable (TermVar "_") -> Ident ("_", None)
 457         | _ -> failwith "Invalid index name."
 458     ]
 459   ];
 460   induction_kind: [
 461     [ "rec" -> `Inductive
 462     | "corec" -> `CoInductive
 463     ]
 464   ];
 465   let_defs: [
 466     [ defs = LIST1 [
 467         name = single_arg;
 468         args = LIST1 arg;
 469         index_name = OPT [ "on"; id = single_arg -> id ];
 470         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 471         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 472           let body = fold_binder `Lambda args body in
 473           let ty =
 474             match ty with
 475             | None -> None
 476             | Some ty -> Some (fold_binder `Pi args ty)
 477           in
 478           let rec position_of name p = function
 479             | [] -> None, p
 480             | n :: _ when n = name -> Some p, p
 481             | _ :: tl -> position_of name (p + 1) tl
 482           in
 483           let rec find_arg name n = function
 484             | [] ->
 485                 fail loc (sprintf "Argument %s not found"
 486                   (CicNotationPp.pp_term name))
 487             | (l,_) :: tl ->
 488                 (match position_of name 0 l with
 489                 | None, len -> find_arg name (n + len) tl
 490                 | Some where, len -> n + where)
 491           in
 492           let index =
 493             match index_name with
 494             | None -> 0
 495             | Some index_name -> find_arg index_name 0 args
 496           in
 497           (name, ty), body, index
 498       ] SEP "and" ->
 499         defs
 500     ]
 501   ];
 502   binder_vars: [
 503     [ vars = [
 504           l = LIST1 single_arg SEP SYMBOL "," -> l
 505         | SYMBOL "_" -> [Ident ("_", None)] ];
 506       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 507     | LPAREN;
 508         vars = [
 509             l =  LIST1 single_arg SEP SYMBOL "," -> l
 510           | SYMBOL "_" -> [Ident ("_", None)] ];
 511       typ = OPT [ SYMBOL ":"; t = term -> t ];
 512       RPAREN -> (vars, typ)
 513     ]
 514   ];
 515   term: LEVEL "10"  (* let in *)
 516     [ "10" NONA
 517       [ "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 518         p1 = term; "in"; p2 = term ->
 519           return_term loc (LetIn (var, p1, p2))
 520       | "let"; k = induction_kind; defs = let_defs; "in";
 521         body = term ->
 522           return_term loc (LetRec (k, defs, body))
 523       ]
 524     ];
 525   term: LEVEL "20"  (* binder *)
 526     [ "20" RIGHTA
 527       [ b = binder; (vars, typ) = binder_vars; SYMBOL "."; body = term ->
 528           return_term loc (fold_cluster b vars typ body)
 529       ]
 530     ];
 531   term: LEVEL "70"  (* apply *)
 532     [ "70" LEFTA
 533       [ p1 = term; p2 = term ->
 534           let rec aux = function
 535             | Appl (hd :: tl)
 536             | AttributedTerm (_, Appl (hd :: tl)) ->
 537                 aux hd @ tl
 538             | term -> [term]
 539           in
 540           return_term loc (Appl (aux p1 @ [p2]))
 541       ]
 542     ];
 543   term: LEVEL "90"  (* simple *)
 544     [ "90" NONA
 545       [ id = IDENT -> return_term loc (Ident (id, None))
 546       | id = IDENT; s = explicit_subst -> return_term loc (Ident (id, Some s))
 547       | s = CSYMBOL -> return_term loc (Symbol (s, 0))
 548       | u = URI -> return_term loc (Uri (u, None))
 549       | n = NUMBER -> return_term loc (Num (n, 0))
 550       | IMPLICIT -> return_term loc (Implicit)
 551       | PLACEHOLDER -> return_term loc UserInput
 552       | m = META -> return_term loc (Meta (int_of_string m, []))
 553       | m = META; s = meta_substs -> return_term loc (Meta (int_of_string m, s))
 554       | s = sort -> return_term loc (Sort s)
 555       | outtyp = OPT [ SYMBOL "["; ty = term; SYMBOL "]" -> ty ];
 556         "match"; t = term;
 557         indty_ident = OPT [ "in"; id = IDENT -> id ];
 558         "with"; SYMBOL "[";
 559         patterns = LIST0 [
 560           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 561           rhs = term ->
 562             lhs, rhs
 563         ] SEP SYMBOL "|";
 564         SYMBOL "]" ->
 565           return_term loc (Case (t, indty_ident, outtyp, patterns))
 566       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 567           return_term loc (Cast (p1, p2))
 568       | LPAREN; p = term; RPAREN -> p
 569       | blob = UNPARSED_META -> !parse_level2_meta_ref (Stream.of_string blob)
 570       ]
 571     ];
 572 (* }}} *)
 573 END
 574
 575 (** {2 API implementation} *)
 576
 577 let exc_located_wrapper f =
 578   try
 579     f ()
 580   with
 581   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 582       raise (Parse_error (floc, msg))
 583   | Stdpp.Exc_located (floc, exn) ->
 584       raise (Parse_error (floc, (Printexc.to_string exn)))
 585
 586 let parse_level1_pattern stream =
 587   exc_located_wrapper (fun () -> Grammar.Entry.parse level1_pattern stream)
 588 let parse_level2_ast stream =
 589   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_ast stream)
 590 let parse_level2_meta stream =
 591   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_meta stream)
 592
 593 let _ =
 594   parse_level1_pattern_ref := parse_level1_pattern;
 595   parse_level2_ast_ref := parse_level2_ast;
 596   parse_level2_meta_ref := parse_level2_meta
 597
 598 (** {2 Debugging} *)
 599
 600 let print_l2_pattern () =
 601   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj term);
 602   Format.pp_print_flush Format.std_formatter ();
 603   flush stdout
 604
 605 (* vim:set encoding=utf8 foldmethod=marker: *)