helm/ocaml/cic_unification/cicMetaSubst.ml

   1
   2 open Printf
   3
   4 exception AssertFailure of string
   5 exception MetaSubstFailure of string
   6
   7 let debug_print = prerr_endline
   8
   9 type substitution = (int * Cic.term) list
  10
  11 let ppsubst subst =
  12   String.concat "\n"
  13     (List.map
  14       (fun (idx, term) -> Printf.sprintf "?%d := %s" idx (CicPp.ppterm term))
  15       subst)
  16
  17 (**** DELIFT ****)
  18 (* the delift function takes in input a metavariable index, an ordered list of
  19  * optional terms [t1,...,tn] and a term t, and substitutes every tk = Some
  20  * (rel(nk)) with rel(k).  Typically, the list of optional terms is the explicit
  21  * substitution that is applied to a metavariable occurrence and the result of
  22  * the delift function is a term the implicit variable can be substituted with
  23  * to make the term [t] unifiable with the metavariable occurrence.  In general,
  24  * the problem is undecidable if we consider equivalence in place of alpha
  25  * convertibility. Our implementation, though, is even weaker than alpha
  26  * convertibility, since it replace the term [tk] if and only if [tk] is a Rel
  27  * (missing all the other cases). Does this matter in practice?
  28  * The metavariable index is the index of the metavariable that must not occur
  29  * in the term (for occur check).
  30  *)
  31
  32 exception NotInTheList;;
  33
  34 let position n =
  35   let rec aux k =
  36    function
  37        [] -> raise NotInTheList
  38      | (Some (Cic.Rel m))::_ when m=n -> k
  39      | _::tl -> aux (k+1) tl in
  40   aux 1
  41 ;;
  42
  43 exception Occur;;
  44
  45 let rec force_does_not_occur subst to_be_restricted t =
  46  let module C = Cic in
  47  let more_to_be_restricted = ref [] in
  48  let rec aux k = function
  49       C.Rel r when List.mem (r+k) to_be_restricted -> raise Occur
  50     | C.Rel _
  51     | C.Sort _ as t -> t
  52     | C.Implicit -> assert false
  53     | C.Meta (n, l) ->
  54        (* we do not retrieve the term associated to ?n in subst since *)
  55        (* in this way we can restrict if something goes wrong         *)
  56        let l' =
  57          let i = ref 0 in
  58          List.map
  59            (function t ->
  60              incr i ;
  61              match t with
  62                 None -> None
  63               | Some t ->
  64                  try
  65                    Some (aux k t)
  66                  with Occur ->
  67                    more_to_be_restricted := (n,!i) :: !more_to_be_restricted;
  68                    None)
  69            l
  70        in
  71         C.Meta (n, l')
  72     | C.Cast (te,ty) -> C.Cast (aux k te, aux k ty)
  73     | C.Prod (name,so,dest) -> C.Prod (name, aux k so, aux (k+1) dest)
  74     | C.Lambda (name,so,dest) -> C.Lambda (name, aux k so, aux (k+1) dest)
  75     | C.LetIn (name,so,dest) -> C.LetIn (name, aux k so, aux (k+1) dest)
  76     | C.Appl l -> C.Appl (List.map (aux k) l)
  77     | C.Var (uri,exp_named_subst) ->
  78         let exp_named_subst' =
  79           List.map (fun (uri,t) -> (uri, aux k t)) exp_named_subst
  80         in
  81         C.Var (uri, exp_named_subst')
  82     | C.Const (uri, exp_named_subst) ->
  83         let exp_named_subst' =
  84           List.map (fun (uri,t) -> (uri, aux k t)) exp_named_subst
  85         in
  86         C.Const (uri, exp_named_subst')
  87     | C.MutInd (uri,tyno,exp_named_subst) ->
  88         let exp_named_subst' =
  89           List.map (fun (uri,t) -> (uri, aux k t)) exp_named_subst
  90         in
  91         C.MutInd (uri, tyno, exp_named_subst')
  92     | C.MutConstruct (uri,tyno,consno,exp_named_subst) ->
  93         let exp_named_subst' =
  94           List.map (fun (uri,t) -> (uri, aux k t)) exp_named_subst
  95         in
  96         C.MutConstruct (uri, tyno, consno, exp_named_subst')
  97     | C.MutCase (uri,tyno,out,te,pl) ->
  98         C.MutCase (uri, tyno, aux k out, aux k te, List.map (aux k) pl)
  99     | C.Fix (i,fl) ->
 100        let len = List.length fl in
 101        let k_plus_len = k + len in
 102        let fl' =
 103          List.map
 104           (fun (name,j,ty,bo) -> (name, j, aux k ty, aux k_plus_len bo)) fl
 105        in
 106        C.Fix (i, fl')
 107     | C.CoFix (i,fl) ->
 108        let len = List.length fl in
 109        let k_plus_len = k + len in
 110        let fl' =
 111          List.map
 112           (fun (name,ty,bo) -> (name, aux k ty, aux k_plus_len bo)) fl
 113        in
 114        C.CoFix (i, fl')
 115  in
 116  let res = aux 0 t in
 117  (!more_to_be_restricted, res)
 118
 119 let rec restrict subst to_be_restricted metasenv =
 120   let names_of_context_indexes context indexes =
 121     String.concat ", "
 122       (List.map
 123         (fun i ->
 124           match List.nth context i with
 125           | None -> assert false
 126           | Some (n, _) -> CicPp.ppname n)
 127         indexes)
 128   in
 129   let force_does_not_occur_in_context to_be_restricted = function
 130     | None -> [], None
 131     | Some (name, Cic.Decl t) ->
 132         let (more_to_be_restricted, t') =
 133           force_does_not_occur subst to_be_restricted t
 134         in
 135         more_to_be_restricted, Some (name, Cic.Decl t)
 136     | Some (name, Cic.Def (bo, ty)) ->
 137         let (more_to_be_restricted, bo') =
 138           force_does_not_occur subst to_be_restricted bo
 139         in
 140         let more_to_be_restricted, ty' =
 141           match ty with
 142           | None ->  more_to_be_restricted, None
 143           | Some ty ->
 144               let more_to_be_restricted', ty' =
 145                 force_does_not_occur subst to_be_restricted ty
 146               in
 147               more_to_be_restricted @ more_to_be_restricted',
 148               Some ty'
 149         in
 150         more_to_be_restricted, Some (name, Cic.Def (bo', ty'))
 151   in
 152   let rec erase i to_be_restricted n = function
 153     | [] -> [], to_be_restricted, []
 154     | hd::tl ->
 155         let restrict_me = List.mem i to_be_restricted in
 156         if restrict_me then
 157           let more_to_be_restricted, restricted, new_tl =
 158             erase (i+1) (i :: to_be_restricted) n tl
 159           in
 160           more_to_be_restricted, restricted, None :: new_tl
 161         else
 162           (try
 163             let more_to_be_restricted, hd' =
 164               force_does_not_occur_in_context to_be_restricted hd
 165             in
 166             let more_to_be_restricted', restricted, tl' =
 167               erase (i+1) to_be_restricted n tl
 168             in
 169             more_to_be_restricted @ more_to_be_restricted',
 170             restricted, hd' :: tl'
 171           with Occur ->
 172             let more_to_be_restricted, restricted, tl' =
 173               erase (i+1) (i :: to_be_restricted) n tl
 174             in
 175             more_to_be_restricted, restricted, None :: tl')
 176   in
 177   let (more_to_be_restricted, metasenv, subst) =
 178     List.fold_right
 179       (fun (n, context, t) (more, metasenv, subst) ->
 180         let to_be_restricted =
 181           List.map snd (List.filter (fun (m, _) -> m = n) to_be_restricted)
 182         in
 183         let (more_to_be_restricted, restricted, context') =
 184           erase 1 to_be_restricted n context
 185         in
 186         try
 187           let more_to_be_restricted', t' =
 188             force_does_not_occur subst restricted t
 189           in
 190           let metasenv' = (n, context', t') :: metasenv in
 191           (try
 192             let s = List.assoc n subst in
 193             try
 194               let more_to_be_restricted'', s' =
 195                 force_does_not_occur subst restricted s
 196               in
 197               let subst' = (n, s') :: (List.remove_assoc n subst) in
 198               let more =
 199                 more @ more_to_be_restricted @ more_to_be_restricted' @
 200                   more_to_be_restricted''
 201               in
 202               (more, metasenv', subst')
 203             with Occur ->
 204               raise (MetaSubstFailure (sprintf
 205                 "Cannot restrict the context of the metavariable ?%d over the hypotheses %s since ?%d is already instantiated with %s and at least one of the hypotheses occurs in the substituted term"
 206                 n (names_of_context_indexes context to_be_restricted) n
 207                 (CicPp.ppterm s)))
 208            with Not_found -> (more @ more_to_be_restricted @ more_to_be_restricted', metasenv', subst))
 209         with Occur ->
 210           raise (MetaSubstFailure (sprintf
 211             "Cannot restrict the context of the metavariable ?%d over the hypotheses %s since metavariable's type depends on at least one of them"
 212             n (names_of_context_indexes context to_be_restricted))))
 213       metasenv ([], [], subst)
 214   in
 215   match more_to_be_restricted with
 216   | [] -> (metasenv, subst)
 217   | _ -> restrict subst more_to_be_restricted metasenv
 218 ;;
 219
 220 (*CSC: maybe we should rename delift in abstract, as I did in my dissertation *)
 221 let delift n subst context metasenv l t =
 222  let module S = CicSubstitution in
 223   let to_be_restricted = ref [] in
 224   let rec deliftaux k =
 225    let module C = Cic in
 226     function
 227        C.Rel m ->
 228          if m <=k then
 229           C.Rel m   (*CSC: che succede se c'e' un Def? Dovrebbe averlo gia' *)
 230                     (*CSC: deliftato la regola per il LetIn                 *)
 231                     (*CSC: FALSO! La regola per il LetIn non lo fa          *)
 232          else
 233           (match List.nth context (m-k-1) with
 234             Some (_,C.Def (t,_)) ->
 235              (*CSC: Hmmm. This bit of reduction is not in the spirit of    *)
 236              (*CSC: first order unification. Does it help or does it harm? *)
 237              deliftaux k (S.lift m t)
 238           | Some (_,C.Decl t) ->
 239              (*CSC: The following check seems to be wrong!             *)
 240              (*CSC: B:Set |- ?2 : Set                                  *)
 241              (*CSC: A:Set ; x:?2[A/B] |- ?1[x/A] =?= x                 *)
 242              (*CSC: Why should I restrict ?2 over B? The instantiation *)
 243              (*CSC: ?1 := A is perfectly reasonable and well-typed.    *)
 244              (*CSC: Thus I comment out the following two lines that    *)
 245              (*CSC: are the incriminated ones.                         *)
 246              (*(* It may augment to_be_restricted *)
 247                ignore (deliftaux k (S.lift m t)) ;*)
 248              (*CSC: end of bug commented out                           *)
 249              C.Rel ((position (m-k) l) + k)
 250           | None -> raise (MetaSubstFailure "RelToHiddenHypothesis"))
 251      | C.Var (uri,exp_named_subst) ->
 252         let exp_named_subst' =
 253          List.map (function (uri,t) -> uri,deliftaux k t) exp_named_subst
 254         in
 255          C.Var (uri,exp_named_subst')
 256      | C.Meta (i, l1) as t ->
 257         if i = n then
 258           raise (MetaSubstFailure (sprintf
 259             "Cannot unify the metavariable ?%d with a term that has as subterm %s in which the same metavariable occurs (occur check)"
 260             i (CicPp.ppterm t)))
 261         else
 262          (* I do not consider the term associated to ?i in subst since *)
 263          (* in this way I can restrict if something goes wrong.        *)
 264           let rec deliftl j =
 265            function
 266               [] -> []
 267             | None::tl -> None::(deliftl (j+1) tl)
 268             | (Some t)::tl ->
 269                let l1' = (deliftl (j+1) tl) in
 270                 try
 271                  Some (deliftaux k t)::l1'
 272                 with
 273                    NotInTheList
 274                  | MetaSubstFailure _ ->
 275                     to_be_restricted := (i,j)::!to_be_restricted ; None::l1'
 276           in
 277            let l' = deliftl 1 l1 in
 278             C.Meta(i,l')
 279      | C.Sort _ as t -> t
 280      | C.Implicit as t -> t
 281      | C.Cast (te,ty) -> C.Cast (deliftaux k te, deliftaux k ty)
 282      | C.Prod (n,s,t) -> C.Prod (n, deliftaux k s, deliftaux (k+1) t)
 283      | C.Lambda (n,s,t) -> C.Lambda (n, deliftaux k s, deliftaux (k+1) t)
 284      | C.LetIn (n,s,t) -> C.LetIn (n, deliftaux k s, deliftaux (k+1) t)
 285      | C.Appl l -> C.Appl (List.map (deliftaux k) l)
 286      | C.Const (uri,exp_named_subst) ->
 287         let exp_named_subst' =
 288          List.map (function (uri,t) -> uri,deliftaux k t) exp_named_subst
 289         in
 290          C.Const (uri,exp_named_subst')
 291      | C.MutInd (uri,typeno,exp_named_subst) ->
 292         let exp_named_subst' =
 293          List.map (function (uri,t) -> uri,deliftaux k t) exp_named_subst
 294         in
 295          C.MutInd (uri,typeno,exp_named_subst')
 296      | C.MutConstruct (uri,typeno,consno,exp_named_subst) ->
 297         let exp_named_subst' =
 298          List.map (function (uri,t) -> uri,deliftaux k t) exp_named_subst
 299         in
 300          C.MutConstruct (uri,typeno,consno,exp_named_subst')
 301      | C.MutCase (sp,i,outty,t,pl) ->
 302         C.MutCase (sp, i, deliftaux k outty, deliftaux k t,
 303          List.map (deliftaux k) pl)
 304      | C.Fix (i, fl) ->
 305         let len = List.length fl in
 306         let liftedfl =
 307          List.map
 308           (fun (name, i, ty, bo) ->
 309            (name, i, deliftaux k ty, deliftaux (k+len) bo))
 310            fl
 311         in
 312          C.Fix (i, liftedfl)
 313      | C.CoFix (i, fl) ->
 314         let len = List.length fl in
 315         let liftedfl =
 316          List.map
 317           (fun (name, ty, bo) -> (name, deliftaux k ty, deliftaux (k+len) bo))
 318            fl
 319         in
 320          C.CoFix (i, liftedfl)
 321   in
 322    let res =
 323     try
 324      deliftaux 0 t
 325     with
 326      NotInTheList ->
 327       (* This is the case where we fail even first order unification. *)
 328       (* The reason is that our delift function is weaker than first  *)
 329       (* order (in the sense of alpha-conversion). See comment above  *)
 330       (* related to the delift function.                              *)
 331 debug_print "!!!!!!!!!!! First Order UnificationFailure, but maybe it could have been successful even in a first order setting (no conversion, only alpha convertibility)! Please, implement a better delift function !!!!!!!!!!!!!!!!" ;
 332       raise (MetaSubstFailure (sprintf
 333         "Error trying to abstract %s over [%s]: the algorithm only tried to abstract over bound variables"
 334         (CicPp.ppterm t)
 335         (String.concat "; "
 336           (List.map
 337             (function Some t -> CicPp.ppterm t | None -> "_")
 338             l))))
 339    in
 340    let (metasenv, subst) = restrict subst !to_be_restricted metasenv in
 341     res, metasenv, subst
 342 ;;
 343
 344 (**** END OF DELIFT ****)
 345
 346 let apply_subst_gen ~appl_fun subst term =
 347  let rec um_aux =
 348   let module C = Cic in
 349   let module S = CicSubstitution in
 350    function
 351       C.Rel _ as t -> t
 352     | C.Var _  as t -> t
 353     | C.Meta (i, l) ->
 354         (try
 355           let t = List.assoc i subst in
 356           um_aux (S.lift_meta l t)
 357         with Not_found -> (* not constrained variable, i.e. free in subst*)
 358           let l' =
 359             List.map (function None -> None | Some t -> Some (um_aux t)) l
 360           in
 361            C.Meta (i,l'))
 362     | C.Sort _ as t -> t
 363     | C.Implicit -> assert false
 364     | C.Cast (te,ty) -> C.Cast (um_aux te, um_aux ty)
 365     | C.Prod (n,s,t) -> C.Prod (n, um_aux s, um_aux t)
 366     | C.Lambda (n,s,t) -> C.Lambda (n, um_aux s, um_aux t)
 367     | C.LetIn (n,s,t) -> C.LetIn (n, um_aux s, um_aux t)
 368     | C.Appl (hd :: tl) -> appl_fun um_aux hd tl
 369     | C.Appl _ -> assert false
 370     | C.Const (uri,exp_named_subst) ->
 371        let exp_named_subst' =
 372          List.map (fun (uri, t) -> (uri, um_aux t)) exp_named_subst
 373        in
 374        C.Const (uri, exp_named_subst')
 375     | C.MutInd (uri,typeno,exp_named_subst) ->
 376        let exp_named_subst' =
 377          List.map (fun (uri, t) -> (uri, um_aux t)) exp_named_subst
 378        in
 379        C.MutInd (uri,typeno,exp_named_subst')
 380     | C.MutConstruct (uri,typeno,consno,exp_named_subst) ->
 381        let exp_named_subst' =
 382          List.map (fun (uri, t) -> (uri, um_aux t)) exp_named_subst
 383        in
 384        C.MutConstruct (uri,typeno,consno,exp_named_subst')
 385     | C.MutCase (sp,i,outty,t,pl) ->
 386        let pl' = List.map um_aux pl in
 387        C.MutCase (sp, i, um_aux outty, um_aux t, pl')
 388     | C.Fix (i, fl) ->
 389        let fl' =
 390          List.map (fun (name, i, ty, bo) -> (name, i, um_aux ty, um_aux bo)) fl
 391        in
 392        C.Fix (i, fl')
 393     | C.CoFix (i, fl) ->
 394        let fl' =
 395          List.map (fun (name, ty, bo) -> (name, um_aux ty, um_aux bo)) fl
 396        in
 397        C.CoFix (i, fl')
 398  in
 399  um_aux term
 400
 401 let apply_subst =
 402   let appl_fun um_aux he tl =
 403     let tl' = List.map um_aux tl in
 404       begin
 405        match um_aux he with
 406           Cic.Appl l -> Cic.Appl (l@tl')
 407         | he' -> Cic.Appl (he'::tl')
 408       end
 409   in
 410   apply_subst_gen ~appl_fun
 411
 412 let ppterm subst term = CicPp.ppterm (apply_subst subst term)
 413
 414 (* apply_subst_reducing subst (Some (mtr,reductions_no)) t              *)
 415 (* performs as (apply_subst subst t) until it finds an application of   *)
 416 (* (META [meta_to_reduce]) that, once unwinding is performed, creates   *)
 417 (* a new beta-redex; in this case up to [reductions_no] consecutive     *)
 418 (* beta-reductions are performed.                                       *)
 419 (* Hint: this function is usually called when [reductions_no]           *)
 420 (*  eta-expansions have been performed and the head of the new          *)
 421 (*  application has been unified with (META [meta_to_reduce]):          *)
 422 (*  during the unwinding the eta-expansions are undone.                 *)
 423
 424 let apply_subst_reducing meta_to_reduce =
 425   let appl_fun um_aux he tl =
 426     let tl' = List.map um_aux tl in
 427     let t' =
 428      match um_aux he with
 429         Cic.Appl l -> Cic.Appl (l@tl')
 430       | he' -> Cic.Appl (he'::tl')
 431     in
 432      begin
 433       match meta_to_reduce, he with
 434          Some (mtr,reductions_no), Cic.Meta (m,_) when m = mtr ->
 435           let rec beta_reduce =
 436            function
 437               (n,(Cic.Appl (Cic.Lambda (_,_,t)::he'::tl'))) when n > 0 ->
 438                 let he'' = CicSubstitution.subst he' t in
 439                  if tl' = [] then
 440                   he''
 441                  else
 442                   beta_reduce (n-1,Cic.Appl(he''::tl'))
 443             | (_,t) -> t
 444           in
 445            beta_reduce (reductions_no,t')
 446        | _,_ -> t'
 447      end
 448   in
 449   apply_subst_gen ~appl_fun
 450
 451 let rec apply_subst_context subst context =
 452   List.fold_right
 453     (fun item context ->
 454       match item with
 455       | Some (n, Cic.Decl t) ->
 456           let t' = apply_subst subst t in
 457           Some (n, Cic.Decl t') :: context
 458       | Some (n, Cic.Def (t, ty)) ->
 459           let ty' =
 460             match ty with
 461             | None -> None
 462             | Some ty -> Some (apply_subst subst ty)
 463           in
 464           let t' = apply_subst subst t in
 465           Some (n, Cic.Def (t', ty')) :: context
 466       | None -> None :: context)
 467     context []
 468
 469 let apply_subst_metasenv subst metasenv =
 470   List.map
 471     (fun (n, context, ty) ->
 472       (n, apply_subst_context subst context, apply_subst subst ty))
 473     (List.filter
 474       (fun (i, _, _) -> not (List.exists (fun (j, _) -> (j = i)) subst))
 475       metasenv)
 476
 477 let ppterm subst term = CicPp.ppterm (apply_subst subst term)
 478
 479 let ppterm_in_context subst term name_context =
 480  CicPp.pp (apply_subst subst term) name_context
 481
 482 let ppcontext' ?(sep = "\n") subst context =
 483  let separate s = if s = "" then "" else s ^ sep in
 484   List.fold_right
 485    (fun context_entry (i,name_context) ->
 486      match context_entry with
 487         Some (n,Cic.Decl t) ->
 488          sprintf "%s%s : %s" (separate i) (CicPp.ppname n)
 489           (ppterm_in_context subst t name_context), (Some n)::name_context
 490       | Some (n,Cic.Def (bo,ty)) ->
 491          sprintf "%s%s : %s := %s" (separate i) (CicPp.ppname n)
 492           (match ty with
 493               None -> "_"
 494             | Some ty -> ppterm_in_context subst ty name_context)
 495           (ppterm_in_context subst bo name_context), (Some n)::name_context
 496        | None ->
 497           sprintf "%s_ :? _" (separate i), None::name_context
 498     ) context ("",[])
 499
 500 let ppcontext ?sep subst context = fst (ppcontext' ?sep subst context)
 501
 502 let ppmetasenv ?(sep = "\n") metasenv subst =
 503   String.concat sep
 504     (List.map
 505       (fun (i, c, t) ->
 506         let context,name_context = ppcontext' ~sep:"; " subst c in
 507          sprintf "%s |- ?%d: %s" context i
 508           (ppterm_in_context subst t name_context))
 509       (List.filter
 510         (fun (i, _, _) -> not (List.exists (fun (j, _) -> (j = i)) subst))
 511         metasenv))
 512
 513 (* UNWIND THE MGU INSIDE THE MGU *)
 514 (*
 515 let unwind_subst metasenv subst =
 516   List.fold_left
 517    (fun (unwinded,metasenv) (i,_) ->
 518      let (_,canonical_context,_) = CicUtil.lookup_meta i metasenv in
 519      let identity_relocation_list =
 520       CicMkImplicit.identity_relocation_list_for_metavariable canonical_context
 521      in
 522       let (_,metasenv',subst') =
 523        unwind metasenv subst unwinded (Cic.Meta (i,identity_relocation_list))
 524       in
 525        subst',metasenv'
 526    ) ([],metasenv) subst
 527 *)
 528
 529 (* From now on we recreate a kernel abstraction where substitutions are part of
 530  * the calculus *)
 531
 532 let lift subst n term =
 533   let term = apply_subst subst term in
 534   try
 535     CicSubstitution.lift n term
 536   with e ->
 537     raise (MetaSubstFailure ("Lift failure: " ^ Printexc.to_string e))
 538
 539 let subst subst t1 t2 =
 540   let t1 = apply_subst subst t1 in
 541   let t2 = apply_subst subst t2 in
 542   try
 543     CicSubstitution.subst t1 t2
 544   with e ->
 545     raise (MetaSubstFailure ("Subst failure: " ^ Printexc.to_string e))
 546
 547 let whd subst context term =
 548   let term = apply_subst subst term in
 549   let context = apply_subst_context subst context in
 550   try
 551     CicReduction.whd context term
 552   with e ->
 553     raise (MetaSubstFailure ("Weak head reduction failure: " ^
 554       Printexc.to_string e))
 555
 556 let are_convertible subst context t1 t2 =
 557   let context = apply_subst_context subst context in
 558   let t1 = apply_subst subst t1 in
 559   let t2 = apply_subst subst t2 in
 560   CicReduction.are_convertible context t1 t2
 561
 562 let type_of_aux' metasenv subst context term =
 563   let term = apply_subst subst term in
 564   let context = apply_subst_context subst context in
 565   let metasenv =
 566     List.map
 567       (fun (i, c, t) -> (i, apply_subst_context subst c, apply_subst subst t))
 568       (List.filter
 569         (fun (i, _, _) -> not (List.exists (fun (j, _) -> (j = i)) subst))
 570         metasenv)
 571   in
 572   try
 573     CicTypeChecker.type_of_aux' metasenv context term
 574   with CicTypeChecker.TypeCheckerFailure msg ->
 575     raise (MetaSubstFailure ("Type checker failure: " ^ msg))
 576