helm/ocaml/cic_notation/cicNotationRew.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 type pattern_id = int
  29 type interpretation_id = pattern_id
  30 type pretty_printer_id = pattern_id
  31
  32 let default_prec = 50
  33 let default_assoc = Gramext.NonA
  34
  35 type term_info =
  36   { sort: (Cic.id, CicNotationPt.sort_kind) Hashtbl.t;
  37     uri: (Cic.id, string) Hashtbl.t;
  38   }
  39
  40 let get_types uri =
  41   let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
  42     match o with
  43       | Cic.InductiveDefinition (l,_,_,_) -> l
  44       | _ -> assert false
  45
  46 let name_of_inductive_type uri i =
  47   let types = get_types uri in
  48   let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  49   name
  50
  51   (* returns <name, type> pairs *)
  52 let constructors_of_inductive_type uri i =
  53   let types = get_types uri in
  54   let (_, _, _, constructors) =
  55     try List.nth types i with Not_found -> assert false
  56   in
  57   constructors
  58
  59   (* returns name only *)
  60 let constructor_of_inductive_type uri i j =
  61   (try
  62     fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  63   with Not_found -> assert false)
  64
  65 module Ast = CicNotationPt
  66 module Parser = CicNotationParser
  67
  68 let string_of_name = function
  69   | Cic.Name s -> s
  70   | Cic.Anonymous -> "_"
  71
  72 let ident_of_name n = Ast.Ident (string_of_name n, None)
  73
  74 let idref id t = Ast.AttributedTerm (`IdRef id, t)
  75
  76 let resolve_binder = function
  77   | `Lambda -> "\\lambda"
  78   | `Pi -> "\\Pi"
  79   | `Forall -> "\\forall"
  80   | `Exists -> "\\exists"
  81
  82 let binder_attributes = [None, "mathcolor", "blue"]
  83 let atop_attributes = [None, "linethickness", "0pt"]
  84 let indent_attributes = [None, "indent", "1em"]
  85 let keyword_attributes = [None, "mathcolor", "blue"]
  86
  87 let pp_ast0 t k =
  88   let reset_href t = Ast.AttributedTerm (`Href [], t) in
  89   let builtin_symbol s = reset_href (Ast.Literal (`Symbol s)) in
  90   let binder_symbol s =
  91     Ast.AttributedTerm (`XmlAttrs binder_attributes, builtin_symbol s)
  92   in
  93   let rec aux = function
  94     | Ast.Appl ts ->
  95         Ast.AttributedTerm (`Level (Parser.apply_prec, Parser.apply_assoc),
  96           Ast.Layout
  97             (Ast.Box ((Ast.HOV, true, true),
  98                       (CicNotationUtil.dress
  99                          (Ast.Layout Ast.Break)
 100                          (List.map k ts)))))
 101     | Ast.Binder (`Forall, (Ast.Ident ("_", _), ty), body)
 102     | Ast.Binder (`Pi, (Ast.Ident ("_", _), ty), body) ->
 103         Ast.AttributedTerm (`Level (Parser.binder_prec, Parser.binder_assoc),
 104           Ast.Layout (Ast.Box ((Ast.HV, false, true), [
 105             aux_ty ty;
 106             Ast.Layout Ast.Break;
 107             binder_symbol "\\to";
 108             k body])))
 109     | Ast.Binder (binder_kind, (id, ty), body) ->
 110         Ast.AttributedTerm (`Level (Parser.binder_prec, Parser.binder_assoc),
 111           Ast.Layout (Ast.Box ((Ast.HV, false, true), [
 112             binder_symbol (resolve_binder binder_kind);
 113             k id;
 114             builtin_symbol ":";
 115             aux_ty ty;
 116             Ast.Layout Ast.Break;
 117             builtin_symbol ".";
 118             k body ])))
 119     | t -> CicNotationUtil.visit_ast ~special_k k t
 120   and aux_ty = function
 121     | None -> builtin_symbol "?"
 122     | Some ty -> k ty
 123   and special_k = function
 124     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 125     | _ -> assert false
 126   in
 127   aux t
 128
 129 let ast_of_acic0 term_info acic k =
 130   let k = k term_info in
 131   let register_uri id uri = Hashtbl.add term_info.uri id uri in
 132   let sort_of_id id =
 133     try
 134       Hashtbl.find term_info.sort id
 135     with Not_found -> assert false
 136   in
 137   let aux_substs substs =
 138     Some
 139       (List.map
 140         (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
 141         substs)
 142   in
 143   let aux_context context =
 144     List.map
 145       (function
 146         | None -> None
 147         | Some annterm -> Some (k annterm))
 148       context
 149   in
 150   let aux = function
 151     | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
 152     | Cic.AVar (id,uri,substs) ->
 153         register_uri id (UriManager.string_of_uri uri);
 154         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 155     | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
 156     | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
 157     | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
 158     | Cic.ASort (id,Cic.Type _) -> idref id (Ast.Sort `Type)
 159     | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
 160     | Cic.AImplicit _ -> assert false
 161     | Cic.AProd (id,n,s,t) ->
 162         let binder_kind =
 163           match sort_of_id id with
 164           | `Set | `Type -> `Pi
 165           | `Prop | `CProp -> `Forall
 166         in
 167         idref id (Ast.Binder (binder_kind, (ident_of_name n, Some (k s)), k t))
 168     | Cic.ACast (id,v,t) ->
 169         idref id (Ast.Appl [idref id (Ast.Symbol ("cast", 0)); k v; k t])
 170     | Cic.ALambda (id,n,s,t) ->
 171         idref id (Ast.Binder (`Lambda, (ident_of_name n, Some (k s)), k t))
 172     | Cic.ALetIn (id,n,s,t) ->
 173         idref id (Ast.LetIn ((ident_of_name n, None), k s, k t))
 174     | Cic.AAppl (aid,args) -> idref aid (Ast.Appl (List.map k args))
 175     | Cic.AConst (id,uri,substs) ->
 176         register_uri id (UriManager.string_of_uri uri);
 177         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 178     | Cic.AMutInd (id,uri,i,substs) as t ->
 179         let name = name_of_inductive_type uri i in
 180         let uri_str = UriManager.string_of_uri uri in
 181         let puri_str =
 182           uri_str ^ "#xpointer(1/" ^ (string_of_int (i + 1)) ^ ")"
 183         in
 184         register_uri id puri_str;
 185         idref id (Ast.Ident (name, aux_substs substs))
 186     | Cic.AMutConstruct (id,uri,i,j,substs) ->
 187         let name = constructor_of_inductive_type uri i j in
 188         let uri_str = UriManager.string_of_uri uri in
 189         let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
 190         register_uri id puri_str;
 191         idref id (Ast.Ident (name, aux_substs substs))
 192     | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
 193         let name = name_of_inductive_type uri typeno in
 194         let constructors = constructors_of_inductive_type uri typeno in
 195         let rec eat_branch ty pat =
 196           match (ty, pat) with
 197           | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
 198               let (cv, rhs) = eat_branch t t' in
 199               (ident_of_name name, Some (k s)) :: cv, rhs
 200           | _, _ -> [], k pat
 201         in
 202         let patterns =
 203           List.map2
 204             (fun (name, ty) pat ->
 205               let (capture_variables, rhs) = eat_branch ty pat in
 206               ((name, capture_variables), rhs))
 207             constructors patterns
 208         in
 209         idref id (Ast.Case (k te, Some name, Some (k ty), patterns))
 210     | Cic.AFix (id, no, funs) ->
 211         let defs =
 212           List.map
 213             (fun (_, n, decr_idx, ty, bo) ->
 214               ((Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
 215             funs
 216         in
 217         let name =
 218           try
 219             (match List.nth defs no with
 220             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 221             | _ -> assert false)
 222           with Not_found -> assert false
 223         in
 224         idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
 225     | Cic.ACoFix (id, no, funs) ->
 226         let defs =
 227           List.map
 228             (fun (_, n, ty, bo) -> ((Ast.Ident (n, None), Some (k ty)), k bo, 0))
 229             funs
 230         in
 231         let name =
 232           try
 233             (match List.nth defs no with
 234             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 235             | _ -> assert false)
 236           with Not_found -> assert false
 237         in
 238         idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
 239   in
 240   aux acic
 241
 242   (* persistent state *)
 243
 244 let level1_patterns21 = Hashtbl.create 211
 245 let level2_patterns32 = Hashtbl.create 211
 246
 247 let compiled21 = ref None
 248 let compiled32 = ref None
 249
 250 let pattern21_matrix = ref []
 251 let pattern32_matrix = ref []
 252
 253 let get_compiled21 () =
 254   match !compiled21 with
 255   | None -> assert false
 256   | Some f -> Lazy.force f
 257 let get_compiled32 () =
 258   match !compiled32 with
 259   | None -> assert false
 260   | Some f -> Lazy.force f
 261
 262 let set_compiled21 f = compiled21 := Some f
 263 let set_compiled32 f = compiled32 := Some f
 264
 265 let instantiate21 env (* precedence associativity *) l1 =
 266   let rec subst_singleton env t =
 267     CicNotationUtil.group (subst env t)
 268   and subst env = function
 269     | Ast.AttributedTerm (_, t) -> subst env t
 270     | Ast.Variable var ->
 271         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 272         let ty, value =
 273           try
 274             List.assoc name env
 275           with Not_found -> assert false
 276         in
 277         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 278         (* following assertion should be a conditional that makes this
 279          * instantiation fail *)
 280         assert (CicNotationEnv.well_typed expected_ty value);
 281         [ CicNotationEnv.term_of_value value ]
 282     | Ast.Magic m -> subst_magic env m
 283     | Ast.Literal (`Keyword k) as t ->
 284         [ Ast.AttributedTerm (`XmlAttrs keyword_attributes, t) ]
 285     | Ast.Literal _ as t -> [ t ]
 286     | Ast.Layout l -> [ Ast.Layout (subst_layout env l) ]
 287     | t -> [ CicNotationUtil.visit_ast (subst_singleton env) t ]
 288   and subst_magic env = function
 289     | Ast.List0 (p, sep_opt)
 290     | Ast.List1 (p, sep_opt) ->
 291         let rec_decls = CicNotationEnv.declarations_of_term p in
 292         let rec_values =
 293           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 294         in
 295         let values = CicNotationUtil.ncombine rec_values in
 296         let sep =
 297           match sep_opt with
 298             | None -> []
 299             | Some l -> [ CicNotationPt.Literal l ]
 300         in
 301         let rec instantiate_list acc = function
 302           | [] -> List.rev acc
 303           | value_set :: [] ->
 304               let env = CicNotationEnv.combine rec_decls value_set in
 305                 instantiate_list (CicNotationUtil.group (subst env p) :: acc) []
 306           | value_set :: tl ->
 307               let env = CicNotationEnv.combine rec_decls value_set in
 308                 instantiate_list (CicNotationUtil.group ((subst env p) @ sep) :: acc) tl
 309         in
 310         instantiate_list [] values
 311     | Ast.Opt p ->
 312         let opt_decls = CicNotationEnv.declarations_of_term p in
 313         let env =
 314           let rec build_env = function
 315             | [] -> []
 316             | (name, ty) :: tl ->
 317                   (* assumption: if one of the value is None then all are *)
 318                 (match CicNotationEnv.lookup_opt env name with
 319                 | None -> raise Exit
 320                 | Some v -> (name, (ty, v)) :: build_env tl)
 321           in
 322           try build_env opt_decls with Exit -> []
 323         in
 324           begin
 325             match env with
 326               | [] -> []
 327               | _ -> subst env p
 328           end
 329     | _ -> assert false (* impossible *)
 330   and subst_layout env = function
 331     | Ast.Box (kind, tl) ->
 332         Ast.Box (kind, List.concat (List.map (subst env) tl))
 333     | l -> CicNotationUtil.visit_layout (subst_singleton env) l
 334   in
 335     subst_singleton env l1
 336
 337 let rec pp_ast1 term =
 338   let rec pp_value = function
 339     | CicNotationEnv.NumValue _ as v -> v
 340     | CicNotationEnv.StringValue _ as v -> v
 341 (*     | CicNotationEnv.TermValue t when t == term -> CicNotationEnv.TermValue (pp_ast0 t pp_ast1) *)
 342     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 343     | CicNotationEnv.OptValue None as v -> v
 344     | CicNotationEnv.OptValue (Some v) ->
 345         CicNotationEnv.OptValue (Some (pp_value v))
 346     | CicNotationEnv.ListValue vl ->
 347         CicNotationEnv.ListValue (List.map pp_value vl)
 348   in
 349   let ast_env_of_env env =
 350     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 351   in
 352   match term with
 353   | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, pp_ast1 t)
 354   | _ ->
 355       begin
 356         match (get_compiled21 ()) term with
 357           | None -> pp_ast0 term pp_ast1
 358           | Some (env, pid) ->
 359               let precedence, associativity, l1 =
 360                 try
 361                   Hashtbl.find level1_patterns21 pid
 362                 with Not_found -> assert false
 363               in
 364                 Ast.AttributedTerm (`Level (precedence, associativity),
 365                                 (instantiate21 (ast_env_of_env env) l1))
 366       end
 367
 368 let instantiate32 term_info env symbol args =
 369   let rec instantiate_arg = function
 370     | GrafiteAst.IdentArg (n, name) ->
 371         let t = (try List.assoc name env with Not_found -> assert false) in
 372         let rec count_lambda = function
 373           | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
 374           | _ -> 0
 375         in
 376         let rec add_lambda t n =
 377           if n > 0 then
 378             let name = CicNotationUtil.fresh_name () in
 379             Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
 380               Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
 381           else
 382             t
 383         in
 384         add_lambda t (n - count_lambda t)
 385   in
 386   let args' = List.map instantiate_arg args in
 387   Ast.Appl (Ast.Symbol (symbol, 0) :: args')
 388
 389 let rec ast_of_acic1 term_info annterm =
 390   match (get_compiled32 ()) annterm with
 391   | None -> ast_of_acic0 term_info annterm ast_of_acic1
 392   | Some (env, pid) ->
 393       let env' =
 394         List.map (fun (name, term) -> (name, ast_of_acic1 term_info term)) env
 395       in
 396       let symbol, args, uris =
 397         try
 398           Hashtbl.find level2_patterns32 pid
 399         with Not_found -> assert false
 400       in
 401       let ast = instantiate32 term_info env' symbol args in
 402       match uris with
 403       | [] -> ast
 404       | _ -> Ast.AttributedTerm (`Href uris, ast)
 405
 406 let load_patterns32 t =
 407   set_compiled32 (lazy (CicNotationMatcher.Matcher32.compiler t))
 408
 409 let load_patterns21 t =
 410   set_compiled21 (lazy (CicNotationMatcher.Matcher21.compiler t))
 411
 412 let ast_of_acic id_to_sort annterm =
 413   let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
 414   let ast = ast_of_acic1 term_info annterm in
 415   ast, term_info.uri
 416
 417 let pp_ast term = pp_ast1 term
 418
 419 let fresh_id =
 420   let counter = ref ~-1 in
 421   fun () ->
 422     incr counter;
 423     !counter
 424
 425 let add_interpretation (symbol, args) appl_pattern =
 426   let id = fresh_id () in
 427   let uris = CicNotationUtil.find_appl_pattern_uris appl_pattern in
 428   Hashtbl.add level2_patterns32 id (symbol, args, uris);
 429   pattern32_matrix := (appl_pattern, id) :: !pattern32_matrix;
 430   load_patterns32 !pattern32_matrix;
 431   id
 432
 433 let add_pretty_printer
 434   ?(precedence = default_prec) ?(associativity = default_assoc) l2 l1
 435 =
 436   let id = fresh_id () in
 437   let l2' = CicNotationUtil.strip_attributes l2 in
 438   Hashtbl.add level1_patterns21 id (precedence, associativity, l1);
 439   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 440   load_patterns21 !pattern21_matrix;
 441   id
 442
 443 exception Interpretation_not_found
 444 exception Pretty_printer_not_found
 445
 446 let remove_interpretation id =
 447   (try
 448     Hashtbl.remove level2_patterns32 id;
 449   with Not_found -> raise Interpretation_not_found);
 450   pattern32_matrix := List.filter (fun (_, id') -> id <> id') !pattern32_matrix;
 451   load_patterns32 !pattern32_matrix
 452
 453 let remove_pretty_printer id =
 454   (try
 455     Hashtbl.remove level1_patterns21 id;
 456   with Not_found -> raise Pretty_printer_not_found);
 457   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 458   load_patterns21 !pattern21_matrix
 459
 460 let _ =
 461   load_patterns21 [];
 462   load_patterns32 []
 463