helm/ocaml/cic_proof_checking/cicReductionNaif.ml

   1 (* Copyright (C) 2000, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 exception CicReductionInternalError;;
  27 exception WrongUriToInductiveDefinition;;
  28
  29 let fdebug = ref 1;;
  30 let debug t env s =
  31  let rec debug_aux t i =
  32   let module C = Cic in
  33   let module U = UriManager in
  34    CicPp.ppobj (C.Variable ("DEBUG", None, t)) ^ "\n" ^ i
  35  in
  36   if !fdebug = 0 then
  37    begin
  38     print_endline (s ^ "\n" ^ List.fold_right debug_aux (t::env) "") ;
  39     flush stdout
  40    end
  41 ;;
  42
  43 exception Impossible of int;;
  44 exception ReferenceToDefinition;;
  45 exception ReferenceToAxiom;;
  46 exception ReferenceToVariable;;
  47 exception ReferenceToCurrentProof;;
  48 exception ReferenceToInductiveDefinition;;
  49 exception RelToHiddenHypothesis;;
  50
  51 (* takes a well-typed term *)
  52 let whd context =
  53  let rec whdaux l =
  54   let module C = Cic in
  55   let module S = CicSubstitution in
  56    function
  57       C.Rel n as t ->
  58        (match List.nth context (n-1) with
  59            Some (_, C.Decl _) -> if l = [] then t else C.Appl (t::l)
  60          | Some (_, C.Def bo) -> whdaux l (S.lift n bo)
  61          | None -> raise RelToHiddenHypothesis
  62        )
  63     | C.Var uri as t ->
  64        (match CicEnvironment.get_cooked_obj uri 0 with
  65            C.Definition _ -> raise ReferenceToDefinition
  66          | C.Axiom _ -> raise ReferenceToAxiom
  67          | C.CurrentProof _ -> raise ReferenceToCurrentProof
  68          | C.InductiveDefinition _ -> raise ReferenceToInductiveDefinition
  69          | C.Variable (_,None,_) -> if l = [] then t else C.Appl (t::l)
  70          | C.Variable (_,Some body,_) -> whdaux l body
  71        )
  72     | C.Meta _ as t -> if l = [] then t else C.Appl (t::l)
  73     | C.Sort _ as t -> t (* l should be empty *)
  74     | C.Implicit as t -> t
  75     | C.Cast (te,ty) -> whdaux l te  (*CSC E' GIUSTO BUTTARE IL CAST? *)
  76     | C.Prod _ as t -> t (* l should be empty *)
  77     | C.Lambda (name,s,t) as t' ->
  78        (match l with
  79            [] -> t'
  80          | he::tl -> whdaux tl (S.subst he t)
  81            (* when name is Anonimous the substitution should be superfluous *)
  82        )
  83     | C.LetIn (n,s,t) -> whdaux l (S.subst (whdaux [] s) t)
  84     | C.Appl (he::tl) -> whdaux (tl@l) he
  85     | C.Appl [] -> raise (Impossible 1)
  86     | C.Const (uri,cookingsno) as t ->
  87        (match CicEnvironment.get_cooked_obj uri cookingsno with
  88            C.Definition (_,body,_,_) -> whdaux l body
  89          | C.Axiom _ -> if l = [] then t else C.Appl (t::l)
  90          | C.Variable _ -> raise ReferenceToVariable
  91          | C.CurrentProof (_,_,body,_) -> whdaux l body
  92          | C.InductiveDefinition _ -> raise ReferenceToInductiveDefinition
  93        )
  94     | C.Abst _ as t -> t (*CSC l should be empty ????? *)
  95     | C.MutInd (uri,_,_) as t -> if l = [] then t else C.Appl (t::l)
  96     | C.MutConstruct (uri,_,_,_) as t -> if l = [] then t else C.Appl (t::l)
  97     | C.MutCase (mutind,cookingsno,i,_,term,pl) as t->
  98        let decofix =
  99         function
 100            C.CoFix (i,fl) as t ->
 101             let (_,_,body) = List.nth fl i in
 102              let body' =
 103               let counter = ref (List.length fl) in
 104                List.fold_right
 105                 (fun _ -> decr counter ; S.subst (C.CoFix (!counter,fl)))
 106                 fl
 107                 body
 108              in
 109               whdaux [] body'
 110          | C.Appl (C.CoFix (i,fl) :: tl) ->
 111             let (_,_,body) = List.nth fl i in
 112              let body' =
 113               let counter = ref (List.length fl) in
 114                List.fold_right
 115                 (fun _ -> decr counter ; S.subst (C.CoFix (!counter,fl)))
 116                 fl
 117                 body
 118              in
 119               whdaux tl body'
 120          | t -> t
 121        in
 122         (match decofix (whdaux [] term) with
 123             C.MutConstruct (_,_,_,j) -> whdaux l (List.nth pl (j-1))
 124           | C.Appl (C.MutConstruct (_,_,_,j) :: tl) ->
 125              let (arity, r, num_ingredients) =
 126               match CicEnvironment.get_obj mutind with
 127                  C.InductiveDefinition (tl,ingredients,r) ->
 128                    let (_,_,arity,_) = List.nth tl i
 129                    and num_ingredients =
 130                     List.fold_right
 131                      (fun (k,l) i ->
 132                        if k < cookingsno then i + List.length l else i
 133                      ) ingredients 0
 134                    in
 135                     (arity,r,num_ingredients)
 136                | _ -> raise WrongUriToInductiveDefinition
 137              in
 138               let ts =
 139                let num_to_eat = r + num_ingredients in
 140                 let rec eat_first =
 141                  function
 142                     (0,l) -> l
 143                   | (n,he::tl) when n > 0 -> eat_first (n - 1, tl)
 144                   | _ -> raise (Impossible 5)
 145                 in
 146                  eat_first (num_to_eat,tl)
 147               in
 148                whdaux (ts@l) (List.nth pl (j-1))
 149          | C.Abst _| C.Cast _ | C.Implicit ->
 150             raise (Impossible 2) (* we don't trust our whd ;-) *)
 151          | _ -> if l = [] then t else C.Appl (t::l)
 152        )
 153     | C.Fix (i,fl) as t ->
 154        let (_,recindex,_,body) = List.nth fl i in
 155         let recparam =
 156          try
 157           Some (List.nth l recindex)
 158          with
 159           _ -> None
 160         in
 161          (match recparam with
 162              Some recparam ->
 163               (match whdaux [] recparam with
 164                   C.MutConstruct _
 165                 | C.Appl ((C.MutConstruct _)::_) ->
 166                    let body' =
 167                     let counter = ref (List.length fl) in
 168                      List.fold_right
 169                       (fun _ -> decr counter ; S.subst (C.Fix (!counter,fl)))
 170                       fl
 171                       body
 172                    in
 173                     (* Possible optimization: substituting whd recparam in l *)
 174                     whdaux l body'
 175                | _ -> if l = [] then t else C.Appl (t::l)
 176              )
 177           | None -> if l = [] then t else C.Appl (t::l)
 178          )
 179     | C.CoFix (i,fl) as t ->
 180        if l = [] then t else C.Appl (t::l)
 181  in
 182 (*CSC
 183 function t ->
 184 prerr_endline ("PRIMA WHD" ^ CicPp.ppterm t) ; flush stderr ;
 185 List.iter (function (Cic.Decl t) -> prerr_endline ("Context: " ^ CicPp.ppterm t) | (Cic.Def t) -> prerr_endline ("Context:= " ^ CicPp.ppterm t)) context ; flush stderr ; prerr_endline "<PRIMA WHD" ; flush stderr ;
 186 let res =
 187 *)
 188   whdaux []
 189 (*CSC
 190 t in prerr_endline "DOPO WHD" ; flush stderr ; res
 191 *)
 192 ;;
 193
 194 (* t1, t2 must be well-typed *)
 195 let are_convertible =
 196  let module U = UriManager in
 197  let rec aux context t1 t2 =
 198   let aux2 t1 t2 =
 199    (* this trivial euristic cuts down the total time of about five times ;-) *)
 200    (* this because most of the time t1 and t2 are "sintactically" the same   *)
 201    if t1 = t2 then
 202     true
 203    else
 204     begin
 205      let module C = Cic in
 206        match (t1,t2) with
 207           (C.Rel n1, C.Rel n2) -> n1 = n2
 208         | (C.Var uri1, C.Var uri2) -> U.eq uri1 uri2
 209         | (C.Meta (n1,l1), C.Meta (n2,l2)) ->
 210             n1 = n2 &&
 211              List.fold_left2
 212               (fun b t1 t2 ->
 213                 b &&
 214                  match t1,t2 with
 215                     None,None -> true
 216                   | Some t1',Some t2' -> aux context t1' t2'
 217                   | _,_ -> false
 218               ) true l1 l2
 219         | (C.Sort s1, C.Sort s2) -> true (*CSC da finire con gli universi *)
 220         | (C.Prod (name1,s1,t1), C.Prod(_,s2,t2)) ->
 221            aux context s1 s2 && aux ((Some (name1, (C.Decl s1)))::context) t1 t2
 222         | (C.Lambda (name1,s1,t1), C.Lambda(_,s2,t2)) ->
 223            aux context s1 s2 && aux ((Some (name1, (C.Decl s1)))::context) t1 t2
 224         | (C.LetIn (name1,s1,t1), C.LetIn(_,s2,t2)) ->
 225            aux context s1 s2 && aux ((Some (name1, (C.Def s1)))::context) t1 t2
 226         | (C.Appl l1, C.Appl l2) ->
 227            (try
 228              List.fold_right2 (fun  x y b -> aux context x y && b) l1 l2 true
 229             with
 230              Invalid_argument _ -> false
 231            )
 232         | (C.Const (uri1,_), C.Const (uri2,_)) ->
 233             (*CSC: questo commento e' chiaro o delirante? Io lo sto scrivendo *)
 234             (*CSC: mentre sono delirante, quindi ...                          *)
 235             (* WARNING: it is really important that the two cookingsno are not*)
 236             (* checked for equality. This allows not to cook an object with no*)
 237             (* ingredients only to update the cookingsno. E.g: if a term t has*)
 238             (* a reference to a term t1 which does not depend on any variable *)
 239             (* and t1 depends on a term t2 (that can't depend on any variable *)
 240             (* because of t1), then t1 cooked at every level could be the same*)
 241             (* as t1 cooked at level 0. Doing so, t2 will be extended in t    *)
 242             (* with cookingsno 0 and not 2. But this will not cause any       *)
 243             (* trouble if here we don't check that the two cookingsno are     *)
 244             (* equal.                                                         *)
 245             U.eq uri1 uri2
 246         | (C.MutInd (uri1,k1,i1), C.MutInd (uri2,k2,i2)) ->
 247             (* WARNIG: see the previous warning *)
 248             U.eq uri1 uri2 && i1 = i2
 249         | (C.MutConstruct (uri1,_,i1,j1), C.MutConstruct (uri2,_,i2,j2)) ->
 250             (* WARNIG: see the previous warning *)
 251             U.eq uri1 uri2 && i1 = i2 && j1 = j2
 252         | (C.MutCase (uri1,_,i1,outtype1,term1,pl1),
 253            C.MutCase (uri2,_,i2,outtype2,term2,pl2)) ->
 254             (* WARNIG: see the previous warning *)
 255             (* aux context outtype1 outtype2 should be true if *)
 256             (* aux context pl1 pl2 *)
 257             U.eq uri1 uri2 && i1 = i2 && aux context outtype1 outtype2 &&
 258              aux context term1 term2 &&
 259              List.fold_right2 (fun x y b -> b && aux context x y) pl1 pl2 true
 260         | (C.Fix (i1,fl1), C.Fix (i2,fl2)) ->
 261            let tys =
 262             List.map (function (n,_,ty,_) -> Some (C.Name n,(C.Decl ty))) fl1
 263            in
 264             i1 = i2 &&
 265              List.fold_right2
 266               (fun (_,recindex1,ty1,bo1) (_,recindex2,ty2,bo2) b ->
 267                 b && recindex1 = recindex2 && aux context ty1 ty2 &&
 268                  aux (tys@context) bo1 bo2)
 269               fl1 fl2 true
 270         | (C.CoFix (i1,fl1), C.CoFix (i2,fl2)) ->
 271            let tys =
 272             List.map (function (n,ty,_) -> Some (C.Name n,(C.Decl ty))) fl1
 273            in
 274             i1 = i2 &&
 275              List.fold_right2
 276               (fun (_,ty1,bo1) (_,ty2,bo2) b ->
 277                 b && aux context ty1 ty2 && aux (tys@context) bo1 bo2)
 278               fl1 fl2 true
 279         | (C.Abst _, _) | (_, C.Abst _) | (C.Cast _, _) | (_, C.Cast _)
 280         | (C.Implicit, _) | (_, C.Implicit) ->
 281            raise (Impossible 3) (* we don't trust our whd ;-) *)
 282         | (_,_) -> false
 283     end
 284   in
 285    if aux2 t1 t2 then true
 286    else
 287     begin
 288      debug t1 [t2] "PREWHD";
 289      let t1' = whd context t1
 290      and t2' = whd context t2 in
 291       debug t1' [t2'] "POSTWHD";
 292       aux2 t1' t2'
 293     end
 294  in
 295   aux
 296 ;;