helm/ocaml/cic_proof_checking/cicElim.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 exception Elim_failure of string
  29 exception Can_t_eliminate
  30
  31 let fresh_binder =
  32   let counter = ref ~-1 in
  33   function
  34     | true ->
  35         incr counter;
  36         Cic.Name ("e" ^ string_of_int !counter)
  37     | _ -> Cic.Anonymous
  38
  39   (** verifies if a given inductive type occurs in a term in target position *)
  40 let rec recursive uri typeno subst = function
  41   | Cic.Prod (_, _, target) -> recursive uri typeno subst target
  42   | Cic.MutInd (uri', typeno', subst')
  43   | Cic.Appl (Cic.MutInd  (uri', typeno', subst') :: _) ->
  44       UriManager.eq uri uri' && typeno = typeno' && subst = subst'
  45 (*   | Cic.Appl args -> List.exists (recursive uri typeno subst) args *)
  46   | _ -> false
  47
  48   (** given a list of constructor types, return true if at least one of them is
  49   * recursive, false otherwise *)
  50 let recursive_type uri typeno subst constructors =
  51   let rec aux = function
  52     | Cic.Prod (_, src, tgt) -> recursive uri typeno subst src || aux tgt
  53     | _ -> false
  54   in
  55   List.exists (fun (_, ty) -> aux ty) constructors
  56
  57 let unfold_appl = function
  58   | Cic.Appl ((Cic.Appl args) :: tl) -> Cic.Appl (args @ tl)
  59   | t -> t
  60
  61 let rec split l n =
  62  match (l,n) with
  63     (l,0) -> ([], l)
  64   | (he::tl, n) -> let (l1,l2) = split tl (n-1) in (he::l1,l2)
  65   | (_,_) -> assert false
  66
  67   (** build elimination principle part related to a single constructor
  68   * @param paramsno number of Prod to ignore in this constructor (i.e. number of
  69   * inductive parameters)
  70   * @param dependent true if we are in the dependent case (i.e. sort <> Prop) *)
  71 let rec delta (uri, typeno, subst) dependent paramsno consno t p args =
  72   assert (subst = []);
  73   match t with
  74   | Cic.MutInd (uri', typeno', subst') when
  75     UriManager.eq uri uri' && typeno = typeno' && subst = subst' ->
  76       if dependent then
  77         (match args with
  78         | [] -> assert false
  79         | [arg] -> unfold_appl (Cic.Appl [p; arg])
  80         | _ -> unfold_appl (Cic.Appl [p; unfold_appl (Cic.Appl args)]))
  81       else
  82         p
  83   | Cic.Appl (Cic.MutInd (uri', typeno', subst') :: tl) when
  84     UriManager.eq uri uri' && typeno = typeno' && subst = subst' ->
  85       let (lparams, rparams) = split tl paramsno in
  86       if dependent then
  87         (match args with
  88         | [] -> assert false
  89         | [arg] -> unfold_appl (Cic.Appl (p :: rparams @ [arg]))
  90         | _ ->
  91             unfold_appl (Cic.Appl (p ::
  92               rparams @ [unfold_appl (Cic.Appl args)])))
  93       else  (* non dependent *)
  94         (match rparams with
  95         | [] -> p
  96         | _ -> Cic.Appl (p :: rparams))
  97   | Cic.Prod (binder, src, tgt) ->
  98       if recursive uri typeno subst src then
  99         let args = List.map (CicSubstitution.lift 2) args in
 100         let phi =
 101           let src = CicSubstitution.lift 1 src in
 102           delta (uri, typeno, subst) dependent paramsno consno src
 103             (CicSubstitution.lift 1 p) [Cic.Rel 1]
 104         in
 105         let tgt = CicSubstitution.lift 1 tgt in
 106         Cic.Prod (fresh_binder dependent, src,
 107           Cic.Prod (Cic.Anonymous, phi,
 108             delta (uri, typeno, subst) dependent paramsno consno tgt
 109               (CicSubstitution.lift 2 p) (args @ [Cic.Rel 2])))
 110       else  (* non recursive *)
 111         let args = List.map (CicSubstitution.lift 1) args in
 112         Cic.Prod (fresh_binder dependent, src,
 113           delta (uri, typeno, subst) dependent paramsno consno tgt
 114             (CicSubstitution.lift 1 p) (args @ [Cic.Rel 1]))
 115   | _ -> assert false
 116
 117 let rec strip_left_params consno leftno = function
 118   | t when leftno = 0 -> t (* no need to lift, the term is (hopefully) closed *)
 119   | Cic.Prod (_, _, tgt) (* when leftno > 0 *) ->
 120       (* after stripping the parameters we lift of consno. consno is 1 based so,
 121       * the first constructor will be lifted by 1 (for P), the second by 2 (1
 122       * for P and 1 for the 1st constructor), and so on *)
 123       if leftno = 1 then
 124         CicSubstitution.lift consno tgt
 125       else
 126         strip_left_params consno (leftno - 1) tgt
 127   | _ -> assert false
 128
 129 let delta (ury, typeno, subst) dependent paramsno consno t p args =
 130   let t = strip_left_params consno paramsno t in
 131   delta (ury, typeno, subst) dependent paramsno consno t p args
 132
 133 let rec add_params binder indno ty eliminator =
 134   if indno = 0 then
 135     eliminator
 136   else
 137     match ty with
 138     | Cic.Prod (name, src, tgt) ->
 139         binder name src (add_params binder (indno - 1) tgt eliminator)
 140     | _ -> assert false
 141
 142 let rec mk_rels consno = function
 143   | 0 -> []
 144   | n -> Cic.Rel (n+consno) :: mk_rels consno (n-1)
 145
 146 let rec strip_pi = function
 147   | Cic.Prod (_, _, tgt) -> strip_pi tgt
 148   | t -> t
 149
 150 let rec count_pi = function
 151   | Cic.Prod (_, _, tgt) -> count_pi tgt + 1
 152   | t -> 0
 153
 154 let rec type_of_p sort dependent leftno indty = function
 155   | Cic.Prod (n, src, tgt) when leftno = 0 ->
 156       Cic.Prod (n, src, type_of_p sort dependent leftno indty tgt)
 157   | Cic.Prod (_, _, tgt) -> type_of_p sort dependent (leftno - 1) indty tgt
 158   | t ->
 159       if dependent then
 160         Cic.Prod (Cic.Anonymous, indty, Cic.Sort sort)
 161       else
 162         Cic.Sort sort
 163
 164 let rec add_right_pi dependent strip liftno liftfrom rightno indty = function
 165   | Cic.Prod (_, src, tgt) when strip = 0 ->
 166       Cic.Prod (fresh_binder true,
 167         CicSubstitution.lift_from (liftfrom + 1) liftno src,
 168         add_right_pi dependent strip liftno (liftfrom + 1) rightno indty tgt)
 169   | Cic.Prod (_, _, tgt) ->
 170       add_right_pi dependent (strip - 1) liftno liftfrom rightno indty tgt
 171   | t ->
 172       if dependent then
 173         Cic.Prod (fresh_binder dependent,
 174           CicSubstitution.lift_from (rightno + 1) liftno indty,
 175           Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 0 (rightno + 1)))
 176       else
 177         Cic.Prod (Cic.Anonymous,
 178           CicSubstitution.lift_from (rightno + 1) liftno indty,
 179           if rightno = 0 then
 180             Cic.Rel (1 + liftno + rightno)
 181           else
 182             Cic.Appl (Cic.Rel (1 + liftno + rightno) :: mk_rels 1 rightno))
 183
 184 let rec add_right_lambda dependent strip liftno liftfrom rightno indty case =
 185 function
 186   | Cic.Prod (_, src, tgt) when strip = 0 ->
 187       Cic.Lambda (fresh_binder true,
 188         CicSubstitution.lift_from (liftfrom + 1) liftno src,
 189         add_right_lambda dependent strip liftno (liftfrom + 1) rightno indty
 190           case tgt)
 191   | Cic.Prod (_, _, tgt) ->
 192       add_right_lambda dependent (strip - 1) liftno liftfrom rightno indty
 193         case tgt
 194   | t ->
 195       Cic.Lambda (fresh_binder true,
 196         CicSubstitution.lift_from (rightno + 1) liftno indty, case)
 197
 198 let string_of_sort = function
 199   | Cic.Prop -> "Prop"
 200   | Cic.CProp -> "CProp"
 201   | Cic.Set -> "Set"
 202   | Cic.Type _ -> "Type"
 203
 204 let rec branch (uri, typeno, subst) insource paramsno t fix head args =
 205   assert (subst = []);
 206   match t with
 207   | Cic.MutInd (uri', typeno', subst') when
 208     UriManager.eq uri uri' && typeno = typeno' && subst = subst' ->
 209       let head = if insource then fix else head in
 210       (match args with
 211       | [] -> head
 212       | _ -> Cic.Appl (head :: args))
 213   | Cic.Appl (Cic.MutInd (uri', typeno', subst') :: tl) when
 214     UriManager.eq uri uri' && typeno = typeno' && subst = subst' ->
 215       if insource then
 216         let (lparams, rparams) = split tl paramsno in
 217         Cic.Appl (fix :: rparams @ args)
 218       else
 219         (match args with
 220         | [] -> head
 221         | _ -> Cic.Appl (head :: args))
 222   | Cic.Prod (binder, src, tgt) ->
 223       if recursive uri typeno subst src then
 224         let args = List.map (CicSubstitution.lift 1) args in
 225         let phi =
 226           let fix = CicSubstitution.lift 1 fix in
 227           let src = CicSubstitution.lift 1 src in
 228           branch (uri, typeno, subst) true paramsno src fix head [Cic.Rel 1]
 229         in
 230         Cic.Lambda (fresh_binder true, src,
 231           branch (uri, typeno, subst) insource paramsno tgt
 232             (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 233             (args @ [Cic.Rel 1; phi]))
 234       else  (* non recursive *)
 235         let args = List.map (CicSubstitution.lift 1) args in
 236         Cic.Lambda (fresh_binder true, src,
 237           branch (uri, typeno, subst) insource paramsno tgt
 238           (CicSubstitution.lift 1 fix) (CicSubstitution.lift 1 head)
 239             (args @ [Cic.Rel 1]))
 240   | _ -> assert false
 241
 242 let branch (uri, typeno, subst) insource liftno paramsno t fix head args =
 243   let t = strip_left_params liftno paramsno t in
 244   branch (uri, typeno, subst) insource paramsno t fix head args
 245
 246 let elim_of ?(sort = Cic.Type (CicUniv.fresh ())) uri typeno =
 247   let (obj, univ) = (CicEnvironment.get_obj uri CicUniv.empty_ugraph) in
 248   let subst = [] in
 249   match obj with
 250   | Cic.InductiveDefinition (indTypes, params, leftno) ->
 251       let (name, inductive, ty, constructors) =
 252         try
 253           List.nth indTypes typeno
 254         with Failure _ -> assert false
 255       in
 256       let paramsno = count_pi ty in (* number of (left or right) parameters *)
 257       let rightno = paramsno - leftno in
 258       let dependent = (strip_pi ty <> Cic.Sort Cic.Prop) in
 259       let conslen = List.length constructors in
 260       let consno = ref (conslen + 1) in
 261       if (not dependent) && (sort <> Cic.Prop) && (conslen > 1) then
 262         raise Can_t_eliminate;
 263       let indty =
 264         let indty = Cic.MutInd (uri, typeno, subst) in
 265         if paramsno = 0 then
 266           indty
 267         else
 268           Cic.Appl (indty :: mk_rels 0 paramsno)
 269       in
 270       let mk_constructor consno =
 271         let constructor = Cic.MutConstruct (uri, typeno, consno, subst) in
 272         if leftno = 0 then
 273           constructor
 274         else
 275           Cic.Appl (constructor :: mk_rels consno leftno)
 276       in
 277       let p_ty = type_of_p sort dependent leftno indty ty in
 278       let final_ty =
 279         add_right_pi dependent leftno (conslen + 1) 1 rightno indty ty
 280       in
 281       let eliminator_type =
 282         let cic =
 283           Cic.Prod (Cic.Name "P", p_ty,
 284             (List.fold_right
 285               (fun (_, constructor) acc ->
 286                 decr consno;
 287                 let p = Cic.Rel !consno in
 288                 Cic.Prod (Cic.Anonymous,
 289                   (delta (uri, typeno, subst) dependent leftno !consno
 290                     constructor p [mk_constructor !consno]),
 291                   acc))
 292               constructors final_ty))
 293         in
 294         add_params (fun b s t -> Cic.Prod (b, s, t)) leftno ty cic
 295       in
 296       let consno = ref (conslen + 1) in
 297       let eliminator_body =
 298         let fix = Cic.Rel (rightno + 2) in
 299         let is_recursive = recursive_type uri typeno subst constructors in
 300         let recshift = if is_recursive then 1 else 0 in
 301         let (_, branches) =
 302           List.fold_right
 303             (fun (_, ty) (shift, branches) ->
 304               let head = Cic.Rel (rightno + shift + 1 + recshift) in
 305               let b =
 306                 branch (uri, typeno, subst) false
 307                   (rightno + conslen + 2 + recshift) leftno ty fix head []
 308               in
 309               (shift + 1,  b :: branches))
 310             constructors (1, [])
 311         in
 312         let mutcase =
 313           Cic.MutCase (uri, typeno, Cic.Rel (conslen + rightno + 2 + recshift),
 314             Cic.Rel 1, branches)
 315         in
 316         let body =
 317           if is_recursive then
 318             let fixfun =
 319               add_right_lambda dependent leftno (conslen + 2) 2 rightno
 320                 indty mutcase ty
 321             in
 322             (* rightno is the decreasing argument, i.e. the argument of
 323              * inductive type *)
 324             Cic.Fix (0, ["f", rightno, final_ty, fixfun])
 325           else
 326             add_right_lambda dependent leftno (conslen + 1) 1 rightno indty
 327               mutcase ty
 328         in
 329         let cic =
 330           Cic.Lambda (Cic.Name "P", p_ty,
 331             (List.fold_right
 332               (fun (_, constructor) acc ->
 333                 decr consno;
 334                 let p = Cic.Rel !consno in
 335                 Cic.Lambda (fresh_binder true,
 336                   (delta (uri, typeno, subst) dependent leftno !consno
 337                     constructor p [mk_constructor !consno]),
 338                   acc))
 339               constructors body))
 340         in
 341         add_params (fun b s t -> Cic.Lambda (b, s, t)) leftno ty cic
 342       in
 343 (*
 344 prerr_endline (CicPp.ppterm eliminator_type);
 345 prerr_endline (CicPp.ppterm eliminator_body);
 346 *)
 347       let (computed_type, ugraph) =
 348         try
 349           CicTypeChecker.type_of_aux' [] [] eliminator_body CicUniv.empty_ugraph
 350         with CicTypeChecker.TypeCheckerFailure msg ->
 351           raise (Elim_failure (sprintf
 352             "type checker failure while type checking:\n%s\nerror:\n%s"
 353             (CicPp.ppterm eliminator_body) msg))
 354       in
 355       if not (fst (CicReduction.are_convertible []
 356         eliminator_type computed_type ugraph))
 357       then
 358         raise (Failure (sprintf
 359           "internal error: type mismatch on eliminator type\n%s\n%s"
 360           (CicPp.ppterm eliminator_type) (CicPp.ppterm computed_type)));
 361       let suffix =
 362         match sort with
 363         | Cic.Prop -> "_ind"
 364         | Cic.Set -> "_rec"
 365         | Cic.Type _ -> "_rect"
 366         | _ -> assert false
 367       in
 368       let name = UriManager.name_of_uri uri ^ suffix in
 369       Cic.Constant (name, Some eliminator_body, eliminator_type, [])
 370   | _ -> assert false
 371