helm/ocaml/cic_notation/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open CicNotationEnv
  29 open CicNotationPt
  30
  31   (* when set to true debugging information, not in sync with input syntax, will
  32    * be added to the output of pp_term.
  33    * set to false if you need, for example, cut and paste from matitac output to
  34    * matitatop *)
  35 let debug_printing = true
  36
  37 let pp_binder = function
  38   | `Lambda -> "lambda"
  39   | `Pi -> "Pi"
  40   | `Exists -> "exists"
  41   | `Forall -> "forall"
  42
  43 let pp_literal = function  (* debugging version *)
  44   | `Symbol s -> sprintf "symbol(%s)" s
  45   | `Keyword s -> sprintf "keyword(%s)" s
  46   | `Number s -> sprintf "number(%s)" s
  47
  48 (* let pp_literal = function
  49   | `Symbol s
  50   | `Keyword s
  51   | `Number s -> s *)
  52
  53 let rec pp_term ?(pp_parens = true) t =
  54   let t_pp =
  55     match t with
  56     | AttributedTerm (`Href _, term) when debug_printing ->
  57         sprintf "#[%s]" (pp_term ~pp_parens:false term)
  58     | AttributedTerm (_, term) when debug_printing ->
  59         sprintf "@[%s]" (pp_term ~pp_parens:false term)
  60     | AttributedTerm (`Raw text, _) -> text
  61     | AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  62
  63     | Appl terms ->
  64         sprintf "%s" (String.concat " " (List.map pp_term terms))
  65     | Binder (`Forall, (Ident ("_", None), typ), body)
  66     | Binder (`Pi, (Ident ("_", None), typ), body) ->
  67         sprintf "%s \\to %s"
  68           (match typ with None -> "?" | Some typ -> pp_term typ)
  69           (pp_term body)
  70     | Binder (kind, var, body) ->
  71         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable var)
  72           (pp_term body)
  73     | Case (term, indtype, typ, patterns) ->
  74         sprintf "%smatch %s with %s"
  75           (match typ with None -> "" | Some t -> sprintf "[%s]" (pp_term t))
  76           (pp_term term) (pp_patterns patterns)
  77     | Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term t1) (pp_term t2)
  78     | LetIn (var, t1, t2) ->
  79         sprintf "let %s = %s in %s" (pp_capture_variable var) (pp_term t1)
  80           (pp_term t2)
  81     | LetRec (kind, definitions, term) ->
  82         sprintf "let %s %s in %s"
  83           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
  84           (String.concat " and "
  85             (List.map
  86               (fun (var, body, _) ->
  87                 sprintf "%s = %s" (pp_capture_variable var) (pp_term body))
  88               definitions))
  89           (pp_term term)
  90     | Ident (name, Some []) | Ident (name, None)
  91     | Uri (name, Some []) | Uri (name, None) ->
  92         name
  93     | Ident (name, Some substs)
  94     | Uri (name, Some substs) ->
  95         sprintf "%s \\subst [%s]" name (pp_substs substs)
  96     | Implicit -> "?"
  97     | Meta (index, substs) ->
  98         sprintf "%d[%s]" index
  99           (String.concat "; "
 100             (List.map (function None -> "_" | Some t -> pp_term t) substs))
 101     | Num (num, _) -> num
 102     | Sort `Set -> "Set"
 103     | Sort `Prop -> "Prop"
 104     | Sort `Type -> "Type"
 105     | Sort `CProp -> "CProp"
 106     | Symbol (name, _) -> "'" ^ name
 107
 108     | UserInput -> ""
 109
 110     | Literal l -> pp_literal l
 111     | Layout l -> pp_layout l
 112     | Magic m -> pp_magic m
 113     | Variable v -> pp_variable v
 114   in
 115   if pp_parens then sprintf "(%s)" t_pp
 116   else t_pp
 117
 118 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 119 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 120
 121 and pp_pattern ((head, vars), term) =
 122   sprintf "%s \\Rightarrow %s"
 123     (match vars with
 124     | [] -> head
 125     | _ ->
 126         sprintf "(%s %s)" head
 127           (String.concat " " (List.map pp_capture_variable vars)))
 128     (pp_term term)
 129
 130 and pp_patterns patterns =
 131   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 132
 133 and pp_capture_variable = function
 134   | term, None -> pp_term term
 135   | term, Some typ -> "(" ^ pp_term term ^ ": " ^ pp_term typ ^ ")"
 136
 137 and pp_box_spec (kind, spacing, indent) =
 138   let int_of_bool b = if b then 1 else 0 in
 139   let kind_string =
 140     match kind with H -> "H" | V -> "V" | HV -> "HV" | HOV -> "HOV"
 141   in
 142   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 143
 144 and pp_layout = function
 145   | Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 146   | Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 147   | Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 148   | Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 149   | Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 150   | Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 151   | Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 152   | Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 153   | Root (arg, index) ->
 154       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 155   | Break -> "\\BREAK"
 156 (*   | Space -> "\\SPACE" *)
 157   | Box (box_spec, terms) ->
 158       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 159         (String.concat " " (List.map pp_term terms))
 160   | Group terms ->
 161       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 162
 163 and pp_magic = function
 164   | List0 (t, sep_opt) -> sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 165   | List1 (t, sep_opt) -> sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 166   | Opt t -> sprintf "opt %s" (pp_term t)
 167   | Fold (kind, p_base, names, p_rec) ->
 168       let acc = match names with acc :: _ -> acc | _ -> assert false in
 169       sprintf "fold %s %s rec %s %s"
 170         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 171   | Default (p_some, p_none) ->
 172       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 173   | If (p_test, p_true, p_false) ->
 174       sprintf "if %s then %s else %s"
 175         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 176   | Fail -> "fail"
 177
 178 and pp_fold_kind = function
 179   | `Left -> "left"
 180   | `Right -> "right"
 181
 182 and pp_sep_opt = function
 183   | None -> ""
 184   | Some sep -> sprintf " sep %s" (pp_literal sep)
 185
 186 and pp_variable = function
 187   | NumVar s -> "number " ^ s
 188   | IdentVar s -> "ident " ^ s
 189   | TermVar s -> "term " ^ s
 190   | Ascription (t, n) -> assert false
 191   | FreshVar n -> "fresh " ^ n
 192
 193 let pp_term t = pp_term ~pp_parens:false t
 194
 195 let rec pp_value = function
 196   | TermValue t -> sprintf "$%s$" (pp_term t)
 197   | StringValue s -> sprintf "\"%s\"" s
 198   | NumValue n -> n
 199   | OptValue (Some v) -> "Some " ^ pp_value v
 200   | OptValue None -> "None"
 201   | ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 202
 203 let rec pp_value_type =
 204   function
 205   | TermType -> "Term"
 206   | StringType -> "String"
 207   | NumType -> "Number"
 208   | OptType t -> "Maybe " ^ pp_value_type t
 209   | ListType l -> "List " ^ pp_value_type l
 210
 211 let pp_env env =
 212   String.concat "; "
 213     (List.map
 214       (fun (name, (ty, value)) ->
 215         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 216       env)
 217