helm/ocaml/cic_notation/cicNotationUtil.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 module Ast = CicNotationPt
  27
  28 let visit_ast ?(special_k = fun _ -> assert false) k =
  29   let rec aux = function
  30     | Ast.Appl terms -> Ast.Appl (List.map k terms)
  31     | Ast.Binder (kind, var, body) ->
  32         Ast.Binder (kind, aux_capture_variable var, k body)
  33     | Ast.Case (term, indtype, typ, patterns) ->
  34         Ast.Case (k term, indtype, aux_opt typ, aux_patterns patterns)
  35     | Ast.Cast (t1, t2) -> Ast.Cast (k t1, k t2)
  36     | Ast.LetIn (var, t1, t2) ->
  37         Ast.LetIn (aux_capture_variable var, k t1, k t2)
  38     | Ast.LetRec (kind, definitions, term) ->
  39         let definitions =
  40           List.map
  41             (fun (var, ty, n) -> aux_capture_variable var, k ty, n)
  42             definitions
  43         in
  44         Ast.LetRec (kind, definitions, k term)
  45     | Ast.Ident (name, Some substs) ->
  46         Ast.Ident (name, Some (aux_substs substs))
  47     | Ast.Uri (name, Some substs) -> Ast.Uri (name, Some (aux_substs substs))
  48     | Ast.Meta (index, substs) -> Ast.Meta (index, List.map aux_opt substs)
  49     | (Ast.AttributedTerm _
  50       | Ast.Layout _
  51       | Ast.Literal _
  52       | Ast.Magic _
  53       | Ast.Variable _) as t -> special_k t
  54     | (Ast.Ident _
  55       | Ast.Implicit
  56       | Ast.Num _
  57       | Ast.Sort _
  58       | Ast.Symbol _
  59       | Ast.Uri _
  60       | Ast.UserInput) as t -> t
  61   and aux_opt = function
  62     | None -> None
  63     | Some term -> Some (k term)
  64   and aux_capture_variable (term, typ_opt) = k term, aux_opt typ_opt
  65   and aux_patterns patterns = List.map aux_pattern patterns
  66   and aux_pattern ((head, vars), term) =
  67     ((head, List.map aux_capture_variable vars), k term)
  68   and aux_subst (name, term) = (name, k term)
  69   and aux_substs substs = List.map aux_subst substs
  70   in
  71   aux
  72
  73 let visit_layout k = function
  74   | Ast.Sub (t1, t2) -> Ast.Sub (k t1, k t2)
  75   | Ast.Sup (t1, t2) -> Ast.Sup (k t1, k t2)
  76   | Ast.Below (t1, t2) -> Ast.Below (k t1, k t2)
  77   | Ast.Above (t1, t2) -> Ast.Above (k t1, k t2)
  78   | Ast.Over (t1, t2) -> Ast.Over (k t1, k t2)
  79   | Ast.Atop (t1, t2) -> Ast.Atop (k t1, k t2)
  80   | Ast.Frac (t1, t2) -> Ast.Frac (k t1, k t2)
  81   | Ast.Sqrt t -> Ast.Sqrt (k t)
  82   | Ast.Root (arg, index) -> Ast.Root (k arg, k index)
  83   | Ast.Break -> Ast.Break
  84   | Ast.Box (kind, terms) -> Ast.Box (kind, List.map k terms)
  85   | Ast.Group terms -> Ast.Group (List.map k terms)
  86
  87 let visit_magic k = function
  88   | Ast.List0 (t, l) -> Ast.List0 (k t, l)
  89   | Ast.List1 (t, l) -> Ast.List1 (k t, l)
  90   | Ast.Opt t -> Ast.Opt (k t)
  91   | Ast.Fold (kind, t1, names, t2) -> Ast.Fold (kind, k t1, names, k t2)
  92   | Ast.Default (t1, t2) -> Ast.Default (k t1, k t2)
  93   | Ast.If (t1, t2, t3) -> Ast.If (k t1, k t2, k t3)
  94   | Ast.Fail -> Ast.Fail
  95
  96 let visit_variable k = function
  97   | Ast.NumVar _
  98   | Ast.IdentVar _
  99   | Ast.TermVar _
 100   | Ast.FreshVar _ as t -> t
 101   | Ast.Ascription (t, s) -> Ast.Ascription (k t, s)
 102
 103 let variables_of_term t =
 104   let rec vars = ref [] in
 105   let add_variable v =
 106     if List.mem v !vars then ()
 107     else vars := v :: !vars
 108   in
 109   let rec aux = function
 110     | Ast.Magic m -> Ast.Magic (visit_magic aux m)
 111     | Ast.Layout l -> Ast.Layout (visit_layout aux l)
 112     | Ast.Variable v -> Ast.Variable (aux_variable v)
 113     | Ast.Literal _ as t -> t
 114     | Ast.AttributedTerm (_, t) -> aux t
 115     | t -> visit_ast aux t
 116   and aux_variable = function
 117     | (Ast.NumVar _
 118       | Ast.IdentVar _
 119       | Ast.TermVar _) as t ->
 120         add_variable t ;
 121         t
 122     | Ast.FreshVar _ as t -> t
 123     | Ast.Ascription _ -> assert false
 124   in
 125     ignore (aux t) ;
 126     !vars
 127
 128 let names_of_term t =
 129   let aux = function
 130     | Ast.NumVar s
 131     | Ast.IdentVar s
 132     | Ast.TermVar s -> s
 133     | _ -> assert false
 134   in
 135     List.map aux (variables_of_term t)
 136
 137 let keywords_of_term t =
 138   let rec keywords = ref [] in
 139   let add_keyword k = keywords := k :: !keywords in
 140   let rec aux = function
 141     | Ast.AttributedTerm (_, t) -> aux t
 142     | Ast.Layout l -> Ast.Layout (visit_layout aux l)
 143     | Ast.Literal (`Keyword k) as t ->
 144         add_keyword k;
 145         t
 146     | Ast.Literal _ as t -> t
 147     | Ast.Magic m -> Ast.Magic (visit_magic aux m)
 148     | Ast.Variable _ as v -> v
 149     | t -> visit_ast aux t
 150   in
 151     ignore (aux t) ;
 152     !keywords
 153
 154 let rec strip_attributes t =
 155   let special_k = function
 156     | Ast.AttributedTerm (_, term) -> strip_attributes term
 157     | Ast.Magic m -> Ast.Magic (visit_magic strip_attributes m)
 158     | Ast.Variable _ as t -> t
 159     | t -> assert false
 160   in
 161   visit_ast ~special_k strip_attributes t
 162
 163 let meta_names_of_term term =
 164   let rec names = ref [] in
 165   let add_name n =
 166     if List.mem n !names then ()
 167     else names := n :: !names
 168   in
 169   let rec aux = function
 170     | Ast.AttributedTerm (_, term) -> aux term
 171     | Ast.Appl terms -> List.iter aux terms
 172     | Ast.Binder (_, _, body) -> aux body
 173     | Ast.Case (term, indty, outty_opt, patterns) ->
 174         aux term ;
 175         aux_opt outty_opt ;
 176         List.iter aux_branch patterns
 177     | Ast.LetIn (_, t1, t2) ->
 178         aux t1 ;
 179         aux t2
 180     | Ast.LetRec (_, definitions, body) ->
 181         List.iter aux_definition definitions ;
 182         aux body
 183     | Ast.Uri (_, Some substs) -> aux_substs substs
 184     | Ast.Ident (_, Some substs) -> aux_substs substs
 185     | Ast.Meta (_, substs) -> aux_meta_substs substs
 186
 187     | Ast.Implicit
 188     | Ast.Ident _
 189     | Ast.Num _
 190     | Ast.Sort _
 191     | Ast.Symbol _
 192     | Ast.Uri _
 193     | Ast.UserInput -> ()
 194
 195     | Ast.Magic magic -> aux_magic magic
 196     | Ast.Variable var -> aux_variable var
 197
 198     | _ -> assert false
 199   and aux_opt = function
 200     | Some term -> aux term
 201     | None -> ()
 202   and aux_capture_var (_, ty_opt) = aux_opt ty_opt
 203   and aux_branch (pattern, term) =
 204     aux_pattern pattern ;
 205     aux term
 206   and aux_pattern (head, vars) =
 207     List.iter aux_capture_var vars
 208   and aux_definition (var, term, i) =
 209     aux_capture_var var ;
 210     aux term
 211   and aux_substs substs = List.iter (fun (_, term) -> aux term) substs
 212   and aux_meta_substs meta_substs = List.iter aux_opt meta_substs
 213   and aux_variable = function
 214     | Ast.NumVar name -> add_name name
 215     | Ast.IdentVar name -> add_name name
 216     | Ast.TermVar name -> add_name name
 217     | Ast.FreshVar _ -> ()
 218     | Ast.Ascription _ -> assert false
 219   and aux_magic = function
 220     | Ast.Default (t1, t2)
 221     | Ast.Fold (_, t1, _, t2) ->
 222         aux t1 ;
 223         aux t2
 224     | Ast.If (t1, t2, t3) ->
 225         aux t1 ;
 226         aux t2 ;
 227         aux t3
 228     | Ast.Fail -> ()
 229     | _ -> assert false
 230   in
 231   aux term ;
 232   !names
 233
 234 let rectangular matrix =
 235   let columns = Array.length matrix.(0) in
 236   try
 237     Array.iter (fun a -> if Array.length a <> columns then raise Exit) matrix;
 238     true
 239   with Exit -> false
 240
 241 let ncombine ll =
 242   let matrix = Array.of_list (List.map Array.of_list ll) in
 243   assert (rectangular matrix);
 244   let rows = Array.length matrix in
 245   let columns = Array.length matrix.(0) in
 246   let lists = ref [] in
 247   for j = 0 to columns - 1 do
 248     let l = ref [] in
 249     for i = 0 to rows - 1 do
 250       l := matrix.(i).(j) :: !l
 251     done;
 252     lists := List.rev !l :: !lists
 253   done;
 254   List.rev !lists
 255
 256 let string_of_literal = function
 257   | `Symbol s
 258   | `Keyword s
 259   | `Number s -> s
 260
 261 let boxify = function
 262   | [ a ] -> a
 263   | l -> Ast.Layout (Ast.Box ((Ast.H, false, false), l))
 264
 265 let unboxify = function
 266   | Ast.Layout (Ast.Box ((Ast.H, false, false), [ a ])) -> a
 267   | l -> l
 268
 269 let group = function
 270   | [ a ] -> a
 271   | l -> Ast.Layout (Ast.Group l)
 272
 273 let ungroup =
 274   let rec aux acc =
 275     function
 276         [] -> List.rev acc
 277       | Ast.Layout (Ast.Group terms) :: terms' -> aux acc (terms @ terms')
 278       | term :: terms -> aux (term :: acc) terms
 279   in
 280     aux []
 281
 282 let dress ~sep:sauce =
 283   let rec aux =
 284     function
 285       | [] -> []
 286       | [hd] -> [hd]
 287       | hd :: tl -> hd :: sauce :: aux tl
 288   in
 289     aux
 290
 291 let dressn ~sep:sauces =
 292   let rec aux =
 293     function
 294       | [] -> []
 295       | [hd] -> [hd]
 296       | hd :: tl -> hd :: sauces @ aux tl
 297   in
 298     aux
 299
 300 let find_appl_pattern_uris ap =
 301   let rec aux acc =
 302     function
 303     | Ast.UriPattern uri ->
 304         (try
 305           ignore (List.find (fun uri' -> UriManager.eq uri uri') acc);
 306           acc
 307         with Not_found -> uri :: acc)
 308     | Ast.ImplicitPattern
 309     | Ast.VarPattern _ -> acc
 310     | Ast.ApplPattern apl -> List.fold_left aux acc apl
 311   in
 312   aux [] ap
 313
 314 let rec find_branch =
 315   function
 316       Ast.Magic (Ast.If (_, Ast.Magic Ast.Fail, t)) -> find_branch t
 317     | Ast.Magic (Ast.If (_, t, _)) -> find_branch t
 318     | t -> t
 319
 320 let cic_name_of_name = function
 321   | Ast.Ident ("_", None) -> Cic.Anonymous
 322   | Ast.Ident (name, None) -> Cic.Name name
 323   | _ -> assert false
 324
 325 let name_of_cic_name =
 326 (*   let add_dummy_xref t = Ast.AttributedTerm (`IdRef "", t) in *)
 327   (* ZACK why we used to generate dummy xrefs? *)
 328   let add_dummy_xref t = t in
 329   function
 330   | Cic.Name s -> add_dummy_xref (Ast.Ident (s, None))
 331   | Cic.Anonymous -> add_dummy_xref (Ast.Ident ("_", None))
 332
 333 let fresh_index = ref ~-1
 334
 335 type notation_id = int
 336
 337 let fresh_id () =
 338   incr fresh_index;
 339   !fresh_index
 340
 341   (* TODO ensure that names generated by fresh_var do not clash with user's *)
 342 let fresh_name () = "fresh" ^ string_of_int (fresh_id ())
 343
 344 let rec freshen_term ?(index = ref 0) term =
 345   let freshen_term = freshen_term ~index in
 346   let fresh_instance () = incr index; !index in
 347   let special_k = function
 348     | Ast.AttributedTerm (attr, t) -> Ast.AttributedTerm (attr, freshen_term t)
 349     | Ast.Layout l -> Ast.Layout (visit_layout freshen_term l)
 350     | Ast.Magic m -> Ast.Magic (visit_magic freshen_term m)
 351     | Ast.Variable v -> Ast.Variable (visit_variable freshen_term v)
 352     | Ast.Literal _ as t -> t
 353     | _ -> assert false
 354   in
 355   match term with
 356   | Ast.Symbol (s, instance) -> Ast.Symbol (s, fresh_instance ())
 357   | Ast.Num (s, instance) -> Ast.Num (s, fresh_instance ())
 358   | t -> visit_ast ~special_k freshen_term t
 359
 360 let freshen_obj obj =
 361   let index = ref 0 in
 362   let freshen_term = freshen_term ~index in
 363   let freshen_name_ty = List.map (fun (n, t) -> (n, freshen_term t)) in
 364   match obj with
 365   | GrafiteAst.Inductive (params, indtypes) ->
 366       let indtypes =
 367         List.map
 368           (fun (n, co, ty, ctors) -> (n, co, ty, freshen_name_ty ctors))
 369           indtypes
 370       in
 371       GrafiteAst.Inductive (freshen_name_ty params, indtypes)
 372   | GrafiteAst.Theorem (flav, n, t, ty_opt) ->
 373       let ty_opt =
 374         match ty_opt with None -> None | Some ty -> Some (freshen_term ty)
 375       in
 376       GrafiteAst.Theorem (flav, n, freshen_term t, ty_opt)
 377   | GrafiteAst.Record (params, n, ty, fields) ->
 378       GrafiteAst.Record (freshen_name_ty params, n, freshen_term ty,
 379         freshen_name_ty fields)
 380
 381 let freshen_term = freshen_term ?index:None
 382