helm/ocaml/cic_notation/cicNotationRew.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 type pattern_id = int
  29 type interpretation_id = pattern_id
  30 type pretty_printer_id = pattern_id
  31
  32 type term_info =
  33   { sort: (Cic.id, CicNotationPt.sort_kind) Hashtbl.t;
  34     uri: (Cic.id, string) Hashtbl.t;
  35   }
  36
  37 let warning s = prerr_endline ("CicNotation WARNING: " ^ s)
  38
  39 let get_types uri =
  40   let o,_ = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
  41     match o with
  42       | Cic.InductiveDefinition (l,_,_,_) -> l
  43       | _ -> assert false
  44
  45 let name_of_inductive_type uri i =
  46   let types = get_types uri in
  47   let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  48   name
  49
  50   (* returns <name, type> pairs *)
  51 let constructors_of_inductive_type uri i =
  52   let types = get_types uri in
  53   let (_, _, _, constructors) =
  54     try List.nth types i with Not_found -> assert false
  55   in
  56   constructors
  57
  58   (* returns name only *)
  59 let constructor_of_inductive_type uri i j =
  60   (try
  61     fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  62   with Not_found -> assert false)
  63
  64 module Ast = CicNotationPt
  65
  66 let string_of_name = function
  67   | Cic.Name s -> s
  68   | Cic.Anonymous -> "_"
  69
  70 let ident_of_name n = Ast.Ident (string_of_name n, None)
  71
  72 let idref id t = Ast.AttributedTerm (`IdRef id, t)
  73
  74 let pp_ast0 t k =
  75   prerr_endline "pp_ast0";
  76   let rec aux t = CicNotationUtil.visit_ast ~special_k k t
  77   and special_k = function
  78     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, aux t)
  79     | _ -> assert false
  80   in
  81   aux t
  82
  83 let ast_of_acic0 term_info acic k =
  84 (*   prerr_endline "ast_of_acic0"; *)
  85   let k = k term_info in
  86   let register_uri id uri = Hashtbl.add term_info.uri id uri in
  87   let sort_of_id id =
  88     try
  89       Hashtbl.find term_info.sort id
  90     with Not_found -> assert false
  91   in
  92   let aux_substs substs =
  93     Some
  94       (List.map
  95         (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
  96         substs)
  97   in
  98   let aux_context context =
  99     List.map
 100       (function
 101         | None -> None
 102         | Some annterm -> Some (k annterm))
 103       context
 104   in
 105   let aux = function
 106     | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
 107     | Cic.AVar (id,uri,substs) ->
 108         register_uri id (UriManager.string_of_uri uri);
 109         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 110     | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
 111     | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
 112     | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
 113     | Cic.ASort (id,Cic.Type _) -> idref id (Ast.Sort `Type)
 114     | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
 115     | Cic.AImplicit _ -> assert false
 116     | Cic.AProd (id,n,s,t) ->
 117         let binder_kind =
 118           match sort_of_id id with
 119           | `Set | `Type -> `Pi
 120           | `Prop | `CProp -> `Forall
 121         in
 122         idref id (Ast.Binder (binder_kind, (ident_of_name n, Some (k s)), k t))
 123     | Cic.ACast (id,v,t) ->
 124         idref id (Ast.Appl [idref id (Ast.Symbol ("cast", 0)); k v; k t])
 125     | Cic.ALambda (id,n,s,t) ->
 126         idref id (Ast.Binder (`Lambda, (ident_of_name n, Some (k s)), k t))
 127     | Cic.ALetIn (id,n,s,t) ->
 128         idref id (Ast.LetIn ((ident_of_name n, None), k s, k t))
 129     | Cic.AAppl (aid,args) -> idref aid (Ast.Appl (List.map k args))
 130     | Cic.AConst (id,uri,substs) ->
 131         register_uri id (UriManager.string_of_uri uri);
 132         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 133     | Cic.AMutInd (id,uri,i,substs) as t ->
 134         let name = name_of_inductive_type uri i in
 135         let uri_str = UriManager.string_of_uri uri in
 136         let puri_str =
 137           uri_str ^ "#xpointer(1/" ^ (string_of_int (i + 1)) ^ ")"
 138         in
 139         register_uri id puri_str;
 140         idref id (Ast.Ident (name, aux_substs substs))
 141     | Cic.AMutConstruct (id,uri,i,j,substs) ->
 142         let name = constructor_of_inductive_type uri i j in
 143         let uri_str = UriManager.string_of_uri uri in
 144         let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
 145         register_uri id puri_str;
 146         idref id (Ast.Ident (name, aux_substs substs))
 147     | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
 148         let name = name_of_inductive_type uri typeno in
 149         let constructors = constructors_of_inductive_type uri typeno in
 150         let rec eat_branch ty pat =
 151           match (ty, pat) with
 152           | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
 153               let (cv, rhs) = eat_branch t t' in
 154               (ident_of_name name, Some (k s)) :: cv, rhs
 155           | _, _ -> [], k pat
 156         in
 157         let patterns =
 158           List.map2
 159             (fun (name, ty) pat ->
 160               let (capture_variables, rhs) = eat_branch ty pat in
 161               ((name, capture_variables), rhs))
 162             constructors patterns
 163         in
 164         idref id (Ast.Case (k te, Some name, Some (k ty), patterns))
 165     | Cic.AFix (id, no, funs) ->
 166         let defs =
 167           List.map
 168             (fun (_, n, decr_idx, ty, bo) ->
 169               ((Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
 170             funs
 171         in
 172         let name =
 173           try
 174             (match List.nth defs no with
 175             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 176             | _ -> assert false)
 177           with Not_found -> assert false
 178         in
 179         idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
 180     | Cic.ACoFix (id, no, funs) ->
 181         let defs =
 182           List.map
 183             (fun (_, n, ty, bo) -> ((Ast.Ident (n, None), Some (k ty)), k bo, 0))
 184             funs
 185         in
 186         let name =
 187           try
 188             (match List.nth defs no with
 189             | (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 190             | _ -> assert false)
 191           with Not_found -> assert false
 192         in
 193         idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
 194   in
 195   aux acic
 196
 197   (* persistent state *)
 198
 199 let level1_patterns21 = Hashtbl.create 211
 200 let level2_patterns32 = Hashtbl.create 211
 201
 202 let (compiled21: (CicNotationPt.term -> (CicNotationEnv.t * int) option)
 203 option ref) =
 204   ref None
 205 let (compiled32: (Cic.annterm -> ((string * Cic.annterm) list * int) option)
 206 option ref) =
 207   ref None
 208
 209 let pattern21_matrix = ref []
 210 let pattern32_matrix = ref []
 211
 212 let get_compiled21 () =
 213   match !compiled21 with
 214   | None -> assert false
 215   | Some f -> f
 216 let get_compiled32 () =
 217   match !compiled32 with
 218   | None -> assert false
 219   | Some f -> f
 220
 221 let set_compiled21 f = compiled21 := Some f
 222 let set_compiled32 f = compiled32 := Some f
 223
 224 let instantiate21 env precedence associativity l1 =
 225   prerr_endline "instantiate21";
 226   let rec subst_singleton env t =
 227     CicNotationUtil.boxify (subst env t)
 228   and subst env = function
 229     | Ast.AttributedTerm (_, t) -> subst env t
 230     | Ast.Variable var ->
 231         let name, expected_ty = CicNotationEnv.declaration_of_var var in
 232         let ty, value =
 233           try
 234             List.assoc name env
 235           with Not_found -> assert false
 236         in
 237         assert (CicNotationEnv.well_typed ty value); (* INVARIANT *)
 238         (* following assertion should be a conditional that makes this
 239          * instantiation fail *)
 240         assert (CicNotationEnv.well_typed expected_ty value);
 241         [ CicNotationEnv.term_of_value value ]
 242     | Ast.Magic m -> subst_magic env m
 243     | Ast.Literal _ as t -> [ t ]
 244     | Ast.Layout l -> [ Ast.Layout (subst_layout env l) ]
 245     | t -> [ CicNotationUtil.visit_ast (subst_singleton env) t ]
 246   and subst_magic env = function
 247     | Ast.List0 (p, sep_opt)
 248     | Ast.List1 (p, sep_opt) ->
 249         let rec_decls = CicNotationEnv.declarations_of_term p in
 250         let rec_values =
 251           List.map (fun (n, _) -> CicNotationEnv.lookup_list env n) rec_decls
 252         in
 253         let values = CicNotationUtil.ncombine rec_values in
 254         let sep =
 255           match sep_opt with
 256           | None -> []
 257           | Some l -> [ CicNotationPt.Literal l ]
 258         in
 259         let rec instantiate_list acc = function
 260           | [] -> List.rev acc
 261           | value_set :: [] ->
 262               let env = CicNotationEnv.combine rec_decls value_set in
 263                 instantiate_list
 264                   ((CicNotationUtil.boxify (subst env p)) :: acc) []
 265           | value_set :: tl ->
 266               let env = CicNotationEnv.combine rec_decls value_set in
 267               instantiate_list
 268                 ((CicNotationUtil.boxify (subst env p @ sep)) :: acc) tl
 269         in
 270         instantiate_list [] values
 271     | Ast.Opt p ->
 272         let opt_decls = CicNotationEnv.declarations_of_term p in
 273         let env =
 274           let rec build_env = function
 275             | [] -> []
 276             | (name, ty) :: tl ->
 277                   (* assumption: if one of the value is None then all are *)
 278                 (match CicNotationEnv.lookup_opt env name with
 279                 | None -> raise Exit
 280                 | Some v -> (name, (ty, v)) :: build_env tl)
 281           in
 282           try build_env opt_decls with Exit -> []
 283         in
 284           begin
 285             match env with
 286               | [] -> []
 287               | _ -> subst env p
 288           end
 289     | _ -> assert false (* impossible *)
 290   and subst_layout env = function
 291     | Ast.Box (kind, tl) -> Ast.Box (kind, List.concat (List.map (subst env) tl))
 292     | l -> CicNotationUtil.visit_layout (subst_singleton env) l
 293   in
 294     subst_singleton env l1
 295
 296 let rec pp_ast1 term =
 297   let rec pp_value = function
 298     | CicNotationEnv.NumValue _ as v -> v
 299     | CicNotationEnv.StringValue _ as v -> v
 300     | CicNotationEnv.TermValue t -> CicNotationEnv.TermValue (pp_ast1 t)
 301     | CicNotationEnv.OptValue None as v -> v
 302     | CicNotationEnv.OptValue (Some v) ->
 303         CicNotationEnv.OptValue (Some (pp_value v))
 304     | CicNotationEnv.ListValue vl ->
 305         CicNotationEnv.ListValue (List.map pp_value vl)
 306   in
 307   let ast_env_of_env env =
 308     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 309   in
 310   match (get_compiled21 ()) term with
 311   | None -> pp_ast0 term pp_ast1
 312   | Some (env, pid) ->
 313       let precedence, associativity, l1 =
 314         try
 315           Hashtbl.find level1_patterns21 pid
 316         with Not_found -> assert false
 317       in
 318       instantiate21 (ast_env_of_env env) precedence associativity l1
 319
 320 let instantiate32 term_info env symbol args =
 321   let rec instantiate_arg = function
 322     | Ast.IdentArg (n, name) ->
 323         let t = (try List.assoc name env with Not_found -> assert false) in
 324         let rec count_lambda = function
 325           | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
 326           | _ -> 0
 327         in
 328         let rec add_lambda t n =
 329           if n > 0 then
 330             let name = CicNotationUtil.fresh_name () in
 331             Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
 332               Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
 333           else
 334             t
 335         in
 336         add_lambda t (n - count_lambda t)
 337   in
 338   let args' = List.map instantiate_arg args in
 339   Ast.Appl (Ast.Symbol (symbol, 0) :: args')
 340
 341 let rec ast_of_acic1 term_info annterm =
 342   match (get_compiled32 ()) annterm with
 343   | None -> ast_of_acic0 term_info annterm ast_of_acic1
 344   | Some (env, pid) ->
 345       let env' =
 346         List.map (fun (name, term) -> (name, ast_of_acic1 term_info term)) env
 347       in
 348       let symbol, args =
 349         try
 350           Hashtbl.find level2_patterns32 pid
 351         with Not_found -> assert false
 352       in
 353       instantiate32 term_info env' symbol args
 354
 355 let load_patterns32 t =
 356   set_compiled32 (CicNotationMatcher.Matcher32.compiler t)
 357
 358 let load_patterns21 t =
 359   set_compiled21 (CicNotationMatcher.Matcher21.compiler t)
 360
 361 let ast_of_acic id_to_sort annterm =
 362   let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
 363   let ast = ast_of_acic1 term_info annterm in
 364   ast, term_info.uri
 365
 366 let pp_ast term = pp_ast1 term
 367
 368 let fresh_id =
 369   let counter = ref ~-1 in
 370   fun () ->
 371     incr counter;
 372     !counter
 373
 374 let add_interpretation (symbol, args) appl_pattern =
 375   let id = fresh_id () in
 376   Hashtbl.add level2_patterns32 id (symbol, args);
 377   pattern32_matrix := (appl_pattern, id) :: !pattern32_matrix;
 378   load_patterns32 !pattern32_matrix;
 379   id
 380
 381 let add_pretty_printer ?precedence ?associativity l2 l1 =
 382   let id = fresh_id () in
 383   let l2' = CicNotationUtil.strip_attributes l2 in
 384   Hashtbl.add level1_patterns21 id (precedence, associativity, l1);
 385   pattern21_matrix := (l2', id) :: !pattern21_matrix;
 386   load_patterns21 !pattern21_matrix;
 387   id
 388
 389 exception Interpretation_not_found
 390 exception Pretty_printer_not_found
 391
 392 let remove_interpretation id =
 393   (try
 394     Hashtbl.remove level2_patterns32 id;
 395   with Not_found -> raise Interpretation_not_found);
 396   pattern32_matrix := List.filter (fun (_, id') -> id <> id') !pattern32_matrix;
 397   load_patterns32 !pattern32_matrix
 398
 399 let remove_pretty_printer id =
 400   (try
 401     Hashtbl.remove level1_patterns21 id;
 402   with Not_found -> raise Pretty_printer_not_found);
 403   pattern21_matrix := List.filter (fun (_, id') -> id <> id') !pattern21_matrix;
 404   load_patterns21 !pattern21_matrix
 405
 406 let _ =
 407   load_patterns21 [];
 408   load_patterns32 []
 409