helm/ocaml/cic_proof_checking/cicPp.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (******************************************************************************)
  27 (*                                                                            *)
  28 (*                               PROJECT HELM                                 *)
  29 (*                                                                            *)
  30 (*                Claudio Sacerdoti Coen <sacerdot@cs.unibo.it>               *)
  31 (*                                 24/01/2000                                 *)
  32 (*                                                                            *)
  33 (* This module implements a very simple Coq-like pretty printer that, given   *)
  34 (* an object of cic (internal representation) returns a string describing the *)
  35 (* object in a syntax similar to that of coq                                  *)
  36 (*                                                                            *)
  37 (******************************************************************************)
  38
  39 exception CicPpInternalError;;
  40 exception NotEnoughElements;;
  41
  42 (* Utility functions *)
  43
  44 let string_of_name =
  45  function
  46     Cic.Name s     -> s
  47   | Cic.Anonimous  -> "_"
  48 ;;
  49
  50 (* get_nth l n   returns the nth element of the list l if it exists or *)
  51 (* raises NotEnoughElements if l has less than n elements             *)
  52 let rec get_nth l n =
  53  match (n,l) with
  54     (1, he::_) -> he
  55   | (n, he::tail) when n > 1 -> get_nth tail (n-1)
  56   | (_,_) -> raise NotEnoughElements
  57 ;;
  58
  59 (* pp t l                                                                  *)
  60 (* pretty-prints a term t of cic in an environment l where l is a list of  *)
  61 (* identifier names used to resolve DeBrujin indexes. The head of l is the *)
  62 (* name associated to the greatest DeBrujin index in t                     *)
  63 let rec pp t l =
  64  let module C = Cic in
  65    match t with
  66       C.Rel n ->
  67        begin
  68         try
  69          (match get_nth l n with
  70              Some (C.Name s) -> s
  71            | _        -> raise CicPpInternalError
  72          )
  73         with
  74          NotEnoughElements -> string_of_int (List.length l - n)
  75        end
  76     | C.Var uri -> UriManager.name_of_uri uri
  77     | C.Meta (n,l1) ->
  78        "?" ^ (string_of_int n) ^ "[" ^
  79         String.concat " ; "
  80          (List.map (function None -> "_" | Some t -> pp t l) l1) ^
  81         "]"
  82     | C.Sort s ->
  83        (match s with
  84            C.Prop -> "Prop"
  85          | C.Set  -> "Set"
  86          | C.Type -> "Type"
  87        )
  88     | C.Implicit -> "?"
  89     | C.Prod (b,s,t) ->
  90        (match b with
  91           C.Name n -> "(" ^ n ^ ":" ^ pp s l ^ ")" ^ pp t ((Some b)::l)
  92         | C.Anonimous -> "(" ^ pp s l ^ "->" ^ pp t ((Some b)::l) ^ ")"
  93        )
  94     | C.Cast (v,t) -> pp v l
  95     | C.Lambda (b,s,t) ->
  96        "[" ^ string_of_name b ^ ":" ^ pp s l ^ "]" ^ pp t ((Some b)::l)
  97     | C.LetIn (b,s,t) ->
  98        "[" ^ string_of_name b ^ ":=" ^ pp s l ^ "]" ^ pp t ((Some b)::l)
  99     | C.Appl li ->
 100        "(" ^
 101        (List.fold_right
 102         (fun x i -> pp x l ^ (match i with "" -> "" | _ -> " ") ^ i)
 103         li ""
 104        ) ^ ")"
 105     | C.Const (uri,_) -> UriManager.name_of_uri uri
 106     | C.MutInd (uri,_,n) ->
 107        begin
 108         try
 109          (match CicEnvironment.get_obj uri with
 110              C.InductiveDefinition (dl,_,_) ->
 111               let (name,_,_,_) = get_nth dl (n+1) in
 112                name
 113            | _ -> raise CicPpInternalError
 114          )
 115         with
 116          NotEnoughElements ->
 117           UriManager.string_of_uri uri ^ "#1/" ^ string_of_int (n + 1)
 118        end
 119     | C.MutConstruct (uri,_,n1,n2) ->
 120        begin
 121         try
 122          (match CicEnvironment.get_obj uri with
 123              C.InductiveDefinition (dl,_,_) ->
 124               let (_,_,_,cons) = get_nth dl (n1+1) in
 125                let (id,_,_) = get_nth cons n2 in
 126                 id
 127            | _ -> raise CicPpInternalError
 128          )
 129         with
 130          NotEnoughElements ->
 131           UriManager.string_of_uri uri ^ "#1/" ^ string_of_int (n1 + 1) ^ "/" ^
 132            string_of_int n2
 133        end
 134     | C.MutCase (uri,_,n1,ty,te,patterns) ->
 135        let connames =
 136         (match CicEnvironment.get_obj uri with
 137             C.InductiveDefinition (dl,_,_) ->
 138              let (_,_,_,cons) = get_nth dl (n1+1) in
 139               List.map (fun (id,_,_) -> id) cons
 140           | _ -> raise CicPpInternalError
 141         )
 142        in
 143         "\n<" ^ pp ty l ^ ">Cases " ^ pp te l ^ " of " ^
 144           List.fold_right (fun (x,y) i -> "\n " ^ x ^ " => " ^ pp y l ^ i)
 145            (List.combine connames patterns) "" ^
 146           "\nend"
 147     | C.Fix (no, funs) ->
 148        let snames = List.map (fun (name,_,_,_) -> name) funs in
 149         let names =
 150          List.rev (List.map (function name -> Some (C.Name name)) snames)
 151         in
 152          "\nFix " ^ get_nth snames (no + 1) ^ " {" ^
 153          List.fold_right
 154           (fun (name,ind,ty,bo) i -> "\n" ^ name ^ " / " ^ string_of_int ind ^
 155             " : " ^ pp ty l ^ " := \n" ^
 156             pp bo (names@l) ^ i)
 157           funs "" ^
 158          "}\n"
 159     | C.CoFix (no,funs) ->
 160        let snames = List.map (fun (name,_,_) -> name) funs in
 161         let names =
 162          List.rev (List.map (function name -> Some (C.Name name)) snames)
 163         in
 164          "\nCoFix " ^ get_nth snames (no + 1) ^ " {" ^
 165          List.fold_right
 166           (fun (name,ty,bo) i -> "\n" ^ name ^
 167             " : " ^ pp ty l ^ " := \n" ^
 168             pp bo (names@l) ^ i)
 169           funs "" ^
 170          "}\n"
 171 ;;
 172
 173 let ppterm t =
 174  pp t []
 175 ;;
 176
 177 (* ppinductiveType (typename, inductive, arity, cons) names                 *)
 178 (* pretty-prints a single inductive definition (typename, inductive, arity, *)
 179 (*  cons) where the cic terms in the inductive definition need to be        *)
 180 (*  evaluated in the environment names that is the list of typenames of the *)
 181 (*  mutual inductive definitions defined in the block of mutual inductive   *)
 182 (*  definitions to which this one belongs to                                *)
 183 let ppinductiveType (typename, inductive, arity, cons) names =
 184   (if inductive then "\nInductive " else "\nCoInductive ") ^ typename ^ ": " ^
 185   (*CSC: bug found: was pp arity names ^ " =\n   " ^*)
 186   pp arity [] ^ " =\n   " ^
 187   List.fold_right
 188    (fun (id,ty,_) i -> id ^ " : " ^ pp ty names ^
 189     (if i = "" then "\n" else "\n | ") ^ i)
 190    cons ""
 191 ;;
 192
 193 (* ppobj obj  returns a string with describing the cic object obj in a syntax *)
 194 (* similar to the one used by Coq                                             *)
 195 let ppobj obj =
 196  let module C = Cic in
 197  let module U = UriManager in
 198   match obj with
 199     C.Definition (id, t1, t2, params) ->
 200       "Definition of " ^ id ^
 201       "(" ^
 202       List.fold_right
 203        (fun (_,x) i ->
 204          List.fold_right
 205           (fun x i ->
 206             U.string_of_uri x ^ match i with "" -> "" | i' -> " " ^ i'
 207           ) x "" ^ match i with "" -> "" | i' -> " " ^ i'
 208        ) params "" ^ ")" ^
 209       ":\n" ^ pp t1 [] ^ " : " ^ pp t2 []
 210    | C.Axiom (id, ty, params) ->
 211       "Axiom " ^ id ^ "(" ^
 212       List.fold_right
 213        (fun (_,x) i ->
 214          List.fold_right
 215           (fun x i ->
 216             U.string_of_uri x ^ match i with "" -> "" | i' -> " " ^ i'
 217           ) x "" ^ match i with "" -> "" | i' -> " " ^ i'
 218        ) params "" ^
 219       "):\n" ^ pp ty []
 220    | C.Variable (name, bo, ty) ->
 221       "Variable " ^ name ^ ":\n" ^ pp ty [] ^ "\n" ^
 222       (match bo with None -> "" | Some bo -> ":= " ^ pp bo [])
 223    | C.CurrentProof (name, conjectures, value, ty) ->
 224       "Current Proof:\n" ^
 225       let separate s = if s = "" then "" else s ^ " ; " in
 226        List.fold_right
 227         (fun (n, context, t) i ->
 228           let conjectures',name_context =
 229            List.fold_right
 230             (fun context_entry (i,name_context) ->
 231               (match context_entry with
 232                   Some (n,C.Decl at) ->
 233                    (separate i) ^
 234                     string_of_name n ^ ":" ^ pp at name_context ^ " ",
 235                    (Some n)::name_context
 236                 | Some (n,C.Def at) ->
 237                    (separate i) ^
 238                     string_of_name n ^ ":= " ^ pp at name_context ^ " ",
 239                    (Some n)::name_context
 240                 | None ->
 241                    (separate i) ^ "_ :? _ ", None::name_context)
 242              ) context ("",[])
 243           in
 244            conjectures' ^ " |- " ^ "?" ^ (string_of_int n) ^ ": " ^
 245             pp t name_context ^ "\n" ^ i
 246         ) conjectures "" ^
 247         "\n" ^ pp value [] ^ " : " ^ pp ty []
 248    | C.InductiveDefinition (l, params, nparams) ->
 249       "Parameters = " ^
 250       List.fold_right
 251        (fun (_,x) i ->
 252          List.fold_right
 253           (fun x i ->
 254             U.string_of_uri x ^ match i with "" -> "" | i' -> " " ^ i'
 255           ) x "" ^ match i with "" -> "" | i' -> " " ^ i'
 256        ) params "" ^ "\n" ^
 257       "NParams = " ^ string_of_int nparams ^ "\n" ^
 258       let names = List.rev (List.map (fun (n,_,_,_) -> Some (C.Name n)) l) in
 259        List.fold_right (fun x i -> ppinductiveType x names ^ i) l ""
 260 ;;