helm/ocaml/cic_notation/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open CicNotationEnv
  29 open CicNotationPt
  30
  31 let print_attributes = true
  32
  33 let pp_binder = function
  34   | `Lambda -> "lambda"
  35   | `Pi -> "Pi"
  36   | `Exists -> "exists"
  37   | `Forall -> "forall"
  38
  39 let pp_literal l =
  40   sprintf "literal(%s)"
  41     (match l with
  42     | `Symbol s
  43     | `Keyword s
  44     | `Number s -> s)
  45
  46 let rec pp_term = function
  47   | AttributedTerm (_, term) when print_attributes ->
  48       sprintf "@[%s]" (pp_term term)
  49   | AttributedTerm (_, term) -> pp_term term
  50
  51   | Appl terms ->
  52       sprintf "(%s)" (String.concat " " (List.map pp_term terms))
  53   | Binder (`Forall, (Ident ("_", None), typ), body)
  54   | Binder (`Pi, (Ident ("_", None), typ), body) ->
  55       sprintf "(%s \\to %s)"
  56         (match typ with None -> "?" | Some typ -> pp_term typ)
  57         (pp_term body)
  58   | Binder (kind, var, body) ->
  59       sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable var)
  60         (pp_term body)
  61   | Case (term, indtype, typ, patterns) ->
  62       sprintf "%smatch %s with %s"
  63         (match typ with None -> "" | Some t -> sprintf "<%s>" (pp_term t))
  64         (pp_term term) (pp_patterns patterns)
  65   | LetIn (var, t1, t2) ->
  66       sprintf "let %s = %s in %s" (pp_capture_variable var) (pp_term t1)
  67         (pp_term t2)
  68   | LetRec (kind, definitions, term) ->
  69       sprintf "let %s %s in %s"
  70         (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
  71         (String.concat " and "
  72           (List.map
  73             (fun (var, body, _) ->
  74               sprintf "%s = %s" (pp_capture_variable var) (pp_term body))
  75             definitions))
  76         (pp_term term)
  77   | Ident (name, Some []) | Ident (name, None)
  78   | Uri (name, Some []) | Uri (name, None) ->
  79       name
  80   | Ident (name, Some substs)
  81   | Uri (name, Some substs) ->
  82       sprintf "%s \\subst [%s]" name (pp_substs substs)
  83   | Implicit -> "?"
  84   | Meta (index, substs) ->
  85       sprintf "%d[%s]" index
  86         (String.concat "; "
  87           (List.map (function None -> "_" | Some term -> pp_term term) substs))
  88   | Num (num, _) -> num
  89   | Sort `Set -> "Set"
  90   | Sort `Prop -> "Prop"
  91   | Sort `Type -> "Type"
  92   | Sort `CProp -> "CProp"
  93   | Symbol (name, _) -> name
  94
  95   | UserInput -> ""
  96
  97   | Literal l -> pp_literal l
  98   | Layout l -> pp_layout l
  99   | Magic m -> pp_magic m
 100   | Variable v -> pp_variable v
 101
 102 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 103 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 104
 105 and pp_pattern ((head, vars), term) =
 106   sprintf "%s \\Rightarrow %s"
 107     (match vars with
 108     | [] -> head
 109     | _ ->
 110         sprintf "(%s %s)" head
 111           (String.concat " " (List.map pp_capture_variable vars)))
 112     (pp_term term)
 113
 114 and pp_patterns patterns =
 115   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 116
 117 and pp_capture_variable = function
 118   | term, None -> pp_term term
 119   | term, Some typ -> "(" ^ pp_term term ^ ": " ^ pp_term typ ^ ")"
 120
 121 and pp_box_spec (kind, spacing, indent) =
 122   let int_of_bool b = if b then 1 else 0 in
 123   let kind_string =
 124     match kind with H -> "H" | V -> "V" | HV -> "HV" | HOV -> "HOV"
 125   in
 126   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 127
 128 and pp_layout = function
 129   | Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 130   | Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 131   | Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 132   | Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 133   | Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 134   | Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 135   | Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 136   | Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 137   | Root (arg, index) ->
 138       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 139 (*   | Break -> "\\BREAK" *)
 140 (*   | Space -> "\\SPACE" *)
 141   | Box (box_spec, terms) ->
 142       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 143         (String.concat " " (List.map pp_term terms))
 144
 145 and pp_magic = function
 146   | List0 (t, sep_opt) ->
 147       sprintf "\\LIST0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 148   | List1 (t, sep_opt) ->
 149       sprintf "\\LIST1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 150   | Opt t -> sprintf "\\OPT %s" (pp_term t)
 151   | Fold (k, p_base, names, p_rec) ->
 152       let acc = match names with acc :: _ -> acc | _ -> assert false in
 153       sprintf "\\FOLD %s \\[%s\\] \\LAMBDA %s \\[%s\\]"
 154         (pp_fold_kind k) (pp_term p_base) acc (pp_term p_rec)
 155   | Default (p_some, p_none) ->
 156       sprintf "\\DEFAULT \\[%s\\] \\[%s\\]" (pp_term p_some) (pp_term p_none)
 157
 158 and pp_fold_kind = function
 159   | `Left -> "left"
 160   | `Right -> "right"
 161
 162 and pp_sep_opt = function
 163   | None -> ""
 164   | Some sep -> sprintf "\\SEP %s" (pp_literal sep)
 165
 166 and pp_variable = function
 167   | NumVar s -> "\\NUM " ^ s
 168   | IdentVar s -> "\\IDENT " ^ s
 169   | TermVar s -> "\\TERM " ^ s
 170   | Ascription (t, n) -> sprintf "[%s \\AS %s]" (pp_term t) n
 171   | FreshVar n -> "\\FRESH " ^ n
 172
 173 let rec pp_value = function
 174   | TermValue t -> sprintf "$%s$" (pp_term t)
 175   | StringValue s -> sprintf "\"%s\"" s
 176   | NumValue n -> n
 177   | OptValue (Some v) -> "Some " ^ pp_value v
 178   | OptValue None -> "None"
 179   | ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 180
 181 let rec pp_value_type =
 182   function
 183   | TermType -> "Term"
 184   | StringType -> "String"
 185   | NumType -> "Number"
 186   | OptType t -> "Maybe " ^ pp_value_type t
 187   | ListType l -> "List " ^ pp_value_type l
 188
 189 let pp_env env =
 190   String.concat "; "
 191     (List.map
 192       (fun (name, (ty, value)) ->
 193         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 194       env)
 195