helm/ocaml/cic_proof_checking/cicElim.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 exception Elim_failure of string
  29 exception Can_t_eliminate
  30
  31 let debug_print = fun _ -> ()
  32
  33 let fresh_binder =
  34   let counter = ref ~-1 in
  35   function
  36     | true ->
  37         incr counter;
  38         Cic.Name ("e" ^ string_of_int !counter)
  39     | _ -> Cic.Anonymous
  40
  41   (** verifies if a given inductive type occurs in a term in target position *)
  42 let rec recursive uri typeno = function
  43   | Cic.Prod (_, _, target) -> recursive uri typeno target
  44   | Cic.MutInd (uri', typeno', [])
  45   | Cic.Appl (Cic.MutInd  (uri', typeno', []) :: _) ->
  46       UriManager.eq uri uri' && typeno = typeno'
  47   | _ -> false
  48
  49   (** given a list of constructor types, return true if at least one of them is
  50   * recursive, false otherwise *)
  51 let recursive_type uri typeno constructors =
  52   let rec aux = function
  53     | Cic.Prod (_, src, tgt) -> recursive uri typeno src || aux tgt
  54     | _ -> false
  55   in
  56   List.exists (fun (_, ty) -> aux ty) constructors
  57
  58 let unfold_appl = function
  59   | Cic.Appl ((Cic.Appl args) :: tl) -> Cic.Appl (args @ tl)
  60   | t -> t
  61
  62 let rec split l n =
  63  match (l,n) with
  64     (l,0) -> ([], l)
  65   | (he::tl, n) -> let (l1,l2) = split tl (n-1) in (he::l1,l2)
  66   | (_,_) -> assert false
  67
  68   (** build elimination principle part related to a single constructor
  69   * @param paramsno number of Prod to ignore in this constructor (i.e. number of
  70   * inductive parameters)
  71   * @param dependent true if we are in the dependent case (i.e. sort <> Prop) *)
  72 let rec delta (uri, typeno) dependent paramsno consno t p args =
  73   match t with
  74   | Cic.MutInd (uri', typeno', []) when
  75     UriManager.eq uri uri' && typeno = typeno' ->
  76       if dependent then
  77         (match args with
  78         | [] -> assert false
  79         | [arg] -> unfold_appl (Cic.Appl [p; arg])
  80         | _ -> unfold_appl (Cic.Appl [p; unfold_appl (Cic.Appl args)]))
  81       else
  82         p
  83   | Cic.Appl (Cic.MutInd (uri', typeno', []) :: tl) when
  84     UriManager.eq uri uri' && typeno = typeno' ->
  85       let (lparams, rparams) = split tl paramsno in
  86       if dependent then
  87         (match args with
  88         | [] -> assert false
  89         | [arg] -> unfold_appl (Cic.Appl (p :: rparams @ [arg]))
  90         | _ ->
  91             unfold_appl (Cic.Appl (p ::
  92               rparams @ [unfold_appl (Cic.Appl args)])))
  93       else  (* non dependent *)
  94         (match rparams with
  95         | [] -> p
  96         | _ -> Cic.Appl (p :: rparams))
  97   | Cic.Prod (binder, src, tgt) ->
  98       if recursive uri typeno src then
  99         let args = List.map (CicSubstitution.lift 2) args in
 100         let phi =
 101           let src = CicSubstitution.lift 1 src in
 102           delta (uri, typeno) dependent paramsno consno src
 103             (CicSubstitution.lift 1 p) [Cic.Rel 1]
 104         in
 105         let tgt = CicSubstitution.lift 1 tgt in
 106         Cic.Prod (fresh_binder dependent, src,
 107           Cic.Prod (Cic.Anonymous, phi,
 108             delta (uri, typeno) dependent paramsno consno tgt
 109               (CicSubstitution.lift 2 p) (args @ [Cic.Rel 2])))
 110       else  (* non recursive *)
 111         let args = List.map (CicSubstitution.lift 1) args in
 112         Cic.Prod (fresh_binder dependent, src,
 113           delta (uri, typeno) dependent paramsno consno tgt
 114             (CicSubstitution.lift 1 p) (args @ [Cic.Rel 1]))
 115   | _ -> assert false
 116
 117 let rec strip_left_params consno leftno = function
 118   | t when leftno = 0 -> t (* no need to lift, the term is (hopefully) closed *)
 119   | Cic.Prod (_, _, tgt) (* when leftno > 0 *) ->
 120       (* after stripping the parameters we lift of consno. consno is 1 based so,
 121       * the first constructor will be lifted by 1 (for P), the second by 2 (1
 122       * for P and 1 for the 1st constructor), and so on *)
 123       if leftno = 1 then
 124         CicSubstitution.lift consno tgt
 125       else
 126         strip_left_params consno (leftno - 1) tgt
 127   | _ -> assert false
 128
 129 let delta (ury, typeno) dependent paramsno consno t p args =
 130   let t = strip_left_params consno paramsno t in
 131   delta (ury, typeno) dependent paramsno consno t p args
 132
 133 let rec add_params binder indno ty eliminator =
 134   if indno = 0 then
 135     eliminator
 136   else
 137     match ty with
 138     | Cic.Prod (name, src, tgt) ->
 139         binder name src (add_params binder (indno - 1) tgt eliminator)
 140     | _ -> assert false
 141
 142 let rec mk_rels consno = function
 143   | 0 -> []
 144   | n -> Cic.Rel (n+consno) :: mk_rels consno (n-1)
 145
 146 let rec strip_pi = function
 147   | Cic.Prod (_, _, tgt) -> strip_pi tgt
 148   | t -> t
 149
 150 let rec count_pi = function
 151   | Cic.Prod (_, _, tgt) -> count_pi tgt + 1
 152   | t -> 0
 153
 154 let rec type_of_p sort dependent leftno indty = function
 155   | Cic.Prod (n, src, tgt) when leftno = 0 ->
 156       Cic.Prod (n, src, type_of_p sort dependent leftno indty tgt)
 157   | Cic.Prod (_, _, tgt) -> type_of_p sort dependent (leftno - 1) indty tgt
 158   | t ->
 159       if dependent then
 160         Cic.Prod (Cic.Anonymous, indty, Cic.Sort sort)
 161       else
 162         Cic.Sort sort
 163
 164 let rec add_right_pi dependent strip liftno liftfrom rightno indty = function
 165   | Cic.Prod (_, src, tgt) when strip = 0 ->
 166       Cic.Prod (fresh_binder true,
 167         CicSubstitution.lift_from liftfrom liftno src,
 168         add_right_pi dependent strip liftno (liftfrom + 1) rightno indty tgt)
 169   | Cic.Prod (_, _, tgt) ->
 170       add_right_pi dependent (strip - 1) liftno liftfrom rightno indty tgt
 171   | t ->
 172       if dependent then
 173         Cic.Prod (fresh_binder dependent,
 174           CicSubstitution.lift_from (rightno + 1) liftno indty,
 175           Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 0 (rightno + 1)))
 176       else
 177         Cic.Prod (Cic.Anonymous,
 178           CicSubstitution.lift_from (rightno + 1) liftno indty,
 179           if rightno = 0 then
 180             Cic.Rel (1 + liftno + rightno)
 181           else
 182             Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 1 rightno))
 183
 184 let rec add_right_lambda dependent strip liftno liftfrom rightno indty case =
 185 function
 186   | Cic.Prod (_, src, tgt) when strip = 0 ->
 187       Cic.Lambda (fresh_binder true,
 188         CicSubstitution.lift_from liftfrom liftno src,
 189         add_right_lambda dependent strip liftno (liftfrom + 1) rightno indty
 190           case tgt)
 191   | Cic.Prod (_, _, tgt) ->
 192       add_right_lambda dependent (strip - 1) liftno liftfrom rightno indty
 193         case tgt
 194   | t ->
 195       Cic.Lambda (fresh_binder true,
 196         CicSubstitution.lift_from (rightno + 1) liftno indty, case)
 197
 198 let rec branch (uri, typeno) insource paramsno t fix head args =
 199   match t with
 200   | Cic.MutInd (uri', typeno', []) when
 201     UriManager.eq uri uri' && typeno = typeno' ->
 202       if insource then
 203         (match args with
 204         | [arg] -> Cic.Appl (fix :: args)
 205         | _ -> Cic.Appl (head :: [Cic.Appl args]))
 206       else
 207         (match args with
 208         | [] -> head
 209         | _ -> Cic.Appl (head :: args))
 210   | Cic.Appl (Cic.MutInd (uri', typeno', []) :: tl) when
 211     UriManager.eq uri uri' && typeno = typeno' ->
 212       if insource then
 213         let (lparams, rparams) = split tl paramsno in
 214         match args with
 215         | [arg] -> Cic.Appl (fix :: rparams @ args)
 216         | _ -> Cic.Appl (fix :: rparams @ [Cic.Appl args])
 217       else
 218         (match args with
 219         | [] -> head
 220         | _ -> Cic.Appl (head :: args))
 221   | Cic.Prod (binder, src, tgt) ->
 222       if recursive uri typeno src then
 223         let args = List.map (CicSubstitution.lift 1) args in
 224         let phi =
 225           let fix = CicSubstitution.lift 1 fix in
 226           let src = CicSubstitution.lift 1 src in
 227           branch (uri, typeno) true paramsno src fix head [Cic.Rel 1]
 228         in
 229         Cic.Lambda (fresh_binder true, src,
 230           branch (uri, typeno) insource paramsno tgt
 231             (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 232             (args @ [Cic.Rel 1; phi]))
 233       else  (* non recursive *)
 234         let args = List.map (CicSubstitution.lift 1) args in
 235         Cic.Lambda (fresh_binder true, src,
 236           branch (uri, typeno) insource paramsno tgt
 237           (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 238             (args @ [Cic.Rel 1]))
 239   | _ -> assert false
 240
 241 let branch (uri, typeno) insource liftno paramsno t fix head args =
 242   let t = strip_left_params liftno paramsno t in
 243   branch (uri, typeno) insource paramsno t fix head args
 244
 245 let elim_of ?(sort = Cic.Type (CicUniv.fresh ())) uri typeno =
 246   let (obj, univ) = (CicEnvironment.get_obj CicUniv.empty_ugraph uri) in
 247   match obj with
 248   | Cic.InductiveDefinition (indTypes, params, leftno, _) ->
 249       let (name, inductive, ty, constructors) =
 250         try
 251           List.nth indTypes typeno
 252         with Failure _ -> assert false
 253       in
 254       let paramsno = count_pi ty in (* number of (left or right) parameters *)
 255       let rightno = paramsno - leftno in
 256       let dependent = (strip_pi ty <> Cic.Sort Cic.Prop) in
 257       let conslen = List.length constructors in
 258       let consno = ref (conslen + 1) in
 259       if (not dependent) && (sort <> Cic.Prop) && (conslen > 1) then
 260         raise Can_t_eliminate;
 261       let indty =
 262         let indty = Cic.MutInd (uri, typeno, []) in
 263         if paramsno = 0 then
 264           indty
 265         else
 266           Cic.Appl (indty :: mk_rels 0 paramsno)
 267       in
 268       let mk_constructor consno =
 269         let constructor = Cic.MutConstruct (uri, typeno, consno, []) in
 270         if leftno = 0 then
 271           constructor
 272         else
 273           Cic.Appl (constructor :: mk_rels consno leftno)
 274       in
 275       let p_ty = type_of_p sort dependent leftno indty ty in
 276       let final_ty =
 277         add_right_pi dependent leftno (conslen + 1) 1 rightno indty ty
 278       in
 279       let eliminator_type =
 280         let cic =
 281           Cic.Prod (Cic.Name "P", p_ty,
 282             (List.fold_right
 283               (fun (_, constructor) acc ->
 284                 decr consno;
 285                 let p = Cic.Rel !consno in
 286                 Cic.Prod (Cic.Anonymous,
 287                   (delta (uri, typeno) dependent leftno !consno
 288                     constructor p [mk_constructor !consno]),
 289                   acc))
 290               constructors final_ty))
 291         in
 292         add_params (fun b s t -> Cic.Prod (b, s, t)) leftno ty cic
 293       in
 294       let consno = ref (conslen + 1) in
 295       let eliminator_body =
 296         let fix = Cic.Rel (rightno + 2) in
 297         let is_recursive = recursive_type uri typeno constructors in
 298         let recshift = if is_recursive then 1 else 0 in
 299         let (_, branches) =
 300           List.fold_right
 301             (fun (_, ty) (shift, branches) ->
 302               let head = Cic.Rel (rightno + shift + 1 + recshift) in
 303               let b =
 304                 branch (uri, typeno) false
 305                   (rightno + conslen + 2 + recshift) leftno ty fix head []
 306               in
 307               (shift + 1,  b :: branches))
 308             constructors (1, [])
 309         in
 310         let mutcase =
 311           Cic.MutCase (uri, typeno, Cic.Rel (conslen + rightno + 2 + recshift),
 312             Cic.Rel 1, branches)
 313         in
 314         let body =
 315           if is_recursive then
 316             let fixfun =
 317               add_right_lambda dependent leftno (conslen + 2) 1 rightno
 318                 indty mutcase ty
 319             in
 320             (* rightno is the decreasing argument, i.e. the argument of
 321              * inductive type *)
 322             Cic.Fix (0, ["f", rightno, final_ty, fixfun])
 323           else
 324             add_right_lambda dependent leftno (conslen + 1) 1 rightno indty
 325               mutcase ty
 326         in
 327         let cic =
 328           Cic.Lambda (Cic.Name "P", p_ty,
 329             (List.fold_right
 330               (fun (_, constructor) acc ->
 331                 decr consno;
 332                 let p = Cic.Rel !consno in
 333                 Cic.Lambda (fresh_binder true,
 334                   (delta (uri, typeno) dependent leftno !consno
 335                     constructor p [mk_constructor !consno]),
 336                   acc))
 337               constructors body))
 338         in
 339         add_params (fun b s t -> Cic.Lambda (b, s, t)) leftno ty cic
 340       in
 341 (*
 342 debug_print (CicPp.ppterm eliminator_type);
 343 debug_print (CicPp.ppterm eliminator_body);
 344 *)
 345       let (computed_type, ugraph) =
 346         try
 347           CicTypeChecker.type_of_aux' [] [] eliminator_body CicUniv.empty_ugraph
 348         with CicTypeChecker.TypeCheckerFailure msg ->
 349           raise (Elim_failure (sprintf
 350             "type checker failure while type checking:\n%s\nerror:\n%s"
 351             (CicPp.ppterm eliminator_body) msg))
 352       in
 353       if not (fst (CicReduction.are_convertible []
 354         eliminator_type computed_type ugraph))
 355       then
 356         raise (Failure (sprintf
 357           "internal error: type mismatch on eliminator type\n%s\n%s"
 358           (CicPp.ppterm eliminator_type) (CicPp.ppterm computed_type)));
 359       let suffix =
 360         match sort with
 361         | Cic.Prop -> "_ind"
 362         | Cic.Set -> "_rec"
 363         | Cic.Type _ -> "_rect"
 364         | _ -> assert false
 365       in
 366       let name = UriManager.name_of_uri uri ^ suffix in
 367       let obj_attrs = [`Class (`Elim sort); `Generated] in
 368       Cic.Constant (name, Some eliminator_body, eliminator_type, [], obj_attrs)
 369   | _ ->
 370       failwith (sprintf "not an inductive definition (%s)"
 371         (UriManager.string_of_uri uri))
 372