helm/ocaml/cic_notation/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open CicNotationEnv
  29 open CicNotationPt
  30
  31 exception Parse_error of Token.flocation * string
  32 exception Level_not_found of int
  33
  34 let grammar = Grammar.gcreate CicNotationLexer.notation_lexer
  35
  36 let min_precedence = 0
  37 let max_precedence = 100
  38 let default_precedence = 50
  39
  40 let level1_pattern = Grammar.Entry.create grammar "level1_pattern"
  41 let level2_pattern = Grammar.Entry.create grammar "level2_pattern"
  42 let level3_term = Grammar.Entry.create grammar "level3_term"
  43 let l2_pattern = Grammar.Entry.create grammar "l2_pattern"
  44 let notation = Grammar.Entry.create grammar "notation" (* level1 <-> level 2 *)
  45 let interpretation =
  46   Grammar.Entry.create grammar "interpretation" (* level2 <-> level 3 *)
  47 let phrase = Grammar.Entry.create grammar "phrase"
  48
  49 let return_term loc term = ()
  50
  51 let fail floc msg =
  52   let (x, y) = loc_of_floc floc in
  53   failwith (sprintf "Error at characters %d - %d: %s" x y msg)
  54
  55 let int_of_string s =
  56   try
  57     Pervasives.int_of_string s
  58   with Failure _ ->
  59     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  60
  61 (** {2 Grammar extension} *)
  62
  63 let symbol s = Gramext.Stoken ("SYMBOL", s)
  64 let ident s = Gramext.Stoken ("IDENT", s)
  65 let number s = Gramext.Stoken ("NUMBER", s)
  66 let term = Gramext.Sself
  67
  68 let g_symbol_of_literal =
  69   function
  70   | `Symbol s -> symbol s
  71   | `Keyword s -> ident s
  72   | `Number s -> number s
  73
  74 type binding =
  75   | NoBinding
  76   | Binding of string * value_type
  77   | Env of (string * value_type) list
  78
  79 let make_action action bindings =
  80   let rec aux (vl : CicNotationEnv.t) =
  81     function
  82       [] -> Gramext.action (fun (loc: location) -> action vl loc)
  83     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
  84     (* LUCA: DEFCON 5 BEGIN *)
  85     | Binding (name, TermType) :: tl ->
  86         Gramext.action
  87           (fun (v:term) -> aux ((name, (TermType, TermValue v))::vl) tl)
  88     | Binding (name, StringType) :: tl ->
  89         Gramext.action
  90           (fun (v:string) ->
  91             aux ((name, (StringType, StringValue v)) :: vl) tl)
  92     | Binding (name, NumType) :: tl ->
  93         Gramext.action
  94           (fun (v:string) -> aux ((name, (NumType, NumValue v)) :: vl) tl)
  95     | Binding (name, OptType t) :: tl ->
  96         Gramext.action
  97           (fun (v:'a option) ->
  98             aux ((name, (OptType t, OptValue v)) :: vl) tl)
  99     | Binding (name, ListType t) :: tl ->
 100         Gramext.action
 101           (fun (v:'a list) ->
 102             aux ((name, (ListType t, ListValue v)) :: vl) tl)
 103     | Env _ :: tl ->
 104         Gramext.action (fun (v:CicNotationEnv.t) -> aux (v @ vl) tl)
 105     (* LUCA: DEFCON 5 END *)
 106   in
 107     aux [] (List.rev bindings)
 108
 109 let flatten_opt =
 110   let rec aux acc =
 111     function
 112       [] -> List.rev acc
 113     | NoBinding :: tl -> aux acc tl
 114     | Env names :: tl -> aux (List.rev names @ acc) tl
 115     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 116   in
 117   aux []
 118
 119   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 120 let extract_term_production pattern =
 121   let rec aux = function
 122     | AttributedTerm (_, t) -> aux t
 123     | Literal l -> aux_literal l
 124     | Layout l -> aux_layout l
 125     | Magic m -> aux_magic m
 126     | Variable v -> aux_variable v
 127     | t ->
 128         prerr_endline (CicNotationPp.pp_term t);
 129         assert false
 130   and aux_literal =
 131     function
 132     | `Symbol s -> [NoBinding, symbol s]
 133     | `Keyword s -> [NoBinding, ident s]
 134     | `Number s -> [NoBinding, number s]
 135   and aux_layout = function
 136     | Sub (p1, p2) -> aux p1 @ [NoBinding, symbol "\\SUB"] @ aux p2
 137     | Sup (p1, p2) -> aux p1 @ [NoBinding, symbol "\\SUP"] @ aux p2
 138     | Below (p1, p2) -> aux p1 @ [NoBinding, symbol "\\BELOW"] @ aux p2
 139     | Above (p1, p2) -> aux p1 @ [NoBinding, symbol "\\ABOVE"] @ aux p2
 140     | Frac (p1, p2) -> aux p1 @ [NoBinding, symbol "\\FRAC"] @ aux p2
 141     | Atop (p1, p2) -> aux p1 @ [NoBinding, symbol "\\ATOP"] @ aux p2
 142     | Over (p1, p2) -> aux p1 @ [NoBinding, symbol "\\OVER"] @ aux p2
 143     | Root (p1, p2) ->
 144         [NoBinding, symbol "\\ROOT"] @ aux p2 @ [NoBinding, symbol "\\OF"]
 145         @ aux p1
 146     | Sqrt p -> [NoBinding, symbol "\\SQRT"] @ aux p
 147     | Break -> []
 148     | Box (_, pl) -> List.flatten (List.map aux pl)
 149   and aux_magic magic =
 150     match magic with
 151     | Opt p ->
 152         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 153         let action (env_opt : CicNotationEnv.t option) (loc : location) =
 154           match env_opt with
 155           | Some env -> List.map opt_binding_some env
 156           | None -> List.map opt_binding_of_name p_names
 157         in
 158         [ Env (List.map opt_declaration p_names),
 159           Gramext.srules
 160             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 161               Gramext.action action ] ]
 162     | List0 (p, _)
 163     | List1 (p, _) ->
 164         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 165 (*         let env0 = List.map list_binding_of_name p_names in
 166         let grow_env_entry env n v =
 167           List.map
 168             (function
 169               | (n', (ty, ListValue vl)) as entry ->
 170                   if n' = n then n', (ty, ListValue (v :: vl)) else entry
 171               | _ -> assert false)
 172             env
 173         in
 174         let grow_env env_i env =
 175           List.fold_left
 176             (fun env (n, (_, v)) -> grow_env_entry env n v)
 177             env env_i
 178         in *)
 179         let action (env_list : CicNotationEnv.t list) (loc : location) =
 180           CicNotationEnv.coalesce_env p_names env_list
 181         in
 182         let g_symbol s =
 183           match magic with
 184           | List0 (_, None) -> Gramext.Slist0 s
 185           | List1 (_, None) -> Gramext.Slist1 s
 186           | List0 (_, Some l) -> Gramext.Slist0sep (s, g_symbol_of_literal l)
 187           | List1 (_, Some l) -> Gramext.Slist1sep (s, g_symbol_of_literal l)
 188           | _ -> assert false
 189         in
 190         [ Env (List.map list_declaration p_names),
 191           Gramext.srules
 192             [ [ g_symbol (Gramext.srules [ p_atoms, p_action ]) ],
 193               Gramext.action action ] ]
 194     | _ -> assert false
 195   and aux_variable =
 196     function
 197     | NumVar s -> [Binding (s, NumType), number ""]
 198     | TermVar s -> [Binding (s, TermType), term]
 199     | IdentVar s -> [Binding (s, StringType), ident ""]
 200     | Ascription (p, s) -> assert false (* TODO *)
 201     | FreshVar _ -> assert false
 202   and inner_pattern p =
 203     let p_bindings, p_atoms = List.split (aux p) in
 204     let p_names = flatten_opt p_bindings in
 205     let _ = prerr_endline ("inner names: " ^ String.concat " " (List.map fst p_names)) in
 206     let action =
 207       make_action (fun (env : CicNotationEnv.t) (loc : location) -> env)
 208         p_bindings
 209     in
 210     p_bindings, p_atoms, p_names, action
 211   in
 212   aux pattern
 213
 214 let level_of_int precedence =
 215   if precedence < min_precedence || precedence > max_precedence then
 216     raise (Level_not_found precedence);
 217   string_of_int precedence
 218
 219 type rule_id = Token.t Gramext.g_symbol list
 220
 221 let extend level1_pattern ?(precedence = default_precedence)
 222   ?associativity action
 223 =
 224   let p_bindings, p_atoms =
 225     List.split (extract_term_production level1_pattern)
 226   in
 227   let level = level_of_int precedence in
 228   let p_names = flatten_opt p_bindings in
 229   let _ =
 230     prerr_endline (string_of_int (List.length p_bindings));
 231     Grammar.extend
 232       [ Grammar.Entry.obj (l2_pattern: 'a Grammar.Entry.e),
 233         Some (Gramext.Level level),
 234         [ None,
 235           associativity,
 236           [ p_atoms,
 237             (make_action
 238               (fun (env: CicNotationEnv.t) (loc: location) -> (action env loc))
 239               p_bindings) ]]]
 240   in
 241   p_atoms
 242
 243 let delete atoms = Grammar.delete_rule l2_pattern atoms
 244
 245 (** {2 Grammar} *)
 246
 247 let fold_binder binder pt_names body =
 248   let fold_cluster binder terms ty body =
 249     List.fold_right
 250       (fun term body -> Binder (binder, (term, ty), body))
 251       terms body  (* terms are names: either Ident or FreshVar *)
 252   in
 253   List.fold_right
 254     (fun (names, ty) body -> fold_cluster binder names ty body)
 255     pt_names body
 256
 257 let return_term loc term = AttributedTerm (`Loc loc, term)
 258
 259 let _ = (* create empty precedence level for "l2_pattern" *)
 260   let mk_level_list first last =
 261     let rec aux acc = function
 262       | i when i < first -> acc
 263       | i -> aux ((Some (string_of_int i), None, []) :: acc) (i - 1)
 264     in
 265     aux [] last
 266   in
 267   Grammar.extend
 268     [ Grammar.Entry.obj (l2_pattern: 'a Grammar.Entry.e),
 269       None,
 270       mk_level_list min_precedence max_precedence ]
 271
 272 EXTEND
 273   GLOBAL: level1_pattern level2_pattern level3_term
 274           l2_pattern
 275           notation interpretation
 276           phrase;
 277 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 278   level1_pattern: [ [ p = l1_simple_pattern -> p ] ];
 279   l1_pattern: [ [ p = LIST1 l1_simple_pattern -> p ] ];
 280   literal: [
 281     [ s = SYMBOL -> `Symbol s
 282     | k = KEYWORD -> `Keyword k
 283     | n = NUMBER -> `Number n
 284     ]
 285   ];
 286   sep:       [ [ SYMBOL "\\SEP";      sep = literal -> sep ] ];
 287 (*   row_sep:   [ [ SYMBOL "\\ROWSEP";   sep = literal -> sep ] ];
 288   field_sep: [ [ SYMBOL "\\FIELDSEP"; sep = literal -> sep ] ]; *)
 289   l1_magic_pattern: [
 290     [ SYMBOL "\\LIST0"; p = l1_simple_pattern; sep = OPT sep -> List0 (p, sep)
 291     | SYMBOL "\\LIST1"; p = l1_simple_pattern; sep = OPT sep -> List1 (p, sep)
 292     | SYMBOL "\\OPT";   p = l1_simple_pattern -> Opt p
 293     ]
 294   ];
 295   l1_pattern_variable: [
 296     [ SYMBOL "\\TERM"; id = IDENT -> TermVar id
 297     | SYMBOL "\\NUM"; id = IDENT -> NumVar id
 298     | SYMBOL "\\IDENT"; id = IDENT -> IdentVar id
 299     ]
 300   ];
 301   l1_simple_pattern:
 302     [ "layout" LEFTA
 303       [ p1 = SELF; SYMBOL "\\SUB"; p2 = SELF ->
 304           return_term loc (Layout (Sub (p1, p2)))
 305       | p1 = SELF; SYMBOL "\\SUP"; p2 = SELF ->
 306           return_term loc (Layout (Sup (p1, p2)))
 307       | p1 = SELF; SYMBOL "\\BELOW"; p2 = SELF ->
 308           return_term loc (Layout (Below (p1, p2)))
 309       | p1 = SELF; SYMBOL "\\ABOVE"; p2 = SELF ->
 310           return_term loc (Layout (Above (p1, p2)))
 311       | p1 = SELF; SYMBOL "\\OVER"; p2 = SELF ->
 312           return_term loc (Layout (Over (p1, p2)))
 313       | p1 = SELF; SYMBOL "\\ATOP"; p2 = SELF ->
 314           return_term loc (Layout (Atop (p1, p2)))
 315 (*       | SYMBOL "\\ARRAY"; p = SELF; csep = OPT field_sep; rsep = OPT row_sep ->
 316           return_term loc (Array (p, csep, rsep)) *)
 317       | SYMBOL "\\FRAC"; p1 = SELF; p2 = SELF ->
 318           return_term loc (Layout (Frac (p1, p2)))
 319       | SYMBOL "\\SQRT"; p = SELF -> return_term loc (Layout (Sqrt p))
 320       | SYMBOL "\\ROOT"; index = SELF; SYMBOL "\\OF"; arg = SELF ->
 321           return_term loc (Layout (Root (arg, index)));
 322       | SYMBOL "\\HBOX"; DELIM "\\["; p = l1_pattern; DELIM "\\]" ->
 323           return_term loc (Layout (Box (H, p)))
 324       | SYMBOL "\\VBOX"; DELIM "\\["; p = l1_pattern; DELIM "\\]" ->
 325           return_term loc (Layout (Box (V, p)))
 326       | SYMBOL "\\BREAK" -> return_term loc (Layout Break)
 327       | DELIM "\\["; p = l1_pattern; DELIM "\\]" ->
 328           return_term loc (CicNotationUtil.boxify p)
 329       | p = SELF; SYMBOL "\\AS"; id = IDENT ->
 330           return_term loc (Variable (Ascription (p, id)))
 331       ]
 332     | "simple" NONA
 333       [ i = IDENT -> return_term loc (Ident (i, None))
 334       | m = l1_magic_pattern -> return_term loc (Magic m)
 335       | v = l1_pattern_variable -> return_term loc (Variable v)
 336       | l = literal -> return_term loc (Literal l)
 337       ]
 338     ];
 339 (* }}} *)
 340 (* {{{ Grammar for ast patterns, notation level 2 *)
 341   level2_pattern: [ [ p = l2_pattern -> p ] ];
 342   sort: [
 343     [ SYMBOL "\\PROP" -> `Prop
 344     | SYMBOL "\\SET" -> `Set
 345     | SYMBOL "\\TYPE" -> `Type
 346     ]
 347   ];
 348   explicit_subst: [
 349     [ SYMBOL "\\subst";  (* to avoid catching frequent "a [1]" cases *)
 350       SYMBOL "[";
 351       substs = LIST1 [
 352         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = l2_pattern -> (i, t)
 353       ] SEP SYMBOL ";";
 354       SYMBOL "]" ->
 355         substs
 356     ]
 357   ];
 358   meta_subst: [
 359     [ s = SYMBOL "_" -> None
 360     | p = l2_pattern -> Some p ]
 361   ];
 362   meta_substs: [
 363     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 364   ];
 365   possibly_typed_name: [
 366     [ SYMBOL "("; id = bound_name; SYMBOL ":"; typ = l2_pattern; SYMBOL ")" ->
 367         id, Some typ
 368     | id = bound_name -> id, None
 369     ]
 370   ];
 371   match_pattern: [
 372     [ id = IDENT -> id, []
 373     | SYMBOL "("; id = IDENT; vars = LIST1 possibly_typed_name; SYMBOL ")" ->
 374         id, vars
 375     ]
 376   ];
 377   binder: [
 378     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 379     | SYMBOL <:unicode<exists>> (* ∃ *) -> `Exists
 380     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 381     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 382     ]
 383   ];
 384   bound_name: [
 385     [ i = IDENT -> Ident (i, None)
 386     | SYMBOL "\\FRESH"; i = IDENT -> Variable (FreshVar i)
 387     ]
 388   ];
 389   bound_names: [
 390     [ vars = LIST1 bound_name SEP SYMBOL ",";
 391       ty = OPT [ SYMBOL ":"; p = l2_pattern -> p ] ->
 392         [ vars, ty ]
 393     | clusters = LIST1 [
 394         SYMBOL "(";
 395         vars = LIST1 bound_name SEP SYMBOL ",";
 396         ty = OPT [ SYMBOL ":"; p = l2_pattern -> p ];
 397         SYMBOL ")" ->
 398           vars, ty
 399       ] ->
 400         clusters
 401     ]
 402   ];
 403   induction_kind: [
 404     [ IDENT "rec" -> `Inductive
 405     | IDENT "corec" -> `CoInductive
 406     ]
 407   ];
 408   let_defs: [
 409     [ defs = LIST1 [
 410         name = bound_name; args = bound_names;
 411         index_name = OPT [ IDENT "on"; id = bound_name -> id ];
 412         ty = OPT [ SYMBOL ":" ; p = l2_pattern -> p ];
 413         SYMBOL <:unicode<def>> (* ≝ *); body = l2_pattern ->
 414           let body = fold_binder `Lambda args body in
 415           let ty =
 416             match ty with
 417             | None -> None
 418             | Some ty -> Some (fold_binder `Pi args ty)
 419           in
 420           let rec position_of name p = function
 421             | [] -> None, p
 422             | n :: _ when n = name -> Some p, p
 423             | _ :: tl -> position_of name (p + 1) tl
 424           in
 425           let rec find_arg name n = function
 426             | [] ->
 427                 fail loc (sprintf "Argument %s not found"
 428                   (CicNotationPp.pp_term name))
 429             | (l,_) :: tl ->
 430                 (match position_of name 0 l with
 431                 | None, len -> find_arg name (n + len) tl
 432                 | Some where, len -> n + where)
 433           in
 434           let index =
 435             match index_name with
 436             | None -> 0
 437             | Some name -> find_arg name 0 args
 438           in
 439           (name, ty), body, index
 440       ] SEP IDENT "and" ->
 441         defs
 442     ]
 443   ];
 444   l2_pattern_variable: [
 445     [ SYMBOL "\\TERM"; id = IDENT -> TermVar id
 446     | SYMBOL "\\NUM"; id = IDENT -> NumVar id
 447     | SYMBOL "\\IDENT"; id = IDENT -> IdentVar id
 448     | SYMBOL "\\FRESH"; id = IDENT -> FreshVar id
 449     ]
 450   ];
 451   l2_magic_pattern: [
 452     [ SYMBOL "\\FOLD";
 453       kind = [ IDENT "left" -> `Left | IDENT "right" -> `Right ];
 454       DELIM "\\["; base = l2_pattern; DELIM "\\]";
 455       SYMBOL "\\LAMBDA"; id = IDENT;
 456       DELIM "\\["; recursive = l2_pattern; DELIM "\\]" ->
 457         Fold (kind, base, [id], recursive)
 458     | SYMBOL "\\DEFAULT";
 459       DELIM "\\["; some = l2_pattern; DELIM "\\]";
 460       DELIM "\\["; none = l2_pattern; DELIM "\\]" ->
 461         Default (some, none)
 462     ]
 463   ];
 464   l2_pattern: LEVEL "10"  (* let in *)
 465     [ "10" NONA
 466       [ IDENT "let"; var = possibly_typed_name; SYMBOL <:unicode<def>> (* ≝ *);
 467         p1 = l2_pattern; "in"; p2 = l2_pattern ->
 468           return_term loc (LetIn (var, p1, p2))
 469       | IDENT "let"; k = induction_kind; defs = let_defs; IDENT "in";
 470         body = l2_pattern ->
 471           return_term loc (LetRec (k, defs, body))
 472       ]
 473     ];
 474   l2_pattern: LEVEL "20"  (* binder *)
 475     [ "20" RIGHTA
 476       [ b = binder; names = bound_names; SYMBOL "."; body = l2_pattern ->
 477           return_term loc (fold_binder b names body)
 478       ]
 479     ];
 480   l2_pattern: LEVEL "70"  (* apply *)
 481     [ "70" LEFTA
 482       [ p1 = l2_pattern; p2 = l2_pattern ->
 483           let rec aux = function
 484             | Appl (hd :: tl)
 485             | AttributedTerm (_, Appl (hd :: tl)) ->
 486                 aux hd @ tl
 487             | term -> [term]
 488           in
 489           return_term loc (Appl (aux p1 @ [p2]))
 490       ]
 491     ];
 492   l2_pattern: LEVEL "90"  (* simple *)
 493     [ "90" NONA
 494       [ id = IDENT -> return_term loc (Ident (id, None))
 495       | id = IDENT; s = explicit_subst -> return_term loc (Ident (id, Some s))
 496       | s = CSYMBOL -> return_term loc (Symbol (s, 0))
 497       | u = URI -> return_term loc (Uri (u, None))
 498       | n = NUMBER -> return_term loc (Num (n, 0))
 499       | IMPLICIT -> return_term loc (Implicit)
 500       | m = META -> return_term loc (Meta (int_of_string m, []))
 501       | m = META; s = meta_substs -> return_term loc (Meta (int_of_string m, s))
 502       | s = sort -> return_term loc (Sort s)
 503       | outtyp = OPT [ SYMBOL "["; ty = l2_pattern; SYMBOL "]" -> ty ];
 504         IDENT "match"; t = l2_pattern;
 505         indty_ident = OPT [ SYMBOL ":"; id = IDENT -> id ];
 506         IDENT "with"; SYMBOL "[";
 507         patterns = LIST0 [
 508           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 509           rhs = l2_pattern ->
 510             lhs, rhs
 511         ] SEP SYMBOL "|";
 512         SYMBOL "]" ->
 513           return_term loc (Case (t, indty_ident, outtyp, patterns))
 514       | SYMBOL "("; p1 = l2_pattern; SYMBOL ":"; p2 = l2_pattern; SYMBOL ")" ->
 515           return_term loc (Appl [ Symbol ("cast", 0); p1; p2 ])
 516       | SYMBOL "("; p = l2_pattern; SYMBOL ")" -> p
 517       | v = l2_pattern_variable -> return_term loc (Variable v)
 518       | m = l2_magic_pattern -> return_term loc (Magic m)
 519       ]
 520     ];
 521 (* }}} *)
 522 (* {{{ Grammar for interpretation, notation level 3 *)
 523   argument: [
 524     [ id = IDENT -> IdentArg (0, id)
 525     | l = LIST1 [ SYMBOL <:unicode<eta>> (* η *) -> () ] SEP SYMBOL ".";
 526       SYMBOL "."; id = IDENT ->
 527         IdentArg (List.length l, id)
 528     ]
 529   ];
 530   level3_term: [
 531     [ u = URI -> UriPattern u
 532     | id = IDENT -> VarPattern id
 533     | SYMBOL "("; terms = LIST1 SELF; SYMBOL ")" ->
 534         (match terms with
 535         | [] -> assert false
 536         | [term] -> term
 537         | terms -> ApplPattern terms)
 538     ]
 539   ];
 540 (* }}} *)
 541 (* {{{ Notation glues *)
 542   associativity: [
 543     [ IDENT "left";  IDENT "associative" -> Gramext.LeftA
 544     | IDENT "right"; IDENT "associative" -> Gramext.RightA
 545     | IDENT "non"; IDENT "associative" -> Gramext.NonA
 546     ]
 547   ];
 548   precedence: [
 549     [ IDENT "with"; IDENT "precedence"; n = NUMBER -> int_of_string n ]
 550   ];
 551   notation: [
 552     [ p1 = level1_pattern;
 553       assoc = OPT associativity; prec = OPT precedence;
 554       IDENT "for"; p2 = level2_pattern ->
 555         (p1, assoc, prec, p2)
 556     ]
 557   ];
 558   interpretation: [
 559     [ s = CSYMBOL; args = LIST1 argument; SYMBOL "="; t = level3_term ->
 560         (s, args, t)
 561     ]
 562   ];
 563 (* }}} *)
 564 (* {{{ Top-level phrases *)
 565   phrase: [
 566     [ IDENT "print"; p2 = level2_pattern; SYMBOL "." -> Print p2
 567     | IDENT "notation"; (l1, assoc, prec, l2) = notation; SYMBOL "." ->
 568         Notation (l1, assoc, prec, l2)
 569     | IDENT "interpretation"; (symbol, args, l3) = interpretation; SYMBOL "." ->
 570         Interpretation ((symbol, args), l3)
 571     | IDENT "render"; u = URI; SYMBOL "." -> Render (UriManager.uri_of_string u)
 572     ]
 573   ];
 574 (* }}} *)
 575 END
 576
 577 (** {2 API implementation} *)
 578
 579 let exc_located_wrapper f =
 580   try
 581     f ()
 582   with
 583   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 584       raise (Parse_error (floc, msg))
 585   | Stdpp.Exc_located (floc, exn) ->
 586       raise (Parse_error (floc, (Printexc.to_string exn)))
 587
 588 let parse_syntax_pattern stream =
 589   exc_located_wrapper (fun () -> Grammar.Entry.parse level1_pattern stream)
 590 let parse_ast_pattern stream =
 591   exc_located_wrapper (fun () -> Grammar.Entry.parse level2_pattern stream)
 592 let parse_interpretation stream =
 593   exc_located_wrapper (fun () -> Grammar.Entry.parse level3_term stream)
 594 let parse_phrase stream =
 595   exc_located_wrapper (fun () -> Grammar.Entry.parse phrase stream)
 596
 597 (** {2 Debugging} *)
 598
 599 let print_l2_pattern () =
 600   Grammar.print_entry Format.std_formatter (Grammar.Entry.obj l2_pattern);
 601   Format.pp_print_flush Format.std_formatter ();
 602   flush stdout
 603
 604 (* vim:set encoding=utf8 foldmethod=marker: *)