helm/ocaml/cic_notation/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 module Ast = CicNotationPt
  29 module Env = CicNotationEnv
  30
  31   (* when set to true debugging information, not in sync with input syntax, will
  32    * be added to the output of pp_term.
  33    * set to false if you need, for example, cut and paste from matitac output to
  34    * matitatop *)
  35 let debug_printing = false
  36
  37 let pp_binder = function
  38   | `Lambda -> "lambda"
  39   | `Pi -> "Pi"
  40   | `Exists -> "exists"
  41   | `Forall -> "forall"
  42
  43 let pp_literal =
  44   if debug_printing then
  45     (function (* debugging version *)
  46       | `Symbol s -> sprintf "symbol(%s)" s
  47       | `Keyword s -> sprintf "keyword(%s)" s
  48       | `Number s -> sprintf "number(%s)" s)
  49   else
  50     (function
  51       | `Symbol s
  52       | `Keyword s
  53       | `Number s -> s)
  54
  55 let rec pp_term ?(pp_parens = true) t =
  56   let t_pp =
  57     match t with
  58     | Ast.AttributedTerm (`Href hrefs, term) when debug_printing ->
  59         sprintf "#(%s)[%s]"
  60           (String.concat "," (List.map UriManager.string_of_uri hrefs))
  61           (pp_term ~pp_parens:false term)
  62     | Ast.AttributedTerm (`IdRef id, term) when debug_printing ->
  63         sprintf "x(%s)[%s]" id (pp_term ~pp_parens:false term)
  64     | Ast.AttributedTerm (_, term) when debug_printing ->
  65         sprintf "@[%s]" (pp_term ~pp_parens:false term)
  66     | Ast.AttributedTerm (`Raw text, _) -> text
  67     | Ast.AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  68
  69     | Ast.Appl terms ->
  70         sprintf "%s" (String.concat " " (List.map pp_term terms))
  71     | Ast.Binder (`Forall, (Ast.Ident ("_", None), typ), body)
  72     | Ast.Binder (`Pi, (Ast.Ident ("_", None), typ), body) ->
  73         sprintf "%s \\to %s"
  74           (match typ with None -> "?" | Some typ -> pp_term typ)
  75           (pp_term body)
  76     | Ast.Binder (kind, var, body) ->
  77         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable var)
  78           (pp_term body)
  79     | Ast.Case (term, indtype, typ, patterns) ->
  80         sprintf "%smatch %s%s with %s"
  81           (match typ with None -> "" | Some t -> sprintf "[%s]" (pp_term t))
  82           (pp_term term)
  83           (match indtype with
  84           | None -> ""
  85           | Some (ty, href_opt) ->
  86               sprintf " in %s%s" ty
  87               (match debug_printing, href_opt with
  88               | true, Some uri ->
  89                   sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
  90               | _ -> ""))
  91           (pp_patterns patterns)
  92     | Ast.Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term t1) (pp_term t2)
  93     | Ast.LetIn (var, t1, t2) ->
  94         sprintf "let %s = %s in %s" (pp_capture_variable var) (pp_term t1)
  95           (pp_term t2)
  96     | Ast.LetRec (kind, definitions, term) ->
  97         sprintf "let %s %s in %s"
  98           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
  99           (String.concat " and "
 100             (List.map
 101               (fun (var, body, _) ->
 102                 sprintf "%s = %s" (pp_capture_variable var) (pp_term body))
 103               definitions))
 104           (pp_term term)
 105     | Ast.Ident (name, Some []) | Ast.Ident (name, None)
 106     | Ast.Uri (name, Some []) | Ast.Uri (name, None) ->
 107         name
 108     | Ast.Ident (name, Some substs)
 109     | Ast.Uri (name, Some substs) ->
 110         sprintf "%s \\subst [%s]" name (pp_substs substs)
 111     | Ast.Implicit -> "?"
 112     | Ast.Meta (index, substs) ->
 113         sprintf "%d[%s]" index
 114           (String.concat "; "
 115             (List.map (function None -> "_" | Some t -> pp_term t) substs))
 116     | Ast.Num (num, _) -> num
 117     | Ast.Sort `Set -> "Set"
 118     | Ast.Sort `Prop -> "Prop"
 119     | Ast.Sort (`Type _) -> "Type"
 120     | Ast.Sort `CProp -> "CProp"
 121     | Ast.Symbol (name, _) -> "'" ^ name
 122
 123     | Ast.UserInput -> ""
 124
 125     | Ast.Literal l -> pp_literal l
 126     | Ast.Layout l -> pp_layout l
 127     | Ast.Magic m -> pp_magic m
 128     | Ast.Variable v -> pp_variable v
 129   in
 130   if pp_parens then sprintf "(%s)" t_pp
 131   else t_pp
 132
 133 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 134 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 135
 136 and pp_pattern ((head, href, vars), term) =
 137   let head_pp =
 138     head ^
 139     (match debug_printing, href with
 140     | true, Some uri -> sprintf "(i.e.%s)" (UriManager.string_of_uri uri)
 141     | _ -> "")
 142   in
 143   sprintf "%s \\Rightarrow %s"
 144     (match vars with
 145     | [] -> head_pp
 146     | _ ->
 147         sprintf "(%s %s)" head_pp
 148           (String.concat " " (List.map pp_capture_variable vars)))
 149     (pp_term term)
 150
 151 and pp_patterns patterns =
 152   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 153
 154 and pp_capture_variable = function
 155   | term, None -> pp_term term
 156   | term, Some typ -> "(" ^ pp_term term ^ ": " ^ pp_term typ ^ ")"
 157
 158 and pp_box_spec (kind, spacing, indent) =
 159   let int_of_bool b = if b then 1 else 0 in
 160   let kind_string =
 161     match kind with
 162     Ast.H -> "H" | Ast.V -> "V" | Ast.HV -> "HV" | Ast.HOV -> "HOV"
 163   in
 164   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 165
 166 and pp_layout = function
 167   | Ast.Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 168   | Ast.Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 169   | Ast.Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 170   | Ast.Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 171   | Ast.Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 172   | Ast.Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 173   | Ast.Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 174   | Ast.Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 175   | Ast.Root (arg, index) ->
 176       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 177   | Ast.Break -> "\\BREAK"
 178 (*   | Space -> "\\SPACE" *)
 179   | Ast.Box (box_spec, terms) ->
 180       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 181         (String.concat " " (List.map pp_term terms))
 182   | Ast.Group terms ->
 183       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 184
 185 and pp_magic = function
 186   | Ast.List0 (t, sep_opt) ->
 187       sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 188   | Ast.List1 (t, sep_opt) ->
 189       sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 190   | Ast.Opt t -> sprintf "opt %s" (pp_term t)
 191   | Ast.Fold (kind, p_base, names, p_rec) ->
 192       let acc = match names with acc :: _ -> acc | _ -> assert false in
 193       sprintf "fold %s %s rec %s %s"
 194         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 195   | Ast.Default (p_some, p_none) ->
 196       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 197   | Ast.If (p_test, p_true, p_false) ->
 198       sprintf "if %s then %s else %s"
 199         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 200   | Ast.Fail -> "fail"
 201
 202 and pp_fold_kind = function
 203   | `Left -> "left"
 204   | `Right -> "right"
 205
 206 and pp_sep_opt = function
 207   | None -> ""
 208   | Some sep -> sprintf " sep %s" (pp_literal sep)
 209
 210 and pp_variable = function
 211   | Ast.NumVar s -> "number " ^ s
 212   | Ast.IdentVar s -> "ident " ^ s
 213   | Ast.TermVar s -> "term " ^ s
 214   | Ast.Ascription (t, n) -> assert false
 215   | Ast.FreshVar n -> "fresh " ^ n
 216
 217 let pp_term t = pp_term ~pp_parens:false t
 218
 219 let rec pp_value = function
 220   | Env.TermValue t -> sprintf "$%s$" (pp_term t)
 221   | Env.StringValue s -> sprintf "\"%s\"" s
 222   | Env.NumValue n -> n
 223   | Env.OptValue (Some v) -> "Some " ^ pp_value v
 224   | Env.OptValue None -> "None"
 225   | Env.ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 226
 227 let rec pp_value_type =
 228   function
 229   | Env.TermType -> "Term"
 230   | Env.StringType -> "String"
 231   | Env.NumType -> "Number"
 232   | Env.OptType t -> "Maybe " ^ pp_value_type t
 233   | Env.ListType l -> "List " ^ pp_value_type l
 234
 235 let pp_env env =
 236   String.concat "; "
 237     (List.map
 238       (fun (name, (ty, value)) ->
 239         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 240       env)
 241