helm/ocaml/cic_transformations/cicAstPp.ml

   1 (* Copyright (C) 2004, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 open Printf
  27
  28 let pp_binder = function
  29   | `Lambda -> "lambda"
  30   | `Pi -> "Pi"
  31   | `Exists -> "exists"
  32   | `Forall -> "forall"
  33
  34 let pp_name = function Cic.Anonymous -> "_" | Cic.Name s -> s
  35
  36 let rec pp_term = function
  37   | CicAst.AttributedTerm (_, term) -> pp_term term
  38   | CicAst.Appl terms ->
  39       sprintf "(%s)" (String.concat " " (List.map pp_term terms))
  40   | CicAst.Binder (`Forall, (Cic.Anonymous, typ), body)
  41   | CicAst.Binder (`Pi, (Cic.Anonymous, typ), body) ->
  42       sprintf "(%s \\to %s)"
  43         (match typ with None -> "?" | Some typ -> pp_term typ)
  44         (pp_term body)
  45   | CicAst.Binder (kind, var, body) ->
  46       sprintf "\\%s %s.%s" (pp_binder kind) (pp_capture_variable var)
  47         (pp_term body)
  48   | CicAst.Case (term, indtype, typ, patterns) ->
  49       sprintf "%smatch %s with %s"
  50         (match typ with None -> "" | Some t -> sprintf "<%s>" (pp_term t))
  51         (pp_term term) (pp_patterns patterns)
  52   | CicAst.LetIn (var, t1, t2) ->
  53       sprintf "let %s = %s in %s" (pp_capture_variable var) (pp_term t1)
  54         (pp_term t2)
  55   | CicAst.LetRec (kind, definitions, term) ->
  56       sprintf "let %s %s in %s"
  57         (match kind with `Inductive -> "rec" | `CoInductive -> "corec")
  58         (String.concat " and "
  59           (List.map
  60             (fun (var, body, _) ->
  61               sprintf "%s = %s" (pp_capture_variable var) (pp_term body))
  62             definitions))
  63         (pp_term term)
  64   | CicAst.Ident (name, Some []) | CicAst.Ident (name, None)
  65   | CicAst.Uri (name, Some []) | CicAst.Uri (name, None) ->
  66       name
  67   | CicAst.Ident (name, Some substs)
  68   | CicAst.Uri (name, Some substs) ->
  69       sprintf "%s \\subst [%s]" name (pp_substs substs)
  70   | CicAst.Implicit -> "?"
  71   | CicAst.Meta (index, substs) ->
  72       sprintf "%d[%s]" index
  73         (String.concat "; "
  74           (List.map (function None -> "_" | Some term -> pp_term term) substs))
  75   | CicAst.Num (num, _) -> num
  76   | CicAst.Sort `Set -> "Set"
  77   | CicAst.Sort `Prop -> "Prop"
  78   | CicAst.Sort `Type -> "Type"
  79   | CicAst.Sort `CProp -> "CProp"
  80   | CicAst.Symbol (name, _) -> name
  81   | CicAst.UserInput -> "%"
  82
  83 and pp_subst (name, term) = sprintf "%s \\Assign %s" name (pp_term term)
  84 and pp_substs substs = String.concat "; " (List.map pp_subst substs)
  85
  86 and pp_pattern ((head, vars), term) =
  87   sprintf "%s \\Rightarrow %s"
  88     (match vars with
  89     | [] -> head
  90     | _ ->
  91         sprintf "(%s %s)" head
  92           (String.concat " " (List.map pp_capture_variable vars)))
  93     (pp_term term)
  94
  95 and pp_patterns patterns =
  96   sprintf "[%s]" (String.concat " | " (List.map pp_pattern patterns))
  97
  98 and pp_capture_variable = function
  99   | name, None -> pp_name name
 100   | name, Some typ -> "(" ^ pp_name name ^ ": " ^ pp_term typ ^ ")"
 101