helm/ocaml/cic_notation/cicNotationPp.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 open CicNotationEnv
  29 open CicNotationPt
  30
  31 let print_attributes = true
  32
  33 let pp_binder = function
  34   | `Lambda -> "lambda"
  35   | `Pi -> "Pi"
  36   | `Exists -> "exists"
  37   | `Forall -> "forall"
  38
  39 (* let pp_literal = function  (* debugging version *)
  40   | `Symbol s -> sprintf "symbol(%s)" s
  41   | `Keyword s -> sprintf "keyword(%s)" s
  42   | `Number s -> sprintf "number(%s)" s *)
  43
  44 let pp_literal = function
  45   | `Symbol s
  46   | `Keyword s
  47   | `Number s -> s
  48
  49 let rec pp_term ?(pp_parens = true) t =
  50   let t_pp =
  51     match t with
  52 (*     | AttributedTerm (`Href _, term) when print_attributes ->
  53         sprintf "#[%s]" (pp_term term)
  54     | AttributedTerm (_, term) when print_attributes ->
  55         sprintf "@[%s]" (pp_term term) *)
  56     | AttributedTerm (`Raw (text, None), _) -> text
  57     | AttributedTerm (`Raw (text, Some `Ast), _) -> sprintf "@{%s}" text
  58     | AttributedTerm (`Raw (text, Some `Meta), _) -> sprintf "${%s}" text
  59     | AttributedTerm (_, term) -> pp_term ~pp_parens:false term
  60
  61     | Appl terms ->
  62         sprintf "%s" (String.concat " " (List.map pp_term terms))
  63     | Binder (`Forall, (Ident ("_", None), typ), body)
  64     | Binder (`Pi, (Ident ("_", None), typ), body) ->
  65         sprintf "%s \\to %s"
  66           (match typ with None -> "?" | Some typ -> pp_term typ)
  67           (pp_term body)
  68     | Binder (kind, var, body) ->
  69         sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable var)
  70           (pp_term body)
  71     | Case (term, indtype, typ, patterns) ->
  72         sprintf "%smatch %s with %s"
  73           (match typ with None -> "" | Some t -> sprintf "[%s]" (pp_term t))
  74           (pp_term term) (pp_patterns patterns)
  75     | Cast (t1, t2) -> sprintf "(%s: %s)" (pp_term t1) (pp_term t2)
  76     | LetIn (var, t1, t2) ->
  77         sprintf "let %s = %s in %s" (pp_capture_variable var) (pp_term t1)
  78           (pp_term t2)
  79     | LetRec (kind, definitions, term) ->
  80         sprintf "let %s %s in %s"
  81           (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
  82           (String.concat " and "
  83             (List.map
  84               (fun (var, body, _) ->
  85                 sprintf "%s = %s" (pp_capture_variable var) (pp_term body))
  86               definitions))
  87           (pp_term term)
  88     | Ident (name, Some []) | Ident (name, None)
  89     | Uri (name, Some []) | Uri (name, None) ->
  90         name
  91     | Ident (name, Some substs)
  92     | Uri (name, Some substs) ->
  93         sprintf "%s \\subst [%s]" name (pp_substs substs)
  94     | Implicit -> "?"
  95     | Meta (index, substs) ->
  96         sprintf "%d[%s]" index
  97           (String.concat "; "
  98             (List.map (function None -> "_" | Some t -> pp_term t) substs))
  99     | Num (num, _) -> num
 100     | Sort `Set -> "Set"
 101     | Sort `Prop -> "Prop"
 102     | Sort `Type -> "Type"
 103     | Sort `CProp -> "CProp"
 104     | Symbol (name, _) -> name
 105
 106     | UserInput -> ""
 107
 108     | Literal l -> pp_literal l
 109     | Layout l -> pp_layout l
 110     | Magic m -> pp_magic m
 111     | Variable v -> pp_variable v
 112   in
 113   if pp_parens then sprintf "(%s)" t_pp
 114   else t_pp
 115
 116 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
 117 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
 118
 119 and pp_pattern ((head, vars), term) =
 120   sprintf "%s \\Rightarrow %s"
 121     (match vars with
 122     | [] -> head
 123     | _ ->
 124         sprintf "(%s %s)" head
 125           (String.concat " " (List.map pp_capture_variable vars)))
 126     (pp_term term)
 127
 128 and pp_patterns patterns =
 129   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
 130
 131 and pp_capture_variable = function
 132   | term, None -> pp_term term
 133   | term, Some typ -> "(" ^ pp_term term ^ ": " ^ pp_term typ ^ ")"
 134
 135 and pp_box_spec (kind, spacing, indent) =
 136   let int_of_bool b = if b then 1 else 0 in
 137   let kind_string =
 138     match kind with H -> "H" | V -> "V" | HV -> "HV" | HOV -> "HOV"
 139   in
 140   sprintf "%sBOX%d%d" kind_string (int_of_bool spacing) (int_of_bool indent)
 141
 142 and pp_layout = function
 143   | Sub (t1, t2) -> sprintf "%s \\SUB %s" (pp_term t1) (pp_term t2)
 144   | Sup (t1, t2) -> sprintf "%s \\SUP %s" (pp_term t1) (pp_term t2)
 145   | Below (t1, t2) -> sprintf "%s \\BELOW %s" (pp_term t1) (pp_term t2)
 146   | Above (t1, t2) -> sprintf "%s \\ABOVE %s" (pp_term t1) (pp_term t2)
 147   | Over (t1, t2) -> sprintf "[%s \\OVER %s]" (pp_term t1) (pp_term t2)
 148   | Atop (t1, t2) -> sprintf "[%s \\ATOP %s]" (pp_term t1) (pp_term t2)
 149   | Frac (t1, t2) -> sprintf "\\FRAC %s %s" (pp_term t1) (pp_term t2)
 150   | Sqrt t -> sprintf "\\SQRT %s" (pp_term t)
 151   | Root (arg, index) ->
 152       sprintf "\\ROOT %s \\OF %s" (pp_term index) (pp_term arg)
 153   | Break -> "\\BREAK"
 154 (*   | Space -> "\\SPACE" *)
 155   | Box (box_spec, terms) ->
 156       sprintf "\\%s [%s]" (pp_box_spec box_spec)
 157         (String.concat " " (List.map pp_term terms))
 158   | Group terms ->
 159       sprintf "\\GROUP [%s]" (String.concat " " (List.map pp_term terms))
 160
 161 and pp_magic = function
 162   | List0 (t, sep_opt) -> sprintf "list0 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 163   | List1 (t, sep_opt) -> sprintf "list1 %s%s" (pp_term t) (pp_sep_opt sep_opt)
 164   | Opt t -> sprintf "opt %s" (pp_term t)
 165   | Fold (kind, p_base, names, p_rec) ->
 166       let acc = match names with acc :: _ -> acc | _ -> assert false in
 167       sprintf "fold %s %s rec %s %s"
 168         (pp_fold_kind kind) (pp_term p_base) acc (pp_term p_rec)
 169   | Default (p_some, p_none) ->
 170       sprintf "default %s %s" (pp_term p_some) (pp_term p_none)
 171   | If (p_test, p_true, p_false) ->
 172       sprintf "if %s then %s else %s"
 173         (pp_term p_test) (pp_term p_true) (pp_term p_false)
 174   | Fail -> "fail"
 175
 176 and pp_fold_kind = function
 177   | `Left -> "left"
 178   | `Right -> "right"
 179
 180 and pp_sep_opt = function
 181   | None -> ""
 182   | Some sep -> sprintf " sep %s" (pp_literal sep)
 183
 184 and pp_variable = function
 185   | NumVar s -> "number " ^ s
 186   | IdentVar s -> "ident " ^ s
 187   | TermVar s -> "term " ^ s
 188   | Ascription (t, n) -> assert false
 189   | FreshVar n -> "fresh " ^ n
 190
 191 let pp_term t = pp_term ~pp_parens:false t
 192
 193 let rec pp_value = function
 194   | TermValue t -> sprintf "$%s$" (pp_term t)
 195   | StringValue s -> sprintf "\"%s\"" s
 196   | NumValue n -> n
 197   | OptValue (Some v) -> "Some " ^ pp_value v
 198   | OptValue None -> "None"
 199   | ListValue l -> sprintf "[%s]" (String.concat "; " (List.map pp_value l))
 200
 201 let rec pp_value_type =
 202   function
 203   | TermType -> "Term"
 204   | StringType -> "String"
 205   | NumType -> "Number"
 206   | OptType t -> "Maybe " ^ pp_value_type t
 207   | ListType l -> "List " ^ pp_value_type l
 208
 209 let pp_env env =
 210   String.concat "; "
 211     (List.map
 212       (fun (name, (ty, value)) ->
 213         sprintf "%s : %s = %s" name (pp_value_type ty) (pp_value value))
 214       env)
 215