helm/ocaml/cic_notation/cicNotationRew.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 type pattern_id = int
  29 type interpretation_id = pattern_id
  30 type pretty_printer_id = pattern_id
  31
  32 let default_prec = 50
  33 let default_assoc = Gramext.NonA
  34
  35 type term_info =
  36   { sort: (Cic.id, CicNotationPt.sort_kind) Hashtbl.t;
  37     uri: (Cic.id, string) Hashtbl.t;
  38   }
  39
  40 let warning s = prerr_endline ("CicNotation WARNING: " ^ s)
  41
  42 let get_types uri =
  43   let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
  44     match o with
  45       | Cic.InductiveDefinition (l,_,_,_) -> l
  46       | _ -> assert false
  47
  48 let name_of_inductive_type uri i =
  49   let types = get_types uri in
  50   let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  51   name
  52
  53   (* returns <name, type> pairs *)
  54 let constructors_of_inductive_type uri i =
  55   let types = get_types uri in
  56   let (_, _, _, constructors) =
  57     try List.nth types i with Not_found -> assert false
  58   in
  59   constructors
  60
  61   (* returns name only *)
  62 let constructor_of_inductive_type uri i j =
  63   (try
  64     fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  65   with Not_found -> assert false)
  66
  67 module Ast = CicNotationPt
  68 module Parser = CicNotationParser
  69
  70 let string_of_name = function
  71   | Cic.Name s -> s
  72   | Cic.Anonymous -> "_"
  73
  74 let ident_of_name n = Ast.Ident (string_of_name n, None)
  75
  76 let idref id t = Ast.AttributedTerm (`IdRef id, t)
  77
  78 let resolve_binder = function
  79   | `Lambda -> "\\lambda"
  80   | `Pi -> "\\Pi"
  81   | `Forall -> "\\forall"
  82   | `Exists -> "\\exists"
  83
  84 let pp_ast0 t k =
  85   let reset_href t = Ast.AttributedTerm (`Href [], t) in
  86   let builtin_symbol s = reset_href (Ast.Literal (`Symbol s)) in
  87   let rec aux = function
  88     | Ast.Appl ts ->
  89         Ast.AttributedTerm (`Level (Parser.apply_prec, Parser.apply_assoc),
  90           Ast.Layout (Ast.Box ((Ast.HOV, true, true), List.map k ts)))
  91     | Ast.Binder (`Forall, (Ast.Ident ("_", _), ty), body)
  92     | Ast.Binder (`Pi, (Ast.Ident ("_", _), ty), body) ->
  93         Ast.AttributedTerm (`Level (Parser.binder_prec, Parser.binder_assoc),
  94           Ast.Layout (Ast.Box ((Ast.HV, false, true), [
  95             aux_ty ty;
  96             Ast.Layout (Ast.Box ((Ast.H, false, false), [
  97               builtin_symbol "\\to";
  98               k body]))])))
  99     | Ast.Binder (binder_kind, (id, ty), body) ->
 100         Ast.AttributedTerm (`Level (Parser.binder_prec, Parser.binder_assoc),
 101           Ast.Layout (Ast.Box ((Ast.HV, false, true), [
 102             Ast.Layout (Ast.Box ((Ast.H, false, false), [
 103               builtin_symbol (resolve_binder binder_kind);
 104               k id;
 105               builtin_symbol ":";
 106               aux_ty ty ]));
 107             Ast.Layout (Ast.Box ((Ast.H, false, false), [
 108               builtin_symbol ".";
 109               k body ]))])))
 110     | t -> CicNotationUtil.visit_ast ~special_k k t
 111   and aux_ty = function
 112     | None -> builtin_symbol "?"
 113     | Some ty -> k ty
 114   and special_k = function
 115     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 116     | _ -> assert false
 117   in
 118   aux t
 119
 120 let ast_of_acic0 term_info acic k =
 121 (*   prerr_endline "ast_of_acic0"; *)
 122   let k = k term_info in
 123   let register_uri id uri = Hashtbl.add term_info.uri id uri in
 124   let sort_of_id id =
 125     try
 126       Hashtbl.find term_info.sort id
 127     with Not_found -> assert false
 128   in
 129   let aux_substs substs =
 130     Some
 131       (List.map
 132         (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
 133         substs)
 134   in
 135   let aux_context context =
 136     List.map
 137       (function
 138         | None -> None
 139         | Some annterm -> Some (k annterm))
 140       context
 141   in
 142   let aux = function
 143     | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
 144     | Cic.AVar (id,uri,substs) ->
 145         register_uri id (UriManager.string_of_uri uri);
 146         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 147     | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
 148     | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
 149     | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
 150     | Cic.ASort (id,Cic.Type _) -> idref id (Ast.Sort `Type)
 151     | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
 152     | Cic.AImplicit _ -> assert false
 153     | Cic.AProd (id,n,s,t) ->
 154         let binder_kind =
 155           match sort_of_id id with
 156           | `Set | `Type -> `Pi
 157           | `Prop | `CProp -> `Forall
 158         in
 159         idref id (Ast.Binder (binder_kind, (ident_of_name n, Some (k s)), k t))
 160     | Cic.ACast (id,v,t) ->
 161         idref id (Ast.Appl [idref id (Ast.Symbol ("cast", 0)); k v; k t])
 162     | Cic.ALambda (id,n,s,t) ->
 163         idref id (Ast.Binder (`Lambda, (ident_of_name n, Some (k s)), k t))
 164     | Cic.ALetIn (id,n,s,t) ->
 165         idref id (Ast.LetIn ((ident_of_name n, None), k s, k t))
 166     | Cic.AAppl (aid,args) -> idref aid (Ast.Appl (List.map k args))
 167     | Cic.AConst (id,uri,substs) ->
 168         register_uri id (UriManager.string_of_uri uri);
 169         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 170     | Cic.AMutInd (id,uri,i,substs) as t ->
 171         let name = name_of_inductive_type uri i in
 172         let uri_str = UriManager.string_of_uri uri in
 173         let puri_str =
 174           uri_str ^ "#xpointer(1/" ^ (string_of_int (i + 1)) ^ ")"
 175         in
 176         register_uri id puri_str;
 177         idref id (Ast.Ident (name, aux_substs substs))
 178     | Cic.AMutConstruct (id,uri,i,j,substs) ->
 179         let name = constructor_of_inductive_type uri i j in
 180         let uri_str = UriManager.string_of_uri uri in
 181         let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
 182         register_uri id puri_str;
 183         idref id (Ast.Ident (name, aux_substs substs))
 184     | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
 185         let name = name_of_inductive_type uri typeno in
 186         let constructors = constructors_of_inductive_type uri typeno in
 187         let rec eat_branch ty pat =
 188           match (ty, pat) with
 189           | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
 190               let (cv, rhs) = eat_branch t t' in
 191               (ident_of_name name, Some (k s)) :: cv, rhs
 192           | _, _ -> [], k pat
 193         in
 194         let patterns =
 195           List.map2
 196             (fun (name, ty) pat ->
 197               let (capture_variables, rhs) = eat_branch ty pat in
 198               ((name, capture_variables), rhs))
 199             constructors patterns
 200         in
 201         idref id (Ast.Case (k te, Some name, Some (k ty), patterns))
 202     | Cic.AFix (id, no, funs) ->
 203         let defs =
 204           List.map
 205             (fun (_, n, decr_idx, ty, bo) ->
 206               ((Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
 207             funs
 208         in
 209         let name =
 210           try
 211             (match List.nth defs no with
 212             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 213             | _ -> assert false)
 214           with Not_found -> assert false
 215         in
 216         idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
 217     | Cic.ACoFix (id, no, funs) ->
 218         let defs =
 219           List.map
 220             (fun (_, n, ty, bo) -> ((Ast.Ident (n, None), Some (k ty)), k bo, 0))
 221             funs
 222         in
 223         let name =
 224           try
 225             (match List.nth defs no with
 226             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 227             | _ -> assert false)
 228           with Not_found -> assert false
 229         in
 230         idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
 231   in
 232   aux acic
 233
 234   (* persistent state *)
 235
 236 let level1_patterns21 = Hashtbl.create 211
 237 let level2_patterns32 = Hashtbl.create 211
 238
 239 let (compiled21: (CicNotationPt.term -> (CicNotationEnv.t * int) option)
 240 option ref) =
 241   ref None
 242 let (compiled32: (Cic.annterm -> ((string * Cic.annterm) list * int) option)
 243 option ref) =
 244   ref None
 245
 246 let pattern21_matrix = ref []
 247 let pattern32_matrix = ref []
 248
 249 let get_compiled21 () =
 250   match !compiled21 with
 251   | None -> assert false
 252   | Some f -> f
 253 let get_compiled32 () =
 254   match !compiled32 with
 255   | None -> assert false
 256   | Some f -> f
 257
 258 let set_compiled21 f = compiled21 := Some f
 259 let set_compiled32 f = compiled32 := Some f
 260
 261 let instantiate21 env (* precedence associativity *) l1 =
 262   let rec subst_singleton env t =
 263     CicNotationUtil.boxify (subst env t)
 264   and subst env = function
 265     | Ast.AttributedTerm (_, t) -> subst env t
 266     | Ast.Variable var ->
 267         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 268         let ty, value =
 269           try
 270             List.assoc name env
 271           with Not_found -> assert false
 272         in
 273         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 274         (* following assertion should be a conditional that makes this
 275          * instantiation fail *)
 276         assert (CicNotationEnv.well_typed expected_ty value);
 277         [ CicNotationEnv.term_of_value value ]
 278     | Ast.Magic m -> subst_magic env m
 279     | Ast.Literal _ as t -> [ t ]
 280     | Ast.Layout l -> [ Ast.Layout (subst_layout env l) ]
 281     | t -> [ CicNotationUtil.visit_ast (subst_singleton env) t ]
 282   and subst_magic env = function
 283     | Ast.List0 (p, sep_opt)
 284     | Ast.List1 (p, sep_opt) ->
 285         let rec_decls = CicNotationEnv.declarations_of_term p in
 286         let rec_values =
 287           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 288         in
 289         let values = CicNotationUtil.ncombine rec_values in
 290         let sep =
 291           match sep_opt with
 292           | None -> []
 293           | Some l -> [ CicNotationPt.Literal l ]
 294         in
 295         let rec instantiate_list acc = function
 296           | [] -> List.rev acc
 297           | value_set :: [] ->
 298               let env = CicNotationEnv.combine rec_decls value_set in
 299                 instantiate_list
 300                   ((CicNotationUtil.boxify (subst env p)) :: acc) []
 301           | value_set :: tl ->
 302               let env = CicNotationEnv.combine rec_decls value_set in
 303               instantiate_list
 304                 ((CicNotationUtil.boxify (subst env p @ sep)) :: acc) tl
 305         in
 306         instantiate_list [] values
 307     | Ast.Opt p ->
 308         let opt_decls = CicNotationEnv.declarations_of_term p in
 309         let env =
 310           let rec build_env = function
 311             | [] -> []
 312             | (name, ty) :: tl ->
 313                   (* assumption: if one of the value is None then all are *)
 314                 (match CicNotationEnv.lookup_opt env name with
 315                 | None -> raise Exit
 316                 | Some v -> (name, (ty, v)) :: build_env tl)
 317           in
 318           try build_env opt_decls with Exit -> []
 319         in
 320           begin
 321             match env with
 322               | [] -> []
 323               | _ -> subst env p
 324           end
 325     | _ -> assert false (* impossible *)
 326   and subst_layout env = function
 327     | Ast.Box (kind, tl) -> Ast.Box (kind, List.concat (List.map (subst env) tl))
 328     | l -> CicNotationUtil.visit_layout (subst_singleton env) l
 329   in
 330     subst_singleton env l1
 331
 332 let rec pp_ast1 term =
 333   let rec pp_value = function
 334     | CicNotationEnv.NumValue _ as v -> v
 335     | CicNotationEnv.StringValue _ as v -> v
 336     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 337     | CicNotationEnv.OptValue None as v -> v
 338     | CicNotationEnv.OptValue (Some v) ->
 339         CicNotationEnv.OptValue (Some (pp_value v))
 340     | CicNotationEnv.ListValue vl ->
 341         CicNotationEnv.ListValue (List.map pp_value vl)
 342   in
 343   let ast_env_of_env env =
 344     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 345   in
 346   match term with
 347   | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, pp_ast1 t)
 348   | _ ->
 349       (match (get_compiled21 ()) term with
 350       | None -> pp_ast0 term pp_ast1
 351       | Some (env, pid) ->
 352           let precedence, associativity, l1 =
 353             try
 354               Hashtbl.find level1_patterns21 pid
 355             with Not_found -> assert false
 356           in
 357           Ast.AttributedTerm (`Level (precedence, associativity),
 358             (instantiate21 (ast_env_of_env env) l1)))
 359
 360 let instantiate32 term_info env symbol args =
 361   let rec instantiate_arg = function
 362     | Ast.IdentArg (n, name) ->
 363         let t = (try List.assoc name env with Not_found -> assert false) in
 364         let rec count_lambda = function
 365           | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
 366           | _ -> 0
 367         in
 368         let rec add_lambda t n =
 369           if n > 0 then
 370             let name = CicNotationUtil.fresh_name () in
 371             Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
 372               Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
 373           else
 374             t
 375         in
 376         add_lambda t (n - count_lambda t)
 377   in
 378   let args' = List.map instantiate_arg args in
 379   Ast.Appl (Ast.Symbol (symbol, 0) :: args')
 380
 381 let rec ast_of_acic1 term_info annterm =
 382   match (get_compiled32 ()) annterm with
 383   | None -> ast_of_acic0 term_info annterm ast_of_acic1
 384   | Some (env, pid) ->
 385       let env' =
 386         List.map (fun (name, term) -> (name, ast_of_acic1 term_info term)) env
 387       in
 388       let symbol, args, uris =
 389         try
 390           Hashtbl.find level2_patterns32 pid
 391         with Not_found -> assert false
 392       in
 393       let ast = instantiate32 term_info env' symbol args in
 394       match uris with
 395       | [] -> ast
 396       | _ -> Ast.AttributedTerm (`Href uris, ast)
 397
 398 let load_patterns32 t =
 399   set_compiled32 (CicNotationMatcher.Matcher32.compiler t)
 400
 401 let load_patterns21 t =
 402   set_compiled21 (CicNotationMatcher.Matcher21.compiler t)
 403
 404 let ast_of_acic id_to_sort annterm =
 405   let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
 406   let ast = ast_of_acic1 term_info annterm in
 407   ast, term_info.uri
 408
 409 let pp_ast term = pp_ast1 term
 410
 411 let fresh_id =
 412   let counter = ref ~-1 in
 413   fun () ->
 414     incr counter;
 415     !counter
 416
 417 let add_interpretation (symbol, args) appl_pattern =
 418   let id = fresh_id () in
 419   let uris = CicNotationUtil.find_appl_pattern_uris appl_pattern in
 420   Hashtbl.add level2_patterns32 id (symbol, args, uris);
 421   pattern32_matrix := (appl_pattern, id) :: !pattern32_matrix;
 422   load_patterns32 !pattern32_matrix;
 423   id
 424
 425 let add_pretty_printer
 426   ?(precedence = default_prec) ?(associativity = default_assoc) l2 l1
 427 =
 428   let id = fresh_id () in
 429   let l2' = CicNotationUtil.strip_attributes l2 in
 430   Hashtbl.add level1_patterns21 id (precedence, associativity, l1);
 431   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 432   load_patterns21 !pattern21_matrix;
 433   id
 434
 435 exception Interpretation_not_found
 436 exception Pretty_printer_not_found
 437
 438 let remove_interpretation id =
 439   (try
 440     Hashtbl.remove level2_patterns32 id;
 441   with Not_found -> raise Interpretation_not_found);
 442   pattern32_matrix := List.filter (fun (_, id') -> id <> id') !pattern32_matrix;
 443   load_patterns32 !pattern32_matrix
 444
 445 let remove_pretty_printer id =
 446   (try
 447     Hashtbl.remove level1_patterns21 id;
 448   with Not_found -> raise Pretty_printer_not_found);
 449   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 450   load_patterns21 !pattern21_matrix
 451
 452 let _ =
 453   load_patterns21 [];
 454   load_patterns32 []
 455